New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in branches/UKMO/dev_r8600_closea_rewrite/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/dev_r8600_closea_rewrite/NEMOGCM/NEMO/OPA_SRC/DOM/domzgr.F90 @ 9207

Last change on this file since 9207 was 9078, checked in by davestorkey, 7 years ago

UKMO/dev_r8600_closea_rewrite branch : slight redesign after discussion with Gurvan:

  1. Mask fields included in domain_cfg file.
  2. Control variables changed.
  3. Suppression of closed seas now done in dom_zgr.
File size: 18.6 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE closea         ! closed seas
32   USE depth_e3       ! depth <=> e3
33   USE wet_dry, ONLY: ln_wd, ht_wd
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O library
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE lib_mpp        ! distributed memory computing library
39   USE wrk_nemo       ! Memory allocation
40   USE timing         ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dom_zgr        ! called by dom_init.F90
46
47  !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3.1 , NEMO Consortium (2011)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS       
55
56   SUBROUTINE dom_zgr( k_top, k_bot )
57      !!----------------------------------------------------------------------
58      !!                ***  ROUTINE dom_zgr  ***
59      !!                   
60      !! ** Purpose :   set the depth of model levels and the resulting
61      !!              vertical scale factors.
62      !!
63      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
64      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
65      !!              - vertical coordinate (gdep., e3.) depending on the
66      !!                coordinate chosen :
67      !!                   ln_zco=T   z-coordinate   
68      !!                   ln_zps=T   z-coordinate with partial steps
69      !!                   ln_zco=T   s-coordinate
70      !!
71      !! ** Action  :   define gdep., e3., mbathy and bathy
72      !!----------------------------------------------------------------------
73      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
74      !
75      INTEGER  ::   jk                  ! dummy loop index
76      INTEGER  ::   ioptio, ibat, ios   ! local integer
77      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
78      !!----------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )   CALL timing_start('dom_zgr')
81      !
82      IF(lwp) THEN                     ! Control print
83         WRITE(numout,*)
84         WRITE(numout,*) 'dom_zgr : vertical coordinate'
85         WRITE(numout,*) '~~~~~~~'
86      ENDIF
87
88      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
89
90
91      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
92         IF(lwp) WRITE(numout,*)
93         IF(lwp) WRITE(numout,*) '          Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
94         !
95         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
96            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
97            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
98            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
99            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
100            &              k_top   , k_bot            )                  ! 1st & last ocean level
101         !
102      ELSE                          !==  User defined configuration  ==!
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
105         !
106         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
107            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
108            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
109            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
110            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
111            &              k_top   , k_bot            )                  ! 1st & last ocean level
112         !
113      ENDIF
114      !
115!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
116      ! Compute gde3w_0 (vertical sum of e3w)
117      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
118      DO jk = 2, jpk
119         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
120      END DO
121      !
122      ! Any closed seas (defined by closea_mask > 0 in domain_cfg file) to be filled
123      ! in at runtime if ln_closea=.false.
124      IF( .not. ln_closea ) CALL clo_bat( k_top, k_bot )
125      !
126      IF(lwp) THEN                     ! Control print
127         WRITE(numout,*)
128         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
129         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
130         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
131         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
132         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
133      ENDIF
134
135      ioptio = 0                       ! Check Vertical coordinate options
136      IF( ln_zco      )   ioptio = ioptio + 1
137      IF( ln_zps      )   ioptio = ioptio + 1
138      IF( ln_sco      )   ioptio = ioptio + 1
139      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
140
141
142      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
143      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
144     
145
146      !                                ! deepest/shallowest W level Above/Below ~10m
147!!gm BUG in s-coordinate this does not work!
148      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
149      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
150      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
151!!gm end bug
152      !
153      IF( nprint == 1 .AND. lwp )   THEN
154         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
155         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
156         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
157            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
158         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
159            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
160            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
161            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
162
163         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
164            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
165         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
166            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
167            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
168            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
169      ENDIF
170      !
171      IF( nn_timing == 1 )  CALL timing_stop('dom_zgr')
172      !
173   END SUBROUTINE dom_zgr
174
175
176   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
177      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
178      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
179      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
180      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
181      &                 k_top  , k_bot    )                            ! top & bottom ocean level
182      !!---------------------------------------------------------------------
183      !!              ***  ROUTINE zgr_read  ***
184      !!
185      !! ** Purpose :   Read the vertical information in the domain configuration file
186      !!
187      !!----------------------------------------------------------------------
188      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
189      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
190      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
191      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
192      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
193      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
194      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
195      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
196      !
197      INTEGER  ::   jk     ! dummy loop index
198      INTEGER  ::   inum   ! local logical unit
199      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
200      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
201      !!----------------------------------------------------------------------
202      !
203      IF(lwp) THEN
204         WRITE(numout,*)
205         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
206         WRITE(numout,*) '   ~~~~~~~~'
207      ENDIF
208      !
209      CALL iom_open( cn_domcfg, inum )
210      !
211      !                          !* type of vertical coordinate
212      CALL iom_get( inum, 'ln_zco'   , z_zco )
213      CALL iom_get( inum, 'ln_zps'   , z_zps )
214      CALL iom_get( inum, 'ln_sco'   , z_sco )
215      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
216      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
217      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
218      !
219      !                          !* ocean cavities under iceshelves
220      CALL iom_get( inum, 'ln_isfcav', z_cav )
221      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
222      !
223      !                          !* vertical scale factors
224      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
225      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
226      !
227      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  , lrowattr=ln_use_jattr )    ! 3D coordinate
228      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  , lrowattr=ln_use_jattr )
229      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  , lrowattr=ln_use_jattr )
230      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  , lrowattr=ln_use_jattr )
231      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  , lrowattr=ln_use_jattr )
232      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw , lrowattr=ln_use_jattr )
233      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw , lrowattr=ln_use_jattr )
234      !
235      !                          !* depths
236      !                                   !- old depth definition (obsolescent feature)
237      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
238         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
239         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
240         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
241         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
242            &           '           depths at t- and w-points read in the domain configuration file')
243         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
244         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
245         CALL iom_get( inum, jpdom_data   , 'gdept_0' , pdept , lrowattr=ln_use_jattr )
246         CALL iom_get( inum, jpdom_data   , 'gdepw_0' , pdepw , lrowattr=ln_use_jattr )
247         !
248      ELSE                                !- depths computed from e3. scale factors
249         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
250         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
251         IF(lwp) THEN
252            WRITE(numout,*)
253            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
254            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
255            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
256         ENDIF
257      ENDIF
258      !
259      !                          !* ocean top and bottom level
260      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d  , lrowattr=ln_use_jattr )   ! 1st wet T-points (ISF)
261      k_top(:,:) = INT( z2d(:,:) )
262      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d  , lrowattr=ln_use_jattr )   ! last wet T-points
263      k_bot(:,:) = INT( z2d(:,:) )
264      !
265      ! bathymetry with orography (wetting and drying only)
266      IF( ln_wd )  CALL iom_get( inum, jpdom_data, 'ht_wd' , ht_wd  , lrowattr=ln_use_jattr )
267      !
268      CALL iom_close( inum )
269      !
270   END SUBROUTINE zgr_read
271
272
273   SUBROUTINE zgr_top_bot( k_top, k_bot )
274      !!----------------------------------------------------------------------
275      !!                    ***  ROUTINE zgr_top_bot  ***
276      !!
277      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
278      !!
279      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
280      !!
281      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
282      !!                                     ocean level at t-, u- & v-points
283      !!                                     (min value = 1)
284      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
285      !!                                     ocean level at t-, u- & v-points
286      !!                                     (min value = 1 over land)
287      !!----------------------------------------------------------------------
288      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
289      !
290      INTEGER ::   ji, jj   ! dummy loop indices
291      REAL(wp), POINTER, DIMENSION(:,:) ::  zk
292      !!----------------------------------------------------------------------
293      !
294      IF( nn_timing == 1 )  CALL timing_start('zgr_top_bot')
295      !
296      CALL wrk_alloc( jpi,jpj,   zk )
297      !
298      IF(lwp) WRITE(numout,*)
299      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
300      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
301      !
302      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
303      !
304      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
305 
306      !                                    ! N.B.  top     k-index of W-level = mikt
307      !                                    !       bottom  k-index of W-level = mbkt+1
308      DO jj = 1, jpjm1
309         DO ji = 1, jpim1
310            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
311            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
312            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
313            !
314            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
315            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
316         END DO
317      END DO
318      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
319      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   miku(:,:) = MAX( INT( zk(:,:) ), 1 )
320      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mikv(:,:) = MAX( INT( zk(:,:) ), 1 )
321      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( zk, 'F', 1. )   ;   mikf(:,:) = MAX( INT( zk(:,:) ), 1 )
322      !
323      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   mbku(:,:) = MAX( INT( zk(:,:) ), 1 )
324      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mbkv(:,:) = MAX( INT( zk(:,:) ), 1 )
325      !
326      CALL wrk_dealloc( jpi,jpj,   zk )
327      !
328      IF( nn_timing == 1 )  CALL timing_stop('zgr_top_bot')
329      !
330   END SUBROUTINE zgr_top_bot
331
332   !!======================================================================
333END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.