1 | MODULE tradmp |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE tradmp *** |
---|
4 | !! Ocean physics: internal restoring trend on active tracers (T and S) |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1991-03 (O. Marti, G. Madec) Original code |
---|
7 | !! ! 1992-06 (M. Imbard) doctor norme |
---|
8 | !! ! 1996-01 (G. Madec) statement function for e3 |
---|
9 | !! ! 1997-05 (G. Madec) macro-tasked on jk-slab |
---|
10 | !! ! 1998-07 (M. Imbard, G. Madec) ORCA version |
---|
11 | !! 7.0 ! 2001-02 (M. Imbard) cofdis, Original code |
---|
12 | !! 8.1 ! 2001-02 (G. Madec, E. Durand) cleaning |
---|
13 | !! NEMO 1.0 ! 2002-08 (G. Madec, E. Durand) free form + modules |
---|
14 | !! 3.2 ! 2009-08 (G. Madec, C. Talandier) DOCTOR norm for namelist parameter |
---|
15 | !! 3.3 ! 2010-06 (C. Ethe, G. Madec) merge TRA-TRC |
---|
16 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | |
---|
19 | !!---------------------------------------------------------------------- |
---|
20 | !! tra_dmp_alloc : allocate tradmp arrays |
---|
21 | !! tra_dmp : update the tracer trend with the internal damping |
---|
22 | !! tra_dmp_init : initialization, namlist read, parameters control |
---|
23 | !!---------------------------------------------------------------------- |
---|
24 | USE oce ! ocean: variables |
---|
25 | USE dom_oce ! ocean: domain variables |
---|
26 | USE c1d ! 1D vertical configuration |
---|
27 | USE trd_oce ! trends: ocean variables |
---|
28 | USE trdtra ! trends manager: tracers |
---|
29 | USE zdf_oce ! ocean: vertical physics |
---|
30 | USE phycst ! physical constants |
---|
31 | USE dtatsd ! data: temperature & salinity |
---|
32 | USE zdfmxl ! vertical physics: mixed layer depth |
---|
33 | USE in_out_manager ! I/O manager |
---|
34 | USE lib_mpp ! MPP library |
---|
35 | USE prtctl ! Print control |
---|
36 | USE wrk_nemo ! Memory allocation |
---|
37 | USE timing ! Timing |
---|
38 | USE iom |
---|
39 | |
---|
40 | IMPLICIT NONE |
---|
41 | PRIVATE |
---|
42 | |
---|
43 | PUBLIC tra_dmp ! routine called by step.F90 |
---|
44 | PUBLIC tra_dmp_init ! routine called by opa.F90 |
---|
45 | |
---|
46 | ! !!* Namelist namtra_dmp : T & S newtonian damping * |
---|
47 | ! nn_zdmp and cn_resto are public as they are used by C1D/dyndmp.F90 |
---|
48 | LOGICAL , PUBLIC :: ln_tradmp !: internal damping flag |
---|
49 | INTEGER , PUBLIC :: nn_zdmp ! = 0/1/2 flag for damping in the mixed layer |
---|
50 | CHARACTER(LEN=200) , PUBLIC :: cn_resto ! name of netcdf file containing restoration coefficient field |
---|
51 | ! |
---|
52 | |
---|
53 | |
---|
54 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: strdmp !: damping salinity trend (psu/s) |
---|
55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ttrdmp !: damping temperature trend (Celcius/s) |
---|
56 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: resto !: restoring coeff. on T and S (s-1) |
---|
57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: tclim !: temperature climatology on each time step(Celcius) |
---|
58 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sclim !: salinity climatology on each time step (psu) |
---|
59 | |
---|
60 | !! * Substitutions |
---|
61 | # include "domzgr_substitute.h90" |
---|
62 | # include "vectopt_loop_substitute.h90" |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
65 | !! $Id$ |
---|
66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
67 | !!---------------------------------------------------------------------- |
---|
68 | CONTAINS |
---|
69 | |
---|
70 | INTEGER FUNCTION tra_dmp_alloc() |
---|
71 | !!---------------------------------------------------------------------- |
---|
72 | !! *** FUNCTION tra_dmp_alloc *** |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | ALLOCATE( strdmp(jpi,jpj,jpk) , ttrdmp(jpi,jpj,jpk), resto(jpi,jpj,jpk), & |
---|
75 | & tclim(jpi,jpj,jpk) , sclim(jpi,jpj,jpk), STAT= tra_dmp_alloc ) |
---|
76 | ! |
---|
77 | IF( lk_mpp ) CALL mpp_sum ( tra_dmp_alloc ) |
---|
78 | IF( tra_dmp_alloc > 0 ) CALL ctl_warn('tra_dmp_alloc: allocation of arrays failed') |
---|
79 | ! |
---|
80 | END FUNCTION tra_dmp_alloc |
---|
81 | |
---|
82 | |
---|
83 | SUBROUTINE tra_dmp( kt ) |
---|
84 | !!---------------------------------------------------------------------- |
---|
85 | !! *** ROUTINE tra_dmp *** |
---|
86 | !! |
---|
87 | !! ** Purpose : Compute the tracer trend due to a newtonian damping |
---|
88 | !! of the tracer field towards given data field and add it to the |
---|
89 | !! general tracer trends. |
---|
90 | !! |
---|
91 | !! ** Method : Newtonian damping towards t_dta and s_dta computed |
---|
92 | !! and add to the general tracer trends: |
---|
93 | !! ta = ta + resto * (t_dta - tb) |
---|
94 | !! sa = sa + resto * (s_dta - sb) |
---|
95 | !! The trend is computed either throughout the water column |
---|
96 | !! (nlmdmp=0) or in area of weak vertical mixing (nlmdmp=1) or |
---|
97 | !! below the well mixed layer (nlmdmp=2) |
---|
98 | !! |
---|
99 | !! ** Action : - (ta,sa) tracer trends updated with the damping trend |
---|
100 | !!---------------------------------------------------------------------- |
---|
101 | ! |
---|
102 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
103 | !! |
---|
104 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
105 | REAL(wp) :: zta, zsa ! local scalars |
---|
106 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zts_dta |
---|
107 | !!---------------------------------------------------------------------- |
---|
108 | ! |
---|
109 | IF( nn_timing == 1 ) CALL timing_start( 'tra_dmp') |
---|
110 | ! |
---|
111 | CALL wrk_alloc( jpi, jpj, jpk, jpts, zts_dta ) |
---|
112 | ! |
---|
113 | ! !== input T-S data at kt ==! |
---|
114 | CALL dta_tsd( kt, zts_dta ) ! read and interpolates T-S data at kt |
---|
115 | |
---|
116 | tclim(:,:,:) = zts_dta(:,:,:,jp_tem) |
---|
117 | sclim(:,:,:) = zts_dta(:,:,:,jp_sal) |
---|
118 | ! |
---|
119 | SELECT CASE ( nn_zdmp ) !== type of damping ==! |
---|
120 | ! |
---|
121 | CASE( 0 ) !== newtonian damping throughout the water column ==! |
---|
122 | DO jk = 1, jpkm1 |
---|
123 | DO jj = 2, jpjm1 |
---|
124 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
125 | zta = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) |
---|
126 | zsa = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
---|
127 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + zta |
---|
128 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) + zsa |
---|
129 | strdmp(ji,jj,jk) = zsa ! save the trend (used in asmtrj) |
---|
130 | ttrdmp(ji,jj,jk) = zta |
---|
131 | END DO |
---|
132 | END DO |
---|
133 | END DO |
---|
134 | ! |
---|
135 | CASE ( 1 ) !== no damping in the turbocline (avt > 5 cm2/s) ==! |
---|
136 | DO jk = 1, jpkm1 |
---|
137 | DO jj = 2, jpjm1 |
---|
138 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
139 | IF( avt(ji,jj,jk) <= 5.e-4_wp ) THEN |
---|
140 | zta = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) |
---|
141 | zsa = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
---|
142 | ELSE |
---|
143 | zta = 0._wp |
---|
144 | zsa = 0._wp |
---|
145 | ENDIF |
---|
146 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + zta |
---|
147 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) + zsa |
---|
148 | strdmp(ji,jj,jk) = zsa ! save the salinity trend (used in asmtrj) |
---|
149 | ttrdmp(ji,jj,jk) = zta |
---|
150 | END DO |
---|
151 | END DO |
---|
152 | END DO |
---|
153 | ! |
---|
154 | CASE ( 2 ) !== no damping in the mixed layer ==! |
---|
155 | DO jk = 1, jpkm1 |
---|
156 | DO jj = 2, jpjm1 |
---|
157 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
158 | IF( fsdept(ji,jj,jk) >= hmlp (ji,jj) ) THEN |
---|
159 | zta = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) |
---|
160 | zsa = resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
---|
161 | ELSE |
---|
162 | zta = 0._wp |
---|
163 | zsa = 0._wp |
---|
164 | ENDIF |
---|
165 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + zta |
---|
166 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) + zsa |
---|
167 | strdmp(ji,jj,jk) = zsa ! save the salinity trend (used in asmtrj) |
---|
168 | ttrdmp(ji,jj,jk) = zta |
---|
169 | END DO |
---|
170 | END DO |
---|
171 | END DO |
---|
172 | ! |
---|
173 | END SELECT |
---|
174 | ! |
---|
175 | IF( l_trdtra ) THEN ! trend diagnostic |
---|
176 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_dmp, ttrdmp ) |
---|
177 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_dmp, strdmp ) |
---|
178 | ENDIF |
---|
179 | ! ! Control print |
---|
180 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' dmp - Ta: ', mask1=tmask, & |
---|
181 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
---|
182 | ! |
---|
183 | CALL wrk_dealloc( jpi, jpj, jpk, jpts, zts_dta ) |
---|
184 | ! |
---|
185 | IF( nn_timing == 1 ) CALL timing_stop( 'tra_dmp') |
---|
186 | ! |
---|
187 | END SUBROUTINE tra_dmp |
---|
188 | |
---|
189 | |
---|
190 | SUBROUTINE tra_dmp_init |
---|
191 | !!---------------------------------------------------------------------- |
---|
192 | !! *** ROUTINE tra_dmp_init *** |
---|
193 | !! |
---|
194 | !! ** Purpose : Initialization for the newtonian damping |
---|
195 | !! |
---|
196 | !! ** Method : read the namtra_dmp namelist and check the parameters |
---|
197 | !!---------------------------------------------------------------------- |
---|
198 | NAMELIST/namtra_dmp/ ln_tradmp, nn_zdmp, cn_resto |
---|
199 | INTEGER :: ios ! Local integer for output status of namelist read |
---|
200 | INTEGER :: imask ! File handle |
---|
201 | !! |
---|
202 | !!---------------------------------------------------------------------- |
---|
203 | ! |
---|
204 | REWIND( numnam_ref ) ! Namelist namtra_dmp in reference namelist : T & S relaxation |
---|
205 | READ ( numnam_ref, namtra_dmp, IOSTAT = ios, ERR = 901) |
---|
206 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_dmp in reference namelist', lwp ) |
---|
207 | ! |
---|
208 | REWIND( numnam_cfg ) ! Namelist namtra_dmp in configuration namelist : T & S relaxation |
---|
209 | READ ( numnam_cfg, namtra_dmp, IOSTAT = ios, ERR = 902 ) |
---|
210 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_dmp in configuration namelist', lwp ) |
---|
211 | IF(lwm) WRITE ( numond, namtra_dmp ) |
---|
212 | |
---|
213 | IF(lwp) THEN !Namelist print |
---|
214 | WRITE(numout,*) |
---|
215 | WRITE(numout,*) 'tra_dmp_init : T and S newtonian relaxation' |
---|
216 | WRITE(numout,*) '~~~~~~~' |
---|
217 | WRITE(numout,*) ' Namelist namtra_dmp : set relaxation parameters' |
---|
218 | WRITE(numout,*) ' Apply relaxation or not ln_tradmp = ', ln_tradmp |
---|
219 | WRITE(numout,*) ' mixed layer damping option nn_zdmp = ', nn_zdmp |
---|
220 | WRITE(numout,*) ' Damping file name cn_resto = ', cn_resto |
---|
221 | WRITE(numout,*) |
---|
222 | ENDIF |
---|
223 | |
---|
224 | IF( ln_tradmp) THEN |
---|
225 | ! |
---|
226 | !Allocate arrays |
---|
227 | IF( tra_dmp_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'tra_dmp_init: unable to allocate arrays' ) |
---|
228 | |
---|
229 | !Check values of nn_zdmp |
---|
230 | SELECT CASE (nn_zdmp) |
---|
231 | CASE ( 0 ) ; IF(lwp) WRITE(numout,*) ' tracer damping as specified by mask' |
---|
232 | CASE ( 1 ) ; IF(lwp) WRITE(numout,*) ' no tracer damping in the turbocline' |
---|
233 | CASE ( 2 ) ; IF(lwp) WRITE(numout,*) ' no tracer damping in the mixed layer' |
---|
234 | END SELECT |
---|
235 | |
---|
236 | !TG: Initialisation of dtatsd - Would it be better to have dmpdta routine |
---|
237 | !so can damp to something other than intitial conditions files? |
---|
238 | IF( .NOT.ln_tsd_tradmp ) THEN |
---|
239 | CALL ctl_warn( 'tra_dmp_init: read T-S data not initialized, we force ln_tsd_tradmp=T' ) |
---|
240 | CALL dta_tsd_init( ld_tradmp=ln_tradmp ) ! forces the initialisation of T-S data |
---|
241 | ENDIF |
---|
242 | |
---|
243 | !initialise arrays - Are these actually used anywhere else? |
---|
244 | strdmp(:,:,:) = 0._wp |
---|
245 | ttrdmp(:,:,:) = 0._wp |
---|
246 | |
---|
247 | !Read in mask from file |
---|
248 | CALL iom_open ( cn_resto, imask) |
---|
249 | CALL iom_get ( imask, jpdom_autoglo, 'resto', resto) |
---|
250 | CALL iom_close( imask ) |
---|
251 | ENDIF |
---|
252 | |
---|
253 | END SUBROUTINE tra_dmp_init |
---|
254 | |
---|
255 | END MODULE tradmp |
---|