1 | MODULE traadv |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE traadv *** |
---|
4 | !! Ocean active tracers: advection trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : 2.0 ! 2005-11 (G. Madec) Original code |
---|
7 | !! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport |
---|
8 | !! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation |
---|
9 | !! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes |
---|
10 | !! - ! 2014-12 (G. Madec) suppression of cross land advection option |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! tra_adv : compute ocean tracer advection trend |
---|
15 | !! tra_adv_ctl : control the different options of advection scheme |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and active tracers |
---|
18 | USE dom_oce ! ocean space and time domain |
---|
19 | USE domvvl ! variable vertical scale factors |
---|
20 | USE traadv_cen ! centered scheme (tra_adv_cen routine) |
---|
21 | USE traadv_fct ! FCT scheme (tra_adv_fct routine) |
---|
22 | USE traadv_mus ! MUSCL scheme (tra_adv_mus routine) |
---|
23 | USE traadv_ubs ! UBS scheme (tra_adv_ubs routine) |
---|
24 | USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine) |
---|
25 | USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine) |
---|
26 | USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff. |
---|
27 | USE ldfslp ! Lateral diffusion: slopes of neutral surfaces |
---|
28 | USE c1d ! 1D vertical configuration |
---|
29 | ! |
---|
30 | USE in_out_manager ! I/O manager |
---|
31 | USE iom ! I/O module |
---|
32 | USE prtctl ! Print control |
---|
33 | USE lib_mpp ! MPP library |
---|
34 | USE wrk_nemo ! Memory Allocation |
---|
35 | USE timing ! Timing |
---|
36 | |
---|
37 | USE diaptr ! Poleward heat transport |
---|
38 | |
---|
39 | IMPLICIT NONE |
---|
40 | PRIVATE |
---|
41 | |
---|
42 | PUBLIC tra_adv ! routine called by step module |
---|
43 | PUBLIC tra_adv_init ! routine called by opa module |
---|
44 | |
---|
45 | ! !!* Namelist namtra_adv * |
---|
46 | LOGICAL :: ln_traadv_cen ! centered scheme flag |
---|
47 | INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme |
---|
48 | LOGICAL :: ln_traadv_fct ! FCT scheme flag |
---|
49 | INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme |
---|
50 | INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping |
---|
51 | LOGICAL :: ln_traadv_mus ! MUSCL scheme flag |
---|
52 | LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths |
---|
53 | LOGICAL :: ln_traadv_ubs ! UBS scheme flag |
---|
54 | INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme |
---|
55 | LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag |
---|
56 | |
---|
57 | INTEGER :: nadv ! choice of the type of advection scheme |
---|
58 | ! |
---|
59 | ! ! associated indices: |
---|
60 | INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection |
---|
61 | INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme |
---|
62 | INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme |
---|
63 | INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping |
---|
64 | INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme |
---|
65 | INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme |
---|
66 | INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme |
---|
67 | |
---|
68 | !! * Substitutions |
---|
69 | # include "domzgr_substitute.h90" |
---|
70 | # include "vectopt_loop_substitute.h90" |
---|
71 | !!---------------------------------------------------------------------- |
---|
72 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
---|
73 | !! $Id$ |
---|
74 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
75 | !!---------------------------------------------------------------------- |
---|
76 | CONTAINS |
---|
77 | |
---|
78 | SUBROUTINE tra_adv( kt ) |
---|
79 | !!---------------------------------------------------------------------- |
---|
80 | !! *** ROUTINE tra_adv *** |
---|
81 | !! |
---|
82 | !! ** Purpose : compute the ocean tracer advection trend. |
---|
83 | !! |
---|
84 | !! ** Method : - Update (ua,va) with the advection term following nadv |
---|
85 | !!---------------------------------------------------------------------- |
---|
86 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
87 | ! |
---|
88 | INTEGER :: jk ! dummy loop index |
---|
89 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn |
---|
90 | !!---------------------------------------------------------------------- |
---|
91 | ! |
---|
92 | IF( nn_timing == 1 ) CALL timing_start('tra_adv') |
---|
93 | ! |
---|
94 | CALL wrk_alloc( jpi,jpj,jpk, zun, zvn, zwn ) |
---|
95 | ! |
---|
96 | ! ! set time step |
---|
97 | IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000 |
---|
98 | r2dtra(:) = rdttra(:) ! = rdtra (restarting with Euler time stepping) |
---|
99 | ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1 |
---|
100 | r2dtra(:) = 2._wp * rdttra(:) ! = 2 rdttra (leapfrog) |
---|
101 | ENDIF |
---|
102 | ! |
---|
103 | ! !== effective transport ==! |
---|
104 | DO jk = 1, jpkm1 |
---|
105 | zun(:,:,jk) = e2u (:,:) * fse3u(:,:,jk) * un(:,:,jk) ! eulerian transport only |
---|
106 | zvn(:,:,jk) = e1v (:,:) * fse3v(:,:,jk) * vn(:,:,jk) |
---|
107 | zwn(:,:,jk) = e1e2t(:,:) * wn(:,:,jk) |
---|
108 | END DO |
---|
109 | ! |
---|
110 | IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections |
---|
111 | zun(:,:,:) = zun(:,:,:) + un_td(:,:,:) |
---|
112 | zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:) |
---|
113 | ENDIF |
---|
114 | ! |
---|
115 | zun(:,:,jpk) = 0._wp ! no transport trough the bottom |
---|
116 | zvn(:,:,jpk) = 0._wp |
---|
117 | zwn(:,:,jpk) = 0._wp |
---|
118 | ! |
---|
119 | IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) & |
---|
120 | & CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary) |
---|
121 | ! |
---|
122 | IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary) |
---|
123 | ! |
---|
124 | CALL iom_put( "uocetr_eff", zun ) ! output effective transport |
---|
125 | CALL iom_put( "vocetr_eff", zvn ) |
---|
126 | CALL iom_put( "wocetr_eff", zwn ) |
---|
127 | ! |
---|
128 | !!gm ??? |
---|
129 | IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF |
---|
130 | !!gm ??? |
---|
131 | ! |
---|
132 | SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==! |
---|
133 | ! |
---|
134 | CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order |
---|
135 | CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v ) |
---|
136 | CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order |
---|
137 | CALL tra_adv_fct ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v ) |
---|
138 | CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting |
---|
139 | CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts ) |
---|
140 | CASE ( np_MUS ) ! MUSCL |
---|
141 | CALL tra_adv_mus ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups ) |
---|
142 | CASE ( np_UBS ) ! UBS |
---|
143 | CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v ) |
---|
144 | CASE ( np_QCK ) ! QUICKEST |
---|
145 | CALL tra_adv_qck ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts ) |
---|
146 | ! |
---|
147 | END SELECT |
---|
148 | ! |
---|
149 | ! ! print mean trends (used for debugging) |
---|
150 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, & |
---|
151 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
---|
152 | ! |
---|
153 | IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' ) |
---|
154 | ! |
---|
155 | CALL wrk_dealloc( jpi,jpj,jpk, zun, zvn, zwn ) |
---|
156 | ! |
---|
157 | END SUBROUTINE tra_adv |
---|
158 | |
---|
159 | |
---|
160 | SUBROUTINE tra_adv_init |
---|
161 | !!--------------------------------------------------------------------- |
---|
162 | !! *** ROUTINE tra_adv_init *** |
---|
163 | !! |
---|
164 | !! ** Purpose : Control the consistency between namelist options for |
---|
165 | !! tracer advection schemes and set nadv |
---|
166 | !!---------------------------------------------------------------------- |
---|
167 | INTEGER :: ioptio, ios ! Local integers |
---|
168 | ! |
---|
169 | NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN |
---|
170 | & ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT |
---|
171 | & ln_traadv_mus, ln_mus_ups, & ! MUSCL |
---|
172 | & ln_traadv_ubs, nn_ubs_v, & ! UBS |
---|
173 | & ln_traadv_qck ! QCK |
---|
174 | !!---------------------------------------------------------------------- |
---|
175 | ! |
---|
176 | ! !== Namelist ==! |
---|
177 | ! |
---|
178 | REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme |
---|
179 | READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901) |
---|
180 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp ) |
---|
181 | ! |
---|
182 | REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme |
---|
183 | READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 ) |
---|
184 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp ) |
---|
185 | IF(lwm) WRITE ( numond, namtra_adv ) |
---|
186 | |
---|
187 | IF(lwp) THEN ! Namelist print |
---|
188 | WRITE(numout,*) |
---|
189 | WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme' |
---|
190 | WRITE(numout,*) '~~~~~~~~~~~' |
---|
191 | WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers' |
---|
192 | WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen |
---|
193 | WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h |
---|
194 | WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v |
---|
195 | WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct |
---|
196 | WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h |
---|
197 | WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v |
---|
198 | WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts |
---|
199 | WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus |
---|
200 | WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups |
---|
201 | WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs |
---|
202 | WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v |
---|
203 | WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck |
---|
204 | ENDIF |
---|
205 | |
---|
206 | ioptio = 0 !== Parameter control ==! |
---|
207 | IF( ln_traadv_cen ) ioptio = ioptio + 1 |
---|
208 | IF( ln_traadv_fct ) ioptio = ioptio + 1 |
---|
209 | IF( ln_traadv_mus ) ioptio = ioptio + 1 |
---|
210 | IF( ln_traadv_ubs ) ioptio = ioptio + 1 |
---|
211 | IF( ln_traadv_qck ) ioptio = ioptio + 1 |
---|
212 | ! |
---|
213 | IF( ioptio == 0 ) THEN |
---|
214 | nadv = np_NO_adv |
---|
215 | CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' ) |
---|
216 | ENDIF |
---|
217 | IF( (ioptio /= 1).AND. (.NOT. lk_c1d ) ) & |
---|
218 | CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' ) |
---|
219 | ! |
---|
220 | IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered |
---|
221 | .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN |
---|
222 | CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' ) |
---|
223 | ENDIF |
---|
224 | IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT |
---|
225 | .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN |
---|
226 | CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' ) |
---|
227 | ENDIF |
---|
228 | IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN |
---|
229 | IF( nn_fct_h == 4 ) THEN |
---|
230 | nn_fct_h = 2 |
---|
231 | CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' ) |
---|
232 | ENDIF |
---|
233 | IF( lk_vvl ) THEN |
---|
234 | CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' ) |
---|
235 | ENDIF |
---|
236 | IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' ) |
---|
237 | ENDIF |
---|
238 | IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS |
---|
239 | CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' ) |
---|
240 | ENDIF |
---|
241 | IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN |
---|
242 | CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' ) |
---|
243 | ENDIF |
---|
244 | IF( ln_isfcav ) THEN ! ice-shelf cavities |
---|
245 | IF( ln_traadv_cen .AND. nn_cen_v /= 4 .OR. & ! NO 4th order with ISF |
---|
246 | & ln_traadv_fct .AND. nn_fct_v /= 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' ) |
---|
247 | ENDIF |
---|
248 | ! |
---|
249 | ! !== used advection scheme ==! |
---|
250 | ! ! set nadv |
---|
251 | IF( ln_traadv_cen ) nadv = np_CEN |
---|
252 | IF( ln_traadv_fct ) nadv = np_FCT |
---|
253 | IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts |
---|
254 | IF( ln_traadv_mus ) nadv = np_MUS |
---|
255 | IF( ln_traadv_ubs ) nadv = np_UBS |
---|
256 | IF( ln_traadv_qck ) nadv = np_QCK |
---|
257 | |
---|
258 | IF(lwp) THEN ! Print the choice |
---|
259 | WRITE(numout,*) |
---|
260 | IF( nadv == np_NO_adv ) WRITE(numout,*) ' NO T-S advection' |
---|
261 | IF( nadv == np_CEN ) WRITE(numout,*) ' CEN scheme is used. Horizontal order: ', nn_cen_h, & |
---|
262 | & ' Vertical order: ', nn_cen_v |
---|
263 | IF( nadv == np_FCT ) WRITE(numout,*) ' FCT scheme is used. Horizontal order: ', nn_fct_h, & |
---|
264 | & ' Vertical order: ', nn_fct_v |
---|
265 | IF( nadv == np_FCT_zts ) WRITE(numout,*) ' use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping' |
---|
266 | IF( nadv == np_MUS ) WRITE(numout,*) ' MUSCL scheme is used' |
---|
267 | IF( nadv == np_UBS ) WRITE(numout,*) ' UBS scheme is used' |
---|
268 | IF( nadv == np_QCK ) WRITE(numout,*) ' QUICKEST scheme is used' |
---|
269 | ENDIF |
---|
270 | ! |
---|
271 | CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==! |
---|
272 | ! |
---|
273 | END SUBROUTINE tra_adv_init |
---|
274 | |
---|
275 | !!====================================================================== |
---|
276 | END MODULE traadv |
---|