| 1 | MODULE traldf_iso |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_iso *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1994-08 (G. Madec, M. Imbard) |
|---|
| 7 | !! 8.0 ! 1997-05 (G. Madec) split into traldf and trazdf |
|---|
| 8 | !! NEMO ! 2002-08 (G. Madec) Free form, F90 |
|---|
| 9 | !! 1.0 ! 2005-11 (G. Madec) merge traldf and trazdf :-) |
|---|
| 10 | !! 3.3 ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.7 ! 2014-01 (G. Madec, S. Masson) restructuration/simplification of aht/aeiv specification |
|---|
| 12 | !! - ! 2014-02 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_ldf_iso : update the tracer trend with the horizontal component of a iso-neutral laplacian operator |
|---|
| 17 | !! and with the vertical part of the isopycnal or geopotential s-coord. operator |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and active tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 22 | USE zdf_oce ! ocean vertical physics |
|---|
| 23 | USE ldftra ! lateral diffusion: tracer eddy coefficients |
|---|
| 24 | USE ldfslp ! iso-neutral slopes |
|---|
| 25 | USE diaptr ! poleward transport diagnostics |
|---|
| 26 | ! |
|---|
| 27 | USE in_out_manager ! I/O manager |
|---|
| 28 | USE iom ! I/O library |
|---|
| 29 | USE phycst ! physical constants |
|---|
| 30 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 31 | USE wrk_nemo ! Memory Allocation |
|---|
| 32 | USE timing ! Timing |
|---|
| 33 | #if defined key_bdy |
|---|
| 34 | USE bdy_oce |
|---|
| 35 | #endif |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC tra_ldf_iso ! routine called by step.F90 |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "domzgr_substitute.h90" |
|---|
| 44 | # include "vectopt_loop_substitute.h90" |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
|---|
| 47 | !! $Id$ |
|---|
| 48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv , & |
|---|
| 53 | & pgui, pgvi, & |
|---|
| 54 | & ptb , ptbb, pta , kjpt, kpass ) |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE tra_ldf_iso *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 59 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 60 | !! add it to the general trend of tracer equation. |
|---|
| 61 | !! |
|---|
| 62 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 63 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 64 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 65 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 66 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 67 | !! |
|---|
| 68 | !! 1st part : masked horizontal derivative of T ( di[ t ] ) |
|---|
| 69 | !! ======== with partial cell update if ln_zps=T |
|---|
| 70 | !! with top cell update if ln_isfcav |
|---|
| 71 | !! |
|---|
| 72 | !! 2nd part : horizontal fluxes of the lateral mixing operator |
|---|
| 73 | !! ======== |
|---|
| 74 | !! zftu = pahu e2u*e3u/e1u di[ tb ] |
|---|
| 75 | !! - pahu e2u*uslp dk[ mi(mk(tb)) ] |
|---|
| 76 | !! zftv = pahv e1v*e3v/e2v dj[ tb ] |
|---|
| 77 | !! - pahv e2u*vslp dk[ mj(mk(tb)) ] |
|---|
| 78 | !! take the horizontal divergence of the fluxes: |
|---|
| 79 | !! difft = 1/(e1e2t*e3t) { di-1[ zftu ] + dj-1[ zftv ] } |
|---|
| 80 | !! Add this trend to the general trend (ta,sa): |
|---|
| 81 | !! ta = ta + difft |
|---|
| 82 | !! |
|---|
| 83 | !! 3rd part: vertical trends of the lateral mixing operator |
|---|
| 84 | !! ======== (excluding the vertical flux proportional to dk[t] ) |
|---|
| 85 | !! vertical fluxes associated with the rotated lateral mixing: |
|---|
| 86 | !! zftw = - { mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ] |
|---|
| 87 | !! + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ] } |
|---|
| 88 | !! take the horizontal divergence of the fluxes: |
|---|
| 89 | !! difft = 1/(e1e2t*e3t) dk[ zftw ] |
|---|
| 90 | !! Add this trend to the general trend (ta,sa): |
|---|
| 91 | !! pta = pta + difft |
|---|
| 92 | !! |
|---|
| 93 | !! ** Action : Update pta arrays with the before rotated diffusion |
|---|
| 94 | !!---------------------------------------------------------------------- |
|---|
| 95 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 96 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 97 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 98 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 99 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 100 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 101 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
|---|
| 102 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 103 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 104 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptbb ! tracer (only used in kpass=2) |
|---|
| 105 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 106 | ! |
|---|
| 107 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 108 | INTEGER :: ierr ! local integer |
|---|
| 109 | REAL(wp) :: zmsku, zahu_w, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 110 | REAL(wp) :: zmskv, zahv_w, zabe2, zcof2, zcoef4 ! - - |
|---|
| 111 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 112 | #if defined key_diaar5 |
|---|
| 113 | REAL(wp) :: zztmp ! local scalar |
|---|
| 114 | #endif |
|---|
| 115 | REAL(wp), POINTER, DIMENSION(:,:) :: zdkt, zdk1t, z2d |
|---|
| 116 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, zftu, zftv, ztfw |
|---|
| 117 | REAL(wp), DIMENSION(jpi,jpj) :: zfactor ! multiplier for diffusion |
|---|
| 118 | !!---------------------------------------------------------------------- |
|---|
| 119 | ! |
|---|
| 120 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_iso') |
|---|
| 121 | ! |
|---|
| 122 | CALL wrk_alloc( jpi,jpj, zdkt, zdk1t, z2d ) |
|---|
| 123 | CALL wrk_alloc( jpi,jpj,jpk, zdit, zdjt , zftu, zftv, ztfw ) |
|---|
| 124 | ! |
|---|
| 125 | IF( kt == kit000 ) THEN |
|---|
| 126 | IF(lwp) WRITE(numout,*) |
|---|
| 127 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype |
|---|
| 128 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
|---|
| 129 | ! |
|---|
| 130 | akz (:,:,:) = 0._wp |
|---|
| 131 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 132 | ENDIF |
|---|
| 133 | ! |
|---|
| 134 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 135 | IF( neuler == 0 .AND. kt == nit000 ) THEN ; z2dt = rdttra(1) ! at nit000 (Euler) |
|---|
| 136 | ELSE ; z2dt = 2.* rdttra(1) ! (Leapfrog) |
|---|
| 137 | ENDIF |
|---|
| 138 | z1_2dt = 1._wp / z2dt |
|---|
| 139 | ! |
|---|
| 140 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 141 | ELSE ; zsign = -1._wp |
|---|
| 142 | ENDIF |
|---|
| 143 | |
|---|
| 144 | |
|---|
| 145 | !!---------------------------------------------------------------------- |
|---|
| 146 | !! 0 - calculate ah_wslp2 and akz |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | ! |
|---|
| 149 | IF( kpass == 1 ) THEN !== first pass only ==! |
|---|
| 150 | ! |
|---|
| 151 | DO jk = 2, jpkm1 |
|---|
| 152 | DO jj = 2, jpjm1 |
|---|
| 153 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 154 | ! |
|---|
| 155 | zmsku = tmask(ji,jj,jk) / MAX( umask(ji ,jj,jk-1) + umask(ji-1,jj,jk) & |
|---|
| 156 | & + umask(ji-1,jj,jk-1) + umask(ji ,jj,jk) , 1._wp ) |
|---|
| 157 | zmskv = tmask(ji,jj,jk) / MAX( vmask(ji,jj ,jk-1) + vmask(ji,jj-1,jk) & |
|---|
| 158 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj ,jk) , 1._wp ) |
|---|
| 159 | ! |
|---|
| 160 | zahu_w = ( pahu(ji ,jj,jk-1) + pahu(ji-1,jj,jk) & |
|---|
| 161 | & + pahu(ji-1,jj,jk-1) + pahu(ji ,jj,jk) ) * zmsku |
|---|
| 162 | zahv_w = ( pahv(ji,jj ,jk-1) + pahv(ji,jj-1,jk) & |
|---|
| 163 | & + pahv(ji,jj-1,jk-1) + pahv(ji,jj ,jk) ) * zmskv |
|---|
| 164 | ! |
|---|
| 165 | ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
|---|
| 166 | & + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk) |
|---|
| 167 | END DO |
|---|
| 168 | END DO |
|---|
| 169 | END DO |
|---|
| 170 | ! |
|---|
| 171 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 172 | DO jk = 2, jpkm1 |
|---|
| 173 | DO jj = 2, jpjm1 |
|---|
| 174 | DO ji = fs_2, fs_jpim1 |
|---|
| 175 | akz(ji,jj,jk) = 0.25_wp * ( & |
|---|
| 176 | & ( pahu(ji ,jj,jk) + pahu(ji ,jj,jk-1) ) / ( e1u(ji ,jj) * e1u(ji ,jj) ) & |
|---|
| 177 | & + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) ) & |
|---|
| 178 | & + ( pahv(ji,jj ,jk) + pahv(ji,jj ,jk-1) ) / ( e2v(ji,jj ) * e2v(ji,jj ) ) & |
|---|
| 179 | & + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) ) ) |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | END DO |
|---|
| 183 | ! |
|---|
| 184 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 185 | DO jk = 2, jpkm1 |
|---|
| 186 | DO jj = 1, jpjm1 |
|---|
| 187 | DO ji = 1, fs_jpim1 |
|---|
| 188 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 189 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( fse3w(ji,jj,jk) * fse3w(ji,jj,jk) ) ) |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 194 | DO jk = 2, jpkm1 |
|---|
| 195 | DO jj = 1, jpjm1 |
|---|
| 196 | DO ji = 1, fs_jpim1 |
|---|
| 197 | ze3w_2 = fse3w(ji,jj,jk) * fse3w(ji,jj,jk) |
|---|
| 198 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 199 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 200 | END DO |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | ENDIF |
|---|
| 204 | ! |
|---|
| 205 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 206 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 207 | ENDIF |
|---|
| 208 | ENDIF |
|---|
| 209 | ! |
|---|
| 210 | #if defined key_bdy |
|---|
| 211 | zfactor(:,:) = sponge_factor(:,:) |
|---|
| 212 | #else |
|---|
| 213 | zfactor(:,:) = 1.0 |
|---|
| 214 | #endif |
|---|
| 215 | ! ! =========== |
|---|
| 216 | DO jn = 1, kjpt ! tracer loop |
|---|
| 217 | ! ! =========== |
|---|
| 218 | ! |
|---|
| 219 | !!---------------------------------------------------------------------- |
|---|
| 220 | !! I - masked horizontal derivative |
|---|
| 221 | !!---------------------------------------------------------------------- |
|---|
| 222 | !!gm : bug.... why (x,:,:)? (1,jpj,:) and (jpi,1,:) should be sufficient.... |
|---|
| 223 | zdit (1,:,:) = 0._wp ; zdit (jpi,:,:) = 0._wp |
|---|
| 224 | zdjt (1,:,:) = 0._wp ; zdjt (jpi,:,:) = 0._wp |
|---|
| 225 | !!end |
|---|
| 226 | |
|---|
| 227 | ! Horizontal tracer gradient |
|---|
| 228 | DO jk = 1, jpkm1 |
|---|
| 229 | DO jj = 1, jpjm1 |
|---|
| 230 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 231 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 232 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | END DO |
|---|
| 236 | IF( ln_zps ) THEN ! botton and surface ocean correction of the horizontal gradient |
|---|
| 237 | DO jj = 1, jpjm1 ! bottom correction (partial bottom cell) |
|---|
| 238 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 239 | !!gm the following anonymous remark is to considered: ! IF useless if zpshde defines pgu everywhere |
|---|
| 240 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 241 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 242 | END DO |
|---|
| 243 | END DO |
|---|
| 244 | IF( ln_isfcav ) THEN ! first wet level beneath a cavity |
|---|
| 245 | DO jj = 1, jpjm1 |
|---|
| 246 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 247 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn) |
|---|
| 248 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn) |
|---|
| 249 | END DO |
|---|
| 250 | END DO |
|---|
| 251 | ENDIF |
|---|
| 252 | ENDIF |
|---|
| 253 | |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | !! II - horizontal trend (full) |
|---|
| 256 | !!---------------------------------------------------------------------- |
|---|
| 257 | ! |
|---|
| 258 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 259 | ! |
|---|
| 260 | ! !== Vertical tracer gradient |
|---|
| 261 | zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1) ! level jk+1 |
|---|
| 262 | ! |
|---|
| 263 | IF( jk == 1 ) THEN ; zdkt(:,:) = zdk1t(:,:) ! surface: zdkt(jk=1)=zdkt(jk=2) |
|---|
| 264 | ELSE ; zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk) |
|---|
| 265 | ENDIF |
|---|
| 266 | !!gm I don't understand why we should need this.... since wmask is used instead of tmask |
|---|
| 267 | ! IF ( ln_isfcav ) THEN |
|---|
| 268 | ! DO jj = 1, jpj |
|---|
| 269 | ! DO ji = 1, jpi ! vector opt. |
|---|
| 270 | ! ikt = mikt(ji,jj) ! surface level |
|---|
| 271 | ! zdk1t(ji,jj,ikt) = ( ptb(ji,jj,ikt,jn ) - ptb(ji,jj,ikt+1,jn) ) * wmask(ji,jj,ikt+1) |
|---|
| 272 | ! zdkt (ji,jj,ikt) = zdk1t(ji,jj,ikt) |
|---|
| 273 | ! END DO |
|---|
| 274 | ! END DO |
|---|
| 275 | ! END IF |
|---|
| 276 | !!gm |
|---|
| 277 | |
|---|
| 278 | DO jj = 1 , jpjm1 !== Horizontal fluxes |
|---|
| 279 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 280 | zabe1 = zfactor(ji,jj) * pahu(ji,jj,jk) * e2_e1u(ji,jj) * fse3u_n(ji,jj,jk) |
|---|
| 281 | zabe2 = zfactor(ji,jj) * pahv(ji,jj,jk) * e1_e2v(ji,jj) * fse3v_n(ji,jj,jk) |
|---|
| 282 | ! |
|---|
| 283 | zmsku = 1. / MAX( tmask(ji+1,jj,jk ) + tmask(ji,jj,jk+1) & |
|---|
| 284 | & + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk ), 1. ) |
|---|
| 285 | ! |
|---|
| 286 | zmskv = 1. / MAX( tmask(ji,jj+1,jk ) + tmask(ji,jj,jk+1) & |
|---|
| 287 | & + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk ), 1. ) |
|---|
| 288 | ! |
|---|
| 289 | zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku |
|---|
| 290 | zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv |
|---|
| 291 | ! |
|---|
| 292 | zftu(ji,jj,jk ) = ( zabe1 * zdit(ji,jj,jk) & |
|---|
| 293 | & + zcof1 * ( zdkt (ji+1,jj) + zdk1t(ji,jj) & |
|---|
| 294 | & + zdk1t(ji+1,jj) + zdkt (ji,jj) ) ) * umask(ji,jj,jk) |
|---|
| 295 | zftv(ji,jj,jk) = ( zabe2 * zdjt(ji,jj,jk) & |
|---|
| 296 | & + zcof2 * ( zdkt (ji,jj+1) + zdk1t(ji,jj) & |
|---|
| 297 | & + zdk1t(ji,jj+1) + zdkt (ji,jj) ) ) * vmask(ji,jj,jk) |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | ! |
|---|
| 301 | DO jj = 2 , jpjm1 !== horizontal divergence and add to pta |
|---|
| 302 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 303 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) & |
|---|
| 304 | & + zftv(ji,jj,jk) - zftv(ji,jj-1,jk) ) & |
|---|
| 305 | & / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 306 | END DO |
|---|
| 307 | END DO |
|---|
| 308 | END DO ! End of slab |
|---|
| 309 | |
|---|
| 310 | |
|---|
| 311 | !!---------------------------------------------------------------------- |
|---|
| 312 | !! III - vertical trend (full) |
|---|
| 313 | !!---------------------------------------------------------------------- |
|---|
| 314 | |
|---|
| 315 | ztfw(1,:,:) = 0._wp ; ztfw(jpi,:,:) = 0._wp |
|---|
| 316 | |
|---|
| 317 | ! Vertical fluxes |
|---|
| 318 | ! --------------- |
|---|
| 319 | |
|---|
| 320 | ! Surface and bottom vertical fluxes set to zero |
|---|
| 321 | ztfw(:,:, 1 ) = 0._wp ; ztfw(:,:,jpk) = 0._wp |
|---|
| 322 | |
|---|
| 323 | ! interior (2=<jk=<jpk-1) |
|---|
| 324 | DO jk = 2, jpkm1 |
|---|
| 325 | DO jj = 2, jpjm1 |
|---|
| 326 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 327 | ! |
|---|
| 328 | zmsku = tmask(ji,jj,jk) / MAX( umask(ji ,jj,jk-1) + umask(ji-1,jj,jk) & |
|---|
| 329 | & + umask(ji-1,jj,jk-1) + umask(ji ,jj,jk) , 1._wp ) |
|---|
| 330 | zmskv = tmask(ji,jj,jk) / MAX( vmask(ji,jj ,jk-1) + vmask(ji,jj-1,jk) & |
|---|
| 331 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj ,jk) , 1._wp ) |
|---|
| 332 | ! |
|---|
| 333 | zahu_w = ( pahu(ji ,jj,jk-1) + pahu(ji-1,jj,jk) & |
|---|
| 334 | & + pahu(ji-1,jj,jk-1) + pahu(ji ,jj,jk) ) * zmsku |
|---|
| 335 | zahv_w = ( pahv(ji,jj ,jk-1) + pahv(ji,jj-1,jk) & |
|---|
| 336 | & + pahv(ji,jj-1,jk-1) + pahv(ji,jj ,jk) ) * zmskv |
|---|
| 337 | ! |
|---|
| 338 | zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk) !wslpi & j are already w-masked |
|---|
| 339 | zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk) |
|---|
| 340 | ! |
|---|
| 341 | ztfw(ji,jj,jk) = zcoef3 * ( zdit(ji ,jj ,jk-1) + zdit(ji-1,jj ,jk) & |
|---|
| 342 | & + zdit(ji-1,jj ,jk-1) + zdit(ji ,jj ,jk) ) & |
|---|
| 343 | & + zcoef4 * ( zdjt(ji ,jj ,jk-1) + zdjt(ji ,jj-1,jk) & |
|---|
| 344 | & + zdjt(ji ,jj-1,jk-1) + zdjt(ji ,jj ,jk) ) |
|---|
| 345 | END DO |
|---|
| 346 | END DO |
|---|
| 347 | END DO |
|---|
| 348 | ! |
|---|
| 349 | ! !== add the vertical 33 flux ==! |
|---|
| 350 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 351 | DO jk = 2, jpkm1 |
|---|
| 352 | DO jj = 1, jpjm1 |
|---|
| 353 | DO ji = fs_2, fs_jpim1 |
|---|
| 354 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / fse3w(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 355 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 356 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 357 | END DO |
|---|
| 358 | END DO |
|---|
| 359 | END DO |
|---|
| 360 | ! |
|---|
| 361 | ELSE ! bilaplacian |
|---|
| 362 | SELECT CASE( kpass ) |
|---|
| 363 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 364 | DO jk = 2, jpkm1 |
|---|
| 365 | DO jj = 1, jpjm1 |
|---|
| 366 | DO ji = fs_2, fs_jpim1 |
|---|
| 367 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) & |
|---|
| 368 | & + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj) & |
|---|
| 369 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * tmask(ji,jj,jk) / fse3w(ji,jj,jk) |
|---|
| 370 | END DO |
|---|
| 371 | END DO |
|---|
| 372 | END DO |
|---|
| 373 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb and ptbb gradients, resp. |
|---|
| 374 | DO jk = 2, jpkm1 |
|---|
| 375 | DO jj = 1, jpjm1 |
|---|
| 376 | DO ji = fs_2, fs_jpim1 |
|---|
| 377 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / fse3w(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 378 | & * ( ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) ) & |
|---|
| 379 | & + akz (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) ) ) |
|---|
| 380 | END DO |
|---|
| 381 | END DO |
|---|
| 382 | END DO |
|---|
| 383 | END SELECT |
|---|
| 384 | ENDIF |
|---|
| 385 | ! |
|---|
| 386 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to pta ==! |
|---|
| 387 | DO jj = 2, jpjm1 |
|---|
| 388 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 389 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1) ) & |
|---|
| 390 | & / ( e1e2t(ji,jj) * fse3t_n(ji,jj,jk) ) |
|---|
| 391 | END DO |
|---|
| 392 | END DO |
|---|
| 393 | END DO |
|---|
| 394 | ! |
|---|
| 395 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 396 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 397 | ! |
|---|
| 398 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 399 | IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN |
|---|
| 400 | ! note sign is reversed to give down-gradient diffusive transports (#1043) |
|---|
| 401 | IF( jn == jp_tem) htr_ldf(:) = ptr_sj( -zftv(:,:,:) ) |
|---|
| 402 | IF( jn == jp_sal) str_ldf(:) = ptr_sj( -zftv(:,:,:) ) |
|---|
| 403 | ENDIF |
|---|
| 404 | ! |
|---|
| 405 | IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN |
|---|
| 406 | ! |
|---|
| 407 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
|---|
| 408 | z2d(:,:) = zftu(ji,jj,1) |
|---|
| 409 | DO jk = 2, jpkm1 |
|---|
| 410 | DO jj = 2, jpjm1 |
|---|
| 411 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 412 | z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) |
|---|
| 413 | END DO |
|---|
| 414 | END DO |
|---|
| 415 | END DO |
|---|
| 416 | !!gm CAUTION I think there is an error of sign when using BLP operator.... |
|---|
| 417 | !!gm a multiplication by zsign is required (to be checked twice !) |
|---|
| 418 | z2d(:,:) = - rau0_rcp * z2d(:,:) ! note sign is reversed to give down-gradient diffusive transports (#1043) |
|---|
| 419 | CALL lbc_lnk( z2d, 'U', -1. ) |
|---|
| 420 | CALL iom_put( "udiff_heattr", z2d ) ! heat transport in i-direction |
|---|
| 421 | ! |
|---|
| 422 | z2d(:,:) = zftv(ji,jj,1) |
|---|
| 423 | DO jk = 2, jpkm1 |
|---|
| 424 | DO jj = 2, jpjm1 |
|---|
| 425 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 426 | z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) |
|---|
| 427 | END DO |
|---|
| 428 | END DO |
|---|
| 429 | END DO |
|---|
| 430 | z2d(:,:) = - rau0_rcp * z2d(:,:) ! note sign is reversed to give down-gradient diffusive transports (#1043) |
|---|
| 431 | CALL lbc_lnk( z2d, 'V', -1. ) |
|---|
| 432 | CALL iom_put( "vdiff_heattr", z2d ) ! heat transport in i-direction |
|---|
| 433 | END IF |
|---|
| 434 | ! |
|---|
| 435 | ENDIF |
|---|
| 436 | ! |
|---|
| 437 | ENDIF !== end pass selection ==! |
|---|
| 438 | ! |
|---|
| 439 | ! ! =============== |
|---|
| 440 | END DO ! end tracer loop |
|---|
| 441 | ! ! =============== |
|---|
| 442 | ! |
|---|
| 443 | CALL wrk_dealloc( jpi, jpj, zdkt, zdk1t, z2d ) |
|---|
| 444 | CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , zftu, zftv, ztfw ) |
|---|
| 445 | ! |
|---|
| 446 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_iso') |
|---|
| 447 | ! |
|---|
| 448 | END SUBROUTINE tra_ldf_iso |
|---|
| 449 | |
|---|
| 450 | !!============================================================================== |
|---|
| 451 | END MODULE traldf_iso |
|---|
