source: branches/dev_001_GM/NEMO/TOP_SRC/PISCES/p4zdiat.F90 @ 3197

MODULE p4zdiat
   !!======================================================================
   !!                         ***  MODULE p4zdiat  ***
   !! TOP :   PISCES Compute the mortality terms for diatoms
   !!======================================================================
   !! History :   1.0  !  2002     (O. Aumont)  Original code
   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
   !!----------------------------------------------------------------------
#if defined key_pisces
   !!----------------------------------------------------------------------
   !!   'key_pisces'                                       PISCES bio-model
   !!----------------------------------------------------------------------
   !!   p4z_diat       :   Compute the mortality terms for diatoms
   !!----------------------------------------------------------------------
   USE oce_trc         !
   USE trp_trc         ! 
   USE sms             ! 
   USE prtctl_trc

   IMPLICIT NONE
   PRIVATE

   PUBLIC   p4z_diat    ! called in p4zbio.F90

   !!* Substitution
#  include "domzgr_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007) 
   !! $Header:$ 
   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE p4z_diat
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE p4z_diat  ***
      !!
      !! ** Purpose :   Compute the mortality terms for diatoms
      !!
      !! ** Method  : - ???
      !!---------------------------------------------------------------------
      INTEGER  ::  ji, jj, jk
      REAL(wp) ::  zfactfe,zfactsi,zfactch, zstep, zcompadi
      REAL(wp) ::  zrespp2, ztortp2, zmortp2
      CHARACTER (len=25) :: charout
 
      !!---------------------------------------------------------------------

        zstep = rfact2 / rjjss      ! Time step duration for biology


!    Aggregation term for diatoms is increased in case of nutrient
!    stress as observed in reality. The stressed cells become more
!    sticky and coagulate to sink quickly out of the euphotic zone
!     ------------------------------------------------------------

      DO jk = 1, jpkm1
         DO jj = 1, jpj
            DO ji = 1, jpi

               zcompadi = MAX( ( trn(ji,jj,jk,jpdia) - 1e-8), 0. )

!    Aggregation term for diatoms is increased in case of nutrient
!    stress as observed in reality. The stressed cells become more
!    sticky and coagulate to sink quickly out of the euphotic zone
!     ------------------------------------------------------------

               zrespp2  = 1.e6 * zstep * (  wchl + wchld * ( 1.- xlimdia(ji,jj,jk) )  )    &
# if defined key_off_degrad
                  &       * facvol(ji,jj,jk)       &
# endif
                  &       * xdiss(ji,jj,jk) * zcompadi * trn(ji,jj,jk,jpdia)
                                                                               

!     Phytoplankton mortality. 
!     ------------------------
               ztortp2  = mprat2 * zstep * trn(ji,jj,jk,jpdia)     &
# if defined key_off_degrad
                  &        * facvol(ji,jj,jk)       &
# endif
                  &      / ( xkmort + trn(ji,jj,jk,jpdia) ) * zcompadi

                zmortp2 = zrespp2 + ztortp2

!   Update the arrays tra which contains the biological sources and sinks
!   ---------------------------------------------------------------------
               zfactch = trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
               zfactfe = trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn )
               zfactsi = trn(ji,jj,jk,jpbsi) / ( trn(ji,jj,jk,jpdia) + rtrn )

               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zmortp2 * zfactsi
               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zmortp2 * zfactsi
#if defined key_kriest
               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp2  
               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp2 * xkr_ndiat + zrespp2 * xkr_naggr
               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp2 * zfactfe
#else
               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
#endif
            END DO
         END DO
      END DO
      !
        IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
         WRITE(charout, FMT="('diat')")
         CALL prt_ctl_trc_info(charout)
         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
       ENDIF
             
   END SUBROUTINE p4z_diat

#else
   !!======================================================================
   !!  Dummy module :                                   No PISCES bio-model
   !!======================================================================
CONTAINS
   SUBROUTINE p4z_diat                    ! Empty routine
   END SUBROUTINE p4z_diat
#endif 

   !!======================================================================
END MODULE  p4zdiat