1 | MODULE limthd_2 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limthd_2 *** |
---|
4 | !! LIM thermo ice model : ice thermodynamic |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2000-01 (LIM) |
---|
7 | !! 2.0 ! 2002-07 (C. Ethe, G. Madec) F90 |
---|
8 | !! 2.0 ! 2003-08 (C. Ethe) add lim_thd_init |
---|
9 | !! - ! 2008-2008 (A. Caubel, G. Madec, E. Maisonnave, S. Masson ) generic coupled interface |
---|
10 | !!--------------------------------------------------------------------- |
---|
11 | #if defined key_lim2 |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! 'key_lim2' : LIM 2.0 sea-ice model |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! lim_thd_2 : thermodynamic of sea ice |
---|
16 | !! lim_thd_init_2 : initialisation of sea-ice thermodynamic |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE phycst ! physical constants |
---|
19 | USE dom_oce ! ocean space and time domain variables |
---|
20 | USE domvvl |
---|
21 | USE lbclnk |
---|
22 | USE in_out_manager ! I/O manager |
---|
23 | USE lib_mpp |
---|
24 | USE wrk_nemo ! work arrays |
---|
25 | USE iom ! IOM library |
---|
26 | USE ice_2 ! LIM sea-ice variables |
---|
27 | USE sbc_oce ! |
---|
28 | USE sbc_ice ! |
---|
29 | USE thd_ice_2 ! LIM thermodynamic sea-ice variables |
---|
30 | USE dom_ice_2 ! LIM sea-ice domain |
---|
31 | USE limthd_zdf_2 |
---|
32 | USE limthd_lac_2 |
---|
33 | USE limtab_2 |
---|
34 | USE prtctl ! Print control |
---|
35 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
36 | |
---|
37 | IMPLICIT NONE |
---|
38 | PRIVATE |
---|
39 | |
---|
40 | PUBLIC lim_thd_2 ! called by lim_step |
---|
41 | |
---|
42 | REAL(wp) :: epsi20 = 1.e-20 ! constant values |
---|
43 | REAL(wp) :: epsi16 = 1.e-16 ! |
---|
44 | REAL(wp) :: epsi04 = 1.e-04 ! |
---|
45 | REAL(wp) :: rzero = 0.e0 ! |
---|
46 | REAL(wp) :: rone = 1.e0 ! |
---|
47 | |
---|
48 | !! * Substitutions |
---|
49 | # include "domzgr_substitute.h90" |
---|
50 | # include "vectopt_loop_substitute.h90" |
---|
51 | !!-------- ------------------------------------------------------------- |
---|
52 | !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010) |
---|
53 | !! $Id$ |
---|
54 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | CONTAINS |
---|
57 | |
---|
58 | SUBROUTINE lim_thd_2( kt ) |
---|
59 | !!------------------------------------------------------------------- |
---|
60 | !! *** ROUTINE lim_thd_2 *** |
---|
61 | !! |
---|
62 | !! ** Purpose : This routine manages the ice thermodynamic. |
---|
63 | !! |
---|
64 | !! ** Action : - Initialisation of some variables |
---|
65 | !! - Some preliminary computation (oceanic heat flux |
---|
66 | !! at the ice base, snow acc.,heat budget of the leads) |
---|
67 | !! - selection of the icy points and put them in an array |
---|
68 | !! - call lim_vert_ther for vert ice thermodynamic |
---|
69 | !! - back to the geographic grid |
---|
70 | !! - selection of points for lateral accretion |
---|
71 | !! - call lim_lat_acc for the ice accretion |
---|
72 | !! - back to the geographic grid |
---|
73 | !! |
---|
74 | !! References : Goosse et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90 |
---|
75 | !!--------------------------------------------------------------------- |
---|
76 | INTEGER, INTENT(in) :: kt ! number of iteration |
---|
77 | !! |
---|
78 | INTEGER :: ji, jj ! dummy loop indices |
---|
79 | INTEGER :: nbpb ! nb of icy pts for thermo. cal. |
---|
80 | INTEGER :: nbpac ! nb of pts for lateral accretion |
---|
81 | CHARACTER (len=22) :: charout |
---|
82 | REAL(wp) :: zfric_umin = 5e-03 ! lower bound for the friction velocity |
---|
83 | REAL(wp) :: zfric_umax = 2e-02 ! upper bound for the friction velocity |
---|
84 | REAL(wp) :: zinda ! switch for test. the val. of concen. |
---|
85 | REAL(wp) :: zindb, zindg ! switches for test. the val of arg |
---|
86 | REAL(wp) :: zfricp ! temporary scalar |
---|
87 | REAL(wp) :: za , zh, zthsnice ! |
---|
88 | REAL(wp) :: zfric_u ! friction velocity |
---|
89 | REAL(wp) :: zfntlat, zpareff ! test. the val. of lead heat budget |
---|
90 | |
---|
91 | REAL(wp) :: zuice_m, zvice_m ! Sea-ice velocities at U & V-points |
---|
92 | REAL(wp) :: zhice_u, zhice_v ! Sea-ice volume at U & V-points |
---|
93 | REAL(wp) :: ztr_fram ! Sea-ice transport through Fram strait |
---|
94 | REAL(wp) :: zrhoij, zrhoijm1 ! temporary scalars |
---|
95 | REAL(wp) :: zztmp ! temporary scalars within a loop |
---|
96 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmp ! 2D workspace |
---|
97 | REAL(wp), POINTER, DIMENSION(:,:) :: zqlbsbq ! link with lead energy budget qldif |
---|
98 | REAL(wp), POINTER, DIMENSION(:,:) :: zlicegr ! link with lateral ice growth |
---|
99 | !!$ REAL(wp), DIMENSION(:,:) :: firic ! IR flux over the ice (outputs only) |
---|
100 | !!$ REAL(wp), DIMENSION(:,:) :: fcsic ! Sensible heat flux over the ice (outputs only) |
---|
101 | !!$ REAL(wp), DIMENSION(:,:) :: fleic ! Latent heat flux over the ice (outputs only) |
---|
102 | !!$ REAL(wp), DIMENSION(:,:) :: qlatic ! latent flux (outputs only) |
---|
103 | REAL(wp), POINTER, DIMENSION(:,:) :: zdvosif ! Variation of volume at surface (outputs only) |
---|
104 | REAL(wp), POINTER, DIMENSION(:,:) :: zdvobif ! Variation of ice volume at the bottom ice (outputs only) |
---|
105 | REAL(wp), POINTER, DIMENSION(:,:) :: zdvolif ! Total variation of ice volume (outputs only) |
---|
106 | REAL(wp), POINTER, DIMENSION(:,:) :: zdvonif ! Surface accretion Snow to Ice transformation (outputs only) |
---|
107 | REAL(wp), POINTER, DIMENSION(:,:) :: zdvomif ! Bottom variation of ice volume due to melting (outputs only) |
---|
108 | REAL(wp), POINTER, DIMENSION(:,:) :: zu_imasstr ! Sea-ice transport along i-axis at U-point (outputs only) |
---|
109 | REAL(wp), POINTER, DIMENSION(:,:) :: zv_imasstr ! Sea-ice transport along j-axis at V-point (outputs only) |
---|
110 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zmsk ! 3D workspace |
---|
111 | !!------------------------------------------------------------------- |
---|
112 | |
---|
113 | CALL wrk_alloc( jpi, jpj, ztmp, zqlbsbq, zlicegr, zdvosif, zdvobif, zdvolif, zdvonif, zdvomif, zu_imasstr, zv_imasstr ) |
---|
114 | CALL wrk_alloc( jpi, jpj, jpk, zmsk ) |
---|
115 | |
---|
116 | IF( kt == nit000 ) CALL lim_thd_init_2 ! Initialization (first time-step only) |
---|
117 | |
---|
118 | !-------------------------------------------! |
---|
119 | ! Initilization of diagnostic variables ! |
---|
120 | !-------------------------------------------! |
---|
121 | |
---|
122 | !!gm needed? yes at least for some of these arrays |
---|
123 | zdvosif(:,:) = 0.e0 ! variation of ice volume at surface |
---|
124 | zdvobif(:,:) = 0.e0 ! variation of ice volume at bottom |
---|
125 | zdvolif(:,:) = 0.e0 ! total variation of ice volume |
---|
126 | zdvonif(:,:) = 0.e0 ! transformation of snow to sea-ice volume |
---|
127 | zlicegr(:,:) = 0.e0 ! lateral variation of ice volume |
---|
128 | zdvomif(:,:) = 0.e0 ! variation of ice volume at bottom due to melting only |
---|
129 | ztr_fram = 0.e0 ! sea-ice transport through Fram strait |
---|
130 | fstric (:,:) = 0.e0 ! part of solar radiation absorbing inside the ice |
---|
131 | fscmbq (:,:) = 0.e0 ! linked with fstric |
---|
132 | ffltbif(:,:) = 0.e0 ! linked with fstric |
---|
133 | qfvbq (:,:) = 0.e0 ! linked with fstric |
---|
134 | rdm_snw(:,:) = 0.e0 ! variation of snow mass over 1 time step |
---|
135 | rdq_snw(:,:) = 0.e0 ! heat content associated with rdm_snw |
---|
136 | rdm_ice(:,:) = 0.e0 ! variation of ice mass over 1 time step |
---|
137 | rdq_ice(:,:) = 0.e0 ! heat content associated with rdm_ice |
---|
138 | zmsk (:,:,:) = 0.e0 |
---|
139 | |
---|
140 | ! set to zero snow thickness smaller than epsi04 |
---|
141 | DO jj = 1, jpj |
---|
142 | DO ji = 1, jpi |
---|
143 | hsnif(ji,jj) = hsnif(ji,jj) * MAX( rzero, SIGN( rone , hsnif(ji,jj) - epsi04 ) ) |
---|
144 | END DO |
---|
145 | END DO |
---|
146 | !!gm better coded (do not use SIGN...) |
---|
147 | ! WHERE( hsnif(:,:) < epsi04 ) hsnif(:,:) = 0.e0 |
---|
148 | !!gm |
---|
149 | |
---|
150 | IF(ln_ctl) CALL prt_ctl( tab2d_1=hsnif, clinfo1=' lim_thd: hsnif : ' ) |
---|
151 | |
---|
152 | !-----------------------------------! |
---|
153 | ! Treatment of particular cases ! |
---|
154 | !-----------------------------------! |
---|
155 | |
---|
156 | DO jj = 1, jpj |
---|
157 | DO ji = 1, jpi |
---|
158 | ! snow is transformed into ice if the original ice cover disappears. |
---|
159 | zindg = tms(ji,jj) * MAX( rzero , SIGN( rone , -hicif(ji,jj) ) ) |
---|
160 | hicif(ji,jj) = hicif(ji,jj) + zindg * rhosn * hsnif(ji,jj) / rau0 |
---|
161 | hsnif(ji,jj) = ( rone - zindg ) * hsnif(ji,jj) + zindg * hicif(ji,jj) * ( rau0 - rhoic ) / rhosn |
---|
162 | dmgwi(ji,jj) = zindg * (1.0 - frld(ji,jj)) * rhoic * hicif(ji,jj) ! snow/ice mass |
---|
163 | |
---|
164 | ! the lead fraction, frld, must be little than or equal to amax (ice ridging). |
---|
165 | zthsnice = hsnif(ji,jj) + hicif(ji,jj) |
---|
166 | zindb = tms(ji,jj) * ( 1.0 - MAX( rzero , SIGN( rone , - zthsnice ) ) ) |
---|
167 | za = zindb * MIN( rone, ( 1.0 - frld(ji,jj) ) * uscomi ) |
---|
168 | hsnif (ji,jj) = hsnif(ji,jj) * za |
---|
169 | hicif (ji,jj) = hicif(ji,jj) * za |
---|
170 | qstoif(ji,jj) = qstoif(ji,jj) * za |
---|
171 | frld (ji,jj) = 1.0 - zindb * ( 1.0 - frld(ji,jj) ) / MAX( za, epsi20 ) |
---|
172 | |
---|
173 | ! the in situ ice thickness, hicif, must be equal to or greater than hiclim. |
---|
174 | zh = MAX( rone , zindb * hiclim / MAX( hicif(ji,jj), epsi20 ) ) |
---|
175 | hsnif (ji,jj) = hsnif(ji,jj) * zh |
---|
176 | hicif (ji,jj) = hicif(ji,jj) * zh |
---|
177 | qstoif(ji,jj) = qstoif(ji,jj) * zh |
---|
178 | frld (ji,jj) = ( frld(ji,jj) + ( zh - 1.0 ) ) / zh |
---|
179 | END DO |
---|
180 | END DO |
---|
181 | |
---|
182 | IF(ln_ctl) THEN |
---|
183 | CALL prt_ctl( tab2d_1=hicif , clinfo1=' lim_thd: hicif : ' ) |
---|
184 | CALL prt_ctl( tab2d_1=hsnif , clinfo1=' lim_thd: hsnif : ' ) |
---|
185 | CALL prt_ctl( tab2d_1=dmgwi , clinfo1=' lim_thd: dmgwi : ' ) |
---|
186 | CALL prt_ctl( tab2d_1=qstoif, clinfo1=' lim_thd: qstoif : ' ) |
---|
187 | CALL prt_ctl( tab2d_1=frld , clinfo1=' lim_thd: frld : ' ) |
---|
188 | ENDIF |
---|
189 | |
---|
190 | |
---|
191 | !-------------------------------! |
---|
192 | ! Thermodynamics of sea ice ! |
---|
193 | !-------------------------------! |
---|
194 | |
---|
195 | ! Partial computation of forcing for the thermodynamic sea ice model. |
---|
196 | !-------------------------------------------------------------------------- |
---|
197 | |
---|
198 | DO jj = 1, jpj |
---|
199 | DO ji = 1, jpi |
---|
200 | zthsnice = hsnif(ji,jj) + hicif(ji,jj) |
---|
201 | zindb = tms(ji,jj) * ( 1.0 - MAX( rzero , SIGN( rone , - zthsnice ) ) ) |
---|
202 | pfrld(ji,jj) = frld(ji,jj) |
---|
203 | zfricp = 1.0 - frld(ji,jj) |
---|
204 | zinda = 1.0 - MAX( rzero , SIGN( rone , - zfricp ) ) |
---|
205 | |
---|
206 | ! solar irradiance transmission at the mixed layer bottom and used in the lead heat budget |
---|
207 | thcm(ji,jj) = 0.e0 |
---|
208 | |
---|
209 | ! net downward heat flux from the ice to the ocean, expressed as a function of ocean |
---|
210 | ! temperature and turbulent mixing (McPhee, 1992) |
---|
211 | zfric_u = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin ) ! friction velocity |
---|
212 | fdtcn(ji,jj) = zindb * rau0 * rcp * 0.006 * zfric_u * ( sst_m(ji,jj) + rt0 - tfu(ji,jj) ) |
---|
213 | qdtcn(ji,jj) = zindb * fdtcn(ji,jj) * frld(ji,jj) * rdt_ice |
---|
214 | |
---|
215 | ! partial computation of the lead energy budget (qldif) |
---|
216 | IF( ln_cpl ) THEN |
---|
217 | qldif(ji,jj) = tms(ji,jj) * rdt_ice & |
---|
218 | & * ( ( qsr_tot(ji,jj) - qsr_ice(ji,jj,1) * zfricp ) * ( 1.0 - thcm(ji,jj) ) & |
---|
219 | & + ( qns_tot(ji,jj) - qns_ice(ji,jj,1) * zfricp ) & |
---|
220 | & + frld(ji,jj) * ( fdtcn(ji,jj) + ( 1.0 - zindb ) * fsbbq(ji,jj) ) ) |
---|
221 | ELSE |
---|
222 | qldif(ji,jj) = tms(ji,jj) * rdt_ice * frld(ji,jj) & |
---|
223 | & * ( qsr(ji,jj) * ( 1.0 - thcm(ji,jj) ) & |
---|
224 | & + qns(ji,jj) + fdtcn(ji,jj) & |
---|
225 | & + ( 1.0 - zindb ) * fsbbq(ji,jj) ) |
---|
226 | ENDIF |
---|
227 | ! parlat : percentage of energy used for lateral ablation (0.0) |
---|
228 | zfntlat = 1.0 - MAX( rzero , SIGN( rone , - qldif(ji,jj) ) ) |
---|
229 | zpareff = 1.0 + ( parlat - 1.0 ) * zinda * zfntlat |
---|
230 | zqlbsbq(ji,jj) = qldif(ji,jj) * ( 1.0 - zpareff ) / MAX( (1.0 - frld(ji,jj)) * rdt_ice , epsi16 ) |
---|
231 | qldif (ji,jj) = zpareff * qldif(ji,jj) |
---|
232 | qdtcn (ji,jj) = zpareff * qdtcn(ji,jj) |
---|
233 | |
---|
234 | ! energy needed to bring ocean surface layer until its freezing |
---|
235 | qcmif (ji,jj) = rau0 * rcp * fse3t_m(ji,jj) * ( tfu(ji,jj) - sst_m(ji,jj) - rt0 ) * ( 1 - zinda ) |
---|
236 | |
---|
237 | ! calculate oceanic heat flux. |
---|
238 | fbif (ji,jj) = zindb * ( fsbbq(ji,jj) / MAX( (1.0 - frld(ji,jj)) , epsi20 ) + fdtcn(ji,jj) ) |
---|
239 | |
---|
240 | ! computation of the thermodynamic ice production (only needed for output) |
---|
241 | hicifp(ji,jj) = hicif(ji,jj) * ( 1.0 - frld(ji,jj) ) |
---|
242 | END DO |
---|
243 | END DO |
---|
244 | |
---|
245 | ! Select icy points and fulfill arrays for the vectorial grid. |
---|
246 | !---------------------------------------------------------------------- |
---|
247 | nbpb = 0 |
---|
248 | DO jj = 1, jpj |
---|
249 | DO ji = 1, jpi |
---|
250 | IF ( frld(ji,jj) < 1.0 ) THEN |
---|
251 | nbpb = nbpb + 1 |
---|
252 | npb(nbpb) = (jj - 1) * jpi + ji |
---|
253 | ENDIF |
---|
254 | END DO |
---|
255 | END DO |
---|
256 | |
---|
257 | IF(ln_ctl) THEN |
---|
258 | CALL prt_ctl(tab2d_1=pfrld, clinfo1=' lim_thd: pfrld : ', tab2d_2=thcm , clinfo2=' thcm : ') |
---|
259 | CALL prt_ctl(tab2d_1=fdtcn, clinfo1=' lim_thd: fdtcn : ', tab2d_2=qdtcn , clinfo2=' qdtcn : ') |
---|
260 | CALL prt_ctl(tab2d_1=qldif, clinfo1=' lim_thd: qldif : ', tab2d_2=zqlbsbq, clinfo2=' zqlbsbq : ') |
---|
261 | CALL prt_ctl(tab2d_1=qcmif, clinfo1=' lim_thd: qcmif : ', tab2d_2=fbif , clinfo2=' fbif : ') |
---|
262 | zmsk(:,:,1) = tms(:,:) |
---|
263 | CALL prt_ctl(tab2d_1=qcmif , clinfo1=' lim_thd: qcmif : ', mask1=zmsk) |
---|
264 | CALL prt_ctl(tab2d_1=hicifp, clinfo1=' lim_thd: hicifp : ') |
---|
265 | WRITE(charout, FMT="('lim_thd: nbpb = ',I4)") nbpb |
---|
266 | CALL prt_ctl_info(charout) |
---|
267 | ENDIF |
---|
268 | |
---|
269 | |
---|
270 | ! If there is no ice, do nothing. Otherwise, compute Top and Bottom accretion/ablation |
---|
271 | !------------------------------------------------------------------------------------ |
---|
272 | |
---|
273 | IF( nbpb > 0 ) THEN |
---|
274 | ! |
---|
275 | ! put the variable in a 1-D array for thermodynamics process |
---|
276 | CALL tab_2d_1d_2( nbpb, frld_1d (1:nbpb) , frld , jpi, jpj, npb(1:nbpb) ) |
---|
277 | CALL tab_2d_1d_2( nbpb, h_ice_1d (1:nbpb) , hicif , jpi, jpj, npb(1:nbpb) ) |
---|
278 | CALL tab_2d_1d_2( nbpb, h_snow_1d (1:nbpb) , hsnif , jpi, jpj, npb(1:nbpb) ) |
---|
279 | CALL tab_2d_1d_2( nbpb, sist_1d (1:nbpb) , sist , jpi, jpj, npb(1:nbpb) ) |
---|
280 | CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 1 ), tbif(:,:,1) , jpi, jpj, npb(1:nbpb) ) |
---|
281 | CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 2 ), tbif(:,:,2) , jpi, jpj, npb(1:nbpb) ) |
---|
282 | CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 3 ), tbif(:,:,3) , jpi, jpj, npb(1:nbpb) ) |
---|
283 | CALL tab_2d_1d_2( nbpb, qsr_ice_1d (1:nbpb) , qsr_ice(:,:,1) , jpi, jpj, npb(1:nbpb) ) |
---|
284 | CALL tab_2d_1d_2( nbpb, fr1_i0_1d (1:nbpb) , fr1_i0 , jpi, jpj, npb(1:nbpb) ) |
---|
285 | CALL tab_2d_1d_2( nbpb, fr2_i0_1d (1:nbpb) , fr2_i0 , jpi, jpj, npb(1:nbpb) ) |
---|
286 | CALL tab_2d_1d_2( nbpb, qns_ice_1d(1:nbpb) , qns_ice(:,:,1), jpi, jpj, npb(1:nbpb) ) |
---|
287 | CALL tab_2d_1d_2( nbpb, dqns_ice_1d(1:nbpb) , dqns_ice(:,:,1), jpi, jpj, npb(1:nbpb) ) |
---|
288 | IF( .NOT. ln_cpl ) THEN |
---|
289 | CALL tab_2d_1d_2( nbpb, qla_ice_1d (1:nbpb) , qla_ice(:,:,1), jpi, jpj, npb(1:nbpb) ) |
---|
290 | CALL tab_2d_1d_2( nbpb, dqla_ice_1d(1:nbpb) , dqla_ice(:,:,1), jpi, jpj, npb(1:nbpb) ) |
---|
291 | ENDIF |
---|
292 | CALL tab_2d_1d_2( nbpb, tfu_1d (1:nbpb) , tfu , jpi, jpj, npb(1:nbpb) ) |
---|
293 | CALL tab_2d_1d_2( nbpb, sprecip_1d (1:nbpb) , sprecip , jpi, jpj, npb(1:nbpb) ) |
---|
294 | CALL tab_2d_1d_2( nbpb, fbif_1d (1:nbpb) , fbif , jpi, jpj, npb(1:nbpb) ) |
---|
295 | CALL tab_2d_1d_2( nbpb, thcm_1d (1:nbpb) , thcm , jpi, jpj, npb(1:nbpb) ) |
---|
296 | CALL tab_2d_1d_2( nbpb, qldif_1d (1:nbpb) , qldif , jpi, jpj, npb(1:nbpb) ) |
---|
297 | CALL tab_2d_1d_2( nbpb, qstbif_1d (1:nbpb) , qstoif , jpi, jpj, npb(1:nbpb) ) |
---|
298 | CALL tab_2d_1d_2( nbpb, rdm_ice_1d (1:nbpb) , rdm_ice , jpi, jpj, npb(1:nbpb) ) |
---|
299 | CALL tab_2d_1d_2( nbpb, rdq_ice_1d (1:nbpb) , rdq_ice , jpi, jpj, npb(1:nbpb) ) |
---|
300 | CALL tab_2d_1d_2( nbpb, dmgwi_1d (1:nbpb) , dmgwi , jpi, jpj, npb(1:nbpb) ) |
---|
301 | CALL tab_2d_1d_2( nbpb, rdm_snw_1d (1:nbpb) , rdm_snw , jpi, jpj, npb(1:nbpb) ) |
---|
302 | CALL tab_2d_1d_2( nbpb, rdq_snw_1d (1:nbpb) , rdq_snw , jpi, jpj, npb(1:nbpb) ) |
---|
303 | CALL tab_2d_1d_2( nbpb, qlbbq_1d (1:nbpb) , zqlbsbq , jpi, jpj, npb(1:nbpb) ) |
---|
304 | ! |
---|
305 | CALL lim_thd_zdf_2( 1, nbpb ) ! compute ice growth |
---|
306 | ! |
---|
307 | ! back to the geographic grid. |
---|
308 | CALL tab_1d_2d_2( nbpb, frld , npb, frld_1d (1:nbpb) , jpi, jpj ) |
---|
309 | CALL tab_1d_2d_2( nbpb, hicif , npb, h_ice_1d (1:nbpb) , jpi, jpj ) |
---|
310 | CALL tab_1d_2d_2( nbpb, hsnif , npb, h_snow_1d (1:nbpb) , jpi, jpj ) |
---|
311 | CALL tab_1d_2d_2( nbpb, sist , npb, sist_1d (1:nbpb) , jpi, jpj ) |
---|
312 | CALL tab_1d_2d_2( nbpb, tbif(:,:,1), npb, tbif_1d (1:nbpb , 1 ), jpi, jpj ) |
---|
313 | CALL tab_1d_2d_2( nbpb, tbif(:,:,2), npb, tbif_1d (1:nbpb , 2 ), jpi, jpj ) |
---|
314 | CALL tab_1d_2d_2( nbpb, tbif(:,:,3), npb, tbif_1d (1:nbpb , 3 ), jpi, jpj ) |
---|
315 | CALL tab_1d_2d_2( nbpb, fscmbq , npb, fscbq_1d (1:nbpb) , jpi, jpj ) |
---|
316 | CALL tab_1d_2d_2( nbpb, ffltbif , npb, fltbif_1d (1:nbpb) , jpi, jpj ) |
---|
317 | CALL tab_1d_2d_2( nbpb, fstric , npb, fstbif_1d (1:nbpb) , jpi, jpj ) |
---|
318 | CALL tab_1d_2d_2( nbpb, qldif , npb, qldif_1d (1:nbpb) , jpi, jpj ) |
---|
319 | CALL tab_1d_2d_2( nbpb, qfvbq , npb, qfvbq_1d (1:nbpb) , jpi, jpj ) |
---|
320 | CALL tab_1d_2d_2( nbpb, qstoif , npb, qstbif_1d (1:nbpb) , jpi, jpj ) |
---|
321 | CALL tab_1d_2d_2( nbpb, rdm_ice , npb, rdm_ice_1d(1:nbpb) , jpi, jpj ) |
---|
322 | CALL tab_1d_2d_2( nbpb, rdq_ice , npb, rdq_ice_1d(1:nbpb) , jpi, jpj ) |
---|
323 | CALL tab_1d_2d_2( nbpb, dmgwi , npb, dmgwi_1d (1:nbpb) , jpi, jpj ) |
---|
324 | CALL tab_1d_2d_2( nbpb, rdm_snw , npb, rdm_snw_1d(1:nbpb) , jpi, jpj ) |
---|
325 | CALL tab_1d_2d_2( nbpb, rdq_snw , npb, rdq_snw_1d(1:nbpb) , jpi, jpj ) |
---|
326 | CALL tab_1d_2d_2( nbpb, zdvosif , npb, dvsbq_1d (1:nbpb) , jpi, jpj ) |
---|
327 | CALL tab_1d_2d_2( nbpb, zdvobif , npb, dvbbq_1d (1:nbpb) , jpi, jpj ) |
---|
328 | CALL tab_1d_2d_2( nbpb, zdvomif , npb, rdvomif_1d(1:nbpb) , jpi, jpj ) |
---|
329 | CALL tab_1d_2d_2( nbpb, zdvolif , npb, dvlbq_1d (1:nbpb) , jpi, jpj ) |
---|
330 | CALL tab_1d_2d_2( nbpb, zdvonif , npb, dvnbq_1d (1:nbpb) , jpi, jpj ) |
---|
331 | CALL tab_1d_2d_2( nbpb, qsr_ice(:,:,1), npb, qsr_ice_1d(1:nbpb) , jpi, jpj ) |
---|
332 | CALL tab_1d_2d_2( nbpb, qns_ice(:,:,1), npb, qns_ice_1d(1:nbpb) , jpi, jpj ) |
---|
333 | IF( .NOT. ln_cpl ) CALL tab_1d_2d_2( nbpb, qla_ice(:,:,1), npb, qla_ice_1d(1:nbpb), jpi, jpj ) |
---|
334 | ! |
---|
335 | ENDIF |
---|
336 | |
---|
337 | ! Up-date sea ice thickness |
---|
338 | !-------------------------- |
---|
339 | DO jj = 1, jpj |
---|
340 | DO ji = 1, jpi |
---|
341 | phicif(ji,jj) = hicif(ji,jj) |
---|
342 | hicif(ji,jj) = hicif(ji,jj) * ( rone - MAX( rzero, SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) ) |
---|
343 | END DO |
---|
344 | END DO |
---|
345 | |
---|
346 | |
---|
347 | ! Tricky trick : add 2 to frld in the Southern Hemisphere |
---|
348 | !-------------------------------------------------------- |
---|
349 | IF( fcor(1,1) < 0.e0 ) THEN |
---|
350 | DO jj = 1, njeqm1 |
---|
351 | DO ji = 1, jpi |
---|
352 | frld(ji,jj) = frld(ji,jj) + 2.0 |
---|
353 | END DO |
---|
354 | END DO |
---|
355 | ENDIF |
---|
356 | |
---|
357 | CALL lbc_lnk( frld , 'T', 1. ) |
---|
358 | |
---|
359 | ! Select points for lateral accretion (this occurs when heat exchange |
---|
360 | ! between ice and ocean is negative; ocean losing heat) |
---|
361 | !----------------------------------------------------------------- |
---|
362 | nbpac = 0 |
---|
363 | DO jj = 1, jpj |
---|
364 | DO ji = 1, jpi |
---|
365 | !i yes! IF ( ( qcmif(ji,jj) - qldif(ji,jj) ) > 0.e0 ) THEN |
---|
366 | IF ( tms(ji,jj) * ( qcmif(ji,jj) - qldif(ji,jj) ) > 0.e0 ) THEN |
---|
367 | nbpac = nbpac + 1 |
---|
368 | npac( nbpac ) = (jj - 1) * jpi + ji |
---|
369 | ENDIF |
---|
370 | END DO |
---|
371 | END DO |
---|
372 | |
---|
373 | IF(ln_ctl) THEN |
---|
374 | CALL prt_ctl(tab2d_1=phicif, clinfo1=' lim_thd: phicif : ', tab2d_2=hicif, clinfo2=' hicif : ') |
---|
375 | WRITE(charout, FMT="('lim_thd: nbpac = ',I4)") nbpac |
---|
376 | CALL prt_ctl_info(charout) |
---|
377 | ENDIF |
---|
378 | |
---|
379 | |
---|
380 | ! If ocean gains heat do nothing ; otherwise, one performs lateral accretion |
---|
381 | !-------------------------------------------------------------------------------- |
---|
382 | IF( nbpac > 0 ) THEN |
---|
383 | ! |
---|
384 | zlicegr(:,:) = rdm_ice(:,:) ! to output the lateral sea-ice growth |
---|
385 | !...Put the variable in a 1-D array for lateral accretion |
---|
386 | CALL tab_2d_1d_2( nbpac, frld_1d (1:nbpac) , frld , jpi, jpj, npac(1:nbpac) ) |
---|
387 | CALL tab_2d_1d_2( nbpac, h_snow_1d (1:nbpac) , hsnif , jpi, jpj, npac(1:nbpac) ) |
---|
388 | CALL tab_2d_1d_2( nbpac, h_ice_1d (1:nbpac) , hicif , jpi, jpj, npac(1:nbpac) ) |
---|
389 | CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 1 ), tbif(:,:,1), jpi, jpj, npac(1:nbpac) ) |
---|
390 | CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 2 ), tbif(:,:,2), jpi, jpj, npac(1:nbpac) ) |
---|
391 | CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 3 ), tbif(:,:,3), jpi, jpj, npac(1:nbpac) ) |
---|
392 | CALL tab_2d_1d_2( nbpac, qldif_1d (1:nbpac) , qldif , jpi, jpj, npac(1:nbpac) ) |
---|
393 | CALL tab_2d_1d_2( nbpac, qcmif_1d (1:nbpac) , qcmif , jpi, jpj, npac(1:nbpac) ) |
---|
394 | CALL tab_2d_1d_2( nbpac, qstbif_1d (1:nbpac) , qstoif , jpi, jpj, npac(1:nbpac) ) |
---|
395 | CALL tab_2d_1d_2( nbpac, rdm_ice_1d(1:nbpac) , rdm_ice , jpi, jpj, npac(1:nbpac) ) |
---|
396 | CALL tab_2d_1d_2( nbpac, rdq_ice_1d(1:nbpac) , rdq_ice , jpi, jpj, npac(1:nbpac) ) |
---|
397 | CALL tab_2d_1d_2( nbpac, dvlbq_1d (1:nbpac) , zdvolif , jpi, jpj, npac(1:nbpac) ) |
---|
398 | CALL tab_2d_1d_2( nbpac, tfu_1d (1:nbpac) , tfu , jpi, jpj, npac(1:nbpac) ) |
---|
399 | ! |
---|
400 | CALL lim_thd_lac_2( 1 , nbpac ) ! lateral accretion routine. |
---|
401 | ! |
---|
402 | ! back to the geographic grid |
---|
403 | CALL tab_1d_2d_2( nbpac, frld , npac(1:nbpac), frld_1d (1:nbpac) , jpi, jpj ) |
---|
404 | CALL tab_1d_2d_2( nbpac, hsnif , npac(1:nbpac), h_snow_1d (1:nbpac) , jpi, jpj ) |
---|
405 | CALL tab_1d_2d_2( nbpac, hicif , npac(1:nbpac), h_ice_1d (1:nbpac) , jpi, jpj ) |
---|
406 | CALL tab_1d_2d_2( nbpac, tbif(:,:,1), npac(1:nbpac), tbif_1d (1:nbpac , 1 ), jpi, jpj ) |
---|
407 | CALL tab_1d_2d_2( nbpac, tbif(:,:,2), npac(1:nbpac), tbif_1d (1:nbpac , 2 ), jpi, jpj ) |
---|
408 | CALL tab_1d_2d_2( nbpac, tbif(:,:,3), npac(1:nbpac), tbif_1d (1:nbpac , 3 ), jpi, jpj ) |
---|
409 | CALL tab_1d_2d_2( nbpac, qstoif , npac(1:nbpac), qstbif_1d (1:nbpac) , jpi, jpj ) |
---|
410 | CALL tab_1d_2d_2( nbpac, rdm_ice , npac(1:nbpac), rdm_ice_1d(1:nbpac) , jpi, jpj ) |
---|
411 | CALL tab_1d_2d_2( nbpac, rdq_ice , npac(1:nbpac), rdq_ice_1d(1:nbpac) , jpi, jpj ) |
---|
412 | CALL tab_1d_2d_2( nbpac, zdvolif , npac(1:nbpac), dvlbq_1d (1:nbpac) , jpi, jpj ) |
---|
413 | ! |
---|
414 | ENDIF |
---|
415 | |
---|
416 | |
---|
417 | ! Recover frld values between 0 and 1 in the Southern Hemisphere (tricky trick) |
---|
418 | ! Update daily thermodynamic ice production. |
---|
419 | !------------------------------------------------------------------------------ |
---|
420 | DO jj = 1, jpj |
---|
421 | DO ji = 1, jpi |
---|
422 | frld (ji,jj) = MIN( frld(ji,jj), ABS( frld(ji,jj) - 2.0 ) ) |
---|
423 | fr_i (ji,jj) = 1.0 - frld(ji,jj) |
---|
424 | hicifp(ji,jj) = hicif(ji,jj) * fr_i(ji,jj) - hicifp(ji,jj) |
---|
425 | END DO |
---|
426 | END DO |
---|
427 | |
---|
428 | ! Outputs |
---|
429 | !-------------------------------------------------------------------------------- |
---|
430 | ztmp(:,:) = 1. - pfrld(:,:) ! fraction of ice after the dynamic, before the thermodynamic |
---|
431 | IF( iom_use('ist_cea' ) ) CALL iom_put( 'ist_cea', (sist(:,:) - rt0) * ztmp(:,:) ) ! Ice surface temperature [Celius] |
---|
432 | IF( iom_use('qsr_ai_cea' ) ) CALL iom_put( 'qsr_ai_cea', qsr_ice(:,:,1) * ztmp(:,:) ) ! Solar flux over the ice [W/m2] |
---|
433 | IF( iom_use('qns_ai_cea' ) ) CALL iom_put( 'qns_ai_cea', qns_ice(:,:,1) * ztmp(:,:) ) ! Non-solar flux over the ice [W/m2] |
---|
434 | IF( iom_use('qla_ai_cea' ) .AND. .NOT. ln_cpl ) & |
---|
435 | & CALL iom_put( 'qla_ai_cea', qla_ice(:,:,1) * ztmp(:,:) ) ! Latent flux over the ice [W/m2] |
---|
436 | ! |
---|
437 | IF( iom_use('snowthic_cea')) CALL iom_put( 'snowthic_cea', hsnif (:,:) * fr_i(:,:) ) ! Snow thickness [m] |
---|
438 | IF( iom_use('icethic_cea' )) CALL iom_put( 'icethic_cea' , hicif (:,:) * fr_i(:,:) ) ! Ice thickness [m] |
---|
439 | zztmp = 1.0 / rdt_ice |
---|
440 | IF( iom_use('iceprod_cea') ) CALL iom_put( 'iceprod_cea' , hicifp (:,:) * zztmp ) ! Ice produced [m/s] |
---|
441 | IF( iom_use('iiceconc' ) ) CALL iom_put( 'iiceconc' , fr_i(:,:) ) ! Ice concentration [-] |
---|
442 | IF( iom_use('snowmel_cea') ) CALL iom_put( 'snowmel_cea' , rdm_snw(:,:) * zztmp ) ! Snow melt [kg/m2/s] |
---|
443 | zztmp = rhoic / rdt_ice |
---|
444 | IF( iom_use('sntoice_cea') ) CALL iom_put( 'sntoice_cea' , zdvonif(:,:) * zztmp ) ! Snow to Ice transformation [kg/m2/s] |
---|
445 | IF( iom_use('ticemel_cea') ) CALL iom_put( 'ticemel_cea' , zdvosif(:,:) * zztmp ) ! Melt at Sea Ice top [kg/m2/s] |
---|
446 | IF( iom_use('bicemel_cea') ) CALL iom_put( 'bicemel_cea' , zdvomif(:,:) * zztmp ) ! Melt at Sea Ice bottom [kg/m2/s] |
---|
447 | IF( iom_use('licepro_cea') ) THEN |
---|
448 | zlicegr(:,:) = MAX( 0.e0, rdm_ice(:,:)-zlicegr(:,:) ) |
---|
449 | CALL iom_put( 'licepro_cea' , zlicegr(:,:) * zztmp ) ! Lateral sea ice growth [kg/m2/s] |
---|
450 | ENDIF |
---|
451 | ! |
---|
452 | ! Compute the Eastward & Northward sea-ice transport |
---|
453 | IF( iom_use('u_imasstr') ) THEN |
---|
454 | zztmp = 0.25 * rhoic |
---|
455 | DO jj = 1, jpjm1 |
---|
456 | DO ji = 1, jpim1 ! NO vector opt. |
---|
457 | ! Ice velocities, volume & transport at U-points |
---|
458 | zuice_m = u_ice(ji+1,jj+1) + u_ice(ji+1,jj ) |
---|
459 | zhice_u = hicif(ji,jj)*e2t(ji,jj)*fr_i(ji,jj) + hicif(ji+1,jj )*e2t(ji+1,jj )*fr_i(ji+1,jj ) |
---|
460 | zu_imasstr(ji,jj) = zztmp * zhice_u * zuice_m |
---|
461 | END DO |
---|
462 | END DO |
---|
463 | CALL lbc_lnk( zu_imasstr, 'U', -1. ) |
---|
464 | CALL iom_put( 'u_imasstr', zu_imasstr(:,:) ) ! Ice transport along i-axis at U-point [kg/s] |
---|
465 | ENDIF |
---|
466 | IF( iom_use('v_imasstr') ) THEN |
---|
467 | zztmp = 0.25 * rhoic |
---|
468 | DO jj = 1, jpjm1 |
---|
469 | DO ji = 1, jpim1 ! NO vector opt. |
---|
470 | ! Ice velocities, volume & transport at V-points |
---|
471 | zvice_m = v_ice(ji+1,jj+1) + v_ice(ji ,jj+1) |
---|
472 | zhice_v = hicif(ji,jj)*e1t(ji,jj)*fr_i(ji,jj) + hicif(ji ,jj+1)*e1t(ji ,jj+1)*fr_i(ji ,jj+1) |
---|
473 | zv_imasstr(ji,jj) = zztmp * zhice_v * zvice_m |
---|
474 | END DO |
---|
475 | END DO |
---|
476 | CALL lbc_lnk( zv_imasstr, 'V', -1. ) |
---|
477 | CALL iom_put( 'v_imasstr', zv_imasstr(:,:) ) ! Ice transport along j-axis at V-point [kg/s] |
---|
478 | ENDIF |
---|
479 | |
---|
480 | !! Fram Strait sea-ice transport (sea-ice + snow) (in ORCA2 = 5 points) |
---|
481 | IF( iom_use('fram_trans') .and. cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN ! ORCA R2 configuration |
---|
482 | DO jj = mj0(137), mj1(137) ! B grid |
---|
483 | IF( mj0(jj-1) >= nldj ) THEN |
---|
484 | DO ji = MAX(mi0(134),nldi), MIN(mi1(138),nlei) |
---|
485 | zrhoij = e1t(ji,jj ) * fr_i(ji,jj ) * ( rhoic*hicif(ji,jj ) + rhosn*hsnif(ji,jj ) ) |
---|
486 | zrhoijm1 = e1t(ji,jj-1) * fr_i(ji,jj-1) * ( rhoic*hicif(ji,jj-1) + rhosn*hsnif(ji,jj-1) ) |
---|
487 | ztr_fram = ztr_fram - 0.25 * ( v_ice(ji,jj)+ v_ice(ji+1,jj) ) * ( zrhoij + zrhoijm1 ) |
---|
488 | END DO |
---|
489 | ENDIF |
---|
490 | END DO |
---|
491 | IF( lk_mpp ) CALL mpp_sum( ztr_fram ) |
---|
492 | CALL iom_put( 'fram_trans', ztr_fram ) ! Ice transport through Fram strait [kg/s] |
---|
493 | ENDIF |
---|
494 | |
---|
495 | IF( iom_use('ice_pres') .OR. iom_use('ist_ipa') .OR. iom_use('uice_ipa') .OR. iom_use('vice_ipa') ) THEN |
---|
496 | !! ce ztmp(:,:) = 1. - AINT( frld(:,:), wp ) ! return 1 as soon as there is ice |
---|
497 | !! ce A big warning because the model crashes on IDRIS/IBM SP6 with xlf 13.1.0.3, see ticket #761 |
---|
498 | !! ce We Unroll the loop and everything works fine |
---|
499 | DO jj = 1, jpj |
---|
500 | DO ji = 1, jpi |
---|
501 | ztmp(ji,jj) = 1. - AINT( frld(ji,jj), wp ) ! return 1 as soon as there is ice |
---|
502 | END DO |
---|
503 | END DO |
---|
504 | ! |
---|
505 | IF( iom_use('ice_pres') ) CALL iom_put( 'ice_pres', ztmp ) ! Ice presence [-] |
---|
506 | IF( iom_use('ist_ipa' ) ) CALL iom_put( 'ist_ipa' , ( sist(:,:) - rt0 ) * ztmp(:,:) ) ! Ice surface temperature [Celius] |
---|
507 | IF( iom_use('uice_ipa') ) CALL iom_put( 'uice_ipa', u_ice(:,:) * ztmp(:,:) ) ! Ice velocity along i-axis at I-point [m/s] |
---|
508 | IF( iom_use('vice_ipa') ) CALL iom_put( 'vice_ipa', v_ice(:,:) * ztmp(:,:) ) ! Ice velocity along j-axis at I-point [m/s] |
---|
509 | ENDIF |
---|
510 | |
---|
511 | IF(ln_ctl) THEN |
---|
512 | CALL prt_ctl_info(' lim_thd end ') |
---|
513 | CALL prt_ctl( tab2d_1=hicif , clinfo1=' lim_thd: hicif : ', tab2d_2=hsnif , clinfo2=' hsnif : ' ) |
---|
514 | CALL prt_ctl( tab2d_1=frld , clinfo1=' lim_thd: frld : ', tab2d_2=hicifp, clinfo2=' hicifp : ' ) |
---|
515 | CALL prt_ctl( tab2d_1=phicif , clinfo1=' lim_thd: phicif : ', tab2d_2=pfrld , clinfo2=' pfrld : ' ) |
---|
516 | CALL prt_ctl( tab2d_1=sist , clinfo1=' lim_thd: sist : ' ) |
---|
517 | CALL prt_ctl( tab2d_1=tbif(:,:,1), clinfo1=' lim_thd: tbif 1 : ' ) |
---|
518 | CALL prt_ctl( tab2d_1=tbif(:,:,2), clinfo1=' lim_thd: tbif 2 : ' ) |
---|
519 | CALL prt_ctl( tab2d_1=tbif(:,:,3), clinfo1=' lim_thd: tbif 3 : ' ) |
---|
520 | CALL prt_ctl( tab2d_1=fdtcn , clinfo1=' lim_thd: fdtcn : ', tab2d_2=qdtcn , clinfo2=' qdtcn : ' ) |
---|
521 | CALL prt_ctl( tab2d_1=qstoif , clinfo1=' lim_thd: qstoif : ', tab2d_2=fsbbq , clinfo2=' fsbbq : ' ) |
---|
522 | ENDIF |
---|
523 | ! |
---|
524 | CALL wrk_dealloc( jpi, jpj, ztmp, zqlbsbq, zlicegr, zdvosif, zdvobif, zdvolif, zdvonif, zdvomif, zu_imasstr, zv_imasstr ) |
---|
525 | CALL wrk_dealloc( jpi, jpj, jpk, zmsk ) |
---|
526 | ! |
---|
527 | END SUBROUTINE lim_thd_2 |
---|
528 | |
---|
529 | |
---|
530 | SUBROUTINE lim_thd_init_2 |
---|
531 | !!------------------------------------------------------------------- |
---|
532 | !! *** ROUTINE lim_thd_init_2 *** |
---|
533 | !! |
---|
534 | !! ** Purpose : Physical constants and parameters linked to the ice |
---|
535 | !! thermodynamics |
---|
536 | !! |
---|
537 | !! ** Method : Read the namicethd namelist and check the ice-thermo |
---|
538 | !! parameter values called at the first timestep (nit000) |
---|
539 | !! |
---|
540 | !! ** input : Namelist namicether |
---|
541 | !!------------------------------------------------------------------- |
---|
542 | INTEGER :: ios ! Local integer output status for namelist read |
---|
543 | NAMELIST/namicethd/ hmelt , hiccrit, hicmin, hiclim, amax , & |
---|
544 | & swiqst, sbeta , parlat, hakspl, hibspl, exld, & |
---|
545 | & hakdif, hnzst , thth , parsub, alphs |
---|
546 | !!------------------------------------------------------------------- |
---|
547 | |
---|
548 | REWIND( numnam_ice_ref ) ! Namelist namicethd in reference namelist : Ice thermodynamics |
---|
549 | READ ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901) |
---|
550 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp ) |
---|
551 | |
---|
552 | REWIND( numnam_ice_cfg ) ! Namelist namicethd in configuration namelist : Ice thermodynamics |
---|
553 | READ ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 ) |
---|
554 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp ) |
---|
555 | IF(lwm) WRITE ( numoni, namicethd ) |
---|
556 | |
---|
557 | IF( ln_cpl .AND. parsub /= 0.0 ) CALL ctl_stop( 'In coupled mode, use parsub = 0. or send dqla' ) |
---|
558 | ! |
---|
559 | IF(lwp) THEN ! control print |
---|
560 | WRITE(numout,*) |
---|
561 | WRITE(numout,*)'lim_thd_init_2: ice parameters for ice thermodynamic computation ' |
---|
562 | WRITE(numout,*)'~~~~~~~~~~~~~~' |
---|
563 | WRITE(numout,*)' maximum melting at the bottom hmelt = ', hmelt |
---|
564 | WRITE(numout,*)' ice thick. for lateral accretion in NH (SH) hiccrit(1/2) = ', hiccrit |
---|
565 | WRITE(numout,*)' ice thick. corr. to max. energy stored in brine pocket hicmin = ', hicmin |
---|
566 | WRITE(numout,*)' minimum ice thickness hiclim = ', hiclim |
---|
567 | WRITE(numout,*)' maximum lead fraction amax = ', amax |
---|
568 | WRITE(numout,*)' energy stored in brine pocket (=1) or not (=0) swiqst = ', swiqst |
---|
569 | WRITE(numout,*)' numerical carac. of the scheme for diffusion in ice ' |
---|
570 | WRITE(numout,*)' Cranck-Nicholson (=0.5), implicit (=1), explicit (=0) sbeta = ', sbeta |
---|
571 | WRITE(numout,*)' percentage of energy used for lateral ablation parlat = ', parlat |
---|
572 | WRITE(numout,*)' slope of distr. for Hakkinen-Mellor lateral melting hakspl = ', hakspl |
---|
573 | WRITE(numout,*)' slope of distribution for Hibler lateral melting hibspl = ', hibspl |
---|
574 | WRITE(numout,*)' exponent for leads-closure rate exld = ', exld |
---|
575 | WRITE(numout,*)' coefficient for diffusions of ice and snow hakdif = ', hakdif |
---|
576 | WRITE(numout,*)' threshold thick. for comp. of eq. thermal conductivity zhth = ', thth |
---|
577 | WRITE(numout,*)' thickness of the surf. layer in temp. computation hnzst = ', hnzst |
---|
578 | WRITE(numout,*)' switch for snow sublimation (=1) or not (=0) parsub = ', parsub |
---|
579 | WRITE(numout,*)' coefficient for snow density when snow ice formation alphs = ', alphs |
---|
580 | ENDIF |
---|
581 | ! |
---|
582 | uscomi = 1.0 / ( 1.0 - amax ) ! inverse of minimum lead fraction |
---|
583 | rcdsn = hakdif * rcdsn |
---|
584 | rcdic = hakdif * rcdic |
---|
585 | ! |
---|
586 | IF( hsndif > 100.e0 .OR. hicdif > 100.e0 ) THEN |
---|
587 | cnscg = 0.e0 |
---|
588 | ELSE |
---|
589 | cnscg = rcpsn / rcpic ! ratio rcpsn/rcpic |
---|
590 | ENDIF |
---|
591 | ! |
---|
592 | END SUBROUTINE lim_thd_init_2 |
---|
593 | |
---|
594 | #else |
---|
595 | !!---------------------------------------------------------------------- |
---|
596 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
---|
597 | !!---------------------------------------------------------------------- |
---|
598 | CONTAINS |
---|
599 | SUBROUTINE lim_thd_2 ! Dummy routine |
---|
600 | END SUBROUTINE lim_thd_2 |
---|
601 | #endif |
---|
602 | |
---|
603 | !!====================================================================== |
---|
604 | END MODULE limthd_2 |
---|