Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

dynhpg.F90 @ 6389

Last change on this file since 6389 was 5954, checked in by rfurner, 9 years ago
added surge code from 2014_Surge_Modelling branch
Property svn:keywords set to `Id`
File size: 79.6 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6? ! 2014-09 (H. Liu) add Wetting/Drying pressure filter
19	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE sbc_oce ! surface variable (only for the flag with ice shelf)
35	USE dom_oce ! ocean space and time domain
36	USE phycst ! physical constants
37	USE trd_oce ! trends: ocean variables
38	USE trddyn ! trend manager: dynamics
39	!
40	USE in_out_manager ! I/O manager
41	USE prtctl ! Print control
42	USE lbclnk ! lateral boundary condition
43	USE lib_mpp ! MPP library
44	USE eosbn2 ! compute density
45	USE wrk_nemo ! Memory Allocation
46	USE timing ! Timing
47
48	IMPLICIT NONE
49	PRIVATE
50
51	PUBLIC dyn_hpg ! routine called by step module
52	PUBLIC dyn_hpg_init ! routine called by opa module
53
54	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
56	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
57	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
58	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
59	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
60	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
61	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
62
63	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65	!! * Substitutions
66	# include "domzgr_substitute.h90"
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE dyn_hpg( kt )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE dyn_hpg *
78	!!
79	!! ** Method : Call the hydrostatic pressure gradient routine
80	!! using the scheme defined in the namelist
81	!!
82	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84	!!----------------------------------------------------------------------
85	INTEGER, INTENT(in) :: kt ! ocean time-step index
86	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
87	!!----------------------------------------------------------------------
88	!
89	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
90	!
91	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
92	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93	ztrdu(:,:,:) = ua(:,:,:)
94	ztrdv(:,:,:) = va(:,:,:)
95	ENDIF
96	!
97	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
98	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
99	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
100	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
101	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
102	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
103	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
104	END SELECT
105	!
106	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111	ENDIF
112	!
113	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
114	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
115	!
116	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
117	!
118	END SUBROUTINE dyn_hpg
119
120
121	SUBROUTINE dyn_hpg_init
122	!!----------------------------------------------------------------------
123	!! * ROUTINE dyn_hpg_init *
124	!!
125	!! ** Purpose : initializations for the hydrostatic pressure gradient
126	!! computation and consistency control
127	!!
128	!! ** Action : Read the namelist namdyn_hpg and check the consistency
129	!! with the type of vertical coordinate used (zco, zps, sco)
130	!!----------------------------------------------------------------------
131	INTEGER :: ioptio = 0 ! temporary integer
132	INTEGER :: ios ! Local integer output status for namelist read
133	!!
134	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
135	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
136	!!----------------------------------------------------------------------
137	!
138	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
139	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
140	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
141
142	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
143	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
144	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
145	IF(lwm) WRITE ( numond, namdyn_hpg )
146	!
147	IF(lwp) THEN ! Control print
148	WRITE(numout,*)
149	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
150	WRITE(numout,*) '~~~~~~~~~~~~'
151	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
152	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
153	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
154	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
155	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
156	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
157	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
158	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
159	ENDIF
160	!
161	IF( ln_hpg_djc ) &
162	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
163	& currently disabled (bugs under investigation). Please select &
164	& either ln_hpg_sco or ln_hpg_prj instead')
165	!
166	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
167	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
168	& the standard jacobian formulation hpg_sco or &
169	& the pressure jacobian formulation hpg_prj')
170
171	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
172	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
173	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
174	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
175	!
176	! ! Set nhpg from ln_hpg_... flags
177	IF( ln_hpg_zco ) nhpg = 0
178	IF( ln_hpg_zps ) nhpg = 1
179	IF( ln_hpg_sco ) nhpg = 2
180	IF( ln_hpg_djc ) nhpg = 3
181	IF( ln_hpg_prj ) nhpg = 4
182	IF( ln_hpg_isf ) nhpg = 5
183	!
184	! ! Consistency check
185	ioptio = 0
186	IF( ln_hpg_zco ) ioptio = ioptio + 1
187	IF( ln_hpg_zps ) ioptio = ioptio + 1
188	IF( ln_hpg_sco ) ioptio = ioptio + 1
189	IF( ln_hpg_djc ) ioptio = ioptio + 1
190	IF( ln_hpg_prj ) ioptio = ioptio + 1
191	IF( ln_hpg_isf ) ioptio = ioptio + 1
192	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
193	!
194	! initialisation of ice load
195	riceload(:,:)=0.0
196	!
197	END SUBROUTINE dyn_hpg_init
198
199
200	SUBROUTINE hpg_zco( kt )
201	!!---------------------------------------------------------------------
202	!! * ROUTINE hpg_zco *
203	!!
204	!! ** Method : z-coordinate case, levels are horizontal surfaces.
205	!! The now hydrostatic pressure gradient at a given level, jk,
206	!! is computed by taking the vertical integral of the in-situ
207	!! density gradient along the model level from the suface to that
208	!! level: zhpi = grav .....
209	!! zhpj = grav .....
210	!! add it to the general momentum trend (ua,va).
211	!! ua = ua - 1/e1u * zhpi
212	!! va = va - 1/e2v * zhpj
213	!!
214	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
215	!!----------------------------------------------------------------------
216	INTEGER, INTENT(in) :: kt ! ocean time-step index
217	!!
218	INTEGER :: ji, jj, jk ! dummy loop indices
219	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
220	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
221	!!----------------------------------------------------------------------
222	!
223	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
224	!
225	IF( kt == nit000 ) THEN
226	IF(lwp) WRITE(numout,*)
227	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
228	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
229	ENDIF
230
231	zcoef0 = - grav * 0.5_wp ! Local constant initialization
232
233	! Surface value
234	DO jj = 2, jpjm1
235	DO ji = fs_2, fs_jpim1 ! vector opt.
236	zcoef1 = zcoef0 * fse3w(ji,jj,1)
237	! hydrostatic pressure gradient
238	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
239	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
240	! add to the general momentum trend
241	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
242	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
243	END DO
244	END DO
245
246	!
247	! interior value (2=<jk=<jpkm1)
248	DO jk = 2, jpkm1
249	DO jj = 2, jpjm1
250	DO ji = fs_2, fs_jpim1 ! vector opt.
251	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252	! hydrostatic pressure gradient
253	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
254	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
255	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
256
257	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
258	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
259	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
260	! add to the general momentum trend
261	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263	END DO
264	END DO
265	END DO
266	!
267	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268	!
269	END SUBROUTINE hpg_zco
270
271
272	SUBROUTINE hpg_zps( kt )
273	!!---------------------------------------------------------------------
274	!! * ROUTINE hpg_zps *
275	!!
276	!! ** Method : z-coordinate plus partial steps case. blahblah...
277	!!
278	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
279	!!----------------------------------------------------------------------
280	INTEGER, INTENT(in) :: kt ! ocean time-step index
281	!!
282	INTEGER :: ji, jj, jk ! dummy loop indices
283	INTEGER :: iku, ikv ! temporary integers
284	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
285	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
286	!!----------------------------------------------------------------------
287	!
288	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289	!
290	IF( kt == nit000 ) THEN
291	IF(lwp) WRITE(numout,*)
292	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
294	ENDIF
295
296
297	! Local constant initialization
298	zcoef0 = - grav * 0.5_wp
299
300	! Surface value (also valid in partial step case)
301	DO jj = 2, jpjm1
302	DO ji = fs_2, fs_jpim1 ! vector opt.
303	zcoef1 = zcoef0 * fse3w(ji,jj,1)
304	! hydrostatic pressure gradient
305	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
306	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
307	! add to the general momentum trend
308	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
309	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
310	END DO
311	END DO
312
313
314	! interior value (2=<jk=<jpkm1)
315	DO jk = 2, jpkm1
316	DO jj = 2, jpjm1
317	DO ji = fs_2, fs_jpim1 ! vector opt.
318	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
319	! hydrostatic pressure gradient
320	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
321	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
322	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
323
324	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
325	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
326	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
327	! add to the general momentum trend
328	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
329	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
330	END DO
331	END DO
332	END DO
333
334
335	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
336	DO jj = 2, jpjm1
337	DO ji = 2, jpim1
338	iku = mbku(ji,jj)
339	ikv = mbkv(ji,jj)
340	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
341	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
342	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
343	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
344	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
345	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
347	ENDIF
348	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
349	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
350	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
351	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
353	ENDIF
354	END DO
355	END DO
356	!
357	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
358	!
359	END SUBROUTINE hpg_zps
360
361	SUBROUTINE hpg_sco( kt )
362	!!---------------------------------------------------------------------
363	!! * ROUTINE hpg_sco *
364	!!
365	!! ** Method : s-coordinate case. Jacobian scheme.
366	!! The now hydrostatic pressure gradient at a given level, jk,
367	!! is computed by taking the vertical integral of the in-situ
368	!! density gradient along the model level from the suface to that
369	!! level. s-coordinates (ln_sco): a corrective term is added
370	!! to the horizontal pressure gradient :
371	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
372	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
373	!! add it to the general momentum trend (ua,va).
374	!! ua = ua - 1/e1u * zhpi
375	!! va = va - 1/e2v * zhpj
376	!!
377	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
378	!!----------------------------------------------------------------------
379	INTEGER, INTENT(in) :: kt ! ocean time-step index
380	!!
381	INTEGER :: ji, jj, jk ! dummy loop indices
382	REAL(wp) :: zcoef0, zuap, zvap, znad, ztmp ! temporary scalars
383	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
384	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
385	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
386	!!----------------------------------------------------------------------
387	!
388	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
389	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
390	!
391	IF( kt == nit000 ) THEN
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
394	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
395	ENDIF
396
397	! Local constant initialization
398	zcoef0 = - grav * 0.5_wp
399	! To use density and not density anomaly
400	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
401	ELSE ; znad = 0._wp ! Fixed volume
402	ENDIF
403
404	IF(ln_wd) THEN
405	DO jj = 2, jpjm1
406	DO ji = 2, jpim1
407	IF ( tmask(ji+1,jj,1) == 0._wp) THEN
408	zcpx(ji,jj) = 1.0_wp
409	ELSE
410	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
411	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
412	& rn_wdmin1 + rn_wdmin2
413
414	IF(ll_tmp1) THEN
415	zcpx(ji,jj) = 1.0_wp
416	ELSE IF(ll_tmp2) THEN
417	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
418	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
419	& (sshn(ji+1,jj) - sshn(ji,jj)))
420	ELSE
421	zcpx(ji,jj) = 0._wp
422	END IF
423	ENDIF
424
425	IF ( tmask(ji,jj+1,1) == 0._wp) THEN
426	zcpy(ji,jj) = 1.0_wp
427	ELSE
428	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
429	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
430	& rn_wdmin1 + rn_wdmin2
431
432	IF(ll_tmp1) THEN
433	zcpy(ji,jj) = 1.0_wp
434	ELSE IF(ll_tmp2) THEN
435	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
436	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
437	& (sshn(ji,jj+1) - sshn(ji,jj)))
438	ELSE
439	zcpy(ji,jj) = 0._wp
440	END IF
441	ENDIF
442	END DO
443	END DO
444	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
445	ENDIF
446
447	#if defined key_surge
448	! Surface value
449	DO jj = 2, jpjm1
450	DO ji = fs_2, fs_jpim1 ! vector opt.
451	! hydrostatic pressure gradient along s-surfaces
452	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad ) &
453	& - fse3w(ji ,jj ,1) * ( znad ) )
454	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad ) &
455	& - fse3w(ji ,jj ,1) * ( znad ) )
456	! s-coordinate pressure gradient correction
457	zuap = -zcoef0 * ( 2._wp * znad ) &
458	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
459	zvap = -zcoef0 * ( 2._wp * znad ) &
460	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
461
462	IF(ln_wd) THEN
463	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
464	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
465	zuap = zuap * zcpx(ji,jj)
466	zvap = zvap * zcpy(ji,jj)
467	ENDIF
468
469	! add to the general momentum trend
470	ua(ji,jj,1) = ua(ji,jj,1) + ( zhpi(ji,jj,1) + zuap ) * umask(ji,jj,1)
471	va(ji,jj,1) = va(ji,jj,1) + ( zhpj(ji,jj,1) + zvap ) * vmask(ji,jj,1)
472	END DO
473	END DO
474
475	! interior value (2=<jk=<jpkm1)
476	DO jk = 2, jpkm1
477	DO jj = 2, jpjm1
478	DO ji = fs_2, fs_jpim1 ! vector opt.
479	! hydrostatic pressure gradient along s-surfaces
480	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
481	& * ( fse3w(ji+1,jj,jk) * ( 2*znad ) &
482	& - fse3w(ji ,jj,jk) * ( 2*znad ) )
483	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
484	& * ( fse3w(ji,jj+1,jk) * ( 2*znad ) &
485	& - fse3w(ji,jj ,jk) * ( 2*znad ) )
486	! s-coordinate pressure gradient correction
487	zuap = -zcoef0 * ( 2._wp * znad ) &
488	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
489	zvap = -zcoef0 * ( 2._wp * znad ) &
490	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
491
492	IF(ln_wd) THEN
493	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
494	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
495	zuap = zuap * zcpx(ji,jj)
496	zvap = zvap * zcpy(ji,jj)
497	ENDIF
498
499	! add to the general momentum trend
500	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap ) * umask(ji,jj,jk)
501	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
502	END DO
503	END DO
504	END DO
505	!
506	#else
507	! Surface value
508	DO jj = 2, jpjm1
509	DO ji = fs_2, fs_jpim1 ! vector opt.
510	! hydrostatic pressure gradient along s-surfaces
511	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
512	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
513	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
514	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
515	! s-coordinate pressure gradient correction
516	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
517	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
518	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
519	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
520
521	IF(ln_wd) THEN
522	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
523	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
524	zuap = zuap * zcpx(ji,jj)
525	zvap = zvap * zcpy(ji,jj)
526	ENDIF
527
528	! add to the general momentum trend
529	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
530	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
531	END DO
532	END DO
533
534	! interior value (2=<jk=<jpkm1)
535	DO jk = 2, jpkm1
536	DO jj = 2, jpjm1
537	DO ji = fs_2, fs_jpim1 ! vector opt.
538	! hydrostatic pressure gradient along s-surfaces
539	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
540	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
541	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
542	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
543	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
544	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
545	! s-coordinate pressure gradient correction
546	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
547	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
548	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
549	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
550
551	IF(ln_wd) THEN
552	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
553	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
554	zuap = zuap * zcpx(ji,jj)
555	zvap = zvap * zcpy(ji,jj)
556	ENDIF
557
558	! add to the general momentum trend
559	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
560	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
561	END DO
562	END DO
563	END DO
564	#endif
565	!
566
567	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
568	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
569	!
570	END SUBROUTINE hpg_sco
571
572	SUBROUTINE hpg_isf( kt )
573	!!---------------------------------------------------------------------
574	!! * ROUTINE hpg_sco *
575	!!
576	!! ** Method : s-coordinate case. Jacobian scheme.
577	!! The now hydrostatic pressure gradient at a given level, jk,
578	!! is computed by taking the vertical integral of the in-situ
579	!! density gradient along the model level from the suface to that
580	!! level. s-coordinates (ln_sco): a corrective term is added
581	!! to the horizontal pressure gradient :
582	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
583	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
584	!! add it to the general momentum trend (ua,va).
585	!! ua = ua - 1/e1u * zhpi
586	!! va = va - 1/e2v * zhpj
587	!! iceload is added and partial cell case are added to the top and bottom
588	!!
589	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
590	!!----------------------------------------------------------------------
591	INTEGER, INTENT(in) :: kt ! ocean time-step index
592	!!
593	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
594	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
595	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
596	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
597	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
598	!!----------------------------------------------------------------------
599	!
600	CALL wrk_alloc( jpi,jpj, 2, ztstop)
601	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
602	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
603	!
604	IF( kt == nit000 ) THEN
605	IF(lwp) WRITE(numout,*)
606	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
607	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
608	ENDIF
609
610	! Local constant initialization
611	zcoef0 = - grav * 0.5_wp
612	! To use density and not density anomaly
613	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
614	! ELSE ; znad = 0._wp ! Fixed volume
615	! ENDIF
616	znad=1._wp
617	! iniitialised to 0. zhpi zhpi
618	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
619
620	!==================================================================================
621	!=====Compute iceload and contribution of the half first wet layer =================
622	!===================================================================================
623
624	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
625	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
626
627	! compute density of the water displaced by the ice shelf
628	zrhd = rhd ! save rhd
629	DO jk = 1, jpk
630	zdept(:,:)=gdept_1d(jk)
631	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
632	END DO
633	WHERE ( tmask(:,:,:) == 1._wp)
634	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
635	END WHERE
636
637	! compute rhd at the ice/oce interface (ice shelf side)
638	CALL eos(ztstop,risfdep,zrhdtop_isf)
639
640	! compute rhd at the ice/oce interface (ocean side)
641	DO ji=1,jpi
642	DO jj=1,jpj
643	ikt=mikt(ji,jj)
644	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
645	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
646	END DO
647	END DO
648	CALL eos(ztstop,risfdep,zrhdtop_oce)
649	!
650	! Surface value + ice shelf gradient
651	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
652	ziceload = 0._wp
653	DO jj = 1, jpj
654	DO ji = 1, jpi ! vector opt.
655	ikt=mikt(ji,jj)
656	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
657	DO jk=2,ikt-1
658	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
659	& * (1._wp - tmask(ji,jj,jk))
660	END DO
661	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
662	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
663	END DO
664	END DO
665	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
666	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
667	DO jj = 2, jpjm1
668	DO ji = fs_2, fs_jpim1 ! vector opt.
669	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
670	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
671	! we assume ISF is in isostatic equilibrium
672	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
673	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
674	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
675	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
676	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
677	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
678	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
679	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
680	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
681	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
682	! s-coordinate pressure gradient correction (=0 if z coordinate)
683	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
684	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
685	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
686	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
687	! add to the general momentum trend
688	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
689	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
690	END DO
691	END DO
692	!==================================================================================
693	!===== Compute partial cell contribution for the top cell =========================
694	!==================================================================================
695	DO jj = 2, jpjm1
696	DO ji = fs_2, fs_jpim1 ! vector opt.
697	iku = miku(ji,jj) ;
698	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
699	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
700	! u direction
701	IF ( iku .GT. 1 ) THEN
702	! case iku
703	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
704	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
705	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
706	! corrective term ( = 0 if z coordinate )
707	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
708	! zhpi will be added in interior loop
709	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
710	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
711	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
712
713	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
714	zhpiint = zcoef0 / e1u(ji,jj) &
715	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
716	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
717	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
718	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
719	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
720	END IF
721
722	! v direction
723	ikv = mikv(ji,jj)
724	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
725	IF ( ikv .GT. 1 ) THEN
726	! case ikv
727	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
728	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
729	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
730	! corrective term ( = 0 if z coordinate )
731	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
732	! zhpi will be added in interior loop
733	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
734	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
735	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
736
737	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
738	zhpjint = zcoef0 / e2v(ji,jj) &
739	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
740	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
741	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
742	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
743	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
744	END IF
745	END DO
746	END DO
747
748	!==================================================================================
749	!===== Compute interior value =====================================================
750	!==================================================================================
751
752	DO jj = 2, jpjm1
753	DO ji = fs_2, fs_jpim1 ! vector opt.
754	iku=miku(ji,jj); ikv=mikv(ji,jj)
755	DO jk = 2, jpkm1
756	! hydrostatic pressure gradient along s-surfaces
757	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
758	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
759	& + zcoef0 / e1u(ji,jj) &
760	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
761	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
762	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
763	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
764	! s-coordinate pressure gradient correction
765	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
766	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
767	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
768	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
769
770	! hydrostatic pressure gradient along s-surfaces
771	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
772	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
773	& + zcoef0 / e2v(ji,jj) &
774	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
775	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
776	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
777	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
778	! s-coordinate pressure gradient correction
779	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
780	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
781	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
782	! add to the general momentum trend
783	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
784	END DO
785	END DO
786	END DO
787
788	!==================================================================================
789	!===== Compute bottom cell contribution (partial cell) ============================
790	!==================================================================================
791
792	DO jj = 2, jpjm1
793	DO ji = 2, jpim1
794	iku = mbku(ji,jj)
795	ikv = mbkv(ji,jj)
796
797	IF (iku .GT. 1) THEN
798	! remove old value (interior case)
799	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
800	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
801	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
802	! put new value
803	! -zpshpi to avoid double contribution of the partial step in the top layer
804	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
805	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
806	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
807	END IF
808	! v direction
809	IF (ikv .GT. 1) THEN
810	! remove old value (interior case)
811	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
812	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
813	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
814	! put new value
815	! -zpshpj to avoid double contribution of the partial step in the top layer
816	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
817	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
818	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
819	END IF
820	END DO
821	END DO
822
823	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
824	rhd = zrhd
825	!
826	CALL wrk_dealloc( jpi,jpj,2, ztstop)
827	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
828	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
829	!
830	END SUBROUTINE hpg_isf
831
832
833	SUBROUTINE hpg_djc( kt )
834	!!---------------------------------------------------------------------
835	!! * ROUTINE hpg_djc *
836	!!
837	!! ** Method : Density Jacobian with Cubic polynomial scheme
838	!!
839	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
840	!!----------------------------------------------------------------------
841	INTEGER, INTENT(in) :: kt ! ocean time-step index
842	!!
843	INTEGER :: ji, jj, jk ! dummy loop indices
844	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
845	REAL(wp) :: z1_10, cffu, cffx ! " "
846	REAL(wp) :: z1_12, cffv, cffy ! " "
847	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
848	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
849	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
850	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
851	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
852	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
853	!!----------------------------------------------------------------------
854	!
855	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
856	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
857	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
858	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
859	!
860
861	IF( kt == nit000 ) THEN
862	IF(lwp) WRITE(numout,*)
863	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
864	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
865	ENDIF
866
867	IF(ln_wd) THEN
868	DO jj = 2, jpjm1
869	DO ji = 2, jpim1
870	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
871	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
872	& rn_wdmin1 + rn_wdmin2
873
874	IF(ll_tmp1) THEN
875	zcpx(ji,jj) = 1.0_wp
876	ELSE IF(ll_tmp2) THEN
877	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
878	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
879	& (sshn(ji+1,jj) - sshn(ji,jj)))
880	ELSE
881	zcpx(ji,jj) = 0._wp
882	END IF
883
884	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
885	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
886	& rn_wdmin1 + rn_wdmin2
887
888	IF(ll_tmp1) THEN
889	zcpy(ji,jj) = 1.0_wp
890	ELSE IF(ll_tmp2) THEN
891	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
892	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
893	& (sshn(ji,jj+1) - sshn(ji,jj)))
894	ELSE
895	zcpy(ji,jj) = 0._wp
896	END IF
897	END DO
898	END DO
899	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
900	ENDIF
901
902	! Local constant initialization
903	zcoef0 = - grav * 0.5_wp
904	z1_10 = 1._wp / 10._wp
905	z1_12 = 1._wp / 12._wp
906
907	!----------------------------------------------------------------------------------------
908	! compute and store in provisional arrays elementary vertical and horizontal differences
909	!----------------------------------------------------------------------------------------
910
911	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
912
913	DO jk = 2, jpkm1
914	DO jj = 2, jpjm1
915	DO ji = fs_2, fs_jpim1 ! vector opt.
916	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
917	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
918	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
919	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
920	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
921	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
922	END DO
923	END DO
924	END DO
925
926	!-------------------------------------------------------------------------
927	! compute harmonic averages using eq. 5.18
928	!-------------------------------------------------------------------------
929	zep = 1.e-15
930
931	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
932	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
933
934	DO jk = 2, jpkm1
935	DO jj = 2, jpjm1
936	DO ji = fs_2, fs_jpim1 ! vector opt.
937	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
938
939	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
940	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
941
942	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
943	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
944
945	IF( cffw > zep) THEN
946	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
947	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
948	ELSE
949	drhow(ji,jj,jk) = 0._wp
950	ENDIF
951
952	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
953	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
954
955	IF( cffu > zep ) THEN
956	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
957	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
958	ELSE
959	drhou(ji,jj,jk ) = 0._wp
960	ENDIF
961
962	IF( cffx > zep ) THEN
963	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
964	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
965	ELSE
966	dzu(ji,jj,jk) = 0._wp
967	ENDIF
968
969	IF( cffv > zep ) THEN
970	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
971	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
972	ELSE
973	drhov(ji,jj,jk) = 0._wp
974	ENDIF
975
976	IF( cffy > zep ) THEN
977	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
978	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
979	ELSE
980	dzv(ji,jj,jk) = 0._wp
981	ENDIF
982
983	END DO
984	END DO
985	END DO
986
987	!----------------------------------------------------------------------------------
988	! apply boundary conditions at top and bottom using 5.36-5.37
989	!----------------------------------------------------------------------------------
990	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
991	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
992	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
993
994	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
995	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
996	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
997
998
999	!--------------------------------------------------------------
1000	! Upper half of top-most grid box, compute and store
1001	!-------------------------------------------------------------
1002
1003	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
1004	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
1005
1006	DO jj = 2, jpjm1
1007	DO ji = fs_2, fs_jpim1 ! vector opt.
1008	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
1009	& * ( rhd(ji,jj,1) &
1010	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
1011	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
1012	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
1013	END DO
1014	END DO
1015
1016	!!bug gm : here also, simplification is possible
1017	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
1018
1019	DO jk = 2, jpkm1
1020	DO jj = 2, jpjm1
1021	DO ji = fs_2, fs_jpim1 ! vector opt.
1022
1023	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
1024	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
1025	& - grav * z1_10 * ( &
1026	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
1027	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
1028	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
1029	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
1030	& )
1031
1032	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
1033	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
1034	& - grav* z1_10 * ( &
1035	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
1036	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
1037	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
1038	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
1039	& )
1040
1041	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
1042	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
1043	& - grav* z1_10 * ( &
1044	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
1045	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
1046	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
1047	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
1048	& )
1049
1050	END DO
1051	END DO
1052	END DO
1053	CALL lbc_lnk(rho_k,'W',1.)
1054	CALL lbc_lnk(rho_i,'U',1.)
1055	CALL lbc_lnk(rho_j,'V',1.)
1056
1057
1058	! ---------------
1059	! Surface value
1060	! ---------------
1061	DO jj = 2, jpjm1
1062	DO ji = fs_2, fs_jpim1 ! vector opt.
1063	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
1064	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
1065	IF(ln_wd) THEN
1066	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
1067	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
1068	ENDIF
1069	! add to the general momentum trend
1070	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
1071	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
1072	END DO
1073	END DO
1074
1075	! ----------------
1076	! interior value (2=<jk=<jpkm1)
1077	! ----------------
1078	DO jk = 2, jpkm1
1079	DO jj = 2, jpjm1
1080	DO ji = fs_2, fs_jpim1 ! vector opt.
1081	! hydrostatic pressure gradient along s-surfaces
1082	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
1083	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
1084	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
1085	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
1086	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
1087	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
1088	IF(ln_wd) THEN
1089	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
1090	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
1091	ENDIF
1092	! add to the general momentum trend
1093	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
1094	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
1095	END DO
1096	END DO
1097	END DO
1098	!
1099	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
1100	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
1101	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
1102	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1103	!
1104	END SUBROUTINE hpg_djc
1105
1106
1107	SUBROUTINE hpg_prj( kt )
1108	!!---------------------------------------------------------------------
1109	!! * ROUTINE hpg_prj *
1110	!!
1111	!! ** Method : s-coordinate case.
1112	!! A Pressure-Jacobian horizontal pressure gradient method
1113	!! based on the constrained cubic-spline interpolation for
1114	!! all vertical coordinate systems
1115	!!
1116	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
1117	!!----------------------------------------------------------------------
1118	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
1119	INTEGER, INTENT(in) :: kt ! ocean time-step index
1120	!!
1121	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
1122	REAL(wp) :: zcoef0, znad ! temporary scalars
1123	!!
1124	!! The local variables for the correction term
1125	INTEGER :: jk1, jis, jid, jjs, jjd
1126	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
1127	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
1128	REAL(wp) :: zrhdt1
1129	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
1130	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
1131	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
1132	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
1133	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
1134	!!----------------------------------------------------------------------
1135	!
1136	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1137	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
1138	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
1139	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
1140	!
1141	IF( kt == nit000 ) THEN
1142	IF(lwp) WRITE(numout,*)
1143	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1144	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
1145	ENDIF
1146
1147	!!----------------------------------------------------------------------
1148	! Local constant initialization
1149	zcoef0 = - grav
1150	znad = 0.0_wp
1151	IF( lk_vvl ) znad = 1._wp
1152
1153	IF(ln_wd) THEN
1154	DO jj = 2, jpjm1
1155	DO ji = 2, jpim1
1156	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
1157	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
1158	& rn_wdmin1 + rn_wdmin2
1159
1160	IF(ll_tmp1) THEN
1161	zcpx(ji,jj) = 1.0_wp
1162	ELSE IF(ll_tmp2) THEN
1163	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
1164	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
1165	& (sshn(ji+1,jj) - sshn(ji,jj)))
1166	ELSE
1167	zcpx(ji,jj) = 0._wp
1168	END IF
1169
1170	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
1171	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
1172	& rn_wdmin1 + rn_wdmin2
1173
1174	IF(ll_tmp1.OR.ll_tmp2) THEN
1175	zcpy(ji,jj) = 1.0_wp
1176	ELSE IF(ll_tmp2) THEN
1177	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
1178	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
1179	& (sshn(ji,jj+1) - sshn(ji,jj)))
1180	ELSE
1181	zcpy(ji,jj) = 0._wp
1182	END IF
1183	END DO
1184	END DO
1185	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
1186	ENDIF
1187
1188	! Clean 3-D work arrays
1189	zhpi(:,:,:) = 0._wp
1190	zrhh(:,:,:) = rhd(:,:,:)
1191
1192	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1193	DO jj = 1, jpj
1194	DO ji = 1, jpi
1195	jk = mbathy(ji,jj)
1196	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1197	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1198	ELSE IF(jk < jpkm1) THEN
1199	DO jkk = jk+1, jpk
1200	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1201	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1202	END DO
1203	ENDIF
1204	END DO
1205	END DO
1206
1207	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1208	DO jj = 1, jpj
1209	DO ji = 1, jpi
1210	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1211	END DO
1212	END DO
1213
1214	DO jk = 2, jpk
1215	DO jj = 1, jpj
1216	DO ji = 1, jpi
1217	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1218	END DO
1219	END DO
1220	END DO
1221
1222	fsp(:,:,:) = zrhh (:,:,:)
1223	xsp(:,:,:) = zdept(:,:,:)
1224
1225	! Construct the vertical density profile with the
1226	! constrained cubic spline interpolation
1227	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1228	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1229
1230	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1231	DO jj = 2, jpj
1232	DO ji = 2, jpi
1233	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1234	bsp(ji,jj,1), csp(ji,jj,1), &
1235	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1236
1237	! assuming linear profile across the top half surface layer
1238	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1239	END DO
1240	END DO
1241
1242	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1243	DO jk = 2, jpkm1
1244	DO jj = 2, jpj
1245	DO ji = 2, jpi
1246	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1247	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1248	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1249	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1250	END DO
1251	END DO
1252	END DO
1253
1254	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1255
1256	! Prepare zsshu_n and zsshv_n
1257	DO jj = 2, jpjm1
1258	DO ji = 2, jpim1
1259	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1260	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1261	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1262	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1263	END DO
1264	END DO
1265
1266	CALL lbc_lnk (zsshu_n, 'U', 1.)
1267	CALL lbc_lnk (zsshv_n, 'V', 1.)
1268
1269	DO jj = 2, jpjm1
1270	DO ji = 2, jpim1
1271	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1272	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1273	END DO
1274	END DO
1275
1276	DO jk = 2, jpkm1
1277	DO jj = 2, jpjm1
1278	DO ji = 2, jpim1
1279	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1280	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1281	END DO
1282	END DO
1283	END DO
1284
1285	DO jk = 1, jpkm1
1286	DO jj = 2, jpjm1
1287	DO ji = 2, jpim1
1288	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1289	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1290	END DO
1291	END DO
1292	END DO
1293
1294	DO jk = 1, jpkm1
1295	DO jj = 2, jpjm1
1296	DO ji = 2, jpim1
1297	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1298	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1299	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1300	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1301	END DO
1302	END DO
1303	END DO
1304
1305
1306	DO jk = 1, jpkm1
1307	DO jj = 2, jpjm1
1308	DO ji = 2, jpim1
1309	zpwes = 0._wp; zpwed = 0._wp
1310	zpnss = 0._wp; zpnsd = 0._wp
1311	zuijk = zu(ji,jj,jk)
1312	zvijk = zv(ji,jj,jk)
1313
1314	!!!!! for u equation
1315	IF( jk <= mbku(ji,jj) ) THEN
1316	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1317	jis = ji + 1; jid = ji
1318	ELSE
1319	jis = ji; jid = ji +1
1320	ENDIF
1321
1322	! integrate the pressure on the shallow side
1323	jk1 = jk
1324	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1325	IF( jk1 == mbku(ji,jj) ) THEN
1326	zuijk = -zdept(jis,jj,jk1)
1327	EXIT
1328	ENDIF
1329	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1330	zpwes = zpwes + &
1331	integ_spline(zdept(jis,jj,jk1), zdeps, &
1332	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1333	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1334	jk1 = jk1 + 1
1335	END DO
1336
1337	! integrate the pressure on the deep side
1338	jk1 = jk
1339	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1340	IF( jk1 == 1 ) THEN
1341	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1342	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1343	bsp(jid,jj,1), csp(jid,jj,1), &
1344	dsp(jid,jj,1)) * zdeps
1345	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1346	EXIT
1347	ENDIF
1348	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1349	zpwed = zpwed + &
1350	integ_spline(zdeps, zdept(jid,jj,jk1), &
1351	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1352	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1353	jk1 = jk1 - 1
1354	END DO
1355
1356	! update the momentum trends in u direction
1357
1358	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1359	IF( lk_vvl ) THEN
1360	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1361	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1362	ELSE
1363	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1364	ENDIF
1365
1366	IF(ln_wd) THEN
1367	zdpdx1 = zdpdx1 * zcpx(ji,jj)
1368	zdpdx2 = zdpdx2 * zcpx(ji,jj)
1369	ENDIF
1370	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk)
1371	ENDIF
1372
1373	!!!!! for v equation
1374	IF( jk <= mbkv(ji,jj) ) THEN
1375	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1376	jjs = jj + 1; jjd = jj
1377	ELSE
1378	jjs = jj ; jjd = jj + 1
1379	ENDIF
1380
1381	! integrate the pressure on the shallow side
1382	jk1 = jk
1383	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1384	IF( jk1 == mbkv(ji,jj) ) THEN
1385	zvijk = -zdept(ji,jjs,jk1)
1386	EXIT
1387	ENDIF
1388	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1389	zpnss = zpnss + &
1390	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1391	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1392	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1393	jk1 = jk1 + 1
1394	END DO
1395
1396	! integrate the pressure on the deep side
1397	jk1 = jk
1398	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1399	IF( jk1 == 1 ) THEN
1400	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1401	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1402	bsp(ji,jjd,1), csp(ji,jjd,1), &
1403	dsp(ji,jjd,1) ) * zdeps
1404	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1405	EXIT
1406	ENDIF
1407	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1408	zpnsd = zpnsd + &
1409	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1410	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1411	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1412	jk1 = jk1 - 1
1413	END DO
1414
1415
1416	! update the momentum trends in v direction
1417
1418	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1419	IF( lk_vvl ) THEN
1420	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1421	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1422	ELSE
1423	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1424	ENDIF
1425
1426	IF(ln_wd) THEN
1427	zdpdy1 = zdpdy1 * zcpy(ji,jj)
1428	zdpdy2 = zdpdy2 * zcpy(ji,jj)
1429	ENDIF
1430
1431	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1432	ENDIF
1433
1434
1435	END DO
1436	END DO
1437	END DO
1438	!
1439	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1440	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1441	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1442	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1443	!
1444	END SUBROUTINE hpg_prj
1445
1446
1447	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1448	!!----------------------------------------------------------------------
1449	!! * ROUTINE cspline *
1450	!!
1451	!! ** Purpose : constrained cubic spline interpolation
1452	!!
1453	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1454	!!
1455	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1456	!!----------------------------------------------------------------------
1457	IMPLICIT NONE
1458	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1459	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1460	! the interpoated function
1461	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1462	! 2: Linear
1463	!
1464	INTEGER :: ji, jj, jk ! dummy loop indices
1465	INTEGER :: jpi, jpj, jpkm1
1466	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1467	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1468	REAL(wp) :: zdf(size(fsp,3))
1469	!!----------------------------------------------------------------------
1470
1471	jpi = size(fsp,1)
1472	jpj = size(fsp,2)
1473	jpkm1 = size(fsp,3) - 1
1474
1475
1476	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1477	DO ji = 1, jpi
1478	DO jj = 1, jpj
1479	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1480	! DO jk = 2, jpkm1-1
1481	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1482	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1483	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1484	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1485	!
1486	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1487	!
1488	! IF(zdf1 * zdf2 <= 0._wp) THEN
1489	! zdf(jk) = 0._wp
1490	! ELSE
1491	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1492	! ENDIF
1493	! END DO
1494
1495	!!Simply geometric average
1496	DO jk = 2, jpkm1-1
1497	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1498	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1499
1500	IF(zdf1 * zdf2 <= 0._wp) THEN
1501	zdf(jk) = 0._wp
1502	ELSE
1503	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1504	ENDIF
1505	END DO
1506
1507	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1508	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1509	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1510	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1511	& 0.5_wp * zdf(jpkm1 - 1)
1512
1513	DO jk = 1, jpkm1 - 1
1514	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1515	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1516	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1517	zddf1 = -2._wp * ztmp1 + ztmp2
1518	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1519	zddf2 = 2._wp * ztmp1 - ztmp2
1520
1521	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1522	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1523	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1524	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1525	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1526	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1527	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1528	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1529	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1530	END DO
1531	END DO
1532	END DO
1533
1534	ELSE IF (polynomial_type == 2) THEN ! Linear
1535	DO ji = 1, jpi
1536	DO jj = 1, jpj
1537	DO jk = 1, jpkm1-1
1538	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1539	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1540
1541	dsp(ji,jj,jk) = 0._wp
1542	csp(ji,jj,jk) = 0._wp
1543	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1544	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1545	END DO
1546	END DO
1547	END DO
1548
1549	ELSE
1550	CALL ctl_stop( 'invalid polynomial type in cspline' )
1551	ENDIF
1552
1553	END SUBROUTINE cspline
1554
1555
1556	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1557	!!----------------------------------------------------------------------
1558	!! * ROUTINE interp1 *
1559	!!
1560	!! ** Purpose : 1-d linear interpolation
1561	!!
1562	!! ** Method : interpolation is straight forward
1563	!! extrapolation is also permitted (no value limit)
1564	!!----------------------------------------------------------------------
1565	IMPLICIT NONE
1566	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1567	REAL(wp) :: f ! result of the interpolation (extrapolation)
1568	REAL(wp) :: zdeltx
1569	!!----------------------------------------------------------------------
1570
1571	zdeltx = xr - xl
1572	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1573	f = 0.5_wp * (fl + fr)
1574	ELSE
1575	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1576	ENDIF
1577
1578	END FUNCTION interp1
1579
1580
1581	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1582	!!----------------------------------------------------------------------
1583	!! * ROUTINE interp1 *
1584	!!
1585	!! ** Purpose : 1-d constrained cubic spline interpolation
1586	!!
1587	!! ** Method : cubic spline interpolation
1588	!!
1589	!!----------------------------------------------------------------------
1590	IMPLICIT NONE
1591	REAL(wp), INTENT(in) :: x, a, b, c, d
1592	REAL(wp) :: f ! value from the interpolation
1593	!!----------------------------------------------------------------------
1594
1595	f = a + x* ( b + x * ( c + d * x ) )
1596
1597	END FUNCTION interp2
1598
1599
1600	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1601	!!----------------------------------------------------------------------
1602	!! * ROUTINE interp1 *
1603	!!
1604	!! ** Purpose : Calculate the first order of deriavtive of
1605	!! a cubic spline function y=a+bx+cx^2+d*x^3
1606	!!
1607	!! ** Method : f=dy/dx=b+2cx+3dx^2
1608	!!
1609	!!----------------------------------------------------------------------
1610	IMPLICIT NONE
1611	REAL(wp), INTENT(in) :: x, a, b, c, d
1612	REAL(wp) :: f ! value from the interpolation
1613	!!----------------------------------------------------------------------
1614
1615	f = b + x * ( 2._wp * c + 3._wp * d * x)
1616
1617	END FUNCTION interp3
1618
1619
1620	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1621	!!----------------------------------------------------------------------
1622	!! * ROUTINE interp1 *
1623	!!
1624	!! ** Purpose : 1-d constrained cubic spline integration
1625	!!
1626	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1627	!!
1628	!!----------------------------------------------------------------------
1629	IMPLICIT NONE
1630	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1631	REAL(wp) :: za1, za2, za3
1632	REAL(wp) :: f ! integration result
1633	!!----------------------------------------------------------------------
1634
1635	za1 = 0.5_wp * b
1636	za2 = c / 3.0_wp
1637	za3 = 0.25_wp * d
1638
1639	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1640	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1641
1642	END FUNCTION integ_spline
1643
1644	!!======================================================================
1645	END MODULE dynhpg
1646

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6389

Download in other formats: