source: branches/dev_001_GM/NEMO/OPA_SRC/TRA/trazdf_exp.F90 @ 786

MODULE trazdf_exp
   !!==============================================================================
   !!                    ***  MODULE  trazdf_exp  ***
   !! Ocean active tracers:  vertical component of the tracer mixing trend using
   !!                        an explicit time-stepping (time spllitting scheme)
   !!==============================================================================
   !! History :  6.0  !  1990-10  (B. Blanke)  Original code
   !!            7.0  !  1991-11  (G. Madec)
   !!                 !  1992-06  (M. Imbard)  correction on tracer trend loops
   !!                 !  1996-01  (G. Madec)  statement function for e3
   !!                 !  1997-05  (G. Madec)  vertical component of isopycnal
   !!                 !  1997-07  (G. Madec)  geopotential diffusion in s-coord
   !!                 !  2000-08  (G. Madec)  double diffusive mixing
   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form and module
   !!             -   !  2004-08  (C. Talandier) New trends organisation
   !!            2.0  !  2005-11  (G. Madec)  New organisation
   !!            2.4  !  2008-01  (G. Madec) Merge TRA-TRC
   !!----------------------------------------------------------------------

   !!----------------------------------------------------------------------
   !!   tra_zdf_exp  : update the tracer trend with the vertical diffusion
   !!                  using an explicit time stepping
   !!----------------------------------------------------------------------
   USE dom_oce         ! ocean space and time domain 
   USE zdf_oce         ! ocean vertical physics
   USE in_out_manager  ! I/O manager

   IMPLICIT NONE
   PRIVATE

   PUBLIC tra_zdf_exp          ! routine called by step.F90

   !! * Substitutions
#  include "domzgr_substitute.h90"
#  include "vectopt_loop_substitute.h90"
   !!----------------------------------------------------------------------
   !!  OPA 9.0 , LOCEAN-IPSL (2005) 
   !! $Header$ 
   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE tra_zdf_exp( kt, p2dt, pavt, ptb , pta   )
      !!----------------------------------------------------------------------
      !!                  ***  ROUTINE tra_zdf_exp  ***
      !!                   
      !! ** Purpose :   Compute the trend due to the vertical tracer mixing 
      !!      using an explicit time stepping and add it to the general trend 
      !!      of the tracer equations.
      !!
      !! ** Method  :   The vertical diffusion of tracers (t & s) is given by:
      !!         difft = dz( avt dz(tb) ) = 1/e3t dk+1( avt/e3w dk(tb) )
      !!      It is evaluated with an Euler scheme, using a time splitting
      !!      technique.
      !!      Surface and bottom boundary conditions: no diffusive flux on
      !!      both tracers (bottom, applied through the masked field avt).
      !!      Add this trend to the general trend ta,sa :
      !!          ta = ta + dz( avt dz(t) )
      !!         (sa = sa + dz( avs dz(t) ) if lk_zdfddm= T)
      !!
      !! ** Action : - Update (ta,sa) with the before vertical diffusion trend
      !!
      !!---------------------------------------------------------------------
      INTEGER , INTENT(in   )                         ::   kt     ! ocean time-step index
      REAL(wp), INTENT(in   ), DIMENSION(jpk)         ::   p2dt   ! vertical profile of tracer time-step
      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pavt   ! eddy diffusivity coef.
      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   ptb    ! before tracer field
      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pta    ! tracer trend 
      !!
      INTEGER  ::   ji, jj, jk, jl             ! dummy loop indices
      REAL(wp) ::   zlavmr, zave3r, ze3tr, zta   !    "         " 
      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zwy
      !!---------------------------------------------------------------------

      IF( kt == nit000 ) THEN
         IF(lwp) WRITE(numout,*)
         IF(lwp) WRITE(numout,*) 'tra_zdf_exp : explicit vertical mixing (j-k-i loops)'
         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
      ENDIF


      ! 0. Local constant initialization
      ! --------------------------------
      zlavmr = 1. / FLOAT( n_zdfexp )

      ! 1. Initializations
      ! ------------------
      zwy(:,:, 1 ) = 0.e0          ! surface : zero diffusive flux
      zwy(:,:,jpk) = 0.e0          ! bottom  : zero diffusive flux
      zwx(:,:,:) = ptb(:,:,:)      ! interior: start from before tracer


      ! 2. Time splitting loop
      ! ----------------------

      DO jl = 1, n_zdfexp
         !
         ! first vertical derivative
         DO jk = 2, jpk
            DO jj = 2, jpjm1
               DO ji = fs_2, fs_jpim1      ! vector opt.
                  zave3r = 1.e0 / fse3w(ji,jj,jk) 
                  zwy(ji,jj,jk) =  pavt(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) * zave3r
               END DO
            END DO
         END DO

         ! trend estimation at kt+l*2*rdt/n_zdfexp
         DO jk = 1, jpkm1
            DO jj = 2, jpjm1
               DO ji = fs_2, fs_jpim1      ! vector opt.
                  ze3tr = zlavmr / fse3t(ji,jj,jk)
                  ! 2nd vertical derivative
                  zta = ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) * ze3tr
                  ! update the tracer trends
                  pta(ji,jj,jk) = pta(ji,jj,jk) + zta
                  ! update tracer fields at kt+l*2*rdt/n_zdfexp
                  zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt(jk) * zta * tmask(ji,jj,jk)
               END DO
            END DO
         END DO
         !
      END DO 
      !
   END SUBROUTINE tra_zdf_exp

   !!==============================================================================
END MODULE trazdf_exp