[888] | 1 | MODULE sbcfwb |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE sbcfwb *** |
---|
| 4 | !! Ocean fluxes : domain averaged freshwater budget |
---|
| 5 | !!====================================================================== |
---|
[2528] | 6 | !! History : OPA ! 2001-02 (E. Durand) Original code |
---|
| 7 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
---|
| 8 | !! 3.0 ! 2006-08 (G. Madec) Surface module |
---|
| 9 | !! 3.2 ! 2009-07 (C. Talandier) emp mean s spread over erp area |
---|
[5120] | 10 | !! 3.6 ! 2014-11 (P. Mathiot ) add ice shelf melting |
---|
[888] | 11 | !!---------------------------------------------------------------------- |
---|
| 12 | |
---|
| 13 | !!---------------------------------------------------------------------- |
---|
| 14 | !! sbc_fwb : freshwater budget for global ocean configurations |
---|
| 15 | !! in free surface and forced mode |
---|
| 16 | !!---------------------------------------------------------------------- |
---|
| 17 | USE oce ! ocean dynamics and tracers |
---|
| 18 | USE dom_oce ! ocean space and time domain |
---|
| 19 | USE sbc_oce ! surface ocean boundary condition |
---|
| 20 | USE phycst ! physical constants |
---|
| 21 | USE sbcrnf ! ocean runoffs |
---|
[4990] | 22 | USE sbcisf ! ice shelf melting contribution |
---|
[1553] | 23 | USE sbcssr ! SS damping terms |
---|
[888] | 24 | USE in_out_manager ! I/O manager |
---|
| 25 | USE lib_mpp ! distribued memory computing library |
---|
[3294] | 26 | USE wrk_nemo ! work arrays |
---|
| 27 | USE timing ! Timing |
---|
[1553] | 28 | USE lbclnk ! ocean lateral boundary conditions |
---|
[2528] | 29 | USE lib_fortran |
---|
[888] | 30 | |
---|
| 31 | IMPLICIT NONE |
---|
| 32 | PRIVATE |
---|
| 33 | |
---|
[2715] | 34 | PUBLIC sbc_fwb ! routine called by step |
---|
[888] | 35 | |
---|
[2715] | 36 | REAL(wp) :: a_fwb_b ! annual domain averaged freshwater budget |
---|
| 37 | REAL(wp) :: a_fwb ! for 2 year before (_b) and before year. |
---|
| 38 | REAL(wp) :: fwfold ! fwfold to be suppressed |
---|
| 39 | REAL(wp) :: area ! global mean ocean surface (interior domain) |
---|
[888] | 40 | |
---|
| 41 | !! * Substitutions |
---|
| 42 | # include "domzgr_substitute.h90" |
---|
| 43 | # include "vectopt_loop_substitute.h90" |
---|
| 44 | !!---------------------------------------------------------------------- |
---|
[2528] | 45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
[1156] | 46 | !! $Id$ |
---|
[2528] | 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[888] | 48 | !!---------------------------------------------------------------------- |
---|
| 49 | CONTAINS |
---|
| 50 | |
---|
| 51 | SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc ) |
---|
| 52 | !!--------------------------------------------------------------------- |
---|
| 53 | !! *** ROUTINE sbc_fwb *** |
---|
| 54 | !! |
---|
| 55 | !! ** Purpose : Control the mean sea surface drift |
---|
| 56 | !! |
---|
| 57 | !! ** Method : several ways depending on kn_fwb |
---|
| 58 | !! =0 no control |
---|
[1168] | 59 | !! =1 global mean of emp set to zero at each nn_fsbc time step |
---|
| 60 | !! =2 annual global mean corrected from previous year |
---|
[4689] | 61 | !! =3 global mean of emp set to zero at each nn_fsbc time step |
---|
| 62 | !! & spread out over erp area depending its sign |
---|
[3625] | 63 | !! Note: if sea ice is embedded it is taken into account when computing the budget |
---|
[888] | 64 | !!---------------------------------------------------------------------- |
---|
| 65 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
| 66 | INTEGER, INTENT( in ) :: kn_fsbc ! |
---|
| 67 | INTEGER, INTENT( in ) :: kn_fwb ! ocean time-step index |
---|
[2715] | 68 | ! |
---|
[3625] | 69 | INTEGER :: inum, ikty, iyear ! local integers |
---|
| 70 | REAL(wp) :: z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp ! local scalars |
---|
| 71 | REAL(wp) :: zsurf_neg, zsurf_pos, zsurf_tospread, zcoef ! - - |
---|
| 72 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces |
---|
| 73 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_tospread, zerp_cor ! - - |
---|
[888] | 74 | !!---------------------------------------------------------------------- |
---|
| 75 | ! |
---|
[3294] | 76 | IF( nn_timing == 1 ) CALL timing_start('sbc_fwb') |
---|
[2715] | 77 | ! |
---|
[3294] | 78 | CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
---|
| 79 | ! |
---|
[888] | 80 | IF( kt == nit000 ) THEN |
---|
| 81 | IF(lwp) THEN |
---|
| 82 | WRITE(numout,*) |
---|
| 83 | WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction' |
---|
| 84 | WRITE(numout,*) '~~~~~~~' |
---|
| 85 | IF( kn_fwb == 1 ) WRITE(numout,*) ' instantaneously set to zero' |
---|
| 86 | IF( kn_fwb == 2 ) WRITE(numout,*) ' adjusted from previous year budget' |
---|
[4689] | 87 | IF( kn_fwb == 3 ) WRITE(numout,*) ' fwf set to zero and spread out over erp area' |
---|
[888] | 88 | ENDIF |
---|
| 89 | ! |
---|
[4689] | 90 | IF( kn_fwb == 3 .AND. nn_sssr /= 2 ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' ) |
---|
[5120] | 91 | IF( kn_fwb == 3 .AND. ln_isfcav ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' ) |
---|
[4689] | 92 | ! |
---|
[5120] | 93 | area = glob_sum( e1e2t(:,:) * tmask(:,:,1)) ! interior global domain surface |
---|
| 94 | ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes |
---|
| 95 | ! and in case of no melt, it can generate HSSW. |
---|
[3625] | 96 | ! |
---|
[4990] | 97 | #if ! defined key_lim2 && ! defined key_lim3 && ! defined key_cice |
---|
[3625] | 98 | snwice_mass_b(:,:) = 0.e0 ! no sea-ice model is being used : no snow+ice mass |
---|
| 99 | snwice_mass (:,:) = 0.e0 |
---|
| 100 | #endif |
---|
| 101 | ! |
---|
[888] | 102 | ENDIF |
---|
| 103 | |
---|
| 104 | |
---|
| 105 | SELECT CASE ( kn_fwb ) |
---|
| 106 | ! |
---|
[2528] | 107 | CASE ( 1 ) !== global mean fwf set to zero ==! |
---|
[1245] | 108 | ! |
---|
[888] | 109 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
---|
[4990] | 110 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) - snwice_fmass(:,:) ) ) / area ! sum over the global domain |
---|
[3625] | 111 | zcoef = z_fwf * rcp |
---|
[5120] | 112 | emp(:,:) = emp(:,:) - z_fwf * tmask(:,:,1) |
---|
| 113 | qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
---|
[888] | 114 | ENDIF |
---|
| 115 | ! |
---|
[2528] | 116 | CASE ( 2 ) !== fwf budget adjusted from the previous year ==! |
---|
| 117 | ! |
---|
[3625] | 118 | IF( kt == nit000 ) THEN ! initialisation |
---|
[2528] | 119 | ! ! Read the corrective factor on precipitations (fwfold) |
---|
[1581] | 120 | CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. ) |
---|
[895] | 121 | READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb |
---|
| 122 | CLOSE( inum ) |
---|
[2528] | 123 | fwfold = a_fwb ! current year freshwater budget correction |
---|
| 124 | ! ! estimate from the previous year budget |
---|
[895] | 125 | IF(lwp)WRITE(numout,*) |
---|
[2528] | 126 | IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear , ' freshwater budget correction = ', fwfold |
---|
[895] | 127 | IF(lwp)WRITE(numout,*)' year = ',iyear-1, ' freshwater budget read = ', a_fwb |
---|
| 128 | IF(lwp)WRITE(numout,*)' year = ',iyear-2, ' freshwater budget read = ', a_fwb_b |
---|
| 129 | ENDIF |
---|
[2528] | 130 | ! ! Update fwfold if new year start |
---|
[888] | 131 | ikty = 365 * 86400 / rdttra(1) !!bug use of 365 days leap year or 360d year !!!!!!! |
---|
| 132 | IF( MOD( kt, ikty ) == 0 ) THEN |
---|
[3625] | 133 | a_fwb_b = a_fwb ! mean sea level taking into account the ice+snow |
---|
| 134 | ! sum over the global domain |
---|
| 135 | a_fwb = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) ) |
---|
[4161] | 136 | a_fwb = a_fwb * 1.e+3 / ( area * rday * 365. ) ! convert in Kg/m3/s = mm/s |
---|
[888] | 137 | !!gm ! !!bug 365d year |
---|
[2528] | 138 | fwfold = a_fwb ! current year freshwater budget correction |
---|
| 139 | ! ! estimate from the previous year budget |
---|
[888] | 140 | ENDIF |
---|
| 141 | ! |
---|
[3625] | 142 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN ! correct the freshwater fluxes |
---|
| 143 | zcoef = fwfold * rcp |
---|
[5120] | 144 | emp(:,:) = emp(:,:) + fwfold * tmask(:,:,1) |
---|
| 145 | qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
---|
[888] | 146 | ENDIF |
---|
| 147 | ! |
---|
[3625] | 148 | IF( kt == nitend .AND. lwp ) THEN ! save fwfold value in a file |
---|
[1581] | 149 | CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea ) |
---|
| 150 | WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb |
---|
| 151 | CLOSE( inum ) |
---|
[888] | 152 | ENDIF |
---|
| 153 | ! |
---|
[4689] | 154 | CASE ( 3 ) !== global fwf set to zero and spread out over erp area ==! |
---|
| 155 | ! |
---|
| 156 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
---|
| 157 | ztmsk_pos(:,:) = tmask_i(:,:) ! Select <0 and >0 area of erp |
---|
| 158 | WHERE( erp < 0._wp ) ztmsk_pos = 0._wp |
---|
| 159 | ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:) |
---|
| 160 | ! |
---|
| 161 | zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) ) ! Area filled by <0 and >0 erp |
---|
| 162 | zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) ) |
---|
| 163 | ! ! fwf global mean (excluding ocean to ice/snow exchanges) |
---|
[5120] | 164 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) - snwice_fmass(:,:) ) ) / area |
---|
[4689] | 165 | ! |
---|
| 166 | IF( z_fwf < 0._wp ) THEN ! spread out over >0 erp area to increase evaporation |
---|
| 167 | zsurf_tospread = zsurf_pos |
---|
| 168 | ztmsk_tospread(:,:) = ztmsk_pos(:,:) |
---|
| 169 | ELSE ! spread out over <0 erp area to increase precipitation |
---|
| 170 | zsurf_tospread = zsurf_neg |
---|
| 171 | ztmsk_tospread(:,:) = ztmsk_neg(:,:) |
---|
| 172 | ENDIF |
---|
| 173 | ! |
---|
| 174 | zsum_fwf = glob_sum( e1e2t(:,:) * z_fwf ) ! fwf global mean over <0 or >0 erp area |
---|
| 175 | !!gm : zsum_fwf = z_fwf * area ??? it is right? I think so.... |
---|
| 176 | z_fwf_nsrf = zsum_fwf / ( zsurf_tospread + rsmall ) |
---|
| 177 | ! ! weight to respect erp field 2D structure |
---|
| 178 | zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) ) |
---|
| 179 | z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall ) |
---|
| 180 | ! ! final correction term to apply |
---|
| 181 | zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:) |
---|
| 182 | ! |
---|
| 183 | !!gm ===>>>> lbc_lnk should be useless as all the computation is done over the whole domain ! |
---|
| 184 | CALL lbc_lnk( zerp_cor, 'T', 1. ) |
---|
| 185 | ! |
---|
| 186 | emp(:,:) = emp(:,:) + zerp_cor(:,:) |
---|
| 187 | qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:) ! account for change to the heat budget due to fw correction |
---|
| 188 | erp(:,:) = erp(:,:) + zerp_cor(:,:) |
---|
| 189 | ! |
---|
| 190 | IF( nprint == 1 .AND. lwp ) THEN ! control print |
---|
| 191 | IF( z_fwf < 0._wp ) THEN |
---|
| 192 | WRITE(numout,*)' z_fwf < 0' |
---|
| 193 | WRITE(numout,*)' SUM(erp+) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
---|
| 194 | ELSE |
---|
| 195 | WRITE(numout,*)' z_fwf >= 0' |
---|
| 196 | WRITE(numout,*)' SUM(erp-) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
---|
| 197 | ENDIF |
---|
| 198 | WRITE(numout,*)' SUM(empG) = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv' |
---|
| 199 | WRITE(numout,*)' z_fwf = ', z_fwf ,' Kg/m2/s' |
---|
| 200 | WRITE(numout,*)' z_fwf_nsrf = ', z_fwf_nsrf ,' Kg/m2/s' |
---|
| 201 | WRITE(numout,*)' MIN(zerp_cor) = ', MINVAL(zerp_cor) |
---|
| 202 | WRITE(numout,*)' MAX(zerp_cor) = ', MAXVAL(zerp_cor) |
---|
| 203 | ENDIF |
---|
| 204 | ENDIF |
---|
| 205 | ! |
---|
[2528] | 206 | CASE DEFAULT !== you should never be there ==! |
---|
[4689] | 207 | CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' ) |
---|
[888] | 208 | ! |
---|
| 209 | END SELECT |
---|
| 210 | ! |
---|
[3294] | 211 | CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
---|
[2715] | 212 | ! |
---|
[3294] | 213 | IF( nn_timing == 1 ) CALL timing_stop('sbc_fwb') |
---|
| 214 | ! |
---|
[888] | 215 | END SUBROUTINE sbc_fwb |
---|
| 216 | |
---|
| 217 | !!====================================================================== |
---|
| 218 | END MODULE sbcfwb |
---|