New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/dev_001_GM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_001_GM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 791

Last change on this file since 791 was 791, checked in by gm, 16 years ago

dev_001_GM - TRA/traadv : switch from velocity to transport + optimised traadv_eiv2 introduced - compilation OK

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 13.0 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :  OPA  !  2006-00  (A.Estublier)  for passive tracers
7   !!            8.2  !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            2.4  !  2008-01  (G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space and time domain
17   USE trdmod          ! ocean active tracers trends
18   USE trdmod_oce      ! ocean variables trends
19   USE in_out_manager  ! I/O manager
20   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
21   USE trabbl          ! tracers: bottom boundary layer
22   USE lib_mpp         ! distribued memory computing
23   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
24   USE diaptr          ! poleward transport diagnostics
25   USE prtctl          ! Print control
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_adv_muscl   ! routine called by step.F90
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 2.4 , LOCEAN-IPSL (2008)
37   !! $Id$
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE tra_adv_muscl( kt, cdtype, ktra, pun, pvn, pwn,   &
44      &                                        ptb     , pta )
45      !!----------------------------------------------------------------------
46      !!                    ***  ROUTINE tra_adv_muscl  ***
47      !!
48      !! ** Purpose :   Compute the now trend due to total advection of T and
49      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
50      !!      Conservation Laws) and add it to the general tracer trend.
51      !!
52      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
53      !!
54      !! ** Action  : - update (pta,sa) with the now advective tracer trends
55      !!              - save trends in (ztrdt,ztrds) ('key_trdtra')
56      !!
57      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
58      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
59      !!----------------------------------------------------------------------
60      INTEGER         , INTENT(in   )                         ::   kt              ! ocean time-step index
61      CHARACTER(len=3), INTENT(in   )                         ::   cdtype          ! =TRA or TRC (tracer indicator)
62      INTEGER         , INTENT(in   )                         ::   ktra            ! tracer index
63      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pun, pvn, pwn   ! 3 ocean velocity components
64      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   ptb             ! before tracer fields
65      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pta             ! tracer trend
66      !!
67      INTEGER  ::   ji, jj, jk   ! dummy loop indices
68      REAL(wp) ::   zu, z0u, zzwx
69      REAL(wp) ::   zv, z0v, zzwy 
70      REAL(wp) ::   zw, z0w 
71      REAL(wp) ::   zbtr, z2, zdt, zalpha 
72      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwx, zwy, zslpx, zslpy   ! 3D workspace
73      !!----------------------------------------------------------------------
74
75      IF( kt == nit000 .AND. lwp ) THEN
76         WRITE(numout,*)
77         WRITE(numout,*) 'tra_adv : MUSCL advection scheme'
78         WRITE(numout,*) '~~~~~~~'
79      ENDIF
80
81      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2 = 1.      ! euler     time-stepping
82      ELSE                                        ;    z2 = 2.      ! leap-frog time-stepping
83      ENDIF
84
85      ! I. Horizontal advective fluxes
86      ! ------------------------------
87      !                                             !-- first guess of the slopes
88      zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
89      DO jk = 1, jpkm1                                     ! interior values
90         DO jj = 1, jpjm1     
91            DO ji = 1, fs_jpim1   ! vector opt.
92               zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk) - ptb(ji,jj,jk) )
93               zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk) - ptb(ji,jj,jk) )
94            END DO
95         END DO
96      END DO
97!!gm optimisation (lbc to be suppressed)
98      CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
99      CALL lbc_lnk( zwy, 'V', -1. )
100!!gm
101
102      !                                             !-- Slopes of tracer
103      zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
104      DO jk = 1, jpkm1                                     ! interior values
105         DO jj = 2, jpjm1
106            DO ji = fs_2, jpim1   ! vector opt.
107               zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
108                  &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
109               zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
110                  &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
111            END DO
112         END DO
113      END DO
114!!gm  :merge the 2 loop (above & below)
115      DO jk = 1, jpkm1                                     ! Slopes limitation
116         DO jj = 2, jpjm1
117            DO ji = fs_2, jpim1   ! vector opt.
118               zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
119                  &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
120                  &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
121               zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
122                  &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
123                  &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
124            END DO
125         END DO
126      END DO       
127!!gm optimisation:  call lbclnk just 1 time here on zslpx & zslpy
128!!    CALL lbc_lnk( zslpx, 'U', -1. )                      ! lateral boundary conditions on zwx, zwy   (changed sign)
129!!    CALL lbc_lnk( zslpy, 'V', -1. )
130!!
131!! and loop below from 1 to jpjm1 and to jpim1
132!!gm
133
134      !                                             !-- MUSCL horizontal advective fluxes
135      DO jk = 1, jpkm1                                     ! interior values
136         zdt  = z2 * rdttra(jk)
137         DO jj = 2, jpjm1     
138            DO ji = fs_2, fs_jpim1   ! vector opt.
139               z0u = SIGN( 0.5, pun(ji,jj,jk) )           
140               zalpha = 0.5 - z0u
141               zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
142               zzwx = ptb(ji+1,jj,jk) + zu * zslpx(ji+1,jj,jk)
143               zzwy = ptb(ji  ,jj,jk) + zu * zslpx(ji  ,jj,jk)
144               zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
145               !
146               z0v = SIGN( 0.5, pvn(ji,jj,jk) )           
147               zalpha = 0.5 - z0v
148               zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
149               zzwx = ptb(ji,jj+1,jk) + zv * zslpy(ji,jj+1,jk)
150               zzwy = ptb(ji,jj  ,jk) + zv * zslpy(ji,jj  ,jk)
151               zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
152            END DO
153         END DO
154      END DO
155!!gm optimisation (lbc to be suppressed)
156      !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
157      CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
158!!gm
159
160      !                                             !-- MUSCL advective trend
161      ! Tracer flux divergence at t-point added to the general trend
162      DO jk = 1, jpkm1
163         DO jj = 2, jpjm1     
164            DO ji = fs_2, fs_jpim1   ! vector opt.
165               zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
166               ! horizontal advective trends added to the general tracer trends
167               pta(ji,jj,jk) = pta(ji,jj,jk) - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
168                  &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) ) 
169            END DO
170        END DO
171      END DO       
172
173      IF( l_trdtra ) THEN                           !-- trend diagnostics
174         CALL trd_tra_adv( kt, ktra, jpt_trd_xad, cdtype, zwx, pun, ptb )
175         CALL trd_tra_adv( kt, ktra, jpt_trd_yad, cdtype, zwy, pvn, ptb )
176      ENDIF
177      !                                             !-- "Poleward" heat or salt transports
178      IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
179         IF( ktra == jp_tem)   pht_adv(:) = ptr_vj( zwy(:,:,:) )
180         IF( ktra == jp_sal)   pst_adv(:) = ptr_vj( zwy(:,:,:) )
181      ENDIF
182      !                                             !-- control print
183      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pta, clinfo1=' muscl - had: ', mask1=tmask, clinfo3=cdtype )
184
185
186      ! II. Vertical advective fluxes
187      ! -----------------------------
188     
189      !                                             !-- first guess of the slopes
190      zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
191      DO jk = 2, jpkm1                                     ! interior values
192         zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1) - ptb(:,:,jk) )
193      END DO
194
195      !                                             !-- Slopes of tracer
196      zslpx(:,:,1) = 0.e0                                  ! surface values
197      DO jk = 2, jpkm1                                     ! interior value
198         DO jj = 1, jpj
199            DO ji = 1, jpi
200               zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
201                  &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
202            END DO
203         END DO
204      END DO
205!!gm : merge the above and below loops
206      !                                             !-- Slopes limitation
207      DO jk = 2, jpkm1                                     ! interior values
208         DO jj = 1, jpj
209            DO ji = 1, jpi
210               zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
211                  &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
212                  &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
213            END DO
214         END DO
215      END DO
216
217      !                                             !-- vertical advective flux
218      !                                                    ! surface values  (bottom already set to zero)
219      IF( lk_dynspg_rl .OR. lk_vvl) THEN    ;   zwx(:,:, 1 ) = 0.e0                      ! rigid lid or variable volume
220      ELSE                                  ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1)   ! linear free surface
221      ENDIF
222      DO jk = 1, jpkm1                                     ! interior values
223         zdt  = z2 * rdttra(jk)
224         DO jj = 2, jpjm1     
225            DO ji = fs_2, fs_jpim1   ! vector opt.
226               z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
227               zalpha = 0.5 + z0w
228               zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt / (e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
229               zzwx = ptb(ji,jj,jk+1) + zw * zslpx(ji,jj,jk+1)
230               zzwy = ptb(ji,jj,jk  ) + zw * zslpx(ji,jj,jk  )
231               zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
232            END DO
233         END DO
234      END DO
235
236      !                                             !-- vertical advective trend
237      DO jk = 1, jpkm1
238         DO jj = 2, jpjm1     
239            DO ji = fs_2, fs_jpim1   ! vector opt.
240               zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
241               ! horizontal advective trends added to the general tracer trends
242               pta(ji,jj,jk) =  pta(ji,jj,jk) - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
243            END DO
244         END DO
245      END DO
246
247      !                                             !-- trend diagnostic
248      IF( l_trdtra )   CALL trd_tra_adv( kt, ktra, jpt_trd_zad, cdtype, zwx, pwn, ptb )
249      !                                             !-- control print
250      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pta, clinfo1=' muscl - zad: ', mask1=tmask, clinfo3=cdtype )
251      !
252   END SUBROUTINE tra_adv_muscl
253
254   !!======================================================================
255END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.