New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 9373

Last change on this file since 9373 was 9366, checked in by andmirek, 6 years ago

#2050 first version. Compiled OK in moci test suite

File size: 16.9 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25   USE iom_def, ONLY:lspr
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dta_tsd_init   ! called by opa.F90
31   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
32   PRIVATE  tsd_namelist
33
34   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
35   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
36   LOGICAL , PUBLIC ::   ln_tsd_sio       !: read file using 1 processor
37
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE dta_tsd_init( ld_tradmp )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_tsd_init  ***
52      !!                   
53      !! ** Purpose :   initialisation of T & S input data
54      !!
55      !! ** Method  : - Read namtsd namelist
56      !!              - allocates T & S data structure
57      !!----------------------------------------------------------------------
58      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
59      !
60      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
61      !
62      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
63      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
64      TYPE(FLD_N)                   ::   sn_tem, sn_sal
65      !!
66      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal, ln_tsd_sio
67      INTEGER  ::   ios
68      !!----------------------------------------------------------------------
69      !
70      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
71      !
72      !  Initialisation
73      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
74      !
75      ln_tsd_sio = .FALSE.
76      IF(lwm) THEN
77         REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
78         READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
79901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwm )
80         REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
81         READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
82902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwm )
83      ENDIF
84      IF(lwm) WRITE ( numond, namtsd )
85
86      call tsd_namelist(cn_dir, sn_tem, sn_sal)
87
88      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
89     
90      IF(lwp) THEN                  ! control print
91         WRITE(numout,*)
92         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
93         WRITE(numout,*) '~~~~~~~~~~~~ '
94         WRITE(numout,*) '   Namelist namtsd'
95         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
96         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
97         WRITE(numout,*)
98         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
99            WRITE(numout,*)
100            WRITE(numout,*) '   T & S data not used'
101         ENDIF
102      ENDIF
103      !
104      IF( ln_rstart .AND. ln_tsd_init ) THEN
105         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
106            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
107         ln_tsd_init = .FALSE.
108      ENDIF
109      !
110      !                             ! allocate the arrays (if necessary)
111      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
112         !
113         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
114         IF( ierr0 > 0 ) THEN
115            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
116         ENDIF
117         !
118                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
119         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
120                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
121         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
122         !
123         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
124            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
125         ENDIF
126         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
127         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
128         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
129         !
130      ENDIF
131      !
132      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
133      !
134   END SUBROUTINE dta_tsd_init
135
136
137   SUBROUTINE dta_tsd( kt, ptsd )
138      !!----------------------------------------------------------------------
139      !!                   ***  ROUTINE dta_tsd  ***
140      !!                   
141      !! ** Purpose :   provides T and S data at kt
142      !!
143      !! ** Method  : - call fldread routine
144      !!              - ORCA_R2: add some hand made alteration to read data 
145      !!              - 'key_orca_lev10' interpolates on 10 times more levels
146      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
147      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
148      !!                as T-S data are no are used
149      !!
150      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
151      !!----------------------------------------------------------------------
152      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
153      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
154      !
155      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
156      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
157      REAL(wp)::   zl, zi
158      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
159      !!----------------------------------------------------------------------
160      !
161      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
162      !
163      lspr = ln_tsd_sio
164      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
165      lspr = .false.
166      !
167      !
168      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
169      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
170         !
171         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
172         ii0 = 141   ;   ii1 = 155
173         DO jj = mj0(ij0), mj1(ij1)
174            DO ji = mi0(ii0), mi1(ii1)
175               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
176               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
177               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
178               !
179               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
180               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
181               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
182               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
183            END DO
184         END DO
185         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
186            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
187            ij0 = 101   ;   ij1 = 102
188            ii0 = 139   ;   ii1 = 139
189            DO jl = mi0(il0), mi1(il1)
190               DO jj = mj0(ij0), mj1(ij1)
191                  DO ji = mi0(ii0), mi1(ii1)
192                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
193                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
194                  END DO
195               END DO
196            END DO
197            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
198            ij0 =  87   ;   ij1 =  88
199            ii0 = 161   ;   ii1 = 163
200            DO jl = mi0(il0), mi1(il1)
201               DO jj = mj0(ij0), mj1(ij1)
202                  DO ji = mi0(ii0), mi1(ii1)
203                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
204                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
205                  END DO
206               END DO
207            END DO
208         ELSE                                            ! No Cross Land advection
209            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
210            ii0 = 148   ;   ii1 = 160
211            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
212            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
213            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
214         ENDIF
215      ENDIF
216      !
217      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
218      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
219      !
220      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
221         !
222         CALL wrk_alloc( jpk, ztp, zsp )
223         !
224         IF( kt == nit000 .AND. lwp )THEN
225            WRITE(numout,*)
226            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
227         ENDIF
228         !
229         DO jj = 1, jpj                         ! vertical interpolation of T & S
230            DO ji = 1, jpi
231               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
232                  zl = gdept_0(ji,jj,jk)
233                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
234                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
235                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
236                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
237                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
238                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
239                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
240                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
241                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
242                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
243                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
244                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
245                        ENDIF
246                     END DO
247                  ENDIF
248               END DO
249               DO jk = 1, jpkm1
250                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
251                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
252               END DO
253               ptsd(ji,jj,jpk,jp_tem) = 0._wp
254               ptsd(ji,jj,jpk,jp_sal) = 0._wp
255            END DO
256         END DO
257         !
258         CALL wrk_dealloc( jpk, ztp, zsp )
259         !
260      ELSE                                !==   z- or zps- coordinate   ==!
261         !                             
262         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
263         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
264         !
265         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
266            DO jj = 1, jpj
267               DO ji = 1, jpi
268                  ik = mbkt(ji,jj) 
269                  IF( ik > 1 ) THEN
270                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
271                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
272                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
273                  ENDIF
274                  ik = mikt(ji,jj)
275                  IF( ik > 1 ) THEN
276                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
277                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
278                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
279                  END IF
280               END DO
281            END DO
282         ENDIF
283         !
284      ENDIF
285      !
286      IF( lwp .AND. kt == nit000 ) THEN
287         WRITE(numout,*) ' temperature Levitus '
288         WRITE(numout,*)
289         WRITE(numout,*)'  level = 1'
290         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
291         WRITE(numout,*)'  level = ', jpk/2
292         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
293         WRITE(numout,*)'  level = ', jpkm1
294         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
295         WRITE(numout,*)
296         WRITE(numout,*) ' salinity Levitus '
297         WRITE(numout,*)
298         WRITE(numout,*)'  level = 1'
299         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
300         WRITE(numout,*)'  level = ', jpk/2
301         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
302         WRITE(numout,*)'  level = ', jpkm1
303         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
304         WRITE(numout,*)
305      ENDIF
306      !
307      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
308         !                                              (data used only for initialisation)
309         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
310                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
311         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
312                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
313         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
314                                        DEALLOCATE( sf_tsd              )     ! the structure itself
315      ENDIF
316      !
317      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
318      !
319   END SUBROUTINE dta_tsd
320
321   SUBROUTINE tsd_namelist(cd_dir, sd_tem, sd_sal)
322     !!---------------------------------------------------------------------
323     !!                   ***  ROUTINE tsd_namelist  ***
324     !!                     
325     !! ** Purpose :   Broadcast namelist variables read by procesor lwm
326     !!
327     !! ** Method  :   use lib_mpp
328     !!----------------------------------------------------------------------
329     CHARACTER(len=100)           ::   cd_dir          ! Root directory for location of ssr files
330     TYPE(FLD_N)                  ::   sd_tem, sd_sal
331#if defined key_mpp_mpi
332      CALL mpp_bcast(ln_tsd_init)
333      CALL mpp_bcast(ln_tsd_tradmp)
334      CALL mpp_bcast(cd_dir, 100)
335      CALL fld_n_bcast(sd_tem)
336      CALL fld_n_bcast(sd_sal)
337      CALL mpp_bcast(ln_tsd_sio)
338#endif
339   END SUBROUTINE tsd_namelist
340
341   !!======================================================================
342END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.