New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 7063

Last change on this file since 7063 was 7063, checked in by timgraham, 8 years ago

Fixes to get kinetic energy from GM & potential energy from vertical mixing to work with VVL
File size: 12.5 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27# endif 
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30   USE diaptr         ! Heat/Salt transport diagnostics
31   USE trddyn
32   USE trd_oce
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv_eiv   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "ldftra_substitute.h90"
42#  include "ldfeiv_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_adv_eiv  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend and add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The eddy induced advection is computed from the slope
59      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
60      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
61      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
62      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
63      !!                               + dj[ aeiv e1v mj(wslpj) ] }
64      !!      add the eiv component to the model velocity:
65      !!         p.n = p.n + z._eiv
66      !!
67      !! ** Action  : - add to p.n the eiv component
68      !!----------------------------------------------------------------------
69      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
70      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
71      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
72      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
73      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
75      !!
76      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
77      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
78      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
79# if defined key_diaeiv 
80      REAL(wp) ::   zztmp                      ! local scalar
81# endif 
82      REAL(wp), POINTER, DIMENSION(:,:) :: zu_eiv, zv_eiv, zw_eiv, z2d
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: z3d
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start( 'tra_adv_eiv')
87      !
88# if defined key_diaeiv 
89      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
90      IF( ln_diaptr ) CALL wrk_alloc( jpi, jpj, jpk, z3d )
91# else
92      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
93# endif
94
95      IF( kt == kit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
99# if defined key_diaeiv 
100         IF( cdtype == 'TRA') THEN
101            u_eiv(:,:,:) = 0.e0
102            v_eiv(:,:,:) = 0.e0
103            w_eiv(:,:,:) = 0.e0
104         END IF
105# endif
106      ENDIF
107
108      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
109     
110                                                    ! =================
111      DO jk = 1, jpkm1                              !  Horizontal slab
112         !                                          ! =================
113         DO jj = 1, jpjm1
114            DO ji = 1, fs_jpim1   ! vector opt.
115               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
116               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
117               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
118               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
119
120               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
121               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
122   
123               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
124               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
125            END DO
126         END DO
127# if defined key_diaeiv 
128         IF( cdtype == 'TRA') THEN
129            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
130            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
131         END IF
132# endif
133         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
134            DO jj = 2, jpjm1
135               DO ji = fs_2, fs_jpim1   ! vector opt.
136# if defined key_traldf_c2d || defined key_traldf_c3d
137                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
138                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
139                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
140                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
141 
142                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
143# else
144                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
145                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
146                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
147                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
148
149                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
150# endif
151                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
152               END DO
153            END DO
154# if defined key_diaeiv 
155            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
156# endif
157         ENDIF
158         !                                          ! =================
159      END DO                                        !    End of slab 
160      !                                             ! =================
161
162# if defined key_diaeiv 
163      IF( cdtype == 'TRA') THEN
164         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
165         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
166         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
167         IF( iom_use('weiv_masstr') ) THEN   ! vertical mass transport & its square value
168           z2d(:,:) = rau0 * e12t(:,:)
169           DO jk = 1, jpk
170              z3d(:,:,jk) = w_eiv(:,:,jk) * z2d(:,:)
171           END DO
172           CALL iom_put( "weiv_masstr" , z3d ) 
173         ENDIF
174         IF( iom_use("ueiv_masstr") .OR. iom_use("ueiv_heattr") ) THEN
175            z3d(:,:,jpk) = 0.e0
176            z2d(:,:) = 0.e0
177            DO jk = 1, jpkm1
178               z3d(:,:,jk) = rau0 * u_eiv(:,:,jk) * e2u(:,:) * fse3u(:,:,jk) * umask(:,:,jk)
179               z2d(:,:) = z2d(:,:) + z3d(:,:,jk)
180            END DO
181            CALL iom_put( "ueiv_masstr", z3d )                  ! mass transport in i-direction
182         ENDIF
183
184         IF( iom_use('ueiv_heattr') ) THEN
185            zztmp = 0.5 * rcp 
186            z2d(:,:) = 0.e0 
187            DO jk = 1, jpkm1
188               DO jj = 2, jpjm1
189                  DO ji = fs_2, fs_jpim1   ! vector opt.
190                     z2d(ji,jj) = z2d(ji,jj) + z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_tem) + tsn(ji+1,jj,jk,jp_tem) )
191                  END DO
192               END DO
193            END DO
194            CALL lbc_lnk( z2d, 'U', -1. )
195            CALL iom_put( "ueiv_heattr", zztmp * z2d )                  ! heat transport in i-direction
196         ENDIF
197
198         IF( iom_use("veiv_masstr") .OR. iom_use("veiv_heattr") ) THEN
199            z3d(:,:,jpk) = 0.e0
200            z2d(:,:) = 0.e0
201            DO jk = 1, jpkm1
202               z3d(:,:,jk) = rau0 * v_eiv(:,:,jk) * e1v(:,:) * fse3v(:,:,jk) * vmask(:,:,jk)
203            END DO
204            CALL iom_put( "veiv_masstr", z3d )                  ! mass transport in j-direction
205         ENDIF
206           
207         IF( iom_use('veiv_heattr') ) THEN
208            zztmp = 0.5 * rcp 
209            z2d(:,:) = 0.e0 
210            DO jk = 1, jpkm1
211               DO jj = 2, jpjm1
212                  DO ji = fs_2, fs_jpim1   ! vector opt.
213                     z2d(ji,jj) = z2d(ji,jj) + z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj+1,jk,jp_tem) )
214                  END DO
215               END DO
216            END DO
217            CALL lbc_lnk( z2d, 'V', -1. )
218            CALL iom_put( "veiv_heattr", zztmp * z2d )                  !  heat transport in j-direction
219         ENDIF
220    END IF
221!
222    IF( ln_diaptr .AND. cdtype == 'TRA' ) THEN
223       z3d(:,:,:) = 0._wp
224       DO jk = 1, jpkm1
225          DO jj = 2, jpjm1
226             DO ji = fs_2, fs_jpim1   ! vector opt.
227                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) &
228                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
229             END DO
230          END DO
231       END DO
232       CALL dia_ptr_ohst_components( jp_tem, 'eiv', z3d )
233       z3d(:,:,:) = 0._wp
234       DO jk = 1, jpkm1
235          DO jj = 2, jpjm1
236             DO ji = fs_2, fs_jpim1   ! vector opt.
237                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_sal)+tsn(ji,jj+1,jk,jp_sal)) &
238                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
239             END DO
240          END DO
241       END DO
242       CALL dia_ptr_ohst_components( jp_sal, 'eiv', z3d )
243    ENDIF
244
245    IF( ln_KE_trd ) CALL trd_dyn(u_eiv, v_eiv, jpdyn_eivke, kt )
246# endif 
247
248# if defined key_diaeiv 
249      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
250      IF( ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, z3d )
251# else
252      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
253# endif
254      !
255      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv_eiv')
256      !
257    END SUBROUTINE tra_adv_eiv
258
259#else
260   !!----------------------------------------------------------------------
261   !!   Dummy module :             No rotation of the lateral mixing tensor
262   !!----------------------------------------------------------------------
263CONTAINS
264   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )              ! Empty routine
265      INTEGER  ::   kt   
266      INTEGER  ::   kit000   
267      CHARACTER(len=3) ::   cdtype
268      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
269      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', &
270          &  kt, cdtype, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
271   END SUBROUTINE tra_adv_eiv
272#endif
273
274   !!==============================================================================
275END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.