New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssr.F90 in branches/UKMO/dev_r5518_fa_am_dt_deltadelta_toa/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_fa_am_dt_deltadelta_toa/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 9991

Last change on this file since 9991 was 7051, checked in by kuniko, 8 years ago

Removed $Id ...
File size: 13.2 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr       : add to sbc a restoring term toward SST/SSS climatology
12   !!   sbc_ssr_init  : initialisation of surface restoring
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE sbc_oce        ! surface boundary condition
17   USE phycst         ! physical constants
18   USE sbcrnf         ! surface boundary condition : runoffs
19   USE sbc_arcmsk     ! surface boundary condition : runoffs & Arctic mask
20   !
21   USE fldread        ! read input fields
22   USE iom            ! I/O manager
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! distribued memory computing library
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE timing         ! Timing
27   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_ssr        ! routine called in sbcmod
33   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
34
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
37
38   !                                   !!* Namelist namsbc_ssr *
39   INTEGER, PUBLIC ::   nn_sstr         ! SST/SSS restoring indicator
40   INTEGER, PUBLIC ::   nn_sssr         ! SST/SSS restoring indicator
41   REAL(wp)        ::   rn_dqdt         ! restoring factor on SST and SSS
42   REAL(wp)        ::   rn_deds         ! restoring factor on SST and SSS
43   LOGICAL         ::   ln_sssr_bnd     ! flag to bound erp term
44   REAL(wp)        ::   rn_sssr_bnd     ! ABS(Max./Min.) value of erp term [mm/day]
45
46   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
49
50   !! * Substitutions
51#  include "domzgr_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
54   !! $Id$
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE sbc_ssr( kt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE sbc_ssr  ***
62      !!
63      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
64      !!                toward observed SST and/or SSS.
65      !!
66      !! ** Method  : - Read namelist namsbc_ssr
67      !!              - Read observed SST and/or SSS
68      !!              - at each nscb time step
69      !!                   add a retroaction term on qns    (nn_sstr = 1)
70      !!                   add a damping term on sfx        (nn_sssr = 1)
71      !!                   add a damping term on emp        (nn_sssr = 2)
72      !!---------------------------------------------------------------------
73      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
74      !!
75      INTEGER  ::   ji, jj   ! dummy loop indices
76      REAL(wp) ::   zerp     ! local scalar for evaporation damping
77      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
78      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
79      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
80      INTEGER  ::   ierror   ! return error code
81      !!
82      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
83      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start('sbc_ssr')
87      !
88      IF( nn_sstr + nn_sssr /= 0 ) THEN
89         !
90         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
91         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
92         !
93         !                                         ! ========================= !
94         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
95            !                                      ! ========================= !
96            !
97            IF( nn_sstr == 1 ) THEN                                   !* Temperature restoring term
98               DO jj = 1, jpj
99                  DO ji = 1, jpi
100                     ! K.Y. 16/03/2016 Apply Arctic mask to SST restoring
101                     zqrp = rn_dqdt * ( 1. - 2.*only_arcmsk(ji,jj) )  &
102                        &           * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
103                     !zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
104                     qns(ji,jj) = qns(ji,jj) + zqrp
105                     qrp(ji,jj) = zqrp
106                  END DO
107               END DO
108               CALL iom_put( "qrp", qrp )                             ! heat flux damping
109               CALL iom_put( "only_arcmsk", only_arcmsk )                             ! arctic mask
110            ENDIF
111            !
112            IF( nn_sssr == 1 ) THEN                                   !* Salinity damping term (salt flux only (sfx))
113               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
114!CDIR COLLAPSE
115               DO jj = 1, jpj
116                  DO ji = 1, jpi
117                     zerp = zsrp * ( 1. - 2.*rnfmsk_arcmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
118                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) 
119                     sfx(ji,jj) = sfx(ji,jj) + zerp                 ! salt flux
120                     erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only)
121                  END DO
122                  !!write(numout,*) 'erp(30,',jj,')=',erp(30,jj), &
123                  !!   &            'sf_sss(1)%fnow(30,',jj,',1)=',sf_sss(1)%fnow(30,jj,1), &
124                  !!   &            'sss_m(30,',jj,')=',sss_m(30,jj),'sst_m(30,',jj,')=',sst_m(30,jj), &
125                  !!   &            'rnfmsk_arcmsk(30,',jj,')=',rnfmsk_arcmsk(30,jj)
126               END DO
127               CALL iom_put( "erp", erp )                             ! freshwater flux damping
128               CALL iom_put( "rnfmsk_arcmsk", rnfmsk_arcmsk )                         ! river mough & arctic
129               !
130            ELSEIF( nn_sssr == 2 ) THEN                               !* Salinity damping term (volume flux (emp) and associated heat flux (qns)
131               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
132               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
133!CDIR COLLAPSE
134               DO jj = 1, jpj
135                  DO ji = 1, jpi                           
136                     zerp = zsrp * ( 1. - 2.*rnfmsk_arcmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
137                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
138                        &        / MAX(  sss_m(ji,jj), 1.e-20   )
139                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
140                     emp(ji,jj) = emp (ji,jj) + zerp
141                     qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj)
142                     erp(ji,jj) = zerp
143                  END DO
144               END DO
145               CALL iom_put( "erp", erp )                             ! freshwater flux damping
146               CALL iom_put( "rnfmsk_arcmsk", rnfmsk_arcmsk )                         ! river mough & arctic
147            ENDIF
148            !
149         ENDIF
150         !
151      ENDIF
152      !
153      IF( nn_timing == 1 )  CALL timing_stop('sbc_ssr')
154      !
155   END SUBROUTINE sbc_ssr
156
157 
158   SUBROUTINE sbc_ssr_init
159      !!---------------------------------------------------------------------
160      !!                  ***  ROUTINE sbc_ssr_init  ***
161      !!
162      !! ** Purpose :   initialisation of surface damping term
163      !!
164      !! ** Method  : - Read namelist namsbc_ssr
165      !!              - Read observed SST and/or SSS if required
166      !!---------------------------------------------------------------------
167      INTEGER  ::   ji, jj   ! dummy loop indices
168      REAL(wp) ::   zerp     ! local scalar for evaporation damping
169      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
170      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
171      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
172      INTEGER  ::   ierror   ! return error code
173      !!
174      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
175      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
176      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
177      INTEGER     ::  ios
178      !!----------------------------------------------------------------------
179      !
180 
181      REWIND( numnam_ref )              ! Namelist namsbc_ssr in reference namelist :
182      READ  ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901)
183901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist', lwp )
184
185      REWIND( numnam_cfg )              ! Namelist namsbc_ssr in configuration namelist :
186      READ  ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 )
187902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist', lwp )
188      IF(lwm) WRITE ( numond, namsbc_ssr )
189
190      IF(lwp) THEN                 !* control print
191         WRITE(numout,*)
192         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
193         WRITE(numout,*) '~~~~~~~ '
194         WRITE(numout,*) '   Namelist namsbc_ssr :'
195         WRITE(numout,*) '      SST restoring term (Yes=1)             nn_sstr     = ', nn_sstr
196         WRITE(numout,*) '      SSS damping term (Yes=1, salt flux)    nn_sssr     = ', nn_sssr
197         WRITE(numout,*) '                       (Yes=2, volume flux) '
198         WRITE(numout,*) '      dQ/dT (restoring magnitude on SST)     rn_dqdt     = ', rn_dqdt, ' W/m2/K'
199         WRITE(numout,*) '      dE/dS (restoring magnitude on SST)     rn_deds     = ', rn_deds, ' mm/day'
200         WRITE(numout,*) '      flag to bound erp term                 ln_sssr_bnd = ', ln_sssr_bnd
201         WRITE(numout,*) '      ABS(Max./Min.) erp threshold           rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
202      ENDIF
203      !
204      !                            !* Allocate erp and qrp array
205      ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), STAT=ierror )
206      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate erp and qrp array' )
207      !
208      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
209         !
210         ALLOCATE( sf_sst(1), STAT=ierror )
211         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
212         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
213         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
214         !
215         ! fill sf_sst with sn_sst and control print
216         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
217         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
218         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
219         !
220      ENDIF
221      !
222      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
223         !
224         ALLOCATE( sf_sss(1), STAT=ierror )
225         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
226         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
227         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
228         !
229         ! fill sf_sss with sn_sss and control print
230         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
231         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
232         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
233         !
234      ENDIF
235      !
236      !                            !* Initialize qrp and erp if no restoring
237      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
238      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
239      !
240   END SUBROUTINE sbc_ssr_init
241     
242   !!======================================================================
243END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.