| [888] | 1 | MODULE sbcfwb |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcfwb *** |
|---|
| 4 | !! Ocean fluxes : domain averaged freshwater budget |
|---|
| 5 | !!====================================================================== |
|---|
| [2528] | 6 | !! History : OPA ! 2001-02 (E. Durand) Original code |
|---|
| 7 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-08 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-07 (C. Talandier) emp mean s spread over erp area |
|---|
| [5120] | 10 | !! 3.6 ! 2014-11 (P. Mathiot ) add ice shelf melting |
|---|
| [888] | 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| [6140] | 14 | !! sbc_fwb : freshwater budget for global ocean configurations (free surface & forced mode) |
|---|
| [888] | 15 | !!---------------------------------------------------------------------- |
|---|
| [6140] | 16 | USE oce ! ocean dynamics and tracers |
|---|
| 17 | USE dom_oce ! ocean space and time domain |
|---|
| 18 | USE sbc_oce ! surface ocean boundary condition |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbcrnf ! ocean runoffs |
|---|
| 21 | USE sbcisf ! ice shelf melting contribution |
|---|
| 22 | USE sbcssr ! Sea-Surface damping terms |
|---|
| 23 | ! |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE lib_mpp ! distribued memory computing library |
|---|
| 26 | USE wrk_nemo ! work arrays |
|---|
| 27 | USE timing ! Timing |
|---|
| 28 | USE lbclnk ! ocean lateral boundary conditions |
|---|
| 29 | USE lib_fortran ! |
|---|
| [888] | 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| [2715] | 34 | PUBLIC sbc_fwb ! routine called by step |
|---|
| [888] | 35 | |
|---|
| [2715] | 36 | REAL(wp) :: a_fwb_b ! annual domain averaged freshwater budget |
|---|
| 37 | REAL(wp) :: a_fwb ! for 2 year before (_b) and before year. |
|---|
| 38 | REAL(wp) :: fwfold ! fwfold to be suppressed |
|---|
| 39 | REAL(wp) :: area ! global mean ocean surface (interior domain) |
|---|
| [888] | 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| [2528] | 44 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| [1156] | 45 | !! $Id$ |
|---|
| [2528] | 46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| [888] | 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc ) |
|---|
| 51 | !!--------------------------------------------------------------------- |
|---|
| 52 | !! *** ROUTINE sbc_fwb *** |
|---|
| 53 | !! |
|---|
| 54 | !! ** Purpose : Control the mean sea surface drift |
|---|
| 55 | !! |
|---|
| 56 | !! ** Method : several ways depending on kn_fwb |
|---|
| 57 | !! =0 no control |
|---|
| [1168] | 58 | !! =1 global mean of emp set to zero at each nn_fsbc time step |
|---|
| 59 | !! =2 annual global mean corrected from previous year |
|---|
| [4689] | 60 | !! =3 global mean of emp set to zero at each nn_fsbc time step |
|---|
| 61 | !! & spread out over erp area depending its sign |
|---|
| [3625] | 62 | !! Note: if sea ice is embedded it is taken into account when computing the budget |
|---|
| [888] | 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 65 | INTEGER, INTENT( in ) :: kn_fsbc ! |
|---|
| 66 | INTEGER, INTENT( in ) :: kn_fwb ! ocean time-step index |
|---|
| [2715] | 67 | ! |
|---|
| [3625] | 68 | INTEGER :: inum, ikty, iyear ! local integers |
|---|
| 69 | REAL(wp) :: z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp ! local scalars |
|---|
| 70 | REAL(wp) :: zsurf_neg, zsurf_pos, zsurf_tospread, zcoef ! - - |
|---|
| 71 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces |
|---|
| 72 | REAL(wp), POINTER, DIMENSION(:,:) :: ztmsk_tospread, zerp_cor ! - - |
|---|
| [888] | 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | ! |
|---|
| [3294] | 75 | IF( nn_timing == 1 ) CALL timing_start('sbc_fwb') |
|---|
| [2715] | 76 | ! |
|---|
| [3294] | 77 | CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
|---|
| 78 | ! |
|---|
| [888] | 79 | IF( kt == nit000 ) THEN |
|---|
| 80 | IF(lwp) THEN |
|---|
| 81 | WRITE(numout,*) |
|---|
| 82 | WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction' |
|---|
| 83 | WRITE(numout,*) '~~~~~~~' |
|---|
| 84 | IF( kn_fwb == 1 ) WRITE(numout,*) ' instantaneously set to zero' |
|---|
| 85 | IF( kn_fwb == 2 ) WRITE(numout,*) ' adjusted from previous year budget' |
|---|
| [4689] | 86 | IF( kn_fwb == 3 ) WRITE(numout,*) ' fwf set to zero and spread out over erp area' |
|---|
| [888] | 87 | ENDIF |
|---|
| 88 | ! |
|---|
| [4689] | 89 | IF( kn_fwb == 3 .AND. nn_sssr /= 2 ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' ) |
|---|
| [5120] | 90 | IF( kn_fwb == 3 .AND. ln_isfcav ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' ) |
|---|
| [4689] | 91 | ! |
|---|
| [5120] | 92 | area = glob_sum( e1e2t(:,:) * tmask(:,:,1)) ! interior global domain surface |
|---|
| 93 | ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes |
|---|
| 94 | ! and in case of no melt, it can generate HSSW. |
|---|
| [3625] | 95 | ! |
|---|
| [4990] | 96 | #if ! defined key_lim2 && ! defined key_lim3 && ! defined key_cice |
|---|
| [3625] | 97 | snwice_mass_b(:,:) = 0.e0 ! no sea-ice model is being used : no snow+ice mass |
|---|
| 98 | snwice_mass (:,:) = 0.e0 |
|---|
| 99 | #endif |
|---|
| 100 | ! |
|---|
| [888] | 101 | ENDIF |
|---|
| 102 | |
|---|
| 103 | |
|---|
| 104 | SELECT CASE ( kn_fwb ) |
|---|
| 105 | ! |
|---|
| [2528] | 106 | CASE ( 1 ) !== global mean fwf set to zero ==! |
|---|
| [1245] | 107 | ! |
|---|
| [888] | 108 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
|---|
| [5643] | 109 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area ! sum over the global domain |
|---|
| [3625] | 110 | zcoef = z_fwf * rcp |
|---|
| [5120] | 111 | emp(:,:) = emp(:,:) - z_fwf * tmask(:,:,1) |
|---|
| 112 | qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
|---|
| [888] | 113 | ENDIF |
|---|
| 114 | ! |
|---|
| [2528] | 115 | CASE ( 2 ) !== fwf budget adjusted from the previous year ==! |
|---|
| 116 | ! |
|---|
| [3625] | 117 | IF( kt == nit000 ) THEN ! initialisation |
|---|
| [2528] | 118 | ! ! Read the corrective factor on precipitations (fwfold) |
|---|
| [1581] | 119 | CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. ) |
|---|
| [895] | 120 | READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb |
|---|
| 121 | CLOSE( inum ) |
|---|
| [2528] | 122 | fwfold = a_fwb ! current year freshwater budget correction |
|---|
| 123 | ! ! estimate from the previous year budget |
|---|
| [895] | 124 | IF(lwp)WRITE(numout,*) |
|---|
| [2528] | 125 | IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear , ' freshwater budget correction = ', fwfold |
|---|
| [895] | 126 | IF(lwp)WRITE(numout,*)' year = ',iyear-1, ' freshwater budget read = ', a_fwb |
|---|
| 127 | IF(lwp)WRITE(numout,*)' year = ',iyear-2, ' freshwater budget read = ', a_fwb_b |
|---|
| 128 | ENDIF |
|---|
| [2528] | 129 | ! ! Update fwfold if new year start |
|---|
| [6140] | 130 | ikty = 365 * 86400 / rdt !!bug use of 365 days leap year or 360d year !!!!!!! |
|---|
| [888] | 131 | IF( MOD( kt, ikty ) == 0 ) THEN |
|---|
| [3625] | 132 | a_fwb_b = a_fwb ! mean sea level taking into account the ice+snow |
|---|
| 133 | ! sum over the global domain |
|---|
| 134 | a_fwb = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) ) |
|---|
| [4161] | 135 | a_fwb = a_fwb * 1.e+3 / ( area * rday * 365. ) ! convert in Kg/m3/s = mm/s |
|---|
| [888] | 136 | !!gm ! !!bug 365d year |
|---|
| [2528] | 137 | fwfold = a_fwb ! current year freshwater budget correction |
|---|
| 138 | ! ! estimate from the previous year budget |
|---|
| [888] | 139 | ENDIF |
|---|
| 140 | ! |
|---|
| [3625] | 141 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN ! correct the freshwater fluxes |
|---|
| 142 | zcoef = fwfold * rcp |
|---|
| [5120] | 143 | emp(:,:) = emp(:,:) + fwfold * tmask(:,:,1) |
|---|
| 144 | qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
|---|
| [888] | 145 | ENDIF |
|---|
| 146 | ! |
|---|
| [3625] | 147 | IF( kt == nitend .AND. lwp ) THEN ! save fwfold value in a file |
|---|
| [1581] | 148 | CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea ) |
|---|
| 149 | WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb |
|---|
| 150 | CLOSE( inum ) |
|---|
| [888] | 151 | ENDIF |
|---|
| 152 | ! |
|---|
| [4689] | 153 | CASE ( 3 ) !== global fwf set to zero and spread out over erp area ==! |
|---|
| 154 | ! |
|---|
| 155 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
|---|
| 156 | ztmsk_pos(:,:) = tmask_i(:,:) ! Select <0 and >0 area of erp |
|---|
| 157 | WHERE( erp < 0._wp ) ztmsk_pos = 0._wp |
|---|
| 158 | ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:) |
|---|
| 159 | ! |
|---|
| 160 | zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) ) ! Area filled by <0 and >0 erp |
|---|
| 161 | zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) ) |
|---|
| 162 | ! ! fwf global mean (excluding ocean to ice/snow exchanges) |
|---|
| [5643] | 163 | z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area |
|---|
| [4689] | 164 | ! |
|---|
| 165 | IF( z_fwf < 0._wp ) THEN ! spread out over >0 erp area to increase evaporation |
|---|
| 166 | zsurf_tospread = zsurf_pos |
|---|
| 167 | ztmsk_tospread(:,:) = ztmsk_pos(:,:) |
|---|
| 168 | ELSE ! spread out over <0 erp area to increase precipitation |
|---|
| 169 | zsurf_tospread = zsurf_neg |
|---|
| 170 | ztmsk_tospread(:,:) = ztmsk_neg(:,:) |
|---|
| 171 | ENDIF |
|---|
| 172 | ! |
|---|
| 173 | zsum_fwf = glob_sum( e1e2t(:,:) * z_fwf ) ! fwf global mean over <0 or >0 erp area |
|---|
| 174 | !!gm : zsum_fwf = z_fwf * area ??? it is right? I think so.... |
|---|
| 175 | z_fwf_nsrf = zsum_fwf / ( zsurf_tospread + rsmall ) |
|---|
| 176 | ! ! weight to respect erp field 2D structure |
|---|
| 177 | zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) ) |
|---|
| 178 | z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall ) |
|---|
| 179 | ! ! final correction term to apply |
|---|
| 180 | zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:) |
|---|
| 181 | ! |
|---|
| 182 | !!gm ===>>>> lbc_lnk should be useless as all the computation is done over the whole domain ! |
|---|
| 183 | CALL lbc_lnk( zerp_cor, 'T', 1. ) |
|---|
| 184 | ! |
|---|
| 185 | emp(:,:) = emp(:,:) + zerp_cor(:,:) |
|---|
| 186 | qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:) ! account for change to the heat budget due to fw correction |
|---|
| 187 | erp(:,:) = erp(:,:) + zerp_cor(:,:) |
|---|
| 188 | ! |
|---|
| 189 | IF( nprint == 1 .AND. lwp ) THEN ! control print |
|---|
| 190 | IF( z_fwf < 0._wp ) THEN |
|---|
| 191 | WRITE(numout,*)' z_fwf < 0' |
|---|
| 192 | WRITE(numout,*)' SUM(erp+) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 193 | ELSE |
|---|
| 194 | WRITE(numout,*)' z_fwf >= 0' |
|---|
| 195 | WRITE(numout,*)' SUM(erp-) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 196 | ENDIF |
|---|
| 197 | WRITE(numout,*)' SUM(empG) = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv' |
|---|
| 198 | WRITE(numout,*)' z_fwf = ', z_fwf ,' Kg/m2/s' |
|---|
| 199 | WRITE(numout,*)' z_fwf_nsrf = ', z_fwf_nsrf ,' Kg/m2/s' |
|---|
| 200 | WRITE(numout,*)' MIN(zerp_cor) = ', MINVAL(zerp_cor) |
|---|
| 201 | WRITE(numout,*)' MAX(zerp_cor) = ', MAXVAL(zerp_cor) |
|---|
| 202 | ENDIF |
|---|
| 203 | ENDIF |
|---|
| 204 | ! |
|---|
| [2528] | 205 | CASE DEFAULT !== you should never be there ==! |
|---|
| [4689] | 206 | CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' ) |
|---|
| [888] | 207 | ! |
|---|
| 208 | END SELECT |
|---|
| 209 | ! |
|---|
| [3294] | 210 | CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor ) |
|---|
| [2715] | 211 | ! |
|---|
| [3294] | 212 | IF( nn_timing == 1 ) CALL timing_stop('sbc_fwb') |
|---|
| 213 | ! |
|---|
| [888] | 214 | END SUBROUTINE sbc_fwb |
|---|
| 215 | |
|---|
| 216 | !!====================================================================== |
|---|
| 217 | END MODULE sbcfwb |
|---|
