| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.4 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !! 3.6 ! 2015-12 (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 18 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and active tracers |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 23 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 24 | USE trd_oce ! trends: ocean variables |
|---|
| 25 | USE trdtra ! trends manager: tracers |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | USE iom ! I/O manager |
|---|
| 30 | USE fldread ! read input fields |
|---|
| 31 | USE restart ! ocean restart |
|---|
| 32 | USE lib_mpp ! MPP library |
|---|
| 33 | USE wrk_nemo ! Memory Allocation |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | USE iom_def, ONLY : lwxios |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 41 | PUBLIC tra_qsr_init ! routine called by nemogcm.F90 |
|---|
| 42 | |
|---|
| 43 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 44 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 45 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 48 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 49 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 50 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 52 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 53 | |
|---|
| 54 | ! Module variables |
|---|
| 55 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 56 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 57 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 58 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 59 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | # include "vectopt_loop_substitute.h90" |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 66 | !! $Id$ |
|---|
| 67 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | CONTAINS |
|---|
| 70 | |
|---|
| 71 | SUBROUTINE tra_qsr( kt ) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE tra_qsr *** |
|---|
| 74 | !! |
|---|
| 75 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 76 | !! penetration and add it to the general temperature trend. |
|---|
| 77 | !! |
|---|
| 78 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 79 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 80 | !! Considering the 2 wavebands case: |
|---|
| 81 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 82 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 83 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 84 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 85 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 86 | !! in the last ocean level. |
|---|
| 87 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 88 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 89 | !! used for the computation are calculated one for once as they |
|---|
| 90 | !! depends on k only. |
|---|
| 91 | !! |
|---|
| 92 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 93 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 94 | !! |
|---|
| 95 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 96 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 97 | !! Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562 |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | ! |
|---|
| 100 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 101 | ! |
|---|
| 102 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 103 | INTEGER :: irgb ! local integers |
|---|
| 104 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 105 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 106 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 107 | REAL(wp) :: zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze |
|---|
| 108 | REAL(wp) :: zlogc, zlogc2, zlogc3 |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d |
|---|
| 111 | !!-------------------------------------------------------------------------- |
|---|
| 112 | ! |
|---|
| 113 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 114 | ! |
|---|
| 115 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 116 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 117 | ! |
|---|
| 118 | IF( kt == nit000 ) THEN |
|---|
| 119 | IF(lwp) WRITE(numout,*) |
|---|
| 120 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 121 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 122 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 123 | ENDIF |
|---|
| 124 | |
|---|
| 125 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 126 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 127 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 128 | ENDIF |
|---|
| 129 | |
|---|
| 130 | ! Set before qsr tracer content field |
|---|
| 131 | ! *********************************** |
|---|
| 132 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 133 | ! ! ----------------------------------- |
|---|
| 134 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 135 | ! |
|---|
| 136 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 137 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 138 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 139 | zfact = 0.5e0 |
|---|
| 140 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 141 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 142 | zfact = 1.e0 |
|---|
| 143 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 144 | ENDIF |
|---|
| 145 | ELSE ! Swap of forcing field |
|---|
| 146 | ! ! --------------------- |
|---|
| 147 | zfact = 0.5e0 |
|---|
| 148 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 149 | ENDIF |
|---|
| 150 | ! Compute now qsr tracer content field |
|---|
| 151 | ! ************************************ |
|---|
| 152 | |
|---|
| 153 | ! ! ============================================== ! |
|---|
| 154 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 155 | ! ! ============================================== ! |
|---|
| 156 | DO jk = 1, jpkm1 |
|---|
| 157 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 158 | END DO |
|---|
| 159 | ! Add to the general trend |
|---|
| 160 | DO jk = 1, jpkm1 |
|---|
| 161 | DO jj = 2, jpjm1 |
|---|
| 162 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 163 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 164 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 165 | END DO |
|---|
| 166 | END DO |
|---|
| 167 | END DO |
|---|
| 168 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 169 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 170 | IF ( ln_qsr_ice ) THEN |
|---|
| 171 | DO jj = 1, jpj |
|---|
| 172 | DO ji = 1, jpi |
|---|
| 173 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 174 | fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 175 | ELSE |
|---|
| 176 | fraqsr_1lev(ji,jj) = 1. |
|---|
| 177 | ENDIF |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | ENDIF |
|---|
| 181 | ! ! ============================================== ! |
|---|
| 182 | ELSE ! Ocean alone : |
|---|
| 183 | ! ! ============================================== ! |
|---|
| 184 | ! |
|---|
| 185 | ! ! ------------------------- ! |
|---|
| 186 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 187 | ! ! ------------------------- ! |
|---|
| 188 | ! Set chlorophyl concentration |
|---|
| 189 | IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 190 | ! |
|---|
| 191 | IF( nn_chldta == 1 ) THEN !* 2D Variable Chlorophyll |
|---|
| 192 | ! |
|---|
| 193 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 194 | DO jk = 1, nksr + 1 |
|---|
| 195 | zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1) |
|---|
| 196 | ENDDO |
|---|
| 197 | ! |
|---|
| 198 | ELSE IF( nn_chldta == 2 ) THEN !* -3-D Variable Chlorophyll |
|---|
| 199 | ! |
|---|
| 200 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 201 | !CDIR NOVERRCHK ! |
|---|
| 202 | DO jj = 1, jpj |
|---|
| 203 | !CDIR NOVERRCHK |
|---|
| 204 | DO ji = 1, jpi |
|---|
| 205 | zchl = sf_chl(1)%fnow(ji,jj,1) |
|---|
| 206 | zCtot = 40.6 * zchl**0.459 |
|---|
| 207 | zze = 568.2 * zCtot**(-0.746) |
|---|
| 208 | IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293) |
|---|
| 209 | zlogc = LOG( zchl ) |
|---|
| 210 | zlogc2 = zlogc * zlogc |
|---|
| 211 | zlogc3 = zlogc * zlogc * zlogc |
|---|
| 212 | zCb = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3 |
|---|
| 213 | zCmax = 0.299 - 0.289 * zlogc + 0.579 * zlogc2 |
|---|
| 214 | zpsimax = 0.6 - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3 |
|---|
| 215 | zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2 |
|---|
| 216 | zCze = 1.12 * (zchl)**0.803 |
|---|
| 217 | DO jk = 1, nksr + 1 |
|---|
| 218 | zpsi = fsdept(ji,jj,jk) / zze |
|---|
| 219 | zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) ) |
|---|
| 220 | END DO |
|---|
| 221 | ! |
|---|
| 222 | END DO |
|---|
| 223 | END DO |
|---|
| 224 | ! |
|---|
| 225 | ELSE !* Variable ocean volume but constant chrlorophyll |
|---|
| 226 | DO jk = 1, nksr + 1 |
|---|
| 227 | zchl3d(:,:,jk) = 0.05 |
|---|
| 228 | ENDDO |
|---|
| 229 | ENDIF |
|---|
| 230 | ! |
|---|
| 231 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 232 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 233 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 234 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 235 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 236 | zea(:,:,1) = qsr(:,:) |
|---|
| 237 | ! |
|---|
| 238 | DO jk = 2, nksr+1 |
|---|
| 239 | ! |
|---|
| 240 | DO jj = 1, jpj ! Separation in R-G-B depending of vertical profile of Chl |
|---|
| 241 | !CDIR NOVERRCHK |
|---|
| 242 | DO ji = 1, jpi |
|---|
| 243 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) ) |
|---|
| 244 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 245 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 246 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 247 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 248 | END DO |
|---|
| 249 | END DO |
|---|
| 250 | !CDIR NOVERRCHK |
|---|
| 251 | DO jj = 1, jpj |
|---|
| 252 | !CDIR NOVERRCHK |
|---|
| 253 | DO ji = 1, jpi |
|---|
| 254 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 255 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 256 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 257 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 258 | ze0(ji,jj,jk) = zc0 |
|---|
| 259 | ze1(ji,jj,jk) = zc1 |
|---|
| 260 | ze2(ji,jj,jk) = zc2 |
|---|
| 261 | ze3(ji,jj,jk) = zc3 |
|---|
| 262 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 263 | END DO |
|---|
| 264 | END DO |
|---|
| 265 | END DO |
|---|
| 266 | ! |
|---|
| 267 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 268 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 269 | END DO |
|---|
| 270 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 271 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 272 | ! |
|---|
| 273 | IF ( ln_qsr_ice ) THEN ! store attenuation coefficient of the first ocean level |
|---|
| 274 | !CDIR NOVERRCHK |
|---|
| 275 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 276 | !CDIR NOVERRCHK |
|---|
| 277 | DO ji = 1, jpi |
|---|
| 278 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) ) |
|---|
| 279 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 280 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 281 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 282 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 283 | END DO |
|---|
| 284 | END DO |
|---|
| 285 | ! |
|---|
| 286 | DO jj = 1, jpj |
|---|
| 287 | DO ji = 1, jpi |
|---|
| 288 | zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 289 | zc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 290 | zc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 291 | zc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 292 | fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,2) |
|---|
| 293 | END DO |
|---|
| 294 | END DO |
|---|
| 295 | ! |
|---|
| 296 | ENDIF |
|---|
| 297 | ! |
|---|
| 298 | ELSE !* Constant Chlorophyll |
|---|
| 299 | DO jk = 1, nksr |
|---|
| 300 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 301 | END DO |
|---|
| 302 | ! store attenuation coefficient of the first ocean level |
|---|
| 303 | IF( ln_qsr_ice ) THEN |
|---|
| 304 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 305 | ENDIF |
|---|
| 306 | ENDIF |
|---|
| 307 | |
|---|
| 308 | ENDIF |
|---|
| 309 | ! ! ------------------------- ! |
|---|
| 310 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 311 | ! ! ------------------------- ! |
|---|
| 312 | ! |
|---|
| 313 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 314 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 315 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 316 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 317 | DO jj = 1, jpj |
|---|
| 318 | DO ji = 1, jpi |
|---|
| 319 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 320 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 321 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 322 | END DO |
|---|
| 323 | END DO |
|---|
| 324 | END DO |
|---|
| 325 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 326 | IF ( ln_qsr_ice ) THEN |
|---|
| 327 | DO jj = 1, jpj |
|---|
| 328 | DO ji = 1, jpi |
|---|
| 329 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 330 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 331 | fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 332 | END DO |
|---|
| 333 | END DO |
|---|
| 334 | ENDIF |
|---|
| 335 | ELSE !* constant volume: coef. computed one for all |
|---|
| 336 | DO jk = 1, nksr |
|---|
| 337 | DO jj = 2, jpjm1 |
|---|
| 338 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 339 | ! (ISF) no light penetration below the ice shelves |
|---|
| 340 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1) |
|---|
| 341 | END DO |
|---|
| 342 | END DO |
|---|
| 343 | END DO |
|---|
| 344 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 345 | IF ( ln_qsr_ice ) THEN |
|---|
| 346 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 347 | ENDIF |
|---|
| 348 | ! |
|---|
| 349 | ENDIF |
|---|
| 350 | ! |
|---|
| 351 | ENDIF |
|---|
| 352 | ! |
|---|
| 353 | ! Add to the general trend |
|---|
| 354 | DO jk = 1, nksr |
|---|
| 355 | DO jj = 2, jpjm1 |
|---|
| 356 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 357 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 358 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 359 | END DO |
|---|
| 360 | END DO |
|---|
| 361 | END DO |
|---|
| 362 | ! |
|---|
| 363 | ENDIF |
|---|
| 364 | ! |
|---|
| 365 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 366 | ! ******************************* |
|---|
| 367 | IF(lwp) WRITE(numout,*) |
|---|
| 368 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 369 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 370 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 371 | IF( lwxios ) CALL iom_swap( wxios_context ) |
|---|
| 372 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc, lxios = lwxios ) |
|---|
| 373 | CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev, lxios = lwxios) ! default definition in sbcssm |
|---|
| 374 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 375 | ! |
|---|
| 376 | ENDIF |
|---|
| 377 | |
|---|
| 378 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 379 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 380 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt ) |
|---|
| 381 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 382 | ENDIF |
|---|
| 383 | ! ! print mean trends (used for debugging) |
|---|
| 384 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 385 | ! |
|---|
| 386 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 387 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 388 | ! |
|---|
| 389 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 390 | ! |
|---|
| 391 | END SUBROUTINE tra_qsr |
|---|
| 392 | |
|---|
| 393 | |
|---|
| 394 | SUBROUTINE tra_qsr_init |
|---|
| 395 | !!---------------------------------------------------------------------- |
|---|
| 396 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 397 | !! |
|---|
| 398 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 399 | !! |
|---|
| 400 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 401 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 402 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 403 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 404 | !! (1968) classification. |
|---|
| 405 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 406 | !! |
|---|
| 407 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 408 | !! |
|---|
| 409 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 410 | !!---------------------------------------------------------------------- |
|---|
| 411 | ! |
|---|
| 412 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 413 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 414 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 415 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 416 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 417 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 418 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 419 | ! |
|---|
| 420 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 421 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 422 | !! |
|---|
| 423 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 424 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 425 | !!---------------------------------------------------------------------- |
|---|
| 426 | |
|---|
| 427 | ! |
|---|
| 428 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 429 | ! |
|---|
| 430 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 431 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 432 | ! |
|---|
| 433 | |
|---|
| 434 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 435 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 436 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 437 | |
|---|
| 438 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 439 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 440 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 441 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 442 | ! |
|---|
| 443 | IF(lwp) THEN ! control print |
|---|
| 444 | WRITE(numout,*) |
|---|
| 445 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 446 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 447 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 448 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 449 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 450 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 451 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 452 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 453 | WRITE(numout,*) ' RGB : Chl data (=1/2) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 454 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 455 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 456 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 457 | ENDIF |
|---|
| 458 | |
|---|
| 459 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 460 | ! |
|---|
| 461 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 462 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 463 | ln_qsr_bio = .FALSE. |
|---|
| 464 | ENDIF |
|---|
| 465 | ! |
|---|
| 466 | ioptio = 0 ! Parameter control |
|---|
| 467 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 468 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 469 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 470 | ! |
|---|
| 471 | IF( ioptio /= 1 ) & |
|---|
| 472 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 473 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 474 | ! |
|---|
| 475 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 476 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 477 | IF( ln_qsr_rgb .AND. nn_chldta == 2 ) nqsr = 3 |
|---|
| 478 | IF( ln_qsr_2bd ) nqsr = 4 |
|---|
| 479 | IF( ln_qsr_bio ) nqsr = 5 |
|---|
| 480 | ! |
|---|
| 481 | IF(lwp) THEN ! Print the choice |
|---|
| 482 | WRITE(numout,*) |
|---|
| 483 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 484 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - 2D Chl data ' |
|---|
| 485 | IF( nqsr == 3 ) WRITE(numout,*) ' R-G-B light penetration - 3D Chl data ' |
|---|
| 486 | IF( nqsr == 4 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 487 | IF( nqsr == 5 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 488 | ENDIF |
|---|
| 489 | ! |
|---|
| 490 | ENDIF |
|---|
| 491 | ! ! ===================================== ! |
|---|
| 492 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 493 | ! ! ===================================== ! |
|---|
| 494 | ! |
|---|
| 495 | xsi0r = 1.e0 / rn_si0 |
|---|
| 496 | xsi1r = 1.e0 / rn_si1 |
|---|
| 497 | ! ! ---------------------------------- ! |
|---|
| 498 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 499 | ! ! ---------------------------------- ! |
|---|
| 500 | ! |
|---|
| 501 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 502 | ! |
|---|
| 503 | ! !* level of light extinction |
|---|
| 504 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 505 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 506 | ENDIF |
|---|
| 507 | |
|---|
| 508 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 509 | ! |
|---|
| 510 | IF( nn_chldta == 1 .OR. nn_chldta == 2 ) THEN !* Chl data : set sf_chl structure |
|---|
| 511 | IF(lwp) WRITE(numout,*) |
|---|
| 512 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 513 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 514 | IF( ierror > 0 ) THEN |
|---|
| 515 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 516 | ENDIF |
|---|
| 517 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 518 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 519 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 520 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 521 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 522 | ! |
|---|
| 523 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 524 | IF(lwp) WRITE(numout,*) |
|---|
| 525 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 526 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 527 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 528 | ELSE ! constant volume: computes one for all |
|---|
| 529 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 530 | ! |
|---|
| 531 | zchl = 0.05 ! constant chlorophyll |
|---|
| 532 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 533 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 534 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 535 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 536 | ! |
|---|
| 537 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 538 | ze0(:,:,1) = rn_abs |
|---|
| 539 | ze1(:,:,1) = zcoef |
|---|
| 540 | ze2(:,:,1) = zcoef |
|---|
| 541 | ze3(:,:,1) = zcoef |
|---|
| 542 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 543 | |
|---|
| 544 | DO jk = 2, nksr+1 |
|---|
| 545 | !CDIR NOVERRCHK |
|---|
| 546 | DO jj = 1, jpj |
|---|
| 547 | !CDIR NOVERRCHK |
|---|
| 548 | DO ji = 1, jpi |
|---|
| 549 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 550 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 551 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 552 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 553 | ze0(ji,jj,jk) = zc0 |
|---|
| 554 | ze1(ji,jj,jk) = zc1 |
|---|
| 555 | ze2(ji,jj,jk) = zc2 |
|---|
| 556 | ze3(ji,jj,jk) = zc3 |
|---|
| 557 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 558 | END DO |
|---|
| 559 | END DO |
|---|
| 560 | END DO |
|---|
| 561 | ! |
|---|
| 562 | DO jk = 1, nksr |
|---|
| 563 | ! (ISF) no light penetration below the ice shelves |
|---|
| 564 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1) |
|---|
| 565 | END DO |
|---|
| 566 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 567 | ENDIF |
|---|
| 568 | ENDIF |
|---|
| 569 | ! |
|---|
| 570 | ENDIF |
|---|
| 571 | ! ! ---------------------------------- ! |
|---|
| 572 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 573 | ! ! ---------------------------------- ! |
|---|
| 574 | ! |
|---|
| 575 | ! ! level of light extinction |
|---|
| 576 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 577 | IF(lwp) THEN |
|---|
| 578 | WRITE(numout,*) |
|---|
| 579 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 580 | ENDIF |
|---|
| 581 | ! |
|---|
| 582 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 583 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 584 | ELSE ! constant volume: computes one for all |
|---|
| 585 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 586 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 587 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 588 | DO jj = 1, jpj ! top 400 meters |
|---|
| 589 | DO ji = 1, jpi |
|---|
| 590 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 591 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 592 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) * tmask(ji,jj,1) |
|---|
| 593 | END DO |
|---|
| 594 | END DO |
|---|
| 595 | END DO |
|---|
| 596 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 597 | ! |
|---|
| 598 | ENDIF |
|---|
| 599 | ENDIF |
|---|
| 600 | ! ! ===================================== ! |
|---|
| 601 | ELSE ! No light penetration ! |
|---|
| 602 | ! ! ===================================== ! |
|---|
| 603 | IF(lwp) THEN |
|---|
| 604 | WRITE(numout,*) |
|---|
| 605 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 606 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 607 | ENDIF |
|---|
| 608 | ENDIF |
|---|
| 609 | ! |
|---|
| 610 | ! initialisation of fraqsr_1lev used in sbcssm |
|---|
| 611 | IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 612 | CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev ) |
|---|
| 613 | ELSE |
|---|
| 614 | fraqsr_1lev(:,:) = 1._wp ! default definition |
|---|
| 615 | ENDIF |
|---|
| 616 | ! |
|---|
| 617 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 618 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 619 | ! |
|---|
| 620 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 621 | ! |
|---|
| 622 | END SUBROUTINE tra_qsr_init |
|---|
| 623 | |
|---|
| 624 | !!====================================================================== |
|---|
| 625 | END MODULE traqsr |
|---|
