New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/UKMO/dev_r6501_GO6_package_trunk/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/dev_r6501_GO6_package_trunk/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6825

Last change on this file since 6825 was 6825, checked in by timgraham, 8 years ago

As used for GO6 from trunk test
File size: 15.8 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE ioipsl, ONLY : ju2ymds    ! for calendar
30   USE sbc_oce         ! for icesheet freshwater input variables
31   USE diurnal_bulk
32   
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   rst_opn         ! routine called by step module
37   PUBLIC   rst_write       ! routine called by step module
38   PUBLIC   rst_read        ! routine called by istate module
39   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE rst_opn( kt )
51      !!---------------------------------------------------------------------
52      !!                   ***  ROUTINE rst_opn  ***
53      !!                     
54      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
55      !!              + open the restart when we are one time step before nitrst
56      !!                   - restart header is defined when kt = nitrst-1
57      !!                   - restart data  are written when kt = nitrst
58      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt     ! ocean time-step
61      INTEGER             ::   iyear, imonth, iday
62      REAL (wp)           ::   zsec
63      !!
64      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
65      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
66      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
67      !!----------------------------------------------------------------------
68      !
69      IF( kt == nit000 ) THEN   ! default definitions
70         lrst_oce = .FALSE.   
71         IF( ln_rst_list ) THEN
72            nrst_lst = 1
73            nitrst = nstocklist( nrst_lst )
74         ELSE
75            nitrst = nitend
76         ENDIF
77      ENDIF
78
79      ! frequency-based restart dumping (nn_stock)
80      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
81         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
82         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
83         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
84      ENDIF
85      ! to get better performances with NetCDF format:
86      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
87      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
88      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
89         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
90            IF ( ln_rstdate ) THEN
91               CALL ju2ymds( fjulday + rdt / rday, iyear, imonth, iday, zsec )           
92               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
93            ELSE
94               ! beware of the format used to write kt (default is i8.8, that should be large enough...)
95               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
96               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
97               ENDIF
98            ENDIF
99            ! create the file
100            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
101            clpath = TRIM(cn_ocerst_outdir)
102            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
103            IF(lwp) THEN
104               WRITE(numout,*)
105               SELECT CASE ( jprstlib )
106               CASE DEFAULT         ;   WRITE(numout,*)                            &
107                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
108               END SELECT
109               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
110               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
111               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
112               ENDIF
113            ENDIF
114            !
115            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
116            lrst_oce = .TRUE.
117         ENDIF
118      ENDIF
119      !
120   END SUBROUTINE rst_opn
121
122
123   SUBROUTINE rst_write( kt )
124      !!---------------------------------------------------------------------
125      !!                   ***  ROUTINE rstwrite  ***
126      !!                     
127      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
128      !!
129      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
130      !!              file, save fields which are necessary for restart
131      !!----------------------------------------------------------------------
132      INTEGER, INTENT(in) ::   kt   ! ocean time-step
133      !!----------------------------------------------------------------------
134
135                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics and tracer time step
136
137      IF ( .NOT. ln_diurnal_only ) THEN
138                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
139                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
140                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
141                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
142                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
143                     !
144                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
145                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
146                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
147                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
148                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
149                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
150
151                  ! extra variable needed for the ice sheet coupling
152                  IF ( ln_iscpl ) THEN
153                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask     ) ! need to extrapolate T/S
154                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask     ) ! need to correct barotropic velocity
155                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask     ) ! need to correct barotropic velocity
156                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask    ) ! need to correct barotropic velocity
157                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:) )   ! need to compute temperature correction
158                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:) )   ! need to compute bt conservation
159                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:) )   ! need to compute bt conservation
160                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:) ) ! need to compute extrapolation if vvl
161                  END IF
162      ENDIF
163     
164      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst    ) 
165
166                     IF( lk_oasis) THEN
167                     ! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
168                     IF( ln_coupled_iceshelf_fluxes ) THEN
169                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass )
170                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
171                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
172                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
173                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
174                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
175                     ENDIF
176                     ENDIF
177
178      IF( kt == nitrst ) THEN
179         CALL iom_close( numrow )     ! close the restart file (only at last time step)
180!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
181!!gm  not sure what to do here   ===>>>  ask to Sebastian
182         lrst_oce = .FALSE.
183            IF( ln_rst_list ) THEN
184               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
185               nitrst = nstocklist( nrst_lst )
186            ENDIF
187            lrst_oce = .FALSE.
188      ENDIF
189      !
190   END SUBROUTINE rst_write
191
192
193   SUBROUTINE rst_read_open
194      !!----------------------------------------------------------------------
195      !!                   ***  ROUTINE rst_read_open  ***
196      !!
197      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
198      !!
199      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
200      !!                the file has already been opened
201      !!----------------------------------------------------------------------
202      INTEGER        ::   jlibalt = jprstlib
203      LOGICAL        ::   llok
204      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
205      !!----------------------------------------------------------------------
206      !
207      IF( numror <= 0 ) THEN
208         IF(lwp) THEN                                             ! Contol prints
209            WRITE(numout,*)
210            SELECT CASE ( jprstlib )
211            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
212            END SELECT
213            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
214            WRITE(numout,*) '~~~~~~~~'
215         ENDIF
216
217         clpath = TRIM(cn_ocerst_indir)
218         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
219         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
220      ENDIF
221   END SUBROUTINE rst_read_open
222
223
224   SUBROUTINE rst_read
225      !!----------------------------------------------------------------------
226      !!                   ***  ROUTINE rst_read  ***
227      !!
228      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
229      !!
230      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
231      !!----------------------------------------------------------------------
232      REAL(wp) ::   zrdt
233      INTEGER  ::   jk
234      !!----------------------------------------------------------------------
235
236      CALL rst_read_open           ! open restart for reading (if not already opened)
237
238      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
239      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
240         CALL iom_get( numror, 'rdt', zrdt )
241         IF( zrdt /= rdt )   neuler = 0
242      ENDIF
243
244      ! Diurnal DSST
245      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst  ) 
246      IF ( ln_diurnal_only ) THEN
247         IF(lwp) WRITE( numout, * ) &
248         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
249         rhop = rau0
250         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem) ) 
251         RETURN
252      ENDIF 
253     
254      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
255         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
256         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
257         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
258         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
259         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
260      ELSE
261         neuler = 0
262      ENDIF
263      !
264      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
265      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
266      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
267      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
268      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
269      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
270         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
271      ELSE
272         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
273      ENDIF
274      !
275      IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
276         CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
277         CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
278         CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
279      ELSE
280         greenland_icesheet_mass = 0.0 
281         greenland_icesheet_mass_rate_of_change = 0.0 
282         greenland_icesheet_timelapsed = 0.0
283      ENDIF
284      IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
285         CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
286         CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
287         CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
288      ELSE
289         antarctica_icesheet_mass = 0.0 
290         antarctica_icesheet_mass_rate_of_change = 0.0 
291         antarctica_icesheet_timelapsed = 0.0
292      ENDIF
293
294      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
295         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
296         ub   (:,:,:)   = un   (:,:,:)
297         vb   (:,:,:)   = vn   (:,:,:)
298         sshb (:,:)     = sshn (:,:)
299         !
300         IF( .NOT.ln_linssh ) THEN
301            DO jk = 1, jpk
302               e3t_b(:,:,jk) = e3t_n(:,:,jk)
303            END DO
304         ENDIF
305         !
306      ENDIF
307      !
308   END SUBROUTINE rst_read
309
310   !!=====================================================================
311END MODULE restart
Note: See TracBrowser for help on using the repository browser.