| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.4 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !! 3.6 ! 2015-12 (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 18 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and active tracers |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 23 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 24 | USE trd_oce ! trends: ocean variables |
|---|
| 25 | USE trdtra ! trends manager: tracers |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | USE iom ! I/O manager |
|---|
| 30 | USE fldread ! read input fields |
|---|
| 31 | USE restart ! ocean restart |
|---|
| 32 | USE lib_mpp ! MPP library |
|---|
| 33 | USE wrk_nemo ! Memory Allocation |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | USE iom_def, ONLY : lxios_read, lwxios |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 41 | PUBLIC tra_qsr_init ! routine called by nemogcm.F90 |
|---|
| 42 | |
|---|
| 43 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 44 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 45 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 48 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 49 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 50 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 52 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 53 | LOGICAL :: ln_qsr_sio !: single processor read flag |
|---|
| 54 | |
|---|
| 55 | ! Module variables |
|---|
| 56 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 57 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 58 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 59 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 60 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 61 | |
|---|
| 62 | !! * Substitutions |
|---|
| 63 | # include "domzgr_substitute.h90" |
|---|
| 64 | # include "vectopt_loop_substitute.h90" |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 67 | !! $Id$ |
|---|
| 68 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | CONTAINS |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE tra_qsr( kt ) |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE tra_qsr *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 77 | !! penetration and add it to the general temperature trend. |
|---|
| 78 | !! |
|---|
| 79 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 80 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 81 | !! Considering the 2 wavebands case: |
|---|
| 82 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 83 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 84 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 85 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 86 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 87 | !! in the last ocean level. |
|---|
| 88 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 89 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 90 | !! used for the computation are calculated one for once as they |
|---|
| 91 | !! depends on k only. |
|---|
| 92 | !! |
|---|
| 93 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 94 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 95 | !! |
|---|
| 96 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 97 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 98 | !! Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562 |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 102 | ! |
|---|
| 103 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 104 | INTEGER :: irgb ! local integers |
|---|
| 105 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 106 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 107 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 108 | REAL(wp) :: zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze |
|---|
| 109 | REAL(wp) :: zlogc, zlogc2, zlogc3 |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 111 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d |
|---|
| 112 | !!-------------------------------------------------------------------------- |
|---|
| 113 | ! |
|---|
| 114 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 115 | ! |
|---|
| 116 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 117 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 118 | ! |
|---|
| 119 | IF( kt == nit000 ) THEN |
|---|
| 120 | IF(lwp) WRITE(numout,*) |
|---|
| 121 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 122 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 123 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 124 | ENDIF |
|---|
| 125 | |
|---|
| 126 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 127 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 128 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 129 | ENDIF |
|---|
| 130 | |
|---|
| 131 | ! Set before qsr tracer content field |
|---|
| 132 | ! *********************************** |
|---|
| 133 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 134 | ! ! ----------------------------------- |
|---|
| 135 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 136 | ! |
|---|
| 137 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 138 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 139 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 140 | zfact = 0.5e0 |
|---|
| 141 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b, lrxios = lxios_read ) ! before heat content trend due to Qsr flux |
|---|
| 142 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 143 | zfact = 1.e0 |
|---|
| 144 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 145 | ENDIF |
|---|
| 146 | ELSE ! Swap of forcing field |
|---|
| 147 | ! ! --------------------- |
|---|
| 148 | zfact = 0.5e0 |
|---|
| 149 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 150 | ENDIF |
|---|
| 151 | ! Compute now qsr tracer content field |
|---|
| 152 | ! ************************************ |
|---|
| 153 | |
|---|
| 154 | ! ! ============================================== ! |
|---|
| 155 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 156 | ! ! ============================================== ! |
|---|
| 157 | DO jk = 1, jpkm1 |
|---|
| 158 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 159 | END DO |
|---|
| 160 | ! Add to the general trend |
|---|
| 161 | DO jk = 1, jpkm1 |
|---|
| 162 | DO jj = 2, jpjm1 |
|---|
| 163 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 164 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 165 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 166 | END DO |
|---|
| 167 | END DO |
|---|
| 168 | END DO |
|---|
| 169 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 170 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 171 | IF ( ln_qsr_ice ) THEN |
|---|
| 172 | DO jj = 1, jpj |
|---|
| 173 | DO ji = 1, jpi |
|---|
| 174 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 175 | fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 176 | ELSE |
|---|
| 177 | fraqsr_1lev(ji,jj) = 1. |
|---|
| 178 | ENDIF |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | ENDIF |
|---|
| 182 | ! ! ============================================== ! |
|---|
| 183 | ELSE ! Ocean alone : |
|---|
| 184 | ! ! ============================================== ! |
|---|
| 185 | ! |
|---|
| 186 | ! ! ------------------------- ! |
|---|
| 187 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 188 | ! ! ------------------------- ! |
|---|
| 189 | lspr = ln_qsr_sio |
|---|
| 190 | ! Set chlorophyl concentration |
|---|
| 191 | IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 192 | ! |
|---|
| 193 | IF( nn_chldta == 1 ) THEN !* 2D Variable Chlorophyll |
|---|
| 194 | ! |
|---|
| 195 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 196 | DO jk = 1, nksr + 1 |
|---|
| 197 | zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1) |
|---|
| 198 | ENDDO |
|---|
| 199 | ! |
|---|
| 200 | ELSE IF( nn_chldta == 2 ) THEN !* -3-D Variable Chlorophyll |
|---|
| 201 | ! |
|---|
| 202 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 203 | !CDIR NOVERRCHK ! |
|---|
| 204 | DO jj = 1, jpj |
|---|
| 205 | !CDIR NOVERRCHK |
|---|
| 206 | DO ji = 1, jpi |
|---|
| 207 | zchl = sf_chl(1)%fnow(ji,jj,1) |
|---|
| 208 | zCtot = 40.6 * zchl**0.459 |
|---|
| 209 | zze = 568.2 * zCtot**(-0.746) |
|---|
| 210 | IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293) |
|---|
| 211 | zlogc = LOG( zchl ) |
|---|
| 212 | zlogc2 = zlogc * zlogc |
|---|
| 213 | zlogc3 = zlogc * zlogc * zlogc |
|---|
| 214 | zCb = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3 |
|---|
| 215 | zCmax = 0.299 - 0.289 * zlogc + 0.579 * zlogc2 |
|---|
| 216 | zpsimax = 0.6 - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3 |
|---|
| 217 | zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2 |
|---|
| 218 | zCze = 1.12 * (zchl)**0.803 |
|---|
| 219 | DO jk = 1, nksr + 1 |
|---|
| 220 | zpsi = fsdept(ji,jj,jk) / zze |
|---|
| 221 | zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) ) |
|---|
| 222 | END DO |
|---|
| 223 | ! |
|---|
| 224 | END DO |
|---|
| 225 | END DO |
|---|
| 226 | ! |
|---|
| 227 | ELSE !* Variable ocean volume but constant chrlorophyll |
|---|
| 228 | DO jk = 1, nksr + 1 |
|---|
| 229 | zchl3d(:,:,jk) = 0.05 |
|---|
| 230 | ENDDO |
|---|
| 231 | ENDIF |
|---|
| 232 | ! |
|---|
| 233 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 234 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 235 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 236 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 237 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 238 | zea(:,:,1) = qsr(:,:) |
|---|
| 239 | ! |
|---|
| 240 | DO jk = 2, nksr+1 |
|---|
| 241 | ! |
|---|
| 242 | DO jj = 1, jpj ! Separation in R-G-B depending of vertical profile of Chl |
|---|
| 243 | !CDIR NOVERRCHK |
|---|
| 244 | DO ji = 1, jpi |
|---|
| 245 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) ) |
|---|
| 246 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 247 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 248 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 249 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 250 | END DO |
|---|
| 251 | END DO |
|---|
| 252 | !CDIR NOVERRCHK |
|---|
| 253 | DO jj = 1, jpj |
|---|
| 254 | !CDIR NOVERRCHK |
|---|
| 255 | DO ji = 1, jpi |
|---|
| 256 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 257 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 258 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 259 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 260 | ze0(ji,jj,jk) = zc0 |
|---|
| 261 | ze1(ji,jj,jk) = zc1 |
|---|
| 262 | ze2(ji,jj,jk) = zc2 |
|---|
| 263 | ze3(ji,jj,jk) = zc3 |
|---|
| 264 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 265 | END DO |
|---|
| 266 | END DO |
|---|
| 267 | END DO |
|---|
| 268 | ! |
|---|
| 269 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 270 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 271 | END DO |
|---|
| 272 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 273 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 274 | ! |
|---|
| 275 | IF ( ln_qsr_ice ) THEN ! store attenuation coefficient of the first ocean level |
|---|
| 276 | !CDIR NOVERRCHK |
|---|
| 277 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 278 | !CDIR NOVERRCHK |
|---|
| 279 | DO ji = 1, jpi |
|---|
| 280 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) ) |
|---|
| 281 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 282 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 283 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 284 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 285 | END DO |
|---|
| 286 | END DO |
|---|
| 287 | ! |
|---|
| 288 | DO jj = 1, jpj |
|---|
| 289 | DO ji = 1, jpi |
|---|
| 290 | zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 291 | zc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 292 | zc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 293 | zc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 294 | fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,2) |
|---|
| 295 | END DO |
|---|
| 296 | END DO |
|---|
| 297 | ! |
|---|
| 298 | ENDIF |
|---|
| 299 | ! |
|---|
| 300 | ELSE !* Constant Chlorophyll |
|---|
| 301 | DO jk = 1, nksr |
|---|
| 302 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 303 | END DO |
|---|
| 304 | ! store attenuation coefficient of the first ocean level |
|---|
| 305 | IF( ln_qsr_ice ) THEN |
|---|
| 306 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 307 | ENDIF |
|---|
| 308 | ENDIF |
|---|
| 309 | lspr = .false. |
|---|
| 310 | ENDIF |
|---|
| 311 | ! ! ------------------------- ! |
|---|
| 312 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 313 | ! ! ------------------------- ! |
|---|
| 314 | ! |
|---|
| 315 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 316 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 317 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 318 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 319 | DO jj = 1, jpj |
|---|
| 320 | DO ji = 1, jpi |
|---|
| 321 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 322 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 323 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 324 | END DO |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 328 | IF ( ln_qsr_ice ) THEN |
|---|
| 329 | DO jj = 1, jpj |
|---|
| 330 | DO ji = 1, jpi |
|---|
| 331 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 332 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 333 | fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 334 | END DO |
|---|
| 335 | END DO |
|---|
| 336 | ENDIF |
|---|
| 337 | ELSE !* constant volume: coef. computed one for all |
|---|
| 338 | DO jk = 1, nksr |
|---|
| 339 | DO jj = 2, jpjm1 |
|---|
| 340 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 341 | ! (ISF) no light penetration below the ice shelves |
|---|
| 342 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1) |
|---|
| 343 | END DO |
|---|
| 344 | END DO |
|---|
| 345 | END DO |
|---|
| 346 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 347 | IF ( ln_qsr_ice ) THEN |
|---|
| 348 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 349 | ENDIF |
|---|
| 350 | ! |
|---|
| 351 | ENDIF |
|---|
| 352 | ! |
|---|
| 353 | ENDIF |
|---|
| 354 | ! |
|---|
| 355 | ! Add to the general trend |
|---|
| 356 | DO jk = 1, nksr |
|---|
| 357 | DO jj = 2, jpjm1 |
|---|
| 358 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 359 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 360 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 361 | END DO |
|---|
| 362 | END DO |
|---|
| 363 | END DO |
|---|
| 364 | ! |
|---|
| 365 | ENDIF |
|---|
| 366 | ! |
|---|
| 367 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 368 | ! ******************************* |
|---|
| 369 | IF(lwp) WRITE(numout,*) |
|---|
| 370 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 371 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 372 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 373 | IF( lwxios ) CALL iom_swap( wxios_context ) |
|---|
| 374 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc, lxios = lwxios ) |
|---|
| 375 | CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev, lxios = lwxios) ! default definition in sbcssm |
|---|
| 376 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 377 | ! |
|---|
| 378 | ENDIF |
|---|
| 379 | |
|---|
| 380 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 381 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 382 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt ) |
|---|
| 383 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 384 | ENDIF |
|---|
| 385 | ! ! print mean trends (used for debugging) |
|---|
| 386 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 387 | ! |
|---|
| 388 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 389 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 390 | ! |
|---|
| 391 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 392 | ! |
|---|
| 393 | END SUBROUTINE tra_qsr |
|---|
| 394 | |
|---|
| 395 | |
|---|
| 396 | SUBROUTINE tra_qsr_init |
|---|
| 397 | !!---------------------------------------------------------------------- |
|---|
| 398 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 399 | !! |
|---|
| 400 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 401 | !! |
|---|
| 402 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 403 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 404 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 405 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 406 | !! (1968) classification. |
|---|
| 407 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 408 | !! |
|---|
| 409 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 410 | !! |
|---|
| 411 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 412 | !!---------------------------------------------------------------------- |
|---|
| 413 | ! |
|---|
| 414 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 415 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 416 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 417 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 418 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 419 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 420 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 421 | ! |
|---|
| 422 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 423 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 424 | !! |
|---|
| 425 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 426 | & nn_chldta, rn_abs, rn_si0, rn_si1, ln_qsr_sio |
|---|
| 427 | !!---------------------------------------------------------------------- |
|---|
| 428 | |
|---|
| 429 | ! |
|---|
| 430 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 431 | ! |
|---|
| 432 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 433 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 434 | ! |
|---|
| 435 | ln_qsr_ice = .FALSE. |
|---|
| 436 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 437 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 438 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 439 | |
|---|
| 440 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 441 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 442 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 443 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 444 | ! |
|---|
| 445 | IF(lwp) THEN ! control print |
|---|
| 446 | WRITE(numout,*) |
|---|
| 447 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 448 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 449 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 450 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 451 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 452 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 453 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 454 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 455 | WRITE(numout,*) ' RGB : Chl data (=1/2) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 456 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 457 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 458 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 459 | ENDIF |
|---|
| 460 | |
|---|
| 461 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 462 | ! |
|---|
| 463 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 464 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 465 | ln_qsr_bio = .FALSE. |
|---|
| 466 | ENDIF |
|---|
| 467 | ! |
|---|
| 468 | ioptio = 0 ! Parameter control |
|---|
| 469 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 470 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 471 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 472 | ! |
|---|
| 473 | IF( ioptio /= 1 ) & |
|---|
| 474 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 475 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 476 | ! |
|---|
| 477 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 478 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 479 | IF( ln_qsr_rgb .AND. nn_chldta == 2 ) nqsr = 3 |
|---|
| 480 | IF( ln_qsr_2bd ) nqsr = 4 |
|---|
| 481 | IF( ln_qsr_bio ) nqsr = 5 |
|---|
| 482 | ! |
|---|
| 483 | IF(lwp) THEN ! Print the choice |
|---|
| 484 | WRITE(numout,*) |
|---|
| 485 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 486 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - 2D Chl data ' |
|---|
| 487 | IF( nqsr == 3 ) WRITE(numout,*) ' R-G-B light penetration - 3D Chl data ' |
|---|
| 488 | IF( nqsr == 4 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 489 | IF( nqsr == 5 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 490 | ENDIF |
|---|
| 491 | ! |
|---|
| 492 | ENDIF |
|---|
| 493 | ! ! ===================================== ! |
|---|
| 494 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 495 | ! ! ===================================== ! |
|---|
| 496 | ! |
|---|
| 497 | xsi0r = 1.e0 / rn_si0 |
|---|
| 498 | xsi1r = 1.e0 / rn_si1 |
|---|
| 499 | ! ! ---------------------------------- ! |
|---|
| 500 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 501 | ! ! ---------------------------------- ! |
|---|
| 502 | ! |
|---|
| 503 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 504 | ! |
|---|
| 505 | ! !* level of light extinction |
|---|
| 506 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 507 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 508 | ENDIF |
|---|
| 509 | |
|---|
| 510 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 511 | ! |
|---|
| 512 | IF( nn_chldta == 1 .OR. nn_chldta == 2 ) THEN !* Chl data : set sf_chl structure |
|---|
| 513 | IF(lwp) WRITE(numout,*) |
|---|
| 514 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 515 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 516 | IF( ierror > 0 ) THEN |
|---|
| 517 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 518 | ENDIF |
|---|
| 519 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 520 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 521 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 522 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 523 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 524 | ! |
|---|
| 525 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 526 | IF(lwp) WRITE(numout,*) |
|---|
| 527 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 528 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 529 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 530 | ELSE ! constant volume: computes one for all |
|---|
| 531 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 532 | ! |
|---|
| 533 | zchl = 0.05 ! constant chlorophyll |
|---|
| 534 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 535 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 536 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 537 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 538 | ! |
|---|
| 539 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 540 | ze0(:,:,1) = rn_abs |
|---|
| 541 | ze1(:,:,1) = zcoef |
|---|
| 542 | ze2(:,:,1) = zcoef |
|---|
| 543 | ze3(:,:,1) = zcoef |
|---|
| 544 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 545 | |
|---|
| 546 | DO jk = 2, nksr+1 |
|---|
| 547 | !CDIR NOVERRCHK |
|---|
| 548 | DO jj = 1, jpj |
|---|
| 549 | !CDIR NOVERRCHK |
|---|
| 550 | DO ji = 1, jpi |
|---|
| 551 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 552 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 553 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 554 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 555 | ze0(ji,jj,jk) = zc0 |
|---|
| 556 | ze1(ji,jj,jk) = zc1 |
|---|
| 557 | ze2(ji,jj,jk) = zc2 |
|---|
| 558 | ze3(ji,jj,jk) = zc3 |
|---|
| 559 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 560 | END DO |
|---|
| 561 | END DO |
|---|
| 562 | END DO |
|---|
| 563 | ! |
|---|
| 564 | DO jk = 1, nksr |
|---|
| 565 | ! (ISF) no light penetration below the ice shelves |
|---|
| 566 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1) |
|---|
| 567 | END DO |
|---|
| 568 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 569 | ENDIF |
|---|
| 570 | ENDIF |
|---|
| 571 | ! |
|---|
| 572 | ENDIF |
|---|
| 573 | ! ! ---------------------------------- ! |
|---|
| 574 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 575 | ! ! ---------------------------------- ! |
|---|
| 576 | ! |
|---|
| 577 | ! ! level of light extinction |
|---|
| 578 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 579 | IF(lwp) THEN |
|---|
| 580 | WRITE(numout,*) |
|---|
| 581 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 582 | ENDIF |
|---|
| 583 | ! |
|---|
| 584 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 585 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 586 | ELSE ! constant volume: computes one for all |
|---|
| 587 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 588 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 589 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 590 | DO jj = 1, jpj ! top 400 meters |
|---|
| 591 | DO ji = 1, jpi |
|---|
| 592 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 593 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 594 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) * tmask(ji,jj,1) |
|---|
| 595 | END DO |
|---|
| 596 | END DO |
|---|
| 597 | END DO |
|---|
| 598 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 599 | ! |
|---|
| 600 | ENDIF |
|---|
| 601 | ENDIF |
|---|
| 602 | ! ! ===================================== ! |
|---|
| 603 | ELSE ! No light penetration ! |
|---|
| 604 | ! ! ===================================== ! |
|---|
| 605 | IF(lwp) THEN |
|---|
| 606 | WRITE(numout,*) |
|---|
| 607 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 608 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 609 | ENDIF |
|---|
| 610 | ENDIF |
|---|
| 611 | ! |
|---|
| 612 | ! initialisation of fraqsr_1lev used in sbcssm |
|---|
| 613 | IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 614 | CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev, lrxios = lxios_read ) |
|---|
| 615 | ELSE |
|---|
| 616 | fraqsr_1lev(:,:) = 1._wp ! default definition |
|---|
| 617 | ENDIF |
|---|
| 618 | ! |
|---|
| 619 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 620 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 621 | ! |
|---|
| 622 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 623 | ! |
|---|
| 624 | END SUBROUTINE tra_qsr_init |
|---|
| 625 | |
|---|
| 626 | !!====================================================================== |
|---|
| 627 | END MODULE traqsr |
|---|
