source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 31.8 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limhdf          ! Ice horizontal diffusion
40   USE limthd          ! Ice thermodynamics
41   USE limitd_me       ! Mechanics on ice thickness distribution
42   USE limsbc          ! sea surface boundary condition
43   USE limdiahsb       ! Ice budget diagnostics
44   USE limwri          ! Ice outputs
45   USE limrst          ! Ice restarts
46   USE limupdate1      ! update of global variables
47   USE limupdate2      ! update of global variables
48   USE limvar          ! Ice variables switch
49
50   USE limmsh          ! LIM mesh
51   USE limistate       ! LIM initial state
52   USE limthd_sal      ! LIM ice thermodynamics: salinity
53
54   USE c1d             ! 1D vertical configuration
55   USE lbclnk          ! lateral boundary condition - MPP link
56   USE lib_mpp         ! MPP library
57   USE wrk_nemo        ! work arrays
58   USE timing          ! Timing
59   USE iom             ! I/O manager library
60   USE in_out_manager  ! I/O manager
61   USE prtctl          ! Print control
62   USE lib_fortran     !
63   USE limctl
64
65#if defined key_bdy 
66   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
67#endif
68
69   IMPLICIT NONE
70   PRIVATE
71
72   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
73   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
74   
75   !! * Substitutions
76#  include "domzgr_substitute.h90"
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
80   !! $Id$
81   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   !!======================================================================
86
87   SUBROUTINE sbc_ice_lim( kt, kblk )
88      !!---------------------------------------------------------------------
89      !!                  ***  ROUTINE sbc_ice_lim  ***
90      !!                   
91      !! ** Purpose :   update the ocean surface boundary condition via the
92      !!                Louvain la Neuve Sea Ice Model time stepping
93      !!
94      !! ** Method  :   ice model time stepping
95      !!              - call the ice dynamics routine
96      !!              - call the ice advection/diffusion routine
97      !!              - call the ice thermodynamics routine
98      !!              - call the routine that computes mass and
99      !!                heat fluxes at the ice/ocean interface
100      !!              - save the outputs
101      !!              - save the outputs for restart when necessary
102      !!
103      !! ** Action  : - time evolution of the LIM sea-ice model
104      !!              - update all sbc variables below sea-ice:
105      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
106      !!---------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt      ! ocean time step
108      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
109      !!
110      INTEGER  ::   jl                 ! dummy loop index
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
112      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice          ! mean ice albedo (for coupled)
113      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zutau_ice, zvtau_ice 
114      !!----------------------------------------------------------------------
115
116      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
117
118      !-----------------------!
119      ! --- Ice time step --- !
120      !-----------------------!
121      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
122
123         ! mean surface ocean current at ice velocity point (C-grid dynamics :  U- & V-points as the ocean)
124         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
125         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
126         
127         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
128         CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
129         t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
130         
131         ! Mask sea ice surface temperature (set to rt0 over land)
132         DO jl = 1, jpl
133            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
134         END DO     
135         !
136         !------------------------------------------------!                                           
137         ! --- Dynamical coupling with the atmosphere --- !                                           
138         !------------------------------------------------!
139         ! It provides the following fields:
140         ! utau_ice, vtau_ice : surface ice stress (U- & V-points)   [N/m2]
141         !-----------------------------------------------------------------
142         SELECT CASE( kblk )
143         CASE( jp_clio    )   ;   CALL blk_ice_clio_tau                         ! CLIO bulk formulation           
144         CASE( jp_core    )   ;   CALL blk_ice_core_tau                         ! CORE bulk formulation
145         CASE( jp_purecpl )   ;   CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled   formulation
146         END SELECT
147         
148         IF( ln_mixcpl) THEN   ! Case of a mixed Bulk/Coupled formulation
149            CALL wrk_alloc( jpi,jpj    , zutau_ice, zvtau_ice)
150            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
151            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
152            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
153            CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
154         ENDIF
155
156         !-------------------------------------------------------!
157         ! --- ice dynamics and transport (except in 1D case) ---!
158         !-------------------------------------------------------!
159         numit = numit + nn_fsbc                  ! Ice model time step
160         !                                                   
161         CALL sbc_lim_bef                         ! Store previous ice values
162         CALL sbc_lim_diag0                       ! set diag of mass, heat and salt fluxes to 0
163         CALL lim_rst_opn( kt )                   ! Open Ice restart file
164         !
165         IF( .NOT. lk_c1d ) THEN
166            !
167            CALL lim_dyn( kt )                    ! Ice dynamics    ( rheology/dynamics )   
168            !
169            CALL lim_trp( kt )                    ! Ice transport   ( Advection/diffusion )
170            !
171            IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
172            !
173#if defined key_bdy
174            CALL bdy_ice_lim( kt )                ! bdy ice thermo
175            IF( ln_icectl )       CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
176#endif
177            !
178            CALL lim_update1( kt )                ! Corrections
179            !
180         ENDIF
181         
182         ! previous lead fraction and ice volume for flux calculations
183         CALL sbc_lim_bef                       
184         CALL lim_var_glo2eqv                     ! ht_i and ht_s for ice albedo calculation
185         CALL lim_var_agg(1)                      ! at_i for coupling (via pfrld)
186         pfrld(:,:)   = 1._wp - at_i(:,:)
187         phicif(:,:)  = vt_i(:,:)
188         
189         !------------------------------------------------------!                                           
190         ! --- Thermodynamical coupling with the atmosphere --- !                                           
191         !------------------------------------------------------!
192         ! It provides the following fields:
193         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
194         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
195         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
196         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
197         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
198         !----------------------------------------------------------------------------------------
199         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
200         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
201
202         SELECT CASE( kblk )
203         CASE( jp_clio )                                       ! CLIO bulk formulation
204            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
205            ! (zalb_ice) is computed within the bulk routine
206            CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, zalb_ice )
207            IF( ln_mixcpl      ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
208            IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
209         CASE( jp_core )                                       ! CORE bulk formulation
210            ! albedo depends on cloud fraction because of non-linear spectral effects
211            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
212            CALL blk_ice_core_flx( t_su, zalb_ice )
213            IF( ln_mixcpl      ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
214            IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
215         CASE ( jp_purecpl )
216            ! albedo depends on cloud fraction because of non-linear spectral effects
217            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
218                                 CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
219            ! clem: evap_ice is forced to 0 in coupled mode for now
220            !       but it needs to be changed (along with modif in limthd_dh) once heat flux from evap will be avail. from atm. models
221            evap_ice  (:,:,:) = 0._wp   ;   devap_ice (:,:,:) = 0._wp
222            IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
223         END SELECT
224         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
225
226         !----------------------------!
227         ! --- ice thermodynamics --- !
228         !----------------------------!
229         CALL lim_thd( kt )                         ! Ice thermodynamics     
230         !
231         CALL lim_update2( kt )                     ! Corrections
232         !
233         CALL lim_sbc_flx( kt )                     ! Update surface ocean mass, heat and salt fluxes
234         !
235         IF(ln_limdiaout) CALL lim_diahsb           ! Diagnostics and outputs
236         !
237         CALL lim_wri( 1 )                          ! Ice outputs
238         !
239         IF( kt == nit000 .AND. ln_rstart )   &
240            &             CALL iom_close( numrir )  ! close input ice restart file
241         !
242         IF( lrst_ice )   CALL lim_rst_write( kt )  ! Ice restart file
243         !
244         IF( ln_icectl )  CALL lim_ctl( kt )        ! alerts in case of model crash
245         !
246      ENDIF   ! End sea-ice time step only
247
248      !-------------------------!
249      ! --- Ocean time step --- !
250      !-------------------------!
251      ! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
252      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
253!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
254      !
255      IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
256      !
257   END SUBROUTINE sbc_ice_lim
258   
259
260   SUBROUTINE sbc_lim_init
261      !!----------------------------------------------------------------------
262      !!                  ***  ROUTINE sbc_lim_init  ***
263      !!
264      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
265      !!----------------------------------------------------------------------
266      INTEGER :: ierr
267      !!----------------------------------------------------------------------
268      IF(lwp) WRITE(numout,*)
269      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
270      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
271      !
272                                       ! Open the reference and configuration namelist files and namelist output file
273      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
274      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
275      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
276
277      CALL ice_run                     ! set some ice run parameters
278      !
279      !                                ! Allocate the ice arrays
280      ierr =        ice_alloc        ()      ! ice variables
281      ierr = ierr + dom_ice_alloc    ()      ! domain
282      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
283      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
284      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
285      !
286      IF( lk_mpp    )   CALL mpp_sum( ierr )
287      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
288      !
289      !                                ! adequation jpk versus ice/snow layers/categories
290      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
291         &      CALL ctl_stop( 'STOP',                          &
292         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
293         &     'use more ocean levels or less ice/snow layers/categories.' )
294      !
295      CALL lim_itd_init                ! ice thickness distribution initialization
296      !
297      CALL lim_hdf_init                ! set ice horizontal diffusion computation parameters
298      !
299      CALL lim_thd_init                ! set ice thermodynics parameters
300      !
301      CALL lim_thd_sal_init            ! set ice salinity parameters
302      !
303      CALL lim_msh                     ! ice mesh initialization
304      !
305      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
306      !                                ! Initial sea-ice state
307      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
308         numit = 0
309         numit = nit000 - 1
310         CALL lim_istate
311      ELSE                                    ! start from a restart file
312         CALL lim_rst_read
313         numit = nit000 - 1
314      ENDIF
315      CALL lim_var_agg(1)
316      CALL lim_var_glo2eqv
317      !
318      CALL lim_sbc_init                 ! ice surface boundary condition   
319      !
320      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
321      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
322      !
323      nstart = numit  + nn_fsbc     
324      nitrun = nitend - nit000 + 1 
325      nlast  = numit  + nitrun 
326      !
327      IF( nstock == 0 )   nstock = nlast + 1
328      !
329   END SUBROUTINE sbc_lim_init
330
331
332   SUBROUTINE ice_run
333      !!-------------------------------------------------------------------
334      !!                  ***  ROUTINE ice_run ***
335      !!                 
336      !! ** Purpose :   Definition some run parameter for ice model
337      !!
338      !! ** Method  :   Read the namicerun namelist and check the parameter
339      !!              values called at the first timestep (nit000)
340      !!
341      !! ** input   :   Namelist namicerun
342      !!-------------------------------------------------------------------
343      INTEGER  ::   ios                 ! Local integer output status for namelist read
344      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir,  &
345         &                ln_limdyn, rn_amax, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt 
346      !!-------------------------------------------------------------------
347      !                   
348      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
349      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
350901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
351
352      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
353      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
354902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
355      IF(lwm) WRITE ( numoni, namicerun )
356      !
357      !
358      IF(lwp) THEN                        ! control print
359         WRITE(numout,*)
360         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
361         WRITE(numout,*) ' ~~~~~~'
362         WRITE(numout,*) '   number of ice  categories                               = ', jpl
363         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
364         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
365         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
366         WRITE(numout,*) '   maximum ice concentration                               = ', rn_amax 
367         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
368         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
369         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
370         WRITE(numout,*) '   i-index for control prints (ln_icectl=true)             = ', iiceprt
371         WRITE(numout,*) '   j-index for control prints (ln_icectl=true)             = ', jiceprt
372      ENDIF
373      !
374      ! sea-ice timestep and inverse
375      rdt_ice   = nn_fsbc * rdttra(1) 
376      r1_rdtice = 1._wp / rdt_ice 
377
378      ! inverse of nlay_i and nlay_s
379      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
380      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
381      !
382#if defined key_bdy
383      IF( lwp .AND. ln_limdiahsb )  CALL ctl_warn('online conservation check activated but it does not work with BDY')
384#endif
385      !
386   END SUBROUTINE ice_run
387
388
389   SUBROUTINE lim_itd_init
390      !!------------------------------------------------------------------
391      !!                ***  ROUTINE lim_itd_init ***
392      !!
393      !! ** Purpose :   Initializes the ice thickness distribution
394      !! ** Method  :   ...
395      !! ** input   :   Namelist namiceitd
396      !!-------------------------------------------------------------------
397      INTEGER  ::   ios                 ! Local integer output status for namelist read
398      NAMELIST/namiceitd/ nn_catbnd, rn_himean
399      !
400      INTEGER  ::   jl                   ! dummy loop index
401      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
402      REAL(wp) ::   zhmax, znum, zden, zalpha !
403      !!------------------------------------------------------------------
404      !
405      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
406      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
407903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
408
409      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
410      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
411904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
412      IF(lwm) WRITE ( numoni, namiceitd )
413      !
414      !
415      IF(lwp) THEN                        ! control print
416         WRITE(numout,*)
417         WRITE(numout,*) 'ice_itd : ice cat distribution'
418         WRITE(numout,*) ' ~~~~~~'
419         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
420         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
421      ENDIF
422
423      !----------------------------------
424      !- Thickness categories boundaries
425      !----------------------------------
426      IF(lwp) WRITE(numout,*)
427      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
428      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
429
430      hi_max(:) = 0._wp
431
432      SELECT CASE ( nn_catbnd  )       
433                                   !----------------------
434         CASE (1)                  ! tanh function (CICE)
435                                   !----------------------
436         zc1 =  3._wp / REAL( jpl, wp )
437         zc2 = 10._wp * zc1
438         zc3 =  3._wp
439
440         DO jl = 1, jpl
441            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
442            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
443         END DO
444
445                                   !----------------------
446         CASE (2)                  ! h^(-alpha) function
447                                   !----------------------
448         zalpha = 0.05             ! exponent of the transform function
449
450         zhmax  = 3.*rn_himean
451
452         DO jl = 1, jpl 
453            znum = jpl * ( zhmax+1 )**zalpha
454            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
455            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
456         END DO
457
458      END SELECT
459
460      DO jl = 1, jpl
461         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
462      END DO
463
464      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
465      hi_max(jpl) = 99._wp
466
467      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
468      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
469      !
470   END SUBROUTINE lim_itd_init
471
472   
473   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
474      !!---------------------------------------------------------------------
475      !!                  ***  ROUTINE ice_lim_flx  ***
476      !!                   
477      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
478      !!                redistributing fluxes on ice categories                   
479      !!
480      !! ** Method  :   average then redistribute
481      !!
482      !! ** Action  :   
483      !!---------------------------------------------------------------------
484      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
485                                                                ! =1 average and redistribute ; =2 redistribute
486      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
487      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
488      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
489      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
490      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
491      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
492      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
493      !
494      INTEGER  ::   jl      ! dummy loop index
495      !
496      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
497      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
498      !
499      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
500      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
501      REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m  ! Mean sublimation over all categories
502      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
503      REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
504      !!----------------------------------------------------------------------
505
506      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
507      !
508      !
509      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
510      CASE( 0 , 1 )
511         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
512         !
513         z_qns_m  (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
514         z_qsr_m  (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
515         z_dqn_m  (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
516         z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
517         z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
518         DO jl = 1, jpl
519            pdqn_ice  (:,:,jl) = z_dqn_m(:,:)
520            pdevap_ice(:,:,jl) = z_devap_m(:,:)
521         END DO
522         !
523         DO jl = 1, jpl
524            pqns_ice (:,:,jl) = z_qns_m(:,:)
525            pqsr_ice (:,:,jl) = z_qsr_m(:,:)
526            pevap_ice(:,:,jl) = z_evap_m(:,:)
527         END DO
528         !
529         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
530      END SELECT
531
532      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
533      CASE( 1 , 2 )
534         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
535         !
536         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
537         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
538         DO jl = 1, jpl
539            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
540            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
541            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
542         END DO
543         !
544         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
545      END SELECT
546      !
547      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
548      !
549   END SUBROUTINE ice_lim_flx
550
551   SUBROUTINE sbc_lim_bef
552      !!----------------------------------------------------------------------
553      !!                  ***  ROUTINE sbc_lim_bef  ***
554      !!
555      !! ** purpose :  store ice variables at "before" time step
556      !!----------------------------------------------------------------------
557      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
558      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
559      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
560      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
561      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
562      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
563      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
564      u_ice_b(:,:)     = u_ice(:,:)
565      v_ice_b(:,:)     = v_ice(:,:)
566     
567   END SUBROUTINE sbc_lim_bef
568
569   SUBROUTINE sbc_lim_diag0
570      !!----------------------------------------------------------------------
571      !!                  ***  ROUTINE sbc_lim_diag0  ***
572      !!
573      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
574      !!               of the time step
575      !!----------------------------------------------------------------------
576      sfx    (:,:) = 0._wp   ;
577      sfx_bri(:,:) = 0._wp   ; 
578      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
579      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
580      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
581      sfx_res(:,:) = 0._wp
582     
583      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
584      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
585      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
586      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
587      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
588      wfx_spr(:,:) = 0._wp   ;   
589     
590      hfx_thd(:,:) = 0._wp   ;   
591      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
592      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
593      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
594      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
595      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
596      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
597      hfx_err_dif(:,:) = 0._wp   ;
598
599      afx_tot(:,:) = 0._wp   ;
600      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
601
602      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp ;
603      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp ;
604     
605   END SUBROUTINE sbc_lim_diag0
606
607     
608   FUNCTION fice_cell_ave ( ptab )
609      !!--------------------------------------------------------------------------
610      !! * Compute average over categories, for grid cell (ice covered and free ocean)
611      !!--------------------------------------------------------------------------
612      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
613      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
614      INTEGER :: jl ! Dummy loop index
615     
616      fice_cell_ave (:,:) = 0.0_wp
617      DO jl = 1, jpl
618         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
619      END DO
620     
621   END FUNCTION fice_cell_ave
622   
623   
624   FUNCTION fice_ice_ave ( ptab )
625      !!--------------------------------------------------------------------------
626      !! * Compute average over categories, for ice covered part of grid cell
627      !!--------------------------------------------------------------------------
628      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
629      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
630
631      fice_ice_ave (:,:) = 0.0_wp
632      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
633
634   END FUNCTION fice_ice_ave
635
636
637#else
638   !!----------------------------------------------------------------------
639   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
640   !!----------------------------------------------------------------------
641CONTAINS
642   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
643      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
644   END SUBROUTINE sbc_ice_lim
645   SUBROUTINE sbc_lim_init                 ! Dummy routine
646   END SUBROUTINE sbc_lim_init
647#endif
648
649   !!======================================================================
650END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.