New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 6428

Last change on this file since 6428 was 6428, checked in by timgraham, 8 years ago

Added advective and diffusive heat transport by basin to diaptr module
File size: 33.7 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88      REAL(wp), POINTER, DIMENSION(:,:) :: ptr_adv_tmp
89      !!----------------------------------------------------------------------
90      !
91      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
92      !
93      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
94      !
95      IF( kt == kit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
99         !
100         l_trd = .FALSE.
101         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
102      ENDIF
103      !
104      IF( l_trd )  THEN
105         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
106         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
107      ENDIF
108      !
109      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
110         CALL wrk_alloc( jpi, nptr, ptr_adv_tmp )
111         ptr_adv_tmp(:,:) = 0._wp
112      ENDIF
113      !
114      zwi(:,:,:) = 0.e0 ; 
115      !
116      !                                                          ! ===========
117      DO jn = 1, kjpt                                            ! tracer loop
118         !                                                       ! ===========
119         ! 1. Bottom and k=1 value : flux set to zero
120         ! ----------------------------------
121         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
122         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
123         
124         zwz(:,:,1  ) = 0._wp
125         ! 2. upstream advection with initial mass fluxes & intermediate update
126         ! --------------------------------------------------------------------
127         ! upstream tracer flux in the i and j direction
128         DO jk = 1, jpkm1
129            DO jj = 1, jpjm1
130               DO ji = 1, fs_jpim1   ! vector opt.
131                  ! upstream scheme
132                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
133                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
134                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
135                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
136                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
137                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
138               END DO
139            END DO
140         END DO
141
142         ! upstream tracer flux in the k direction
143         ! Interior value
144         DO jk = 2, jpkm1
145            DO jj = 1, jpj
146               DO ji = 1, jpi
147                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
148                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
149                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
150               END DO
151            END DO
152         END DO
153         ! Surface value
154         IF( lk_vvl ) THEN   
155            IF ( ln_isfcav ) THEN
156               DO jj = 1, jpj
157                  DO ji = 1, jpi
158                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
159                  END DO
160               END DO
161            ELSE
162               zwz(:,:,1) = 0.e0          ! volume variable
163            END IF
164         ELSE               
165            IF ( ln_isfcav ) THEN
166               DO jj = 1, jpj
167                  DO ji = 1, jpi
168                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
169                  END DO
170               END DO   
171            ELSE
172               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
173            END IF
174         ENDIF
175
176         ! total advective trend
177         DO jk = 1, jpkm1
178            z2dtt = p2dt(jk)
179            DO jj = 2, jpjm1
180               DO ji = fs_2, fs_jpim1   ! vector opt.
181                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
182                  ! total intermediate advective trends
183                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
184                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
185                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
186                  ! update and guess with monotonic sheme
187                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
188                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
189               END DO
190            END DO
191         END DO
192         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
193         CALL lbc_lnk( zwi, 'T', 1. ) 
194
195         !                                 ! trend diagnostics (contribution of upstream fluxes)
196         IF( l_trd )  THEN 
197            ! store intermediate advective trends
198            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
199         END IF
200         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
201         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
202           CALL dia_ptr_ohst_components( zwy(:,:,:), ptr_adv_tmp(:,:)  )
203         ENDIF
204
205         ! 3. antidiffusive flux : high order minus low order
206         ! --------------------------------------------------
207         ! antidiffusive flux on i and j
208         DO jk = 1, jpkm1
209            DO jj = 1, jpjm1
210               DO ji = 1, fs_jpim1   ! vector opt.
211                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
212                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
213               END DO
214            END DO
215         END DO
216     
217         ! antidiffusive flux on k
218         ! Interior value
219         DO jk = 2, jpkm1                   
220            DO jj = 1, jpj
221               DO ji = 1, jpi
222                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
223               END DO
224            END DO
225         END DO
226         ! surface value
227         IF ( ln_isfcav ) THEN
228            DO jj = 1, jpj
229               DO ji = 1, jpi
230                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
231               END DO
232            END DO
233         ELSE
234            zwz(:,:,1) = 0.e0
235         END IF
236         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
237         CALL lbc_lnk( zwz, 'W',  1. )
238
239         ! 4. monotonicity algorithm
240         ! -------------------------
241         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
242
243
244         ! 5. final trend with corrected fluxes
245         ! ------------------------------------
246         DO jk = 1, jpkm1
247            DO jj = 2, jpjm1
248               DO ji = fs_2, fs_jpim1   ! vector opt. 
249                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
250                  ! total advective trends
251                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
252                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
253                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
254                  ! add them to the general tracer trends
255                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
256               END DO
257            END DO
258         END DO
259
260         !                                 ! trend diagnostics (contribution of upstream fluxes)
261         IF( l_trd )  THEN
262            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
263            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
264            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
265           
266            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
267            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
268            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
269         END IF
270         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
271         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
272           IF( jn == jp_tem ) THEN
273              CALL dia_ptr_ohst_components( zwy(:,:,:), htr_adv(:,:)  )
274              htr_adv(:,:) = htr_adv(:,:) + ptr_adv_tmp(:,:)
275           ENDIF
276           IF( jn == jp_sal )  THEN
277              CALL dia_ptr_ohst_components( zwy(:,:,:), str_adv(:,:)  )
278              htr_adv(:,:) = htr_adv(:,:) + ptr_adv_tmp(:,:)
279           ENDIF
280           ptr_adv_tmp(:,:) = 0._wp
281         ENDIF
282         !
283      END DO
284      !
285                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
286      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
287      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN wrk_dealloc( jpi, nptr, ptr_adv_tmp )
288      !
289      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
290      !
291   END SUBROUTINE tra_adv_tvd
292
293   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
294      &                                       ptb, ptn, pta, kjpt )
295      !!----------------------------------------------------------------------
296      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
297      !!
298      !! **  Purpose :   Compute the now trend due to total advection of
299      !!       tracers and add it to the general trend of tracer equations
300      !!
301      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
302      !!       corrected flux (monotonic correction). This version use sub-
303      !!       timestepping for the vertical advection which increases stability
304      !!       when vertical metrics are small.
305      !!       note: - this advection scheme needs a leap-frog time scheme
306      !!
307      !! ** Action : - update (pta) with the now advective tracer trends
308      !!             - save the trends
309      !!----------------------------------------------------------------------
310      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
311      !
312      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
313      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
314      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
315      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
316      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
317      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
318      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
319      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
320      !
321      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
322      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
323      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
324      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
325      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
326      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
327      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
328      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
329      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
330      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
331      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
332      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
333      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
334      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
335      !!----------------------------------------------------------------------
336      !
337      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
338      !
339      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
340      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
341      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
342      !
343      IF( kt == kit000 )  THEN
344         IF(lwp) WRITE(numout,*)
345         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
346         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
347      ENDIF
348      !
349      l_trd = .FALSE.
350      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
351      !
352      IF( l_trd )  THEN
353         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
354         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
355      ENDIF
356      !
357      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
358         CALL wrk_alloc( jpi, nptr, ptr_adv_tmp )
359         ptr_adv_tmp(:,:) = 0._wp
360      ENDIF
361      !
362      zwi(:,:,:) = 0._wp
363      z_rzts = 1._wp / REAL( jnzts, wp )
364      zr_p2dt(:) = 1._wp / p2dt(:)
365      !
366      !                                                          ! ===========
367      DO jn = 1, kjpt                                            ! tracer loop
368         !                                                       ! ===========
369         ! 1. Bottom value : flux set to zero
370         ! ----------------------------------
371         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
372         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
373
374         ! 2. upstream advection with initial mass fluxes & intermediate update
375         ! --------------------------------------------------------------------
376         ! upstream tracer flux in the i and j direction
377         DO jk = 1, jpkm1
378            DO jj = 1, jpjm1
379               DO ji = 1, fs_jpim1   ! vector opt.
380                  ! upstream scheme
381                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
382                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
383                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
384                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
385                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
386                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
387               END DO
388            END DO
389         END DO
390
391         ! upstream tracer flux in the k direction
392         ! Interior value
393         DO jk = 2, jpkm1
394            DO jj = 1, jpj
395               DO ji = 1, jpi
396                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
397                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
398                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
399               END DO
400            END DO
401         END DO
402         ! Surface value
403         IF( lk_vvl ) THEN
404            IF ( ln_isfcav ) THEN
405               DO jj = 1, jpj
406                  DO ji = 1, jpi
407                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
408                  END DO
409               END DO
410            ELSE
411               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
412            END IF
413         ELSE
414            IF ( ln_isfcav ) THEN
415               DO jj = 1, jpj
416                  DO ji = 1, jpi
417                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
418                  END DO
419               END DO
420            ELSE
421               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
422            END IF
423         ENDIF
424
425         ! total advective trend
426         DO jk = 1, jpkm1
427            z2dtt = p2dt(jk)
428            DO jj = 2, jpjm1
429               DO ji = fs_2, fs_jpim1   ! vector opt.
430                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
431                  ! total intermediate advective trends
432                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
433                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
434                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
435                  ! update and guess with monotonic sheme
436                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
437                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
438               END DO
439            END DO
440         END DO
441         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
442         CALL lbc_lnk( zwi, 'T', 1. ) 
443
444         !                                 ! trend diagnostics (contribution of upstream fluxes)
445         IF( l_trd )  THEN 
446            ! store intermediate advective trends
447            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
448         END IF
449         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
450         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
451           CALL dia_ptr_ohst_components( zwy(:,:,:), ptr_adv_tmp(:,:)  )
452         ENDIF
453
454         ! 3. antidiffusive flux : high order minus low order
455         ! --------------------------------------------------
456         ! antidiffusive flux on i and j
457
458
459         DO jk = 1, jpkm1
460
461            DO jj = 1, jpjm1
462               DO ji = 1, fs_jpim1   ! vector opt.
463                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
464                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
465
466                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
467                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
468               END DO
469            END DO
470
471            DO jj = 2, jpjm1         ! partial horizontal divergence
472               DO ji = fs_2, fs_jpim1
473                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
474                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
475               END DO
476            END DO
477
478            DO jj = 1, jpjm1
479               DO ji = 1, fs_jpim1   ! vector opt.
480                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
481                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
482               END DO
483            END DO
484         END DO
485     
486         ! antidiffusive flux on k
487         zwz(:,:,1) = 0._wp        ! Surface value
488         zwz_sav(:,:,:) = zwz(:,:,:)
489         !
490         ztrs(:,:,:,1) = ptb(:,:,:,jn)
491         zwzts(:,:,:) = 0._wp
492
493         DO jl = 1, jnzts                   ! Start of sub timestepping loop
494
495            IF( jl == 1 ) THEN              ! Euler forward to kick things off
496              jtb = 1   ;   jtn = 1   ;   jta = 2
497              zts(:) = p2dt(:) * z_rzts
498              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
499                                            ! starting at jl =1 if jnzts is odd;
500                                            ! starting at jl =2 otherwise
501            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
502              jtb = 1   ;   jtn = 2   ;   jta = 3
503              zts(:) = 2._wp * p2dt(:) * z_rzts
504            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
505              jtb = MOD(jtb,3) + 1
506              jtn = MOD(jtn,3) + 1
507              jta = MOD(jta,3) + 1
508            ENDIF
509            DO jk = 2, jpkm1          ! Interior value
510               DO jj = 2, jpjm1
511                  DO ji = fs_2, fs_jpim1
512                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
513                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
514                  END DO
515               END DO
516            END DO
517
518            jtaken = MOD( jtaken + 1 , 2 )
519
520            DO jk = 2, jpkm1          ! Interior value
521               DO jj = 2, jpjm1
522                  DO ji = fs_2, fs_jpim1
523                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
524                     ! total advective trends
525                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
526                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
527                  END DO
528               END DO
529            END DO
530
531         END DO
532
533         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
534            DO jj = 2, jpjm1
535               DO ji = fs_2, fs_jpim1
536                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
537               END DO
538            END DO
539         END DO
540         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
541         CALL lbc_lnk( zwz, 'W',  1. )
542
543         ! 4. monotonicity algorithm
544         ! -------------------------
545         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
546
547
548         ! 5. final trend with corrected fluxes
549         ! ------------------------------------
550         DO jk = 1, jpkm1
551            DO jj = 2, jpjm1
552               DO ji = fs_2, fs_jpim1   ! vector opt. 
553                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
554                  ! total advective trends
555                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
556                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
557                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
558                  ! add them to the general tracer trends
559                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
560               END DO
561            END DO
562         END DO
563
564         !                                 ! trend diagnostics (contribution of upstream fluxes)
565         IF( l_trd )  THEN
566            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
567            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
568            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
569           
570            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
571            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
572            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
573         END IF
574         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
575         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
576           IF( jn == jp_tem ) THEN
577              CALL dia_ptr_ohst_components( zwy(:,:,:), htr_adv(:,:)  )
578              htr_adv(:,:) = htr_adv(:,:) + ptr_adv_tmp(:,:)
579           ENDIF
580           IF( jn == jp_sal )  THEN
581              CALL dia_ptr_ohst_components( zwy(:,:,:), str_adv(:,:)  )
582              htr_adv(:,:) = htr_adv(:,:) + ptr_adv_tmp(:,:)
583           ENDIF
584           ptr_adv_tmp(:,:) = 0._wp
585         ENDIF
586         !
587      END DO
588      !
589                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
590                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
591                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
592      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
593      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN wrk_dealloc( jpi, nptr, ptr_adv_tmp )
594      !
595      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
596      !
597   END SUBROUTINE tra_adv_tvd_zts
598
599   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
600      !!---------------------------------------------------------------------
601      !!                    ***  ROUTINE nonosc  ***
602      !!     
603      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
604      !!       scheme and the before field by a nonoscillatory algorithm
605      !!
606      !! **  Method  :   ... ???
607      !!       warning : pbef and paft must be masked, but the boundaries
608      !!       conditions on the fluxes are not necessary zalezak (1979)
609      !!       drange (1995) multi-dimensional forward-in-time and upstream-
610      !!       in-space based differencing for fluid
611      !!----------------------------------------------------------------------
612      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
613      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
614      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
615      !
616      INTEGER  ::   ji, jj, jk   ! dummy loop indices
617      INTEGER  ::   ikm1         ! local integer
618      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
619      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
620      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
621      !!----------------------------------------------------------------------
622      !
623      IF( nn_timing == 1 )  CALL timing_start('nonosc')
624      !
625      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
626      !
627      zbig  = 1.e+40_wp
628      zrtrn = 1.e-15_wp
629      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
630
631      ! Search local extrema
632      ! --------------------
633      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
634      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
635         &        paft * tmask - zbig * ( 1._wp - tmask )  )
636      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
637         &        paft * tmask + zbig * ( 1._wp - tmask )  )
638
639      DO jk = 1, jpkm1
640         ikm1 = MAX(jk-1,1)
641         z2dtt = p2dt(jk)
642         DO jj = 2, jpjm1
643            DO ji = fs_2, fs_jpim1   ! vector opt.
644
645               ! search maximum in neighbourhood
646               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
647                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
648                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
649                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
650
651               ! search minimum in neighbourhood
652               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
653                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
654                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
655                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
656
657               ! positive part of the flux
658               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
659                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
660                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
661
662               ! negative part of the flux
663               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
664                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
665                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
666
667               ! up & down beta terms
668               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
669               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
670               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
671            END DO
672         END DO
673      END DO
674      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
675
676      ! 3. monotonic flux in the i & j direction (paa & pbb)
677      ! ----------------------------------------
678      DO jk = 1, jpkm1
679         DO jj = 2, jpjm1
680            DO ji = fs_2, fs_jpim1   ! vector opt.
681               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
682               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
683               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
684               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
685
686               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
687               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
688               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
689               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
690
691      ! monotonic flux in the k direction, i.e. pcc
692      ! -------------------------------------------
693               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
694               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
695               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
696               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
697            END DO
698         END DO
699      END DO
700      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
701      !
702      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
703      !
704      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
705      !
706   END SUBROUTINE nonosc
707
708   !!======================================================================
709END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.