New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in branches/dev_001_GM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_001_GM/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 791

Last change on this file since 791 was 791, checked in by gm, 16 years ago

dev_001_GM - TRA/traadv : switch from velocity to transport + optimised traadv_eiv2 introduced - compilation OK

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 13.5 KB
Line 
1MODULE traadv_muscl2
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            2.4  !  2008-01  (G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE dom_oce         ! ocean space and time domain
15   USE trdmod          ! ocean active tracers trends
16   USE trdmod_oce      ! ocean variables trends
17   USE in_out_manager  ! I/O manager
18   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
19   USE trabbl          ! tracers: bottom boundary layer
20   USE lib_mpp
21   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
22   USE diaptr          ! poleward transport diagnostics
23   USE prtctl          ! Print control
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC tra_adv_muscl2        ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "vectopt_loop_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 2.4 , LOCEAN-IPSL (2008)
35   !! $Id$
36   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE tra_adv_muscl2( kt, cdtype, ktra, pun, pvn, pwn,   &
42      &                                         ptb, ptn, pta )
43      !!----------------------------------------------------------------------
44      !!                   ***  ROUTINE tra_adv_muscl2  ***
45      !!
46      !! ** Purpose :   Compute the now trend due to total advection of T and
47      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
48      !!      Conservation Laws) and add it to the general tracer trend.
49      !!
50      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
51      !!
52      !! ** Action  : - update (ta,sa) with the now advective tracer trends
53      !!              - save trends (lk_trdtra=T)
54      !!
55      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
56      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
57      !!----------------------------------------------------------------------
58      INTEGER         , INTENT(in   )                         ::   kt              ! ocean time-step index
59      CHARACTER(len=3), INTENT(in   )                         ::   cdtype          ! =TRA or TRC (tracer indicator)
60      INTEGER         , INTENT(in   )                         ::   ktra            ! tracer index
61      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pun, pvn, pwn   ! 3 ocean velocity components
62      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   ptb             ! before tracer fields
63      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   ptn             ! now    tracer fields
64      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pta             ! tracer trend
65      !!
66      INTEGER  ::   ji, jj, jk   ! dummy loop indices
67      REAL(wp) ::   zu, zv, zw
68      REAL(wp) ::   zbtr, zstep, z2 
69      REAL(wp) ::   z0u, z0v, z0w
70      REAL(wp) ::   zzwx, zzwy, zalpha
71      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwx, zwy, zslpx, zslpy   ! 3D workspace
72      !!----------------------------------------------------------------------
73
74      IF( kt == nit000 .AND. lwp ) THEN
75         WRITE(numout,*)
76         WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme'
77         WRITE(numout,*) '~~~~~~~~~~~~~~~'
78      ENDIF
79
80      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2 = 1.
81      ELSE                                        ;   z2 = 2.
82      ENDIF
83
84      ! I. Horizontal advective fluxes
85      ! ------------------------------
86
87      ! first guess of the slopes
88      DO jk = 1, jpkm1                                       ! interior values
89
90         DO jj = 1, jpjm1     
91            DO ji = 1, fs_jpim1   ! vector opt.
92               zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk) - ptb(ji,jj,jk) )
93               zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk) - ptb(ji,jj,jk) )
94            END DO
95         END DO
96      END DO
97      zwx(:,:,jpk) = 0.e0    ;    zwy(:,:,jpk) = 0.e0        ! bottom values
98
99!!gm  this lbc_lnk can be omitted
100      ! lateral boundary conditions on zwx, zwy   (changed sign)
101      CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
102
103      ! Slopes
104      DO jk = 1, jpkm1                                       ! interior values
105         DO jj = 2, jpj
106            DO ji = fs_2, jpi   ! vector opt.
107               zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
108                  &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
109               zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
110                  &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
111            END DO
112         END DO
113      END DO
114      zslpx(:,:,jpk) = 0.e0    ;    zslpy(:,:,jpk) = 0.e0      ! bottom values
115
116      DO jk = 1, jpkm1                                       ! Slopes limitation
117         DO jj = 2, jpj
118            DO ji = fs_2, jpi   ! vector opt.
119               zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
120                  &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
121                  &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
122               zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
123                  &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
124                  &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
125            END DO
126         END DO
127      END DO       
128
129      ! Advection terms
130      DO jk = 1, jpkm1                                        ! interior values
131         zstep  = z2 * rdttra(jk)
132         DO jj = 2, jpjm1     
133            DO ji = fs_2, fs_jpim1   ! vector opt.
134               z0u  = SIGN( 0.5, pun(ji,jj,jk) )           
135               zalpha = 0.5 - z0u
136               zu   = z0u - 0.5 * pun(ji,jj,jk) * zstep / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
137               zzwx = ptb(ji+1,jj,jk) + zu * zslpx(ji+1,jj,jk)
138               zzwy = ptb(ji  ,jj,jk) + zu * zslpx(ji  ,jj,jk)
139               zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
140               !
141               z0v = SIGN( 0.5, pvn(ji,jj,jk) )           
142               zalpha = 0.5 - z0v
143               zv   = z0v - 0.5 * pvn(ji,jj,jk) * zstep / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
144               zzwx = ptb(ji,jj+1,jk) + zv * zslpy(ji,jj+1,jk)
145               zzwy = ptb(ji,jj  ,jk) + zv * zslpy(ji,jj  ,jk)
146               zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
147            END DO
148         END DO
149      END DO
150
151      !!!!  centered scheme at lateral b.C. if off-shore velocity
152!!gm bug  :   seems to access jpj+1... jpi+1....
153!!gm bug2 :   centered...  use tn, not ptb !
154      DO jk = 1, jpkm1
155        DO jj = 2, jpjm1
156            DO ji = fs_2, fs_jpim1   ! vector opt.
157               IF( umask(ji,jj,jk) == 0. ) THEN
158                  IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
159                     zwx(ji+1,jj,jk) = pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk) + ptn(ji+2,jj,jk) ) * 0.5
160                  ENDIF
161                  IF( pun(ji-1,jj,jk) < 0. ) THEN
162                     zwx(ji-1,jj,jk) = pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk) + ptn(ji  ,jj,jk) ) * 0.5
163                  ENDIF
164               ENDIF
165               IF( vmask(ji,jj,jk) == 0. ) THEN
166                  IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
167                     zwy(ji,jj+1,jk) = pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk) + ptn(ji,jj+2,jk) ) * 0.5
168                  ENDIF
169                  IF( pvn(ji,jj-1,jk) < 0. ) THEN
170                     zwy(ji,jj-1,jk) = pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk) + ptn(ji  ,jj,jk) ) * 0.5
171                  ENDIF
172               ENDIF
173            END DO
174         END DO
175      END DO
176
177      ! lateral boundary conditions on zwx, zwy   (changed sign)
178      CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
179
180      ! Compute & add the horizontal advective trend
181
182      DO jk = 1, jpkm1
183         DO jj = 2, jpjm1     
184            DO ji = fs_2, fs_jpim1   ! vector opt.
185               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
186               ! horizontal advective trends added to the general tracer trends
187               pta(ji,jj,jk) = pta(ji,jj,jk) - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
188                  &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) ) 
189            END DO
190        END DO
191      END DO       
192
193      ! Save the horizontal advective trends for diagnostic
194      IF( l_trdtra ) THEN
195         CALL trd_tra_adv( kt, ktra, jpt_trd_xad, cdtype, zwx, pun, ptb )
196         CALL trd_tra_adv( kt, ktra, jpt_trd_yad, cdtype, zwy, pvn, ptb )
197      ENDIF
198
199      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pta, clinfo1=' muscl2 - had: ', mask1=tmask, clinfo3=cdtype )
200
201      ! "Poleward" heat and salt transports
202      IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
203         IF( lk_zco ) THEN
204            DO jk = 1, jpkm1
205               DO jj = 2, jpjm1
206                  DO ji = fs_2, fs_jpim1   ! vector opt.
207                    zwy(ji,jj,jk) = zwy(ji,jj,jk) * fse3v(ji,jj,jk)
208                  END DO
209               END DO
210            END DO
211         ENDIF
212         IF( ktra == jp_tem)   pht_adv(:) = ptr_vj( zwy(:,:,:) )
213         IF( ktra == jp_sal)   pst_adv(:) = ptr_vj( zwy(:,:,:) )
214      ENDIF
215
216      ! II. Vertical advective fluxes
217      ! -----------------------------
218     
219      ! First guess of the slope
220      ! interior values
221      DO jk = 2, jpkm1
222         zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1) - ptb(:,:,jk) )
223      END DO
224      ! surface & bottom boundary conditions
225      zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0
226
227      ! Slopes
228      DO jk = 2, jpkm1
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231               zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
232                  &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
233            END DO
234         END DO
235      END DO
236
237      ! Slopes limitation
238      DO jk = 2, jpkm1        ! interior values
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241               zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
242                  &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
243                  &                                                 2.*ABS( zwx  (ji,jj,jk  ) ) )
244            END DO
245         END DO
246      END DO
247      zslpx(:,:,1) = 0.e0      ! surface values
248
249      ! vertical advective flux
250      DO jk = 1, jpkm1        ! interior values
251         zstep  = z2 * rdttra(jk)
252         DO jj = 2, jpjm1     
253            DO ji = fs_2, fs_jpim1   ! vector opt.
254               z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
255               zalpha = 0.5 + z0w
256               zw  = z0w - 0.5 * pwn(ji,jj,jk+1)*zstep / ( e1t(ji,jj) *e2t(ji,jj) * fse3w(ji,jj,jk+1) )
257               zzwx = ptb(ji,jj,jk+1) + zw * zslpx(ji,jj,jk+1)
258               zzwy = ptb(ji,jj,jk  ) + zw * zslpx(ji,jj,jk  )
259               zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha)*zzwy )
260            END DO
261         END DO
262      END DO
263      DO jk = 2, jpkm1        ! centered near the bottom
264        DO jj = 2, jpjm1
265            DO ji = fs_2, fs_jpim1   ! vector opt.
266               IF( tmask(ji,jj,jk+1) == 0. ) THEN
267                  IF( pwn(ji,jj,jk) > 0. ) THEN
268                     zwx(ji,jj,jk) = pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1) + ptn(ji,jj,jk) ) * 0.5
269                  ENDIF
270               ENDIF
271            END DO
272         END DO
273      END DO
274
275      zwx(:,:,jpk) = 0.e0                                       ! bottom value
276      !                                                         ! surface values
277      IF( lk_dynspg_rl .OR. lk_vvl) THEN    ;   zwx(:,:, 1 ) = 0.e0                      ! rigid lid or variable volume
278      ELSE                                  ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1)   ! linear free surface
279      ENDIF 
280
281
282      ! Compute & add the vertical advective trend
283      DO jk = 1, jpkm1
284         DO jj = 2, jpjm1     
285            DO ji = fs_2, fs_jpim1   ! vector opt.
286               zbtr = 1. / fse3t(ji,jj,jk)
287               ! horizontal advective trends added to the general tracer trends
288               pta(ji,jj,jk) =  pta(ji,jj,jk) - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
289            END DO
290         END DO
291      END DO
292
293      ! Save the vertical advective trends for diagnostic
294      IF( l_trdtra )   CALL trd_tra_adv( kt, ktra, jpt_trd_zad, cdtype, zwx, pwn, ptb )
295
296      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pta, clinfo1=' muscl2 - zad: ', mask1=tmask, clinfo3=cdtype )
297      !
298   END SUBROUTINE tra_adv_muscl2
299
300   !!======================================================================
301END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.