New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7878

Last change on this file since 7878 was 7878, checked in by jcastill, 7 years ago

Add Phillips vertical Stokes drift parameterization as in the HZG wave branch
File size: 22.6 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!            3.6  !   2014-09  (Clementi E, Oddo P)New Stokes Drift Computation
9   !!             -   !   2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                     + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean variables
19   USE sbc_oce        ! Surface boundary condition: ocean fields
20   USE zdf_oce,  ONLY : ln_zdfqiao
21   USE bdy_oce        ! open boundary condition variables
22   USE domvvl         ! domain: variable volume layers
23   !
24   USE iom            ! I/O manager library
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE fldread        ! read input fields
28   USE wrk_nemo       !
29   USE phycst         ! physical constants
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wfreq  = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_tauoc  = .FALSE.
47   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
48
49   INTEGER ::   jpfld    ! number of files to read for stokes drift
50   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
51   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
52   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
53   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
54   INTEGER ::   jp_wfr   ! index of wave peak frequency         (s^-1)   at T-point
55
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_phioc ! structure of input fields (file informations, fields read) wave to ocean energy
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wfreq               !:
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   rn_crban            !: Craig and Banner constant for surface breaking waves mixing
65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !:
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
68   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
69   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
70
71#  include "vectopt_loop_substitute.h90"
72   !!----------------------------------------------------------------------
73   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
74   !! $Id$
75   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   SUBROUTINE sbc_stokes( )
80      !!---------------------------------------------------------------------
81      !!                     ***  ROUTINE sbc_stokes  ***
82      !!
83      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
84      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
85      !!
86      !! ** Method  : - Calculate Stokes transport speed
87      !!              - Calculate horizontal divergence
88      !!              - Integrate the horizontal divergenze from the bottom
89      !! ** action 
90      !!---------------------------------------------------------------------
91      INTEGER  ::   jj, ji, jk   ! dummy loop argument
92      INTEGER  ::   ik           ! local integer
93      REAL(wp) ::  ztransp, zfac, ztemp
94      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
95      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
96      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
97
98      !!---------------------------------------------------------------------
99      !
100
101      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
102      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd ) 
103      !
104      ! select parameterization for the calculation of vertical Stokes drift
105      SELECT CASE ( nn_sdrift )
106      !
107      CASE ( jp_breivik )
108         zfac = 2.0_wp * rpi / 16.0_wp
109         DO jj = 1, jpj               ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
110            DO ji = 1, jpi
111               ! Stokes drift velocity estimated from Hs and Tmean
112               ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
113               ! Stokes surface speed
114               tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
115               ! Wavenumber scale
116               zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
117            END DO
118         END DO
119         DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
120            DO ji = 1, jpim1
121               zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
122               zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
123               !
124               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
125               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
126            END DO
127         END DO
128         !
129         !                       !==  horizontal Stokes Drift 3D velocity  ==!
130         DO jk = 1, jpkm1
131            DO jj = 2, jpjm1
132               DO ji = 2, jpim1
133                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
134                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
135                  !                         
136                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
137                  zkh_v = zk_v(ji,jj) * zdep_v
138                  !                                ! Depth attenuation
139                  zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
140                  zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
141                  !
142                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
143                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
144               END DO
145            END DO
146         END DO
147      CASE ( jp_phillips )
148         DO jj = 1, jpjm1              ! Peak wavenumber & Stokes drift velocity at u- & v-points
149            DO ji = 1, jpim1
150               zk_u(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji+1,jj)*wfreq(ji+1,jj) ) / grav
151               zk_v(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji,jj+1)*wfreq(ji,jj+1) ) / grav
152               !
153               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
154               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
155            END DO
156         END DO
157         !
158         !                       !==  horizontal Stokes Drift 3D velocity  ==!
159         DO jk = 1, jpkm1
160            DO jj = 2, jpjm1
161               DO ji = 2, jpim1
162                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
163                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
164                  !                         
165                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
166                  zkh_v = zk_v(ji,jj) * zdep_v
167                  !                                ! Depth attenuation: beta=1 for Phillips
168                  zda_u = EXP( -2.0_wp*zkh_u ) - 1.0*SQRT(2.0*rpi*zkh_u) * ERFC(SQRT(2.0*zkh_u))
169                  zda_v = EXP( -2.0_wp*zkh_v ) - 1.0*SQRT(2.0*rpi*zkh_v) * ERFC(SQRT(2.0*zkh_v))
170                  !
171                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
172                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
173               END DO
174            END DO
175         END DO
176      END SELECT
177
178      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
179      !
180      !                       !==  vertical Stokes Drift 3D velocity  ==!
181      !
182      DO jk = 1, jpkm1               ! Horizontal e3*divergence
183         DO jj = 2, jpj
184            DO ji = fs_2, jpi
185               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji,  jj,jk)    &
186                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
187                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
188                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e12t(ji,jj)
189            END DO
190         END DO
191      END DO
192      !
193      IF( .NOT. AGRIF_Root() ) THEN
194         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
195         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
196         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
197         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
198      ENDIF
199      !
200      CALL lbc_lnk( ze3divh, 'T', 1. )
201      !
202      IF( .NOT. lk_vvl ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
203      ELSE                      ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
204      ENDIF
205      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
206         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
207      END DO
208#if defined key_bdy
209      IF( lk_bdy ) THEN
210         DO jk = 1, jpkm1
211            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
212         END DO
213      ENDIF
214#endif
215      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
216      div_sd(:,:) = 0._wp
217      DO jk = 1, jpkm1                                 !
218        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
219      END DO
220      !
221      CALL iom_put( "ustokes",  usd  )
222      CALL iom_put( "vstokes",  vsd  )
223      CALL iom_put( "wstokes",  wsd  )
224      !
225      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
226      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
227      !
228   END SUBROUTINE sbc_stokes
229
230
231   SUBROUTINE sbc_wave( kt )
232      !!---------------------------------------------------------------------
233      !!                     ***  ROUTINE sbc_wave  ***
234      !!
235      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
236      !!
237      !! ** Method  : - Read namelist namsbc_wave
238      !!              - Read Cd_n10 fields in netcdf files
239      !!              - Read stokes drift 2d in netcdf files
240      !!              - Read wave number in netcdf files
241      !!              - Compute 3d stokes drift using Breivik et al.,2014
242      !!                formulation
243      !! ** action 
244      !!---------------------------------------------------------------------
245      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
246      !!---------------------------------------------------------------------
247      !
248      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
249         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
250         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
251         ! check that the drag coefficient contains proper information even if
252         ! the masks do not match - the momentum stress is not masked!
253         WHERE( cdn_wave < 0.0 ) cdn_wave = 1.5e-3
254         WHERE( cdn_wave > 1.0 ) cdn_wave = 1.5e-3
255      ENDIF
256
257      IF( ln_tauoc .AND. .NOT. cpl_tauoc ) THEN    !==  Wave induced stress  ==!
258         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
259         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
260         WHERE( tauoc_wave < -100.0 ) tauoc_wave = 1.0
261         WHERE( tauoc_wave >  100.0 ) tauoc_wave = 1.0
262      ENDIF
263
264      IF( ln_phioc .AND. .NOT. cpl_phioc ) THEN    !==  Wave to ocean energy  ==!
265         CALL fld_read( kt, nn_fsbc, sf_phioc )          ! read wave to ocean energy from external forcing
266         rn_crban(:,:) = 29.0 * sf_phioc(1)%fnow(:,:,1)     ! ! Alfa is phioc*sqrt(rau0/zrhoa)  : rau0=water density, zhroa= air density
267         WHERE( rn_crban < -1000.0 ) rn_crban = 0.0
268         WHERE( rn_crban >  1000.0 ) rn_crban = 0.0
269      ENDIF
270
271      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
272         !
273         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
274            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
275            IF( jp_hsw > 0 ) THEN
276               hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
277               WHERE( hsw > 100.0 ) hsw = 0.0
278               WHERE( hsw <   0.0 ) hsw = 0.0
279            ENDIF
280            IF( jp_wmp > 0 ) THEN
281               wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
282               WHERE( wmp > 100.0 ) wmp = 0.0
283               WHERE( wmp <   0.0 ) wmp = 0.0
284            ENDIF
285            IF( jp_wfr > 0 ) THEN
286               wfreq(:,:) = sf_sd(jp_wfr)%fnow(:,:,1)   ! Peak wave frequency
287               WHERE( wfreq <    0.0 ) wfreq = 0.001 
288               WHERE( wfreq >  100.0 ) wfreq = 0.001
289            ENDIF
290            IF( jp_usd > 0 ) THEN
291               ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
292               WHERE( ut0sd < -100.0 ) ut0sd = 1.0
293               WHERE( ut0sd >  100.0 ) ut0sd = 1.0
294            ENDIF
295            IF( jp_vsd > 0 ) THEN
296               vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
297               WHERE( vt0sd < -100.0 ) vt0sd = 1.0
298               WHERE( vt0sd >  100.0 ) vt0sd = 1.0
299            ENDIF
300         ENDIF
301         !
302         ! Read also wave number if needed, so that it is available in coupling routines
303         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
304            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
305            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
306         ENDIF
307           
308         !                                         !==  Computation of the 3d Stokes Drift  ==!
309         !
310         IF( (nn_sdrift==jp_breivik  .AND. jp_hsw>0 .AND. jp_wmp>0 .AND. jp_usd>0 .AND. jp_vsd>0) .OR. &
311             (nn_sdrift==jp_phillips .AND. jp_wfr>0 .AND. jp_usd>0 .AND. jp_vsd>0) ) &
312            CALL sbc_stokes()            ! Calculate only if required fields are read
313         !                               ! In coupled wave model-NEMO case the call is done after coupling
314         !
315      ENDIF
316      !
317   END SUBROUTINE sbc_wave
318
319
320   SUBROUTINE sbc_wave_init
321      !!---------------------------------------------------------------------
322      !!                     ***  ROUTINE sbc_wave_init  ***
323      !!
324      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
325      !!
326      !! ** Method  : - Read namelist namsbc_wave
327      !!              - Read Cd_n10 fields in netcdf files
328      !!              - Read stokes drift 2d in netcdf files
329      !!              - Read wave number in netcdf files
330      !!              - Compute 3d stokes drift using Breivik et al.,2014
331      !!                formulation
332      !! ** action 
333      !!---------------------------------------------------------------------
334      INTEGER ::   ierror, ios   ! local integer
335      INTEGER ::   ifpr
336      !!
337      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
338      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
339      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd, sn_phioc, &
340                             &   sn_hsw, sn_wmp, sn_wfr, sn_wnum , &
341                             &   sn_tauoc      ! informations about the fields to be read
342      !
343      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wfr, sn_wnum, sn_tauoc, sn_phioc
344      !!---------------------------------------------------------------------
345      !
346      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
347      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
348901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
349         
350      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
351      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
352902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
353      IF(lwm) WRITE ( numond, namsbc_wave )
354      !
355      IF( ln_cdgw ) THEN
356         IF( .NOT. cpl_wdrag ) THEN
357            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
358            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_cd structure' )
359            !
360                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
361            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
362            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
363         ENDIF
364         ALLOCATE( cdn_wave(jpi,jpj) )
365      ENDIF
366
367      IF( ln_tauoc ) THEN
368         IF( .NOT. cpl_tauoc ) THEN
369            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
370            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauoc structure' )
371            !
372                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
373            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
374            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
375         ENDIF
376         ALLOCATE( tauoc_wave(jpi,jpj) )
377      ENDIF
378
379      IF( ln_phioc ) THEN
380         IF( .NOT. cpl_phioc ) THEN
381            ALLOCATE( sf_phioc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_phioc
382            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_phioc structure' )
383            !
384                                    ALLOCATE( sf_phioc(1)%fnow(jpi,jpj,1)   )
385            IF( sn_phioc%ln_tint )  ALLOCATE( sf_phioc(1)%fdta(jpi,jpj,1,2) )
386            CALL fld_fill( sf_phioc, (/ sn_phioc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
387         ENDIF
388         ALLOCATE( rn_crban(jpi,jpj) )
389      ENDIF
390
391      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
392         jpfld=0
393         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0   ;   jp_wfr=0
394         IF( .NOT. cpl_sdrftx ) THEN
395            jpfld  = jpfld + 1
396            jp_usd = jpfld
397         ENDIF
398         IF( .NOT. cpl_sdrfty ) THEN
399            jpfld  = jpfld + 1
400            jp_vsd = jpfld
401         ENDIF
402         IF( .NOT. cpl_hsig ) THEN
403            jpfld  = jpfld + 1
404            jp_hsw = jpfld
405         ENDIF
406         IF( .NOT. cpl_wper ) THEN
407            jpfld  = jpfld + 1
408            jp_wmp = jpfld
409         ENDIF
410         IF( .NOT. cpl_wfreq ) THEN
411            jpfld  = jpfld + 1
412            jp_wfr = jpfld
413         ENDIF
414
415         ! Read from file only the non-coupled fields
416         IF( jpfld > 0 ) THEN
417            ALLOCATE( slf_i(jpfld) )
418            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
419            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
420            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
421            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
422            IF( jp_wfr > 0 )   slf_i(jp_wfr) = sn_wfr
423            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
424            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_sd structure' )
425            !
426            DO ifpr= 1, jpfld
427               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
428               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
429            END DO
430            !
431            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
432         ENDIF
433         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
434         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
435         ALLOCATE( wfreq (jpi,jpj) )
436         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
437         ALLOCATE( div_sd(jpi,jpj) )
438         ALLOCATE( tsd2d (jpi,jpj) )
439         usd(:,:,:) = 0._wp
440         vsd(:,:,:) = 0._wp
441         wsd(:,:,:) = 0._wp
442         ! Wave number needed only if ln_zdfqiao=T
443         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
444            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
445            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wn structure' )
446                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
447            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
448            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
449         ENDIF
450         ALLOCATE( wnum(jpi,jpj) )
451      ENDIF
452      !
453   END SUBROUTINE sbc_wave_init
454
455   !!======================================================================
456END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.