New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 6652

Last change on this file since 6652 was 6652, checked in by timgraham, 8 years ago

Added heat transport from Bolus advection to diaptr (global and by sub basin).
File size: 11.4 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27# endif 
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30   USE diaptr         ! Heat/Salt transport diagnostics
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_adv_eiv   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "ldfeiv_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_adv_eiv  ***
52      !!
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   The eddy induced advection is computed from the slope
57      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
58      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
59      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
60      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
61      !!                               + dj[ aeiv e1v mj(wslpj) ] }
62      !!      add the eiv component to the model velocity:
63      !!         p.n = p.n + z._eiv
64      !!
65      !! ** Action  : - add to p.n the eiv component
66      !!----------------------------------------------------------------------
67      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
68      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
69      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
70      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
73      !!
74      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
75      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
76      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
77# if defined key_diaeiv 
78      REAL(wp) ::   zztmp                      ! local scalar
79# endif 
80      REAL(wp), POINTER, DIMENSION(:,:) :: zu_eiv, zv_eiv, zw_eiv, z2d
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: z3d
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start( 'tra_adv_eiv')
85      !
86# if defined key_diaeiv 
87      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
88      IF( ln_diaptr ) CALL wrk_alloc( jpi, jpj, jpk, z3d )
89# else
90      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
91# endif
92
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
97# if defined key_diaeiv 
98         IF( cdtype == 'TRA') THEN
99            u_eiv(:,:,:) = 0.e0
100            v_eiv(:,:,:) = 0.e0
101            w_eiv(:,:,:) = 0.e0
102         END IF
103# endif
104      ENDIF
105
106      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
107     
108                                                    ! =================
109      DO jk = 1, jpkm1                              !  Horizontal slab
110         !                                          ! =================
111         DO jj = 1, jpjm1
112            DO ji = 1, fs_jpim1   ! vector opt.
113               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
114               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
115               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
116               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
117
118               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
119               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
120   
121               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
122               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
123            END DO
124         END DO
125# if defined key_diaeiv 
126         IF( cdtype == 'TRA') THEN
127            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
128            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
129         END IF
130# endif
131         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
132            DO jj = 2, jpjm1
133               DO ji = fs_2, fs_jpim1   ! vector opt.
134# if defined key_traldf_c2d || defined key_traldf_c3d
135                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
136                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
137                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
138                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
139 
140                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
141# else
142                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
143                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
144                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
145                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
146
147                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
148# endif
149                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
150               END DO
151            END DO
152# if defined key_diaeiv 
153            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
154# endif
155         ENDIF
156         !                                          ! =================
157      END DO                                        !    End of slab 
158      !                                             ! =================
159
160# if defined key_diaeiv 
161      IF( cdtype == 'TRA') THEN
162         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
163         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
164         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
165         IF( iom_use('ueiv_heattr') ) THEN
166            zztmp = 0.5 * rau0 * rcp 
167            z2d(:,:) = 0.e0 
168            DO jk = 1, jpkm1
169               DO jj = 2, jpjm1
170                  DO ji = fs_2, fs_jpim1   ! vector opt.
171                     z2d(ji,jj) = z2d(ji,jj) + u_eiv(ji,jj,jk) &
172                       &         * (tsn(ji,jj,jk,jp_tem)+tsn(ji+1,jj,jk,jp_tem)) * e2u(ji,jj) * fse3u(ji,jj,jk) 
173                  END DO
174               END DO
175            END DO
176            CALL lbc_lnk( z2d, 'U', -1. )
177            CALL iom_put( "ueiv_heattr", zztmp * z2d )                  ! heat transport in i-direction
178         ENDIF
179           
180         IF( iom_use('veiv_heattr') ) THEN
181            zztmp = 0.5 * rau0 * rcp 
182            z2d(:,:) = 0.e0 
183            DO jk = 1, jpkm1
184               DO jj = 2, jpjm1
185                  DO ji = fs_2, fs_jpim1   ! vector opt.
186                     z2d(ji,jj) = z2d(ji,jj) + v_eiv(ji,jj,jk) &
187                     &           * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) * e1v(ji,jj) * fse3v(ji,jj,jk) 
188                  END DO
189               END DO
190            END DO
191            CALL lbc_lnk( z2d, 'V', -1. )
192            CALL iom_put( "veiv_heattr", zztmp * z2d )                  !  heat transport in i-direction
193         ENDIF
194    END IF
195!
196    IF( ln_diaptr .AND. cdtype == 'TRA' ) THEN
197       z3d(:,:,:) = 0._wp
198       DO jk = 1, jpkm1
199          DO jj = 2, jpjm1
200             DO ji = fs_2, fs_jpim1   ! vector opt.
201                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) &
202                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
203             END DO
204          END DO
205       END DO
206       CALL dia_ptr_ohst_components( jp_tem, 'eiv', z3d )
207       z3d(:,:,:) = 0._wp
208       DO jk = 1, jpkm1
209          DO jj = 2, jpjm1
210             DO ji = fs_2, fs_jpim1   ! vector opt.
211                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_sal)+tsn(ji,jj+1,jk,jp_sal)) &
212                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
213             END DO
214          END DO
215       END DO
216       CALL dia_ptr_ohst_components( jp_sal, 'eiv', z3d )
217    ENDIF
218# endif 
219
220# if defined key_diaeiv 
221      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
222      IF( ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, z3d )
223# else
224      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
225# endif
226      !
227      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv_eiv')
228      !
229    END SUBROUTINE tra_adv_eiv
230
231#else
232   !!----------------------------------------------------------------------
233   !!   Dummy module :             No rotation of the lateral mixing tensor
234   !!----------------------------------------------------------------------
235CONTAINS
236   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )              ! Empty routine
237      INTEGER  ::   kt   
238      INTEGER  ::   kit000   
239      CHARACTER(len=3) ::   cdtype
240      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
241      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', &
242          &  kt, cdtype, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
243   END SUBROUTINE tra_adv_eiv
244#endif
245
246   !!==============================================================================
247END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.