| 1 | MODULE sbcflx |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcflx *** |
|---|
| 4 | !! Ocean forcing: momentum, heat and freshwater flux formulation |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : 1.0 ! 2006-06 (G. Madec) Original code |
|---|
| 7 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! namflx : flux formulation namlist |
|---|
| 12 | !! sbc_flx : flux formulation as ocean surface boundary condition (forced mode, fluxes read in NetCDF files) |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers |
|---|
| 15 | USE dom_oce ! ocean space and time domain |
|---|
| 16 | USE sbc_oce ! surface boundary condition: ocean fields |
|---|
| 17 | USE sbcdcy ! surface boundary condition: diurnal cycle on qsr |
|---|
| 18 | USE phycst ! physical constants |
|---|
| 19 | USE fldread ! read input fields |
|---|
| 20 | USE iom ! IOM library |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE lib_mpp ! distribued memory computing library |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC sbc_flx ! routine called by step.F90 |
|---|
| 29 | PRIVATE flx_namelist |
|---|
| 30 | |
|---|
| 31 | INTEGER , PARAMETER :: jpfld = 5 ! maximum number of files to read |
|---|
| 32 | INTEGER , PARAMETER :: jp_utau = 1 ! index of wind stress (i-component) file |
|---|
| 33 | INTEGER , PARAMETER :: jp_vtau = 2 ! index of wind stress (j-component) file |
|---|
| 34 | INTEGER , PARAMETER :: jp_qtot = 3 ! index of total (non solar+solar) heat file |
|---|
| 35 | INTEGER , PARAMETER :: jp_qsr = 4 ! index of solar heat file |
|---|
| 36 | INTEGER , PARAMETER :: jp_emp = 5 ! index of evaporation-precipation file |
|---|
| 37 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf ! structure of input fields (file informations, fields read) |
|---|
| 38 | LOGICAL, PRIVATE :: ln_lfx_sio ! single processor read flag |
|---|
| 39 | |
|---|
| 40 | !! * Substitutions |
|---|
| 41 | # include "domzgr_substitute.h90" |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! NEMO/OPA 3.3 , NEMO-consortium (2010) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE sbc_flx( kt ) |
|---|
| 51 | !!--------------------------------------------------------------------- |
|---|
| 52 | !! *** ROUTINE sbc_flx *** |
|---|
| 53 | !! |
|---|
| 54 | !! ** Purpose : provide at each time step the surface ocean fluxes |
|---|
| 55 | !! (momentum, heat, freshwater and runoff) |
|---|
| 56 | !! |
|---|
| 57 | !! ** Method : - READ each fluxes in NetCDF files: |
|---|
| 58 | !! i-component of the stress utau (N/m2) |
|---|
| 59 | !! j-component of the stress vtau (N/m2) |
|---|
| 60 | !! net downward heat flux qtot (watt/m2) |
|---|
| 61 | !! net downward radiative flux qsr (watt/m2) |
|---|
| 62 | !! net upward freshwater (evapo - precip) emp (kg/m2/s) |
|---|
| 63 | !! |
|---|
| 64 | !! CAUTION : - never mask the surface stress fields |
|---|
| 65 | !! - the stress is assumed to be in the (i,j) mesh referential |
|---|
| 66 | !! |
|---|
| 67 | !! ** Action : update at each time-step |
|---|
| 68 | !! - utau, vtau i- and j-component of the wind stress |
|---|
| 69 | !! - taum wind stress module at T-point |
|---|
| 70 | !! - wndm 10m wind module at T-point |
|---|
| 71 | !! - qns non solar heat flux including heat flux due to emp |
|---|
| 72 | !! - qsr solar heat flux |
|---|
| 73 | !! - emp upward mass flux (evap. - precip.) |
|---|
| 74 | !! - sfx salt flux; set to zero at nit000 but possibly non-zero |
|---|
| 75 | !! if ice is present (computed in limsbc(_2).F90) |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 78 | !! |
|---|
| 79 | INTEGER :: ji, jj, jf ! dummy indices |
|---|
| 80 | INTEGER :: ierror ! return error code |
|---|
| 81 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 82 | REAL(wp) :: zfact ! temporary scalar |
|---|
| 83 | REAL(wp) :: zrhoa = 1.22 ! Air density kg/m3 |
|---|
| 84 | REAL(wp) :: zcdrag = 1.5e-3 ! drag coefficient |
|---|
| 85 | REAL(wp) :: ztx, zty, zmod, zcoef ! temporary variables |
|---|
| 86 | !! |
|---|
| 87 | CHARACTER(len=100) :: cn_dir ! Root directory for location of flx files |
|---|
| 88 | TYPE(FLD_N), DIMENSION(jpfld) :: slf_i ! array of namelist information structures |
|---|
| 89 | TYPE(FLD_N) :: sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp ! informations about the fields to be read |
|---|
| 90 | NAMELIST/namsbc_flx/ cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp, ln_lfx_sio |
|---|
| 91 | !!--------------------------------------------------------------------- |
|---|
| 92 | ! |
|---|
| 93 | IF( kt == nit000 ) THEN ! First call kt=nit000 |
|---|
| 94 | ! set file information |
|---|
| 95 | ln_lfx_sio = .FALSE. |
|---|
| 96 | IF(lwm) THEN |
|---|
| 97 | REWIND( numnam_ref ) ! Namelist namsbc_flx in reference namelist : Files for fluxes |
|---|
| 98 | READ ( numnam_ref, namsbc_flx, IOSTAT = ios, ERR = 901) |
|---|
| 99 | 901 CONTINUE |
|---|
| 100 | ENDIF |
|---|
| 101 | call mpp_bcast(ios) |
|---|
| 102 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in reference namelist', lwp ) |
|---|
| 103 | IF(lwm) THEN |
|---|
| 104 | REWIND( numnam_cfg ) ! Namelist namsbc_flx in configuration namelist : Files for fluxes |
|---|
| 105 | READ ( numnam_cfg, namsbc_flx, IOSTAT = ios, ERR = 902 ) |
|---|
| 106 | 902 CONTINUE |
|---|
| 107 | ENDIF |
|---|
| 108 | call mpp_bcast(ios) |
|---|
| 109 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in configuration namelist', lwp ) |
|---|
| 110 | |
|---|
| 111 | IF(lwm) WRITE ( numond, namsbc_flx ) |
|---|
| 112 | ! |
|---|
| 113 | CALL flx_namelist(cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp) |
|---|
| 114 | ! ! check: do we plan to use ln_dm2dc with non-daily forcing? |
|---|
| 115 | IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 ) & |
|---|
| 116 | & CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) |
|---|
| 117 | ! |
|---|
| 118 | ! ! store namelist information in an array |
|---|
| 119 | slf_i(jp_utau) = sn_utau ; slf_i(jp_vtau) = sn_vtau |
|---|
| 120 | slf_i(jp_qtot) = sn_qtot ; slf_i(jp_qsr ) = sn_qsr |
|---|
| 121 | slf_i(jp_emp ) = sn_emp |
|---|
| 122 | ! |
|---|
| 123 | ALLOCATE( sf(jpfld), STAT=ierror ) ! set sf structure |
|---|
| 124 | IF( ierror > 0 ) THEN |
|---|
| 125 | CALL ctl_stop( 'sbc_flx: unable to allocate sf structure' ) ; RETURN |
|---|
| 126 | ENDIF |
|---|
| 127 | DO ji= 1, jpfld |
|---|
| 128 | ALLOCATE( sf(ji)%fnow(jpi,jpj,1) ) |
|---|
| 129 | IF( slf_i(ji)%ln_tint ) ALLOCATE( sf(ji)%fdta(jpi,jpj,1,2) ) |
|---|
| 130 | END DO |
|---|
| 131 | ! ! fill sf with slf_i and control print |
|---|
| 132 | CALL fld_fill( sf, slf_i, cn_dir, 'sbc_flx', 'flux formulation for ocean surface boundary condition', 'namsbc_flx' ) |
|---|
| 133 | ! |
|---|
| 134 | sfx(:,:) = 0.0_wp ! salt flux due to freezing/melting (non-zero only if ice is present; set in limsbc(_2).F90) |
|---|
| 135 | ! |
|---|
| 136 | ENDIF |
|---|
| 137 | |
|---|
| 138 | lspr = ln_lfx_sio |
|---|
| 139 | CALL fld_read( kt, nn_fsbc, sf ) ! input fields provided at the current time-step |
|---|
| 140 | lspr = .false. |
|---|
| 141 | |
|---|
| 142 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! update ocean fluxes at each SBC frequency |
|---|
| 143 | |
|---|
| 144 | IF( ln_dm2dc ) THEN ; qsr(:,:) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) ! modify now Qsr to include the diurnal cycle |
|---|
| 145 | ELSE ; qsr(:,:) = sf(jp_qsr)%fnow(:,:,1) |
|---|
| 146 | ENDIF |
|---|
| 147 | !CDIR COLLAPSE |
|---|
| 148 | DO jj = 1, jpj ! set the ocean fluxes from read fields |
|---|
| 149 | DO ji = 1, jpi |
|---|
| 150 | utau(ji,jj) = sf(jp_utau)%fnow(ji,jj,1) |
|---|
| 151 | vtau(ji,jj) = sf(jp_vtau)%fnow(ji,jj,1) |
|---|
| 152 | qns (ji,jj) = sf(jp_qtot)%fnow(ji,jj,1) - sf(jp_qsr)%fnow(ji,jj,1) |
|---|
| 153 | emp (ji,jj) = sf(jp_emp )%fnow(ji,jj,1) |
|---|
| 154 | END DO |
|---|
| 155 | END DO |
|---|
| 156 | ! ! add to qns the heat due to e-p |
|---|
| 157 | qns(:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp ! mass flux is at SST |
|---|
| 158 | ! |
|---|
| 159 | ! ! module of wind stress and wind speed at T-point |
|---|
| 160 | zcoef = 1. / ( zrhoa * zcdrag ) |
|---|
| 161 | !CDIR NOVERRCHK |
|---|
| 162 | DO jj = 2, jpjm1 |
|---|
| 163 | !CDIR NOVERRCHK |
|---|
| 164 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 165 | ztx = utau(ji-1,jj ) + utau(ji,jj) |
|---|
| 166 | zty = vtau(ji ,jj-1) + vtau(ji,jj) |
|---|
| 167 | zmod = 0.5 * SQRT( ztx * ztx + zty * zty ) |
|---|
| 168 | taum(ji,jj) = zmod |
|---|
| 169 | wndm(ji,jj) = SQRT( zmod * zcoef ) |
|---|
| 170 | END DO |
|---|
| 171 | END DO |
|---|
| 172 | taum(:,:) = taum(:,:) * tmask(:,:,1) ; wndm(:,:) = wndm(:,:) * tmask(:,:,1) |
|---|
| 173 | CALL lbc_lnk( taum(:,:), 'T', 1. ) ; CALL lbc_lnk( wndm(:,:), 'T', 1. ) |
|---|
| 174 | |
|---|
| 175 | IF( nitend-nit000 <= 100 .AND. lwp ) THEN ! control print (if less than 100 time-step asked) |
|---|
| 176 | WRITE(numout,*) |
|---|
| 177 | WRITE(numout,*) ' read daily momentum, heat and freshwater fluxes OK' |
|---|
| 178 | DO jf = 1, jpfld |
|---|
| 179 | IF( jf == jp_utau .OR. jf == jp_vtau ) zfact = 1. |
|---|
| 180 | IF( jf == jp_qtot .OR. jf == jp_qsr ) zfact = 0.1 |
|---|
| 181 | IF( jf == jp_emp ) zfact = 86400. |
|---|
| 182 | WRITE(numout,*) |
|---|
| 183 | WRITE(numout,*) ' day: ', ndastp , TRIM(sf(jf)%clvar), ' * ', zfact |
|---|
| 184 | CALL prihre( sf(jf)%fnow, jpi, jpj, 1, jpi, 20, 1, jpj, 10, zfact, numout ) |
|---|
| 185 | END DO |
|---|
| 186 | ENDIF |
|---|
| 187 | ! |
|---|
| 188 | ENDIF |
|---|
| 189 | ! |
|---|
| 190 | END SUBROUTINE sbc_flx |
|---|
| 191 | |
|---|
| 192 | SUBROUTINE flx_namelist(cd_dir, sd_utau, sd_vtau, sd_qtot, sd_qsr, sd_emp) |
|---|
| 193 | !!--------------------------------------------------------------------- |
|---|
| 194 | !! *** ROUTINE flx_namelist *** |
|---|
| 195 | !! |
|---|
| 196 | !! ** Purpose : Broadcast namelist variables read by procesor lwm |
|---|
| 197 | !! |
|---|
| 198 | !! ** Method : use lib_mpp |
|---|
| 199 | !!---------------------------------------------------------------------- |
|---|
| 200 | CHARACTER(len=100), INTENT(INOUT) :: cd_dir ! Root directory for location of flx files |
|---|
| 201 | TYPE(FLD_N), INTENT(INOUT) :: sd_utau, sd_vtau, sd_qtot, sd_qsr, sd_emp ! informations about the fields to be read |
|---|
| 202 | #if defined key_mpp_mpi |
|---|
| 203 | CALL mpp_bcast(cd_dir, 100) |
|---|
| 204 | CALL fld_n_bcast(sd_utau) |
|---|
| 205 | CALL fld_n_bcast(sd_vtau) |
|---|
| 206 | CALL fld_n_bcast(sd_qtot) |
|---|
| 207 | CALL fld_n_bcast(sd_qsr) |
|---|
| 208 | CALL fld_n_bcast(sd_emp) |
|---|
| 209 | CALL mpp_bcast(ln_lfx_sio) |
|---|
| 210 | #endif |
|---|
| 211 | END SUBROUTINE flx_namelist |
|---|
| 212 | |
|---|
| 213 | !!====================================================================== |
|---|
| 214 | END MODULE sbcflx |
|---|
