New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/UKMO/dev_r6393_CO6_package_trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_r6393_CO6_package_trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7019

Last change on this file since 7019 was 7019, checked in by deazer, 7 years ago

Cleared svn keywords

File size: 31.1 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislope2        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excret          !:
39   REAL(wp), PUBLIC ::  excret2         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcret                !: 1 - excret
54   REAL(wp) :: texcret2               !: 1 - excret2       
55
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p4z_prod( kt , knt )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p4z_prod  ***
66      !!
67      !! ** Purpose :   Compute the phytoplankton production depending on
68      !!              light, temperature and nutrient availability
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) :: kt, knt
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
77      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
78      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
79      REAL(wp) ::   zmxltst, zmxlday, zmaxday
80      REAL(wp) ::   zpislopen  , zpislope2n
81      REAL(wp) ::   zrum, zcodel, zargu, zval
82      REAL(wp) ::   zfact
83      CHARACTER (len=25) :: charout
84      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
90      !
91      !  Allocate temporary workspace
92      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
93      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
94      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
95      !
96      zprorca (:,:,:) = 0._wp
97      zprorcad(:,:,:) = 0._wp
98      zprofed (:,:,:) = 0._wp
99      zprofen (:,:,:) = 0._wp
100      zprochln(:,:,:) = 0._wp
101      zprochld(:,:,:) = 0._wp
102      zpronew (:,:,:) = 0._wp
103      zpronewd(:,:,:) = 0._wp
104      zprdia  (:,:,:) = 0._wp
105      zprbio  (:,:,:) = 0._wp
106      zprdch  (:,:,:) = 0._wp
107      zprnch  (:,:,:) = 0._wp
108      zysopt  (:,:,:) = 0._wp
109
110      ! Computation of the optimal production
111      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
112      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
113
114      ! compute the day length depending on latitude and the day
115      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
116      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
117
118      ! day length in hours
119      zstrn(:,:) = 0.
120      DO jj = 1, jpj
121         DO ji = 1, jpi
122            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
123            zargu = MAX( -1., MIN(  1., zargu ) )
124            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
125         END DO
126      END DO
127
128      ! Impact of the day duration on phytoplankton growth
129      DO jk = 1, jpkm1
130         DO jj = 1 ,jpj
131            DO ji = 1, jpi
132               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
133                  zval = MAX( 1., zstrn(ji,jj) )
134                  zval = 1.5 * zval / ( 12. + zval )
135                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval
136                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
137               ENDIF
138            END DO
139         END DO
140      END DO
141
142      ! Maximum light intensity
143      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
144      zstrn(:,:) = 24. / zstrn(:,:)
145
146      IF( ln_newprod ) THEN
147         DO jk = 1, jpkm1
148            DO jj = 1, jpj
149               DO ji = 1, jpi
150                  ! Computation of the P-I slope for nanos and diatoms
151                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
152                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
153                      zadap       = xadap * ztn / ( 2.+ ztn )
154                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
155                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
156                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
157                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
158                      !
159                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
160                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
161                      !
162                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
163                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
164
165                      ! Computation of production function for Carbon
166                      !  ---------------------------------------------
167                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
168                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
169                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
170                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
171
172                      !  Computation of production function for Chlorophyll
173                      !--------------------------------------------------
174                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
175                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
176                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
177                  ENDIF
178               END DO
179            END DO
180         END DO
181      ELSE
182         DO jk = 1, jpkm1
183            DO jj = 1, jpj
184               DO ji = 1, jpi
185
186                  ! Computation of the P-I slope for nanos and diatoms
187                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
188                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
189                      zadap       = ztn / ( 2.+ ztn )
190                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
191                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
192                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
193                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
194                      !
195                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )
196                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )
197
198                      zpislopen =  zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch)                &
199                        &          / ( trb(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
200                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
201
202                      zpislope2n = zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch)                &
203                        &          / ( trb(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
204                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
205
206                      ! Computation of production function for Carbon
207                      !  ---------------------------------------------
208                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
209                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
210
211                      !  Computation of production function for Chlorophyll
212                      !--------------------------------------------------
213                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
214                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
215                  ENDIF
216               END DO
217            END DO
218         END DO
219      ENDIF
220
221
222      !  Computation of a proxy of the N/C ratio
223      !  ---------------------------------------
224      DO jk = 1, jpkm1
225         DO jj = 1, jpj
226            DO ji = 1, jpi
227                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
228                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
229                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
230                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
231                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
232                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
233            END DO
234         END DO
235      END DO
236
237
238      DO jk = 1, jpkm1
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241
242                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
243                   !    Si/C of diatoms
244                   !    ------------------------
245                   !    Si/C increases with iron stress and silicate availability
246                   !    Si/C is arbitrariliy increased for very high Si concentrations
247                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
248                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
249                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
250                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
251                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
252                  IF (gphit(ji,jj) < -30 ) THEN
253                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
254                  ELSE
255                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
256                  ENDIF
257                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
258              ENDIF
259            END DO
260         END DO
261      END DO
262
263      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
264      DO jj = 1, jpj
265         DO ji = 1, jpi
266            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
267            zmxlday = zmxltst * zmxltst * r1_rday
268            zmixnano(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
269            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
270         END DO
271      END DO
272 
273      !  Mixed-layer effect on production                                                                               
274      DO jk = 1, jpkm1
275         DO jj = 1, jpj
276            DO ji = 1, jpi
277               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
278                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
279                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
280               ENDIF
281            END DO
282         END DO
283      END DO
284
285      ! Computation of the various production terms
286      DO jk = 1, jpkm1
287         DO jj = 1, jpj
288            DO ji = 1, jpi
289               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
290                  !  production terms for nanophyto.
291                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
292                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
293                  !
294                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
295                  zratio = zratio / fecnm 
296                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
297                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
298                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
299                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
300                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
301                  !  production terms for diatomees
302                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
303                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
304                  !
305                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
306                  zratio = zratio / fecdm 
307                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
308                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
309                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
310                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
311                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
312               ENDIF
313            END DO
314         END DO
315      END DO
316
317      IF( ln_newprod ) THEN
318         DO jk = 1, jpkm1
319            DO jj = 1, jpj
320               DO ji = 1, jpi
321                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
322                     zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
323                     zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
324                  ENDIF
325                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
326                     !  production terms for nanophyto. ( chlorophyll )
327                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
328                     zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
329                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
330                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
331                                        & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
332                     !  production terms for diatomees ( chlorophyll )
333                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
334                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
335                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
336                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
337                                        & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
338                  ENDIF
339               END DO
340            END DO
341         END DO
342      ELSE
343         DO jk = 1, jpkm1
344            DO jj = 1, jpj
345               DO ji = 1, jpi
346                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
347                     !  production terms for nanophyto. ( chlorophyll )
348                     znanotot = enano(ji,jj,jk)
349                     zprod = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * trb(ji,jj,jk,jpphy) * xlimphy(ji,jj,jk)
350                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
351                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 144. * zprod            &
352                     &                    / ( zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch) * znanotot +rtrn )
353                     !  production terms for diatomees ( chlorophyll )
354                     zdiattot = ediat(ji,jj,jk)
355                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * trb(ji,jj,jk,jpdia) * xlimdia(ji,jj,jk)
356                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
357                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 144. * zprod             &
358                     &                    / ( zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch) * zdiattot +rtrn )
359                  ENDIF
360               END DO
361            END DO
362         END DO
363      ENDIF
364
365      !   Update the arrays TRA which contain the biological sources and sinks
366      DO jk = 1, jpkm1
367         DO jj = 1, jpj
368           DO ji =1 ,jpi
369              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
370              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
371              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
372              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
373              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
374              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
375              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
376              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
377              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
378              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
379              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
380              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
381              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
382              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
383                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
384              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
385              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
386              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
387              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
388                 &                                      - rno3 * ( zproreg + zproreg2 )
389          END DO
390        END DO
391     END DO
392
393
394    ! Total primary production per year
395    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
396         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
397
398    IF( lk_iomput ) THEN
399       IF( knt == nrdttrc ) THEN
400          CALL wrk_alloc( jpi, jpj,      zw2d )
401          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
402          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
403          !
404          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
405              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
406              CALL iom_put( "PPPHY"  , zw3d )
407              !
408              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
409              CALL iom_put( "PPPHY2"  , zw3d )
410          ENDIF
411          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
412              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
413              CALL iom_put( "PPNEWN"  , zw3d )
414              !
415              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
416              CALL iom_put( "PPNEWD"  , zw3d )
417          ENDIF
418          IF( iom_use( "PBSi" ) )  THEN
419              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
420              CALL iom_put( "PBSi"  , zw3d )
421          ENDIF
422          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
423              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
424              CALL iom_put( "PFeN"  , zw3d )
425              !
426              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
427              CALL iom_put( "PFeD"  , zw3d )
428          ENDIF
429          IF( iom_use( "Mumax" ) )  THEN
430              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
431              CALL iom_put( "Mumax"  , zw3d )
432          ENDIF
433          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
434              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
435              CALL iom_put( "MuN"  , zw3d )
436              !
437              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
438              CALL iom_put( "MuD"  , zw3d )
439          ENDIF
440          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
441              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
442              CALL iom_put( "LNlight"  , zw3d )
443              !
444              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
445              CALL iom_put( "LDlight"  , zw3d )
446          ENDIF
447          IF( iom_use( "TPP" ) )  THEN
448              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
449              CALL iom_put( "TPP"  , zw3d )
450          ENDIF
451          IF( iom_use( "TPNEW" ) )  THEN
452              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
453              CALL iom_put( "TPNEW"  , zw3d )
454          ENDIF
455          IF( iom_use( "TPBFE" ) )  THEN
456              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
457              CALL iom_put( "TPBFE"  , zw3d )
458          ENDIF
459          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
460             zw2d(:,:) = 0.
461             DO jk = 1, jpkm1
462               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
463             ENDDO
464             CALL iom_put( "INTPPPHY" , zw2d )
465             !
466             zw2d(:,:) = 0.
467             DO jk = 1, jpkm1
468                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
469             ENDDO
470             CALL iom_put( "INTPPPHY2" , zw2d )
471          ENDIF
472          IF( iom_use( "INTPP" ) ) THEN   
473             zw2d(:,:) = 0.
474             DO jk = 1, jpkm1
475                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
476             ENDDO
477             CALL iom_put( "INTPP" , zw2d )
478          ENDIF
479          IF( iom_use( "INTPNEW" ) ) THEN   
480             zw2d(:,:) = 0.
481             DO jk = 1, jpkm1
482                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
483             ENDDO
484             CALL iom_put( "INTPNEW" , zw2d )
485          ENDIF
486          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
487             zw2d(:,:) = 0.
488             DO jk = 1, jpkm1
489                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
490             ENDDO
491            CALL iom_put( "INTPBFE" , zw2d )
492          ENDIF
493          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
494             zw2d(:,:) = 0.
495             DO jk = 1, jpkm1
496                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
497             ENDDO
498             CALL iom_put( "INTPBSI" , zw2d )
499          ENDIF
500          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
501          !
502          CALL wrk_dealloc( jpi, jpj,      zw2d )
503          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
504       ENDIF
505     ELSE
506        IF( ln_diatrc ) THEN
507           zfact = 1.e+3 * rfact2r
508           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zfact * tmask(:,:,:)
509           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
510           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zfact * tmask(:,:,:)
511           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
512           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
513           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
514#  if ! defined key_kriest
515           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
516#  endif
517        ENDIF
518     ENDIF
519
520     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
521         WRITE(charout, FMT="('prod')")
522         CALL prt_ctl_trc_info(charout)
523         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
524     ENDIF
525     !
526     CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
527     CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
528     CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
529     !
530     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
531     !
532   END SUBROUTINE p4z_prod
533
534
535   SUBROUTINE p4z_prod_init
536      !!----------------------------------------------------------------------
537      !!                  ***  ROUTINE p4z_prod_init  ***
538      !!
539      !! ** Purpose :   Initialization of phytoplankton production parameters
540      !!
541      !! ** Method  :   Read the nampisprod namelist and check the parameters
542      !!      called at the first timestep (nittrc000)
543      !!
544      !! ** input   :   Namelist nampisprod
545      !!----------------------------------------------------------------------
546      !
547      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
548         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
549      INTEGER :: ios                 ! Local integer output status for namelist read
550      !!----------------------------------------------------------------------
551
552      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
553      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
554901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
555
556      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
557      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
558902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
559      IF(lwm) WRITE ( numonp, nampisprod )
560
561      IF(lwp) THEN                         ! control print
562         WRITE(numout,*) ' '
563         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
564         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
565         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
566         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
567         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
568         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
569         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
570         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
571         IF( ln_newprod )  THEN
572            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
573            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
574         ENDIF
575         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
576         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
577         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
578         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
579         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
580      ENDIF
581      !
582      r1_rday   = 1._wp / rday 
583      texcret   = 1._wp - excret
584      texcret2  = 1._wp - excret2
585      tpp       = 0._wp
586      !
587   END SUBROUTINE p4z_prod_init
588
589
590   INTEGER FUNCTION p4z_prod_alloc()
591      !!----------------------------------------------------------------------
592      !!                     ***  ROUTINE p4z_prod_alloc  ***
593      !!----------------------------------------------------------------------
594      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
595      !
596      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
597      !
598   END FUNCTION p4z_prod_alloc
599
600#else
601   !!======================================================================
602   !!  Dummy module :                                   No PISCES bio-model
603   !!======================================================================
604CONTAINS
605   SUBROUTINE p4z_prod                    ! Empty routine
606   END SUBROUTINE p4z_prod
607#endif 
608
609   !!======================================================================
610END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.