New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/UKMO/r5518_bdy_sponge_temp/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/r5518_bdy_sponge_temp/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 7123

Last change on this file since 7123 was 7123, checked in by jcastill, 8 years ago

Changes as in UKMO/dev_r5518_bdy_sponge_temp@5878
File size: 9.1 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  OPA  ! 1987-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 ! 1991-11  (G. Madec)
8   !!                 ! 1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 ! 1996-01  (G. Madec)  statement function for e3
10   !!            NEMO ! 2002-06  (G. Madec)  F90: Free form and module
11   !!            1.0  ! 2004-08  (C. Talandier) New trends organization
12   !!                 ! 2005-11  (G. Madec)  add zps case
13   !!            3.0  ! 2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!            3.7  ! 2014-01  (G. Madec, S. Masson) re-entrant laplacian
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   tra_ldf_lap : update the tracer trend with the lateral diffusion : iso-level laplacian operator
19   !!   tra_ldf_blp : update the tracer trend with the lateral diffusion : iso-level bilaplacian operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra          ! lateral physics: eddy diffusivity
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
27   !
28   USE in_out_manager  ! I/O manager
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp         ! distribued memory computing library
31   USE timing          ! Timing
32#if defined key_bdy 
33   USE bdy_oce 
34#endif
35   USE wrk_nemo        ! Memory allocation
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_ldf_lap   ! routine called by traldf.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
53      &                                                    pgui, pgvi,   &
54      &                                        ptb , pta , kjpt, kpass ) 
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf_lap  ***
57      !!                   
58      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59      !!      trend and add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   Second order diffusive operator evaluated using before
62      !!      fields (forward time scheme). The horizontal diffusive trends of
63      !!      the tracer is given by:
64      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
65      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
66      !!      Add this trend to the general tracer trend pta :
67      !!          pta = pta + difft
68      !!
69      !! ** Action  : - Update pta arrays with the before iso-level
70      !!                harmonic mixing trend.
71      !!----------------------------------------------------------------------
72      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
76      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
77      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
78      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
79      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
82      !
83      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
84      REAL(wp) ::   zsign            ! local scalars
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztu, ztv, zaheeu, zaheev
86      REAL(wp), DIMENSION(jpi,jpj)        ::  zfactor  ! multiplier for diffusion
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )   CALL timing_start('tra_ldf_lap')
90      !
91      IF( kt == nit000 .AND. lwp )  THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
94         WRITE(numout,*) '~~~~~~~~~~~ '
95      ENDIF
96#if defined key_bdy 
97     zfactor(:,:) = sponge_factor(:,:) 
98#else
99     zfactor(:,:) = 1.0 
100#endif 
101      !
102      CALL wrk_alloc( jpi,jpj,jpk,   ztu, ztv, zaheeu, zaheev ) 
103      !
104      !                                !==  Initialization of metric arrays used for all tracers  ==!
105      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
106      ELSE                    ;   zsign = -1._wp
107      ENDIF
108      DO jk = 1, jpkm1
109         DO jj = 1, jpjm1
110            DO ji = 1, fs_jpim1   ! vector opt.
111               zaheeu(ji,jj,jk) = zfactor(ji,jj) * zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * fse3u_n(ji,jj,jk)   !!gm   * umask(ji,jj,jk) pah masked!
112               zaheev(ji,jj,jk) = zfactor(ji,jj) * zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * fse3v_n(ji,jj,jk)   !!gm   * vmask(ji,jj,jk)
113            END DO
114         END DO
115      END DO
116      !
117      !                             ! =========== !
118      DO jn = 1, kjpt               ! tracer loop !
119         !                          ! =========== !   
120         !                               
121         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
122            DO jj = 1, jpjm1
123               DO ji = 1, fs_jpim1
124                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
125                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
126               END DO
127            END DO
128         END DO 
129         IF( ln_zps ) THEN                ! set gradient at bottom/top ocean level
130            DO jj = 1, jpjm1                    ! bottom
131               DO ji = 1, fs_jpim1
132                  ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn)
133                  ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn)
134               END DO
135            END DO 
136            IF( ln_isfcav ) THEN                ! top in ocean cavities only
137               DO jj = 1, jpjm1
138                  DO ji = 1, fs_jpim1   ! vector opt.
139                     IF( miku(ji,jj) > 1 )   ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) 
140                     IF( mikv(ji,jj) > 1 )   ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) 
141                  END DO
142               END DO
143            ENDIF
144         ENDIF
145         !
146         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
147            DO jj = 2, jpjm1
148               DO ji = fs_2, fs_jpim1
149                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
150                     &                                   + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
151                     &                                / ( e1e2t(ji,jj) * fse3t_n(ji,jj,jk) )
152               END DO
153            END DO
154         END DO 
155         !
156         !                             !== "Poleward" diffusive heat or salt transports  ==!
157         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
158             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
159            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
160               IF( jn  == jp_tem)   htr_ldf(:) = ptr_sj( -ztv(:,:,:) )
161               IF( jn  == jp_sal)   str_ldf(:) = ptr_sj( -ztv(:,:,:) )
162            ENDIF
163         ENDIF
164         !                          ! ==================
165      END DO                        ! end of tracer loop
166      !                             ! ==================
167      !
168      CALL wrk_dealloc( jpi,jpj,jpk,   ztu, ztv, zaheeu, zaheev ) 
169      !
170      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_lap')
171      !
172   END SUBROUTINE tra_ldf_lap
173   
174   !!==============================================================================
175END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.