| 1 | MODULE sbcfwb |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcfwb *** |
|---|
| 4 | !! Ocean fluxes : domain averaged freshwater budget |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 2001-02 (E. Durand) Original code |
|---|
| 7 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-08 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-07 (C. Talandier) emp mean s spread over erp area |
|---|
| 10 | !! 3.6 ! 2014-11 (P. Mathiot ) add ice shelf melting |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! sbc_fwb : freshwater budget for global ocean configurations |
|---|
| 15 | !! in free surface and forced mode |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE sbc_oce ! surface ocean boundary condition |
|---|
| 20 | USE phycst ! physical constants |
|---|
| 21 | USE sbcrnf ! ocean runoffs |
|---|
| 22 | USE sbcisf ! ice shelf melting contribution |
|---|
| 23 | USE sbcssr ! SS damping terms |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE lib_mpp ! distribued memory computing library |
|---|
| 26 | USE wrk_nemo ! work arrays |
|---|
| 27 | USE timing ! Timing |
|---|
| 28 | USE lbclnk ! ocean lateral boundary conditions |
|---|
| 29 | USE lib_fortran |
|---|
| 30 | |
|---|
| 31 | USE yomhook, ONLY: lhook, dr_hook |
|---|
| 32 | USE parkind1, ONLY: jprb, jpim |
|---|
| 33 | |
|---|
| 34 | IMPLICIT NONE |
|---|
| 35 | PRIVATE |
|---|
| 36 | |
|---|
| 37 | PUBLIC sbc_fwb ! routine called by step |
|---|
| 38 | |
|---|
| 39 | REAL(wp) :: a_fwb_b ! annual domain averaged freshwater budget |
|---|
| 40 | REAL(wp) :: a_fwb ! for 2 year before (_b) and before year. |
|---|
| 41 | REAL(wp) :: fwfold ! fwfold to be suppressed |
|---|
| 42 | REAL(wp) :: area ! global mean ocean surface (interior domain) |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "domzgr_substitute.h90" |
|---|
| 46 | # include "vectopt_loop_substitute.h90" |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 49 | !! $Id$ |
|---|
| 50 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | CONTAINS |
|---|
| 53 | |
|---|
| 54 | SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc ) |
|---|
| 55 | !!--------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE sbc_fwb *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Control the mean sea surface drift |
|---|
| 59 | !! |
|---|
| 60 | !! ** Method : several ways depending on kn_fwb |
|---|
| 61 | !! =0 no control |
|---|
| 62 | !! =1 global mean of emp set to zero at each nn_fsbc time step |
|---|
| 63 | !! =2 annual global mean corrected from previous year |
|---|
| 64 | !! =3 global mean of emp set to zero at each nn_fsbc time step |
|---|
| 65 | !! & spread out over erp area depending its sign |
|---|
| 66 | !! Note: if sea ice is embedded it is taken into account when computing the budget |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 69 | INTEGER, INTENT( in ) :: kn_fsbc ! |
|---|
| 70 | INTEGER, INTENT( in ) :: kn_fwb ! ocean time-step index |
|---|
| 71 | ! |
|---|
| 72 | INTEGER :: inum, ikty, iyear ! local integers |
|---|
| 73 | REAL(wp) :: z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp ! local scalars |
|---|
| 74 | REAL(wp) :: zsurf_neg, zsurf_pos, zsurf_tospread, zcoef ! - - |
|---|
| 75 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces |
|---|
| 76 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_tospread, zerp_cor ! - - |
|---|
| 77 | INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0 |
|---|
| 78 | INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1 |
|---|
| 79 | REAL(KIND=jprb) :: zhook_handle |
|---|
| 80 | |
|---|
| 81 | CHARACTER(LEN=*), PARAMETER :: RoutineName='SBC_FWB' |
|---|
| 82 | |
|---|
| 83 | IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle) |
|---|
| 84 | |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | ! |
|---|
| 87 | IF( nn_timing == 1 ) CALL timing_start('sbc_fwb') |
|---|
| 88 | ! |
|---|
| 89 | CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
|---|
| 90 | ! |
|---|
| 91 | IF( kt == nit000 ) THEN |
|---|
| 92 | IF(lwp) THEN |
|---|
| 93 | WRITE(numout,*) |
|---|
| 94 | WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction' |
|---|
| 95 | WRITE(numout,*) '~~~~~~~' |
|---|
| 96 | IF( kn_fwb == 1 ) WRITE(numout,*) ' instantaneously set to zero' |
|---|
| 97 | IF( kn_fwb == 2 ) WRITE(numout,*) ' adjusted from previous year budget' |
|---|
| 98 | IF( kn_fwb == 3 ) WRITE(numout,*) ' fwf set to zero and spread out over erp area' |
|---|
| 99 | ENDIF |
|---|
| 100 | ! |
|---|
| 101 | IF( kn_fwb == 3 .AND. nn_sssr /= 2 ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' ) |
|---|
| 102 | IF( kn_fwb == 3 .AND. ln_isfcav ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' ) |
|---|
| 103 | ! |
|---|
| 104 | area = glob_sum( e1e2t(:,:) * tmask(:,:,1)) ! interior global domain surface |
|---|
| 105 | ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes |
|---|
| 106 | ! and in case of no melt, it can generate HSSW. |
|---|
| 107 | ! |
|---|
| 108 | #if ! defined key_lim2 && ! defined key_lim3 && ! defined key_cice |
|---|
| 109 | snwice_mass_b(:,:) = 0.e0 ! no sea-ice model is being used : no snow+ice mass |
|---|
| 110 | snwice_mass (:,:) = 0.e0 |
|---|
| 111 | #endif |
|---|
| 112 | ! |
|---|
| 113 | ENDIF |
|---|
| 114 | |
|---|
| 115 | |
|---|
| 116 | SELECT CASE ( kn_fwb ) |
|---|
| 117 | ! |
|---|
| 118 | CASE ( 1 ) !== global mean fwf set to zero ==! |
|---|
| 119 | ! |
|---|
| 120 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
|---|
| 121 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area ! sum over the global domain |
|---|
| 122 | zcoef = z_fwf * rcp |
|---|
| 123 | emp(:,:) = emp(:,:) - z_fwf * tmask(:,:,1) |
|---|
| 124 | qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | CASE ( 2 ) !== fwf budget adjusted from the previous year ==! |
|---|
| 128 | ! |
|---|
| 129 | IF( kt == nit000 ) THEN ! initialisation |
|---|
| 130 | ! ! Read the corrective factor on precipitations (fwfold) |
|---|
| 131 | CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. ) |
|---|
| 132 | READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb |
|---|
| 133 | CLOSE( inum ) |
|---|
| 134 | fwfold = a_fwb ! current year freshwater budget correction |
|---|
| 135 | ! ! estimate from the previous year budget |
|---|
| 136 | IF(lwp)WRITE(numout,*) |
|---|
| 137 | IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear , ' freshwater budget correction = ', fwfold |
|---|
| 138 | IF(lwp)WRITE(numout,*)' year = ',iyear-1, ' freshwater budget read = ', a_fwb |
|---|
| 139 | IF(lwp)WRITE(numout,*)' year = ',iyear-2, ' freshwater budget read = ', a_fwb_b |
|---|
| 140 | ENDIF |
|---|
| 141 | ! ! Update fwfold if new year start |
|---|
| 142 | ikty = 365 * 86400 / rdttra(1) !!bug use of 365 days leap year or 360d year !!!!!!! |
|---|
| 143 | IF( MOD( kt, ikty ) == 0 ) THEN |
|---|
| 144 | a_fwb_b = a_fwb ! mean sea level taking into account the ice+snow |
|---|
| 145 | ! sum over the global domain |
|---|
| 146 | a_fwb = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) ) |
|---|
| 147 | a_fwb = a_fwb * 1.e+3 / ( area * rday * 365. ) ! convert in Kg/m3/s = mm/s |
|---|
| 148 | !!gm ! !!bug 365d year |
|---|
| 149 | fwfold = a_fwb ! current year freshwater budget correction |
|---|
| 150 | ! ! estimate from the previous year budget |
|---|
| 151 | ENDIF |
|---|
| 152 | ! |
|---|
| 153 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN ! correct the freshwater fluxes |
|---|
| 154 | zcoef = fwfold * rcp |
|---|
| 155 | emp(:,:) = emp(:,:) + fwfold * tmask(:,:,1) |
|---|
| 156 | qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
|---|
| 157 | ENDIF |
|---|
| 158 | ! |
|---|
| 159 | IF( kt == nitend .AND. lwp ) THEN ! save fwfold value in a file |
|---|
| 160 | CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea ) |
|---|
| 161 | WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb |
|---|
| 162 | CLOSE( inum ) |
|---|
| 163 | ENDIF |
|---|
| 164 | ! |
|---|
| 165 | CASE ( 3 ) !== global fwf set to zero and spread out over erp area ==! |
|---|
| 166 | ! |
|---|
| 167 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
|---|
| 168 | ztmsk_pos(:,:) = tmask_i(:,:) ! Select <0 and >0 area of erp |
|---|
| 169 | WHERE( erp < 0._wp ) ztmsk_pos = 0._wp |
|---|
| 170 | ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:) |
|---|
| 171 | ! |
|---|
| 172 | zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) ) ! Area filled by <0 and >0 erp |
|---|
| 173 | zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) ) |
|---|
| 174 | ! ! fwf global mean (excluding ocean to ice/snow exchanges) |
|---|
| 175 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area |
|---|
| 176 | ! |
|---|
| 177 | IF( z_fwf < 0._wp ) THEN ! spread out over >0 erp area to increase evaporation |
|---|
| 178 | zsurf_tospread = zsurf_pos |
|---|
| 179 | ztmsk_tospread(:,:) = ztmsk_pos(:,:) |
|---|
| 180 | ELSE ! spread out over <0 erp area to increase precipitation |
|---|
| 181 | zsurf_tospread = zsurf_neg |
|---|
| 182 | ztmsk_tospread(:,:) = ztmsk_neg(:,:) |
|---|
| 183 | ENDIF |
|---|
| 184 | ! |
|---|
| 185 | zsum_fwf = glob_sum( e1e2t(:,:) * z_fwf ) ! fwf global mean over <0 or >0 erp area |
|---|
| 186 | !!gm : zsum_fwf = z_fwf * area ??? it is right? I think so.... |
|---|
| 187 | z_fwf_nsrf = zsum_fwf / ( zsurf_tospread + rsmall ) |
|---|
| 188 | ! ! weight to respect erp field 2D structure |
|---|
| 189 | zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) ) |
|---|
| 190 | z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall ) |
|---|
| 191 | ! ! final correction term to apply |
|---|
| 192 | zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:) |
|---|
| 193 | ! |
|---|
| 194 | !!gm ===>>>> lbc_lnk should be useless as all the computation is done over the whole domain ! |
|---|
| 195 | CALL lbc_lnk( zerp_cor, 'T', 1. ) |
|---|
| 196 | ! |
|---|
| 197 | emp(:,:) = emp(:,:) + zerp_cor(:,:) |
|---|
| 198 | qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:) ! account for change to the heat budget due to fw correction |
|---|
| 199 | erp(:,:) = erp(:,:) + zerp_cor(:,:) |
|---|
| 200 | ! |
|---|
| 201 | IF( nprint == 1 .AND. lwp ) THEN ! control print |
|---|
| 202 | IF( z_fwf < 0._wp ) THEN |
|---|
| 203 | WRITE(numout,*)' z_fwf < 0' |
|---|
| 204 | WRITE(numout,*)' SUM(erp+) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 205 | ELSE |
|---|
| 206 | WRITE(numout,*)' z_fwf >= 0' |
|---|
| 207 | WRITE(numout,*)' SUM(erp-) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 208 | ENDIF |
|---|
| 209 | WRITE(numout,*)' SUM(empG) = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 210 | WRITE(numout,*)' z_fwf = ', z_fwf ,' Kg/m2/s' |
|---|
| 211 | WRITE(numout,*)' z_fwf_nsrf = ', z_fwf_nsrf ,' Kg/m2/s' |
|---|
| 212 | WRITE(numout,*)' MIN(zerp_cor) = ', MINVAL(zerp_cor) |
|---|
| 213 | WRITE(numout,*)' MAX(zerp_cor) = ', MAXVAL(zerp_cor) |
|---|
| 214 | ENDIF |
|---|
| 215 | ENDIF |
|---|
| 216 | ! |
|---|
| 217 | CASE DEFAULT !== you should never be there ==! |
|---|
| 218 | CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' ) |
|---|
| 219 | ! |
|---|
| 220 | END SELECT |
|---|
| 221 | ! |
|---|
| 222 | CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
|---|
| 223 | ! |
|---|
| 224 | IF( nn_timing == 1 ) CALL timing_stop('sbc_fwb') |
|---|
| 225 | ! |
|---|
| 226 | IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle) |
|---|
| 227 | END SUBROUTINE sbc_fwb |
|---|
| 228 | |
|---|
| 229 | !!====================================================================== |
|---|
| 230 | END MODULE sbcfwb |
|---|
