New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 9373

Last change on this file since 9373 was 8243, checked in by andmirek, 7 years ago

#1914 working XIOS read, XIOS write and single processor read
File size: 13.8 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23   USE iom_def, ONLY : lxios_read
24   USE iom_def, ONLY : lwxios
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm         ! routine called by step.F90
30   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
33                                                  ! from restart file
34   
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE sbc_ssm( kt )
45      !!---------------------------------------------------------------------
46      !!                     ***  ROUTINE sbc_oce  ***
47      !!                     
48      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
49      !!                condition computation
50      !!               
51      !! ** Method  :   compute mean surface velocity (2 components at U and
52      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
53      !!      the periode (kt - nn_fsbc) to kt
54      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
55      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
56      !!---------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt   ! ocean time step
58      !
59      INTEGER  ::   ji, jj               ! loop index
60      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
61      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
62      !!---------------------------------------------------------------------
63
64      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
65      DO jj = 1, jpj
66         DO ji = 1, jpi
67            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
68            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
69         END DO
70      END DO
71      !
72      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
73         !                                                ! ---------------------------------------- !
74         ssu_m(:,:) = ub(:,:,1)
75         ssv_m(:,:) = vb(:,:,1)
76         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
77         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
78         ENDIF
79         sss_m(:,:) = zts(:,:,jp_sal)
80         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
81         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
82         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
83         ENDIF
84         !
85         IF( lk_vvl )   e3t_m(:,:) = fse3t_n(:,:,1)
86         !
87         frq_m(:,:) = fraqsr_1lev(:,:)
88         !
89      ELSE
90         !                                                ! ----------------------------------------------- !
91         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
92            !                                             ! ----------------------------------------------- !
93            IF(lwp) WRITE(numout,*)
94            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
95            zcoef = REAL( nn_fsbc - 1, wp )
96            ssu_m(:,:) = zcoef * ub(:,:,1)
97            ssv_m(:,:) = zcoef * vb(:,:,1)
98            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
99            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
100            ENDIF
101            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
102            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
103            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
104            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
105            ENDIF
106            !
107            IF( lk_vvl )   e3t_m(:,:) = zcoef * fse3t_n(:,:,1)
108            !
109            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
110            !                                             ! ---------------------------------------- !
111         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
112            !                                             ! ---------------------------------------- !
113            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
114            ssv_m(:,:) = 0.e0
115            sst_m(:,:) = 0.e0
116            sss_m(:,:) = 0.e0
117            ssh_m(:,:) = 0.e0
118            IF( lk_vvl )   e3t_m(:,:) = 0.e0
119            frq_m(:,:) = 0.e0
120         ENDIF
121         !                                                ! ---------------------------------------- !
122         !                                                !        Cumulate at each time step        !
123         !                                                ! ---------------------------------------- !
124         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
125         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
126         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
127         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
128         ENDIF
129         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
130         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
131         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
132         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
133         ENDIF
134         !
135         IF( lk_vvl )   e3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
136         !
137         frq_m(:,:) =   frq_m(:,:) + fraqsr_1lev(:,:)
138
139         !                                                ! ---------------------------------------- !
140         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
141            !                                             ! ---------------------------------------- !
142            zcoef = 1. / REAL( nn_fsbc, wp )
143            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
144            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
145            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
146            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
147            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
148            IF( lk_vvl )   e3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
149            frq_m(:,:) = frq_m(:,:) * zcoef   ! mean fraction of solar net radiation absorbed in the 1st T level [-]
150            !
151         ENDIF
152         !                                                ! ---------------------------------------- !
153         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
154            !                                             ! ---------------------------------------- !
155            IF(lwp) WRITE(numout,*)
156            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
157               &                    'at it= ', kt,' date= ', ndastp
158            IF(lwp) WRITE(numout,*) '~~~~~~~'
159            zf_sbc = REAL( nn_fsbc, wp )
160            IF( lwxios ) CALL iom_swap(      wxios_context          )
161            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, lxios = lwxios )    ! sbc frequency
162            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, lxios = lwxios  )    ! sea surface mean fields
163            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, lxios = lwxios  )
164            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, lxios = lwxios  )
165            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, lxios = lwxios  )
166            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, lxios = lwxios  )
167            IF( lk_vvl )   CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m   )
168            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, lxios = lwxios )
169            !
170            IF( lwxios ) CALL iom_swap(      cxios_context          )
171         ENDIF
172         !
173      ENDIF
174      !
175      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
176         CALL iom_put( 'ssu_m', ssu_m )
177         CALL iom_put( 'ssv_m', ssv_m )
178         CALL iom_put( 'sst_m', sst_m )
179         CALL iom_put( 'sss_m', sss_m )
180         CALL iom_put( 'ssh_m', ssh_m )
181         IF( lk_vvl )   CALL iom_put( 'e3t_m', e3t_m )
182         CALL iom_put( 'frq_m', frq_m )
183      ENDIF
184      !
185   END SUBROUTINE sbc_ssm
186
187   SUBROUTINE sbc_ssm_init
188      !!----------------------------------------------------------------------
189      !!                  ***  ROUTINE sbc_ssm_init  ***
190      !!
191      !! ** Purpose :   Initialisation of the sbc data
192      !!
193      !! ** Action  : - read parameters
194      !!----------------------------------------------------------------------
195      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
196      !!----------------------------------------------------------------------
197
198      IF( nn_fsbc == 1 ) THEN
199         !
200         IF(lwp) WRITE(numout,*)
201         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
202         IF(lwp) WRITE(numout,*) '~~~~~~~ '
203         !
204      ELSE
205         !               
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
208         IF(lwp) WRITE(numout,*) '~~~~~~~ '
209         !
210         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
211            l_ssm_mean = .TRUE.
212            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, lrxios = lxios_read )   ! sbc frequency of previous run
213            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, lrxios = lxios_read  )   ! sea surface mean velocity    (T-point)
214            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, lrxios = lxios_read  )   !   "         "    velocity    (V-point)
215            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, lrxios = lxios_read  )   !   "         "    temperature (T-point)
216            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, lrxios = lxios_read  )   !   "         "    salinity    (T-point)
217            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, lrxios = lxios_read  )   !   "         "    height      (T-point)
218            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'e3t_m', e3t_m, lrxios = lxios_read )
219            ! fraction of solar net radiation absorbed in 1st T level
220            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
221               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, lrxios = lxios_read  )
222            ELSE
223               frq_m(:,:) = 1._wp   ! default definition
224            ENDIF
225            !
226            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
227               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
228                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
229               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
230               ssu_m(:,:) = zcoef * ssu_m(:,:) 
231               ssv_m(:,:) = zcoef * ssv_m(:,:)
232               sst_m(:,:) = zcoef * sst_m(:,:)
233               sss_m(:,:) = zcoef * sss_m(:,:)
234               ssh_m(:,:) = zcoef * ssh_m(:,:)
235               IF( lk_vvl )   e3t_m(:,:) = zcoef * fse3t_m(:,:)
236               frq_m(:,:) = zcoef * frq_m(:,:)
237            ELSE
238               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
239            ENDIF
240         ENDIF
241      ENDIF
242      !
243      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
244         !
245         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
246         ssu_m(:,:) = ub(:,:,1)
247         ssv_m(:,:) = vb(:,:,1)
248         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
249         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
250         ENDIF
251         sss_m(:,:) = tsn(:,:,1,jp_sal)
252         ssh_m(:,:) = sshn(:,:)
253         IF( lk_vvl )   e3t_m(:,:) = fse3t_n(:,:,1)
254         frq_m(:,:) = 1._wp
255         !
256      ENDIF
257      !
258   END SUBROUTINE sbc_ssm_init
259
260   !!======================================================================
261END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.