Context Navigation

dynhpg.F90 @ 9383

Last change on this file since 9383 was 9383, checked in by andmirek, 6 years ago
#2050 fixes and changes
File size: 70.8 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE phycst ! physical constants
36	USE trd_oce ! trends: ocean variables
37	USE trddyn ! trend manager: dynamics
38	!
39	USE in_out_manager ! I/O manager
40	USE prtctl ! Print control
41	USE lbclnk ! lateral boundary condition
42	USE lib_mpp ! MPP library
43	USE eosbn2 ! compute density
44	USE wrk_nemo ! Memory Allocation
45	USE timing ! Timing
46
47	IMPLICIT NONE
48	PRIVATE
49
50	PUBLIC dyn_hpg ! routine called by step module
51	PUBLIC dyn_hpg_init ! routine called by opa module
52	PRIVATE hpg_namelist
53
54	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
56	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
57	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
58	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
59	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
60	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
61	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
62
63	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65	!! * Substitutions
66	# include "domzgr_substitute.h90"
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE dyn_hpg( kt )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE dyn_hpg *
78	!!
79	!! ** Method : Call the hydrostatic pressure gradient routine
80	!! using the scheme defined in the namelist
81	!!
82	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84	!!----------------------------------------------------------------------
85	INTEGER, INTENT(in) :: kt ! ocean time-step index
86	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
87	!!----------------------------------------------------------------------
88	!
89	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
90	!
91	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
92	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93	ztrdu(:,:,:) = ua(:,:,:)
94	ztrdv(:,:,:) = va(:,:,:)
95	ENDIF
96	!
97	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
98	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
99	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
100	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
101	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
102	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
103	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
104	END SELECT
105	!
106	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111	ENDIF
112	!
113	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
114	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
115	!
116	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
117	!
118	END SUBROUTINE dyn_hpg
119
120
121	SUBROUTINE dyn_hpg_init
122	!!----------------------------------------------------------------------
123	!! * ROUTINE dyn_hpg_init *
124	!!
125	!! ** Purpose : initializations for the hydrostatic pressure gradient
126	!! computation and consistency control
127	!!
128	!! ** Action : Read the namelist namdyn_hpg and check the consistency
129	!! with the type of vertical coordinate used (zco, zps, sco)
130	!!----------------------------------------------------------------------
131	INTEGER :: ioptio = 0 ! temporary integer
132	INTEGER :: ios ! Local integer output status for namelist read
133	!!
134	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
135	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
136	!!----------------------------------------------------------------------
137	!
138	IF(lwm) THEN
139	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
140	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
141	901 CONTINUE
142	ENDIF
143	call mpp_bcast(ios)
144	IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
145	IF(lwm) THEN
146	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
147	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
148	902 CONTINUE
149	ENDIF
150	call mpp_bcast(ios)
151	IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
152
153	IF(lwm) WRITE ( numond, namdyn_hpg )
154	!
155	CALL hpg_namelist()
156
157	IF(lwp) THEN ! Control print
158	WRITE(numout,*)
159	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
160	WRITE(numout,*) '~~~~~~~~~~~~'
161	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
162	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
163	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
164	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
165	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
166	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
167	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
168	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
169	ENDIF
170	!
171	IF( ln_hpg_djc ) &
172	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
173	& currently disabled (bugs under investigation). Please select &
174	& either ln_hpg_sco or ln_hpg_prj instead')
175	!
176	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
177	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
178	& the standard jacobian formulation hpg_sco or &
179	& the pressure jacobian formulation hpg_prj')
180
181	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
182	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
183	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
184	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
185	!
186	! ! Set nhpg from ln_hpg_... flags
187	IF( ln_hpg_zco ) nhpg = 0
188	IF( ln_hpg_zps ) nhpg = 1
189	IF( ln_hpg_sco ) nhpg = 2
190	IF( ln_hpg_djc ) nhpg = 3
191	IF( ln_hpg_prj ) nhpg = 4
192	IF( ln_hpg_isf ) nhpg = 5
193	!
194	! ! Consistency check
195	ioptio = 0
196	IF( ln_hpg_zco ) ioptio = ioptio + 1
197	IF( ln_hpg_zps ) ioptio = ioptio + 1
198	IF( ln_hpg_sco ) ioptio = ioptio + 1
199	IF( ln_hpg_djc ) ioptio = ioptio + 1
200	IF( ln_hpg_prj ) ioptio = ioptio + 1
201	IF( ln_hpg_isf ) ioptio = ioptio + 1
202	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
203	!
204	! initialisation of ice load
205	riceload(:,:)=0.0
206	!
207	END SUBROUTINE dyn_hpg_init
208
209
210	SUBROUTINE hpg_zco( kt )
211	!!---------------------------------------------------------------------
212	!! * ROUTINE hpg_zco *
213	!!
214	!! ** Method : z-coordinate case, levels are horizontal surfaces.
215	!! The now hydrostatic pressure gradient at a given level, jk,
216	!! is computed by taking the vertical integral of the in-situ
217	!! density gradient along the model level from the suface to that
218	!! level: zhpi = grav .....
219	!! zhpj = grav .....
220	!! add it to the general momentum trend (ua,va).
221	!! ua = ua - 1/e1u * zhpi
222	!! va = va - 1/e2v * zhpj
223	!!
224	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
225	!!----------------------------------------------------------------------
226	INTEGER, INTENT(in) :: kt ! ocean time-step index
227	!!
228	INTEGER :: ji, jj, jk ! dummy loop indices
229	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
230	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
231	!!----------------------------------------------------------------------
232	!
233	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
234	!
235	IF( kt == nit000 ) THEN
236	IF(lwp) WRITE(numout,*)
237	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
238	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
239	ENDIF
240
241	zcoef0 = - grav * 0.5_wp ! Local constant initialization
242
243	! Surface value
244	DO jj = 2, jpjm1
245	DO ji = fs_2, fs_jpim1 ! vector opt.
246	zcoef1 = zcoef0 * fse3w(ji,jj,1)
247	! hydrostatic pressure gradient
248	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
249	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
250	! add to the general momentum trend
251	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
252	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
253	END DO
254	END DO
255
256	!
257	! interior value (2=<jk=<jpkm1)
258	DO jk = 2, jpkm1
259	DO jj = 2, jpjm1
260	DO ji = fs_2, fs_jpim1 ! vector opt.
261	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
262	! hydrostatic pressure gradient
263	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
264	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
265	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
266
267	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
268	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
269	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
270	! add to the general momentum trend
271	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
272	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
273	END DO
274	END DO
275	END DO
276	!
277	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
278	!
279	END SUBROUTINE hpg_zco
280
281
282	SUBROUTINE hpg_zps( kt )
283	!!---------------------------------------------------------------------
284	!! * ROUTINE hpg_zps *
285	!!
286	!! ** Method : z-coordinate plus partial steps case. blahblah...
287	!!
288	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
289	!!----------------------------------------------------------------------
290	INTEGER, INTENT(in) :: kt ! ocean time-step index
291	!!
292	INTEGER :: ji, jj, jk ! dummy loop indices
293	INTEGER :: iku, ikv ! temporary integers
294	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
295	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
296	!!----------------------------------------------------------------------
297	!
298	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
299	!
300	IF( kt == nit000 ) THEN
301	IF(lwp) WRITE(numout,*)
302	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
303	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
304	ENDIF
305
306
307	! Local constant initialization
308	zcoef0 = - grav * 0.5_wp
309
310	! Surface value (also valid in partial step case)
311	DO jj = 2, jpjm1
312	DO ji = fs_2, fs_jpim1 ! vector opt.
313	zcoef1 = zcoef0 * fse3w(ji,jj,1)
314	! hydrostatic pressure gradient
315	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
316	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
317	! add to the general momentum trend
318	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
319	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
320	END DO
321	END DO
322
323
324	! interior value (2=<jk=<jpkm1)
325	DO jk = 2, jpkm1
326	DO jj = 2, jpjm1
327	DO ji = fs_2, fs_jpim1 ! vector opt.
328	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
329	! hydrostatic pressure gradient
330	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
331	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
332	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
333
334	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
335	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
336	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
337	! add to the general momentum trend
338	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
339	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
340	END DO
341	END DO
342	END DO
343
344
345	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
346	DO jj = 2, jpjm1
347	DO ji = 2, jpim1
348	iku = mbku(ji,jj)
349	ikv = mbkv(ji,jj)
350	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
351	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
352	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
353	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
354	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
355	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
356	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
357	ENDIF
358	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
359	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
360	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
361	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
362	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
363	ENDIF
364	END DO
365	END DO
366	!
367	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
368	!
369	END SUBROUTINE hpg_zps
370
371	SUBROUTINE hpg_sco( kt )
372	!!---------------------------------------------------------------------
373	!! * ROUTINE hpg_sco *
374	!!
375	!! ** Method : s-coordinate case. Jacobian scheme.
376	!! The now hydrostatic pressure gradient at a given level, jk,
377	!! is computed by taking the vertical integral of the in-situ
378	!! density gradient along the model level from the suface to that
379	!! level. s-coordinates (ln_sco): a corrective term is added
380	!! to the horizontal pressure gradient :
381	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
382	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
383	!! add it to the general momentum trend (ua,va).
384	!! ua = ua - 1/e1u * zhpi
385	!! va = va - 1/e2v * zhpj
386	!!
387	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
388	!!----------------------------------------------------------------------
389	INTEGER, INTENT(in) :: kt ! ocean time-step index
390	!!
391	INTEGER :: ji, jj, jk ! dummy loop indices
392	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
393	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
394	!!----------------------------------------------------------------------
395	!
396	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
397	!
398	IF( kt == nit000 ) THEN
399	IF(lwp) WRITE(numout,*)
400	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
401	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
402	ENDIF
403
404	! Local constant initialization
405	zcoef0 = - grav * 0.5_wp
406	! To use density and not density anomaly
407	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
408	ELSE ; znad = 0._wp ! Fixed volume
409	ENDIF
410
411	! Surface value
412	DO jj = 2, jpjm1
413	DO ji = fs_2, fs_jpim1 ! vector opt.
414	! hydrostatic pressure gradient along s-surfaces
415	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
416	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
417	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
418	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
419	! s-coordinate pressure gradient correction
420	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
421	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
422	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
423	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
424	! add to the general momentum trend
425	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
426	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
427	END DO
428	END DO
429
430	! interior value (2=<jk=<jpkm1)
431	DO jk = 2, jpkm1
432	DO jj = 2, jpjm1
433	DO ji = fs_2, fs_jpim1 ! vector opt.
434	! hydrostatic pressure gradient along s-surfaces
435	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
436	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
437	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
438	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
439	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
440	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
441	! s-coordinate pressure gradient correction
442	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
443	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
444	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
445	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
446	! add to the general momentum trend
447	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
448	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
449	END DO
450	END DO
451	END DO
452	!
453	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
454	!
455	END SUBROUTINE hpg_sco
456
457	SUBROUTINE hpg_isf( kt )
458	!!---------------------------------------------------------------------
459	!! * ROUTINE hpg_sco *
460	!!
461	!! ** Method : s-coordinate case. Jacobian scheme.
462	!! The now hydrostatic pressure gradient at a given level, jk,
463	!! is computed by taking the vertical integral of the in-situ
464	!! density gradient along the model level from the suface to that
465	!! level. s-coordinates (ln_sco): a corrective term is added
466	!! to the horizontal pressure gradient :
467	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
468	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
469	!! add it to the general momentum trend (ua,va).
470	!! ua = ua - 1/e1u * zhpi
471	!! va = va - 1/e2v * zhpj
472	!! iceload is added and partial cell case are added to the top and bottom
473	!!
474	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
475	!!----------------------------------------------------------------------
476	INTEGER, INTENT(in) :: kt ! ocean time-step index
477	!!
478	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
479	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
480	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
481	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
482	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
483	!!----------------------------------------------------------------------
484	!
485	CALL wrk_alloc( jpi,jpj, 2, ztstop)
486	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
487	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
488	!
489	IF( kt == nit000 ) THEN
490	IF(lwp) WRITE(numout,*)
491	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
492	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
493	ENDIF
494
495	! Local constant initialization
496	zcoef0 = - grav * 0.5_wp
497	! To use density and not density anomaly
498	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
499	! ELSE ; znad = 0._wp ! Fixed volume
500	! ENDIF
501	znad=1._wp
502	! iniitialised to 0. zhpi zhpi
503	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
504
505	!==================================================================================
506	!=====Compute iceload and contribution of the half first wet layer =================
507	!===================================================================================
508
509	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
510	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
511
512	! compute density of the water displaced by the ice shelf
513	zrhd = rhd ! save rhd
514	DO jk = 1, jpk
515	zdept(:,:)=gdept_1d(jk)
516	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
517	END DO
518	WHERE ( tmask(:,:,:) == 1._wp)
519	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
520	END WHERE
521
522	! compute rhd at the ice/oce interface (ice shelf side)
523	CALL eos(ztstop,risfdep,zrhdtop_isf)
524
525	! compute rhd at the ice/oce interface (ocean side)
526	DO ji=1,jpi
527	DO jj=1,jpj
528	ikt=mikt(ji,jj)
529	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
530	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
531	END DO
532	END DO
533	CALL eos(ztstop,risfdep,zrhdtop_oce)
534	!
535	! Surface value + ice shelf gradient
536	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
537	ziceload = 0._wp
538	DO jj = 1, jpj
539	DO ji = 1, jpi ! vector opt.
540	ikt=mikt(ji,jj)
541	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
542	DO jk=2,ikt-1
543	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
544	& * (1._wp - tmask(ji,jj,jk))
545	END DO
546	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
547	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
548	END DO
549	END DO
550	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
551	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
552	DO jj = 2, jpjm1
553	DO ji = fs_2, fs_jpim1 ! vector opt.
554	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
555	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
556	! we assume ISF is in isostatic equilibrium
557	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
558	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
559	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
560	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
561	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
562	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
563	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
564	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
565	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
566	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
567	! s-coordinate pressure gradient correction (=0 if z coordinate)
568	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
569	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
570	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
571	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
572	! add to the general momentum trend
573	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
574	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
575	END DO
576	END DO
577	!==================================================================================
578	!===== Compute partial cell contribution for the top cell =========================
579	!==================================================================================
580	DO jj = 2, jpjm1
581	DO ji = fs_2, fs_jpim1 ! vector opt.
582	iku = miku(ji,jj) ;
583	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
584	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
585	! u direction
586	IF ( iku .GT. 1 ) THEN
587	! case iku
588	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
589	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
590	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
591	! corrective term ( = 0 if z coordinate )
592	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
593	! zhpi will be added in interior loop
594	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
595	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
596	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
597
598	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
599	zhpiint = zcoef0 / e1u(ji,jj) &
600	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
601	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
602	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
603	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
604	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
605	END IF
606
607	! v direction
608	ikv = mikv(ji,jj)
609	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
610	IF ( ikv .GT. 1 ) THEN
611	! case ikv
612	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
613	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
614	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
615	! corrective term ( = 0 if z coordinate )
616	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
617	! zhpi will be added in interior loop
618	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
619	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
620	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
621
622	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
623	zhpjint = zcoef0 / e2v(ji,jj) &
624	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
625	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
626	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
627	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
628	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
629	END IF
630	END DO
631	END DO
632
633	!==================================================================================
634	!===== Compute interior value =====================================================
635	!==================================================================================
636
637	DO jj = 2, jpjm1
638	DO ji = fs_2, fs_jpim1 ! vector opt.
639	iku=miku(ji,jj); ikv=mikv(ji,jj)
640	DO jk = 2, jpkm1
641	! hydrostatic pressure gradient along s-surfaces
642	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
643	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
644	& + zcoef0 / e1u(ji,jj) &
645	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
646	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
647	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
648	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
649	! s-coordinate pressure gradient correction
650	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
651	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
652	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
653	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
654
655	! hydrostatic pressure gradient along s-surfaces
656	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
657	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
658	& + zcoef0 / e2v(ji,jj) &
659	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
660	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
661	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
662	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
663	! s-coordinate pressure gradient correction
664	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
665	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
666	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
667	! add to the general momentum trend
668	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
669	END DO
670	END DO
671	END DO
672
673	!==================================================================================
674	!===== Compute bottom cell contribution (partial cell) ============================
675	!==================================================================================
676
677	DO jj = 2, jpjm1
678	DO ji = 2, jpim1
679	iku = mbku(ji,jj)
680	ikv = mbkv(ji,jj)
681
682	IF (iku .GT. 1) THEN
683	! remove old value (interior case)
684	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
685	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
686	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
687	! put new value
688	! -zpshpi to avoid double contribution of the partial step in the top layer
689	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
690	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
691	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
692	END IF
693	! v direction
694	IF (ikv .GT. 1) THEN
695	! remove old value (interior case)
696	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
697	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
698	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
699	! put new value
700	! -zpshpj to avoid double contribution of the partial step in the top layer
701	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
702	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
703	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
704	END IF
705	END DO
706	END DO
707
708	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
709	rhd = zrhd
710	!
711	CALL wrk_dealloc( jpi,jpj,2, ztstop)
712	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
713	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
714	!
715	END SUBROUTINE hpg_isf
716
717
718	SUBROUTINE hpg_djc( kt )
719	!!---------------------------------------------------------------------
720	!! * ROUTINE hpg_djc *
721	!!
722	!! ** Method : Density Jacobian with Cubic polynomial scheme
723	!!
724	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
725	!!----------------------------------------------------------------------
726	INTEGER, INTENT(in) :: kt ! ocean time-step index
727	!!
728	INTEGER :: ji, jj, jk ! dummy loop indices
729	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
730	REAL(wp) :: z1_10, cffu, cffx ! " "
731	REAL(wp) :: z1_12, cffv, cffy ! " "
732	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
733	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
734	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
735	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
736	!!----------------------------------------------------------------------
737	!
738	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
739	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
740	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
741	!
742
743	IF( kt == nit000 ) THEN
744	IF(lwp) WRITE(numout,*)
745	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
746	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
747	ENDIF
748
749	! Local constant initialization
750	zcoef0 = - grav * 0.5_wp
751	z1_10 = 1._wp / 10._wp
752	z1_12 = 1._wp / 12._wp
753
754	!----------------------------------------------------------------------------------------
755	! compute and store in provisional arrays elementary vertical and horizontal differences
756	!----------------------------------------------------------------------------------------
757
758	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
759
760	DO jk = 2, jpkm1
761	DO jj = 2, jpjm1
762	DO ji = fs_2, fs_jpim1 ! vector opt.
763	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
764	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
765	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
766	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
767	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
768	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
769	END DO
770	END DO
771	END DO
772
773	!-------------------------------------------------------------------------
774	! compute harmonic averages using eq. 5.18
775	!-------------------------------------------------------------------------
776	zep = 1.e-15
777
778	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
779	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
780
781	DO jk = 2, jpkm1
782	DO jj = 2, jpjm1
783	DO ji = fs_2, fs_jpim1 ! vector opt.
784	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
785
786	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
787	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
788
789	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
790	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
791
792	IF( cffw > zep) THEN
793	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
794	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
795	ELSE
796	drhow(ji,jj,jk) = 0._wp
797	ENDIF
798
799	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
800	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
801
802	IF( cffu > zep ) THEN
803	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
804	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
805	ELSE
806	drhou(ji,jj,jk ) = 0._wp
807	ENDIF
808
809	IF( cffx > zep ) THEN
810	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
811	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
812	ELSE
813	dzu(ji,jj,jk) = 0._wp
814	ENDIF
815
816	IF( cffv > zep ) THEN
817	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
818	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
819	ELSE
820	drhov(ji,jj,jk) = 0._wp
821	ENDIF
822
823	IF( cffy > zep ) THEN
824	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
825	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
826	ELSE
827	dzv(ji,jj,jk) = 0._wp
828	ENDIF
829
830	END DO
831	END DO
832	END DO
833
834	!----------------------------------------------------------------------------------
835	! apply boundary conditions at top and bottom using 5.36-5.37
836	!----------------------------------------------------------------------------------
837	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
838	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
839	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
840
841	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
842	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
843	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
844
845
846	!--------------------------------------------------------------
847	! Upper half of top-most grid box, compute and store
848	!-------------------------------------------------------------
849
850	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
851	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
852
853	DO jj = 2, jpjm1
854	DO ji = fs_2, fs_jpim1 ! vector opt.
855	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
856	& * ( rhd(ji,jj,1) &
857	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
858	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
859	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
860	END DO
861	END DO
862
863	!!bug gm : here also, simplification is possible
864	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
865
866	DO jk = 2, jpkm1
867	DO jj = 2, jpjm1
868	DO ji = fs_2, fs_jpim1 ! vector opt.
869
870	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
871	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
872	& - grav * z1_10 * ( &
873	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
874	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
875	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
876	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
877	& )
878
879	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
880	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
881	& - grav* z1_10 * ( &
882	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
883	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
884	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
885	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
886	& )
887
888	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
889	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
890	& - grav* z1_10 * ( &
891	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
892	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
893	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
894	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
895	& )
896
897	END DO
898	END DO
899	END DO
900	CALL lbc_lnk(rho_k,'W',1.)
901	CALL lbc_lnk(rho_i,'U',1.)
902	CALL lbc_lnk(rho_j,'V',1.)
903
904
905	! ---------------
906	! Surface value
907	! ---------------
908	DO jj = 2, jpjm1
909	DO ji = fs_2, fs_jpim1 ! vector opt.
910	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
911	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
912	! add to the general momentum trend
913	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
914	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
915	END DO
916	END DO
917
918	! ----------------
919	! interior value (2=<jk=<jpkm1)
920	! ----------------
921	DO jk = 2, jpkm1
922	DO jj = 2, jpjm1
923	DO ji = fs_2, fs_jpim1 ! vector opt.
924	! hydrostatic pressure gradient along s-surfaces
925	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
926	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
927	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
928	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
929	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
930	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
931	! add to the general momentum trend
932	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
933	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
934	END DO
935	END DO
936	END DO
937	!
938	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
939	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
940	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
941	!
942	END SUBROUTINE hpg_djc
943
944
945	SUBROUTINE hpg_prj( kt )
946	!!---------------------------------------------------------------------
947	!! * ROUTINE hpg_prj *
948	!!
949	!! ** Method : s-coordinate case.
950	!! A Pressure-Jacobian horizontal pressure gradient method
951	!! based on the constrained cubic-spline interpolation for
952	!! all vertical coordinate systems
953	!!
954	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
955	!!----------------------------------------------------------------------
956	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
957	INTEGER, INTENT(in) :: kt ! ocean time-step index
958	!!
959	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
960	REAL(wp) :: zcoef0, znad ! temporary scalars
961	!!
962	!! The local variables for the correction term
963	INTEGER :: jk1, jis, jid, jjs, jjd
964	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
965	REAL(wp) :: zrhdt1
966	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
967	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
968	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
969	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
970	!!----------------------------------------------------------------------
971	!
972	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
973	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
974	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
975	!
976	IF( kt == nit000 ) THEN
977	IF(lwp) WRITE(numout,*)
978	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
979	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
980	ENDIF
981
982	!!----------------------------------------------------------------------
983	! Local constant initialization
984	zcoef0 = - grav
985	znad = 0.0_wp
986	IF( lk_vvl ) znad = 1._wp
987
988	! Clean 3-D work arrays
989	zhpi(:,:,:) = 0._wp
990	zrhh(:,:,:) = rhd(:,:,:)
991
992	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
993	DO jj = 1, jpj
994	DO ji = 1, jpi
995	jk = mbathy(ji,jj)
996	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
997	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
998	ELSE IF(jk < jpkm1) THEN
999	DO jkk = jk+1, jpk
1000	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1001	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1002	END DO
1003	ENDIF
1004	END DO
1005	END DO
1006
1007	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1008	DO jj = 1, jpj
1009	DO ji = 1, jpi
1010	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1011	END DO
1012	END DO
1013
1014	DO jk = 2, jpk
1015	DO jj = 1, jpj
1016	DO ji = 1, jpi
1017	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1018	END DO
1019	END DO
1020	END DO
1021
1022	fsp(:,:,:) = zrhh (:,:,:)
1023	xsp(:,:,:) = zdept(:,:,:)
1024
1025	! Construct the vertical density profile with the
1026	! constrained cubic spline interpolation
1027	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1028	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1029
1030	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1031	DO jj = 2, jpj
1032	DO ji = 2, jpi
1033	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1034	bsp(ji,jj,1), csp(ji,jj,1), &
1035	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1036
1037	! assuming linear profile across the top half surface layer
1038	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1039	END DO
1040	END DO
1041
1042	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1043	DO jk = 2, jpkm1
1044	DO jj = 2, jpj
1045	DO ji = 2, jpi
1046	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1047	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1048	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1049	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1050	END DO
1051	END DO
1052	END DO
1053
1054	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1055
1056	! Prepare zsshu_n and zsshv_n
1057	DO jj = 2, jpjm1
1058	DO ji = 2, jpim1
1059	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1060	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1061	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1062	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1063	END DO
1064	END DO
1065
1066	DO jj = 2, jpjm1
1067	DO ji = 2, jpim1
1068	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1069	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1070	END DO
1071	END DO
1072
1073	DO jk = 2, jpkm1
1074	DO jj = 2, jpjm1
1075	DO ji = 2, jpim1
1076	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1077	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1078	END DO
1079	END DO
1080	END DO
1081
1082	DO jk = 1, jpkm1
1083	DO jj = 2, jpjm1
1084	DO ji = 2, jpim1
1085	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1086	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1087	END DO
1088	END DO
1089	END DO
1090
1091	DO jk = 1, jpkm1
1092	DO jj = 2, jpjm1
1093	DO ji = 2, jpim1
1094	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1095	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1096	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1097	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1098	END DO
1099	END DO
1100	END DO
1101
1102
1103	DO jk = 1, jpkm1
1104	DO jj = 2, jpjm1
1105	DO ji = 2, jpim1
1106	zpwes = 0._wp; zpwed = 0._wp
1107	zpnss = 0._wp; zpnsd = 0._wp
1108	zuijk = zu(ji,jj,jk)
1109	zvijk = zv(ji,jj,jk)
1110
1111	!!!!! for u equation
1112	IF( jk <= mbku(ji,jj) ) THEN
1113	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1114	jis = ji + 1; jid = ji
1115	ELSE
1116	jis = ji; jid = ji +1
1117	ENDIF
1118
1119	! integrate the pressure on the shallow side
1120	jk1 = jk
1121	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1122	IF( jk1 == mbku(ji,jj) ) THEN
1123	zuijk = -zdept(jis,jj,jk1)
1124	EXIT
1125	ENDIF
1126	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1127	zpwes = zpwes + &
1128	integ_spline(zdept(jis,jj,jk1), zdeps, &
1129	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1130	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1131	jk1 = jk1 + 1
1132	END DO
1133
1134	! integrate the pressure on the deep side
1135	jk1 = jk
1136	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1137	IF( jk1 == 1 ) THEN
1138	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1139	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1140	bsp(jid,jj,1), csp(jid,jj,1), &
1141	dsp(jid,jj,1)) * zdeps
1142	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1143	EXIT
1144	ENDIF
1145	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1146	zpwed = zpwed + &
1147	integ_spline(zdeps, zdept(jid,jj,jk1), &
1148	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1149	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1150	jk1 = jk1 - 1
1151	END DO
1152
1153	! update the momentum trends in u direction
1154
1155	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1156	IF( lk_vvl ) THEN
1157	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1158	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1159	ELSE
1160	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1161	ENDIF
1162
1163	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1164	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1165	ENDIF
1166
1167	!!!!! for v equation
1168	IF( jk <= mbkv(ji,jj) ) THEN
1169	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1170	jjs = jj + 1; jjd = jj
1171	ELSE
1172	jjs = jj ; jjd = jj + 1
1173	ENDIF
1174
1175	! integrate the pressure on the shallow side
1176	jk1 = jk
1177	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1178	IF( jk1 == mbkv(ji,jj) ) THEN
1179	zvijk = -zdept(ji,jjs,jk1)
1180	EXIT
1181	ENDIF
1182	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1183	zpnss = zpnss + &
1184	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1185	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1186	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1187	jk1 = jk1 + 1
1188	END DO
1189
1190	! integrate the pressure on the deep side
1191	jk1 = jk
1192	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1193	IF( jk1 == 1 ) THEN
1194	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1195	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1196	bsp(ji,jjd,1), csp(ji,jjd,1), &
1197	dsp(ji,jjd,1) ) * zdeps
1198	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1199	EXIT
1200	ENDIF
1201	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1202	zpnsd = zpnsd + &
1203	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1204	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1205	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1206	jk1 = jk1 - 1
1207	END DO
1208
1209
1210	! update the momentum trends in v direction
1211
1212	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1213	IF( lk_vvl ) THEN
1214	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1215	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1216	ELSE
1217	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1218	ENDIF
1219
1220	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1221	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1222	ENDIF
1223
1224
1225	END DO
1226	END DO
1227	END DO
1228	!
1229	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1230	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1231	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1232	!
1233	END SUBROUTINE hpg_prj
1234
1235
1236	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1237	!!----------------------------------------------------------------------
1238	!! * ROUTINE cspline *
1239	!!
1240	!! ** Purpose : constrained cubic spline interpolation
1241	!!
1242	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1243	!!
1244	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1245	!!----------------------------------------------------------------------
1246	IMPLICIT NONE
1247	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1248	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1249	! the interpoated function
1250	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1251	! 2: Linear
1252	!
1253	INTEGER :: ji, jj, jk ! dummy loop indices
1254	INTEGER :: jpi, jpj, jpkm1
1255	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1256	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1257	REAL(wp) :: zdf(size(fsp,3))
1258	!!----------------------------------------------------------------------
1259
1260	jpi = size(fsp,1)
1261	jpj = size(fsp,2)
1262	jpkm1 = size(fsp,3) - 1
1263
1264
1265	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1266	DO ji = 1, jpi
1267	DO jj = 1, jpj
1268	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1269	! DO jk = 2, jpkm1-1
1270	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1271	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1272	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1273	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1274	!
1275	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1276	!
1277	! IF(zdf1 * zdf2 <= 0._wp) THEN
1278	! zdf(jk) = 0._wp
1279	! ELSE
1280	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1281	! ENDIF
1282	! END DO
1283
1284	!!Simply geometric average
1285	DO jk = 2, jpkm1-1
1286	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1287	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1288
1289	IF(zdf1 * zdf2 <= 0._wp) THEN
1290	zdf(jk) = 0._wp
1291	ELSE
1292	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1293	ENDIF
1294	END DO
1295
1296	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1297	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1298	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1299	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1300	& 0.5_wp * zdf(jpkm1 - 1)
1301
1302	DO jk = 1, jpkm1 - 1
1303	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1304	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1305	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1306	zddf1 = -2._wp * ztmp1 + ztmp2
1307	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1308	zddf2 = 2._wp * ztmp1 - ztmp2
1309
1310	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1311	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1312	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1313	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1314	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1315	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1316	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1317	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1318	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1319	END DO
1320	END DO
1321	END DO
1322
1323	ELSE IF (polynomial_type == 2) THEN ! Linear
1324	DO ji = 1, jpi
1325	DO jj = 1, jpj
1326	DO jk = 1, jpkm1-1
1327	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1328	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1329
1330	dsp(ji,jj,jk) = 0._wp
1331	csp(ji,jj,jk) = 0._wp
1332	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1333	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1334	END DO
1335	END DO
1336	END DO
1337
1338	ELSE
1339	CALL ctl_stop( 'invalid polynomial type in cspline' )
1340	ENDIF
1341
1342	END SUBROUTINE cspline
1343
1344
1345	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1346	!!----------------------------------------------------------------------
1347	!! * ROUTINE interp1 *
1348	!!
1349	!! ** Purpose : 1-d linear interpolation
1350	!!
1351	!! ** Method : interpolation is straight forward
1352	!! extrapolation is also permitted (no value limit)
1353	!!----------------------------------------------------------------------
1354	IMPLICIT NONE
1355	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1356	REAL(wp) :: f ! result of the interpolation (extrapolation)
1357	REAL(wp) :: zdeltx
1358	!!----------------------------------------------------------------------
1359
1360	zdeltx = xr - xl
1361	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1362	f = 0.5_wp * (fl + fr)
1363	ELSE
1364	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1365	ENDIF
1366
1367	END FUNCTION interp1
1368
1369
1370	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1371	!!----------------------------------------------------------------------
1372	!! * ROUTINE interp1 *
1373	!!
1374	!! ** Purpose : 1-d constrained cubic spline interpolation
1375	!!
1376	!! ** Method : cubic spline interpolation
1377	!!
1378	!!----------------------------------------------------------------------
1379	IMPLICIT NONE
1380	REAL(wp), INTENT(in) :: x, a, b, c, d
1381	REAL(wp) :: f ! value from the interpolation
1382	!!----------------------------------------------------------------------
1383
1384	f = a + x* ( b + x * ( c + d * x ) )
1385
1386	END FUNCTION interp2
1387
1388
1389	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1390	!!----------------------------------------------------------------------
1391	!! * ROUTINE interp1 *
1392	!!
1393	!! ** Purpose : Calculate the first order of deriavtive of
1394	!! a cubic spline function y=a+bx+cx^2+d*x^3
1395	!!
1396	!! ** Method : f=dy/dx=b+2cx+3dx^2
1397	!!
1398	!!----------------------------------------------------------------------
1399	IMPLICIT NONE
1400	REAL(wp), INTENT(in) :: x, a, b, c, d
1401	REAL(wp) :: f ! value from the interpolation
1402	!!----------------------------------------------------------------------
1403
1404	f = b + x * ( 2._wp * c + 3._wp * d * x)
1405
1406	END FUNCTION interp3
1407
1408
1409	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1410	!!----------------------------------------------------------------------
1411	!! * ROUTINE interp1 *
1412	!!
1413	!! ** Purpose : 1-d constrained cubic spline integration
1414	!!
1415	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1416	!!
1417	!!----------------------------------------------------------------------
1418	IMPLICIT NONE
1419	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1420	REAL(wp) :: za1, za2, za3
1421	REAL(wp) :: f ! integration result
1422	!!----------------------------------------------------------------------
1423
1424	za1 = 0.5_wp * b
1425	za2 = c / 3.0_wp
1426	za3 = 0.25_wp * d
1427
1428	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1429	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1430
1431	END FUNCTION integ_spline
1432
1433	SUBROUTINE hpg_namelist()
1434	!!---------------------------------------------------------------------
1435	!! * ROUTINE hpg_namelist *
1436	!!
1437	!! ** Purpose : Broadcast namelist variables read by procesor lwm
1438	!!
1439	!! ** Method : use lib_mpp
1440	!!----------------------------------------------------------------------
1441	#if defined key_mpp_mpi
1442	CALL mpp_bcast(ln_hpg_zco)
1443	CALL mpp_bcast(ln_hpg_zps)
1444	CALL mpp_bcast(ln_hpg_sco)
1445	CALL mpp_bcast(ln_hpg_djc)
1446	CALL mpp_bcast(ln_hpg_prj)
1447	CALL mpp_bcast(ln_hpg_isf)
1448	CALL mpp_bcast(ln_dynhpg_imp)
1449	#endif
1450	END SUBROUTINE hpg_namelist
1451
1452	!!======================================================================
1453	END MODULE dynhpg
1454

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 9383

Download in other formats: