source: branches/dev_001_GM/NEMO/TOP_SRC/trclec.F90 @ 768

MODULE trclec
   !!======================================================================
   !!                       ***  MODULE trclec  ***
   !! TOP :   Read and print options for the passive tracer run (namelist)
   !!======================================================================
   !! History :    -   !  1996-11  (M.A. Foujols, M. Levy)  original code
   !!              -   !  1998-04  (M.A Foujols, L. Bopp) ahtrb0 for isopycnal mixing
   !!              -   !  1999-10  (M.A. Foujols, M. Levy) separation of sms
   !!              -   !  2000-07  (A. Estublier) add TVD and MUSCL : Tests on ndttrc
   !!              -   !  2000-11  (M.A Foujols, E Kestenare) trcrat, ahtrc0 and aeivtr0
   !!              -   !  2001-01 (E Kestenare) suppress ndttrc=1 for CEN2 and TVD schemes
   !!             1.0  !  2005-03 (O. Aumont, A. El Moussaoui) F90
   !!----------------------------------------------------------------------
#if defined key_passivetrc
   !!----------------------------------------------------------------------
   !!   'key_passivetrc'                                    Passive tracers
   !!----------------------------------------------------------------------
   !!   trc_lec    :  Read and print options for the passive tracer run (namelist)
   !!----------------------------------------------------------------------
   USE oce_trc
   USE trc
   USE trctrp_lec
   USE trclsm

   IMPLICIT NONE
   PRIVATE 

   PUBLIC trc_lec      ! called in ???

   !! * Substitutions
#  include "passivetrc_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/TOP 1.0 , LOCEAN-IPSL (2005) 
   !! $Header:$ 
   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE trc_lec
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE trc_lec  ***
      !!
      !! ** Purpose :   READ and PRINT options for the passive tracer run (namelist) 
      !!
      !! ** Method  : - read namelist
      !!---------------------------------------------------------------------
      INTEGER ::  ji
      CHARACTER (len=32) ::   clname
      !!
      NAMELIST/nattrc/ nwritetrc, lrsttr, nrsttr, ctrcnm, ctrcnl, ctrcun, lutini     ! general   
      NAMELIST/natnum/ rsc, rtrn, ncortrc, ndttrc, crosster
#if defined key_trc_diatrd
      NAMELIST/natrtd/ luttrd, nwritetrd                                             ! dynamical trends
#endif
#if defined key_trc_diaadd
      NAMELIST/natadd/ ctrc3d, ctrc3l, ctrc2d, ctrc2l, ctrc3u, ctrc2u, nwriteadd     ! additional diagnostics
#endif
      !!---------------------------------------------------------------------

      IF(lwp) WRITE(numout,*)
      IF(lwp) WRITE(numout,*) 'trc_lec : read the passive tracer namelists'
      IF(lwp) WRITE(numout,*) '~~~~~~~'

      clname = 'namelist.passivetrc'
      CALL ctlopn( numnat, clname, 'OLD', 'FORMATTED', 'SEQUENTIAL',   &
         &         1, numout, .FALSE., 1 )


      ! Namelist nattrc (files)
      ! ----------------------------------------------
      nwritetrc = 10                 ! default values
      lrsttr    = .FALSE.
      nrsttr    =  0
      DO ji = 1, jptra
         WRITE(ctrcnm(ji),'("TR_",I1)'           ) ji
         WRITE(ctrcnl(ji),'("TRACER NUMBER ",I1)') ji
         ctrcun(ji) = 'mmole/m3'
         lutini(ji) = .FALSE. 
      END DO

      REWIND( numnat )               ! read nattrc
      READ  ( numnat, nattrc )

      IF(lwp) THEN                   ! control print
         WRITE(numout,*)
         WRITE(numout,*) ' Namelist : nattrc'
         WRITE(numout,*) '    frequency of outputs for passive tracers nwritetrc = ', nwritetrc  
         WRITE(numout,*) '    restart LOGICAL for passive tr. lrsttr = ', lrsttr
         WRITE(numout,*) '    control of time step for p. tr. nrsttr = ', nrsttr
         DO ji = 1, jptra
            WRITE(numout,*) '    tracer nb: ', ji, ' name = ', ctrcnm(ji), ctrcnl(ji), ' in unit = ',ctrcun(ji)
            WRITE(numout,*) '    initial value in FILE : ',lutini(ji) 
         END DO
      ENDIF

#if defined key_trc_diatrd

      ! Namelist natrtd (transport trends)
      ! ----------------------------------------------
      nwritetrd = 10                 ! default values (no dynamical trend recording)
      DO ji = 1, jptra
         luttrd(ji) = .FALSE.
      END DO

      REWIND( numnat )               ! read natrtd
      READ  ( numnat, natrtd )

      nkeep=0
      ikeep(:)=0
      DO ji = 1, jptra
         IF( luttrd(ji) ) THEN 
             nkeep    = nkeep + 1
             ikeep(ji)=nkeep
         END IF 
      END DO
      IF( nkeep > 0 ) THEN  
        IF(.NOT. ALLOCATED( trtrd ) )   ALLOCATE( trtrd(jpi,jpj,jpk,nkeep,jpdiatrc) ) 
        trtrd(:,:,:,:,:) = 0.e0
      ENDIF 

      IF(lwp) THEN                   ! control print
         WRITE(numout,*)
         WRITE(numout,*) ' Namelist : natrtd'
         WRITE(numout,*) '    frequency of outputs for dynamical trends nwritetrd = ', nwritetrd
         DO ji = 1, jptra
            WRITE(numout,*) '    keep dynamical trends for tracer number :', ji, luttrd(ji), ikeep(ji)
         END DO
         WRITE(numout,*) '    total = ', nkeep, ' tracers dyn trends saved'
         WRITE(numout,*) '    size of trtrd = ', jpi*jpj*jpk*nkeep*jpdiatrc
      ENDIF
#endif

#if defined key_trc_diaadd

      ! Namelist natrtd (transport trends)
      ! ----------------------------------------------
      nwriteadd = 10                 ! default values 
      !                                 ! 3D output arrays
      DO ji = 1, jpdia3d
         WRITE(ctrc3d(ji),'("3D_",I1)') ji                      ! short name
         WRITE(ctrc3l(ji),'("3D DIAGNOSTIC NUMBER ",I2)') ji    ! long name
         ctrc3u(ji) = ' '                                       ! units 
      END DO
      !                                 ! 2D output arrays
      DO ji = 1, jpdia2d
         WRITE(ctrc2d(ji),'("2D_",I1)') ji                      ! short name
         WRITE(ctrc2l(ji),'("2D DIAGNOSTIC NUMBER ",I2)') ji    ! long name
         ctrc2u(ji) = ' '                                       ! units
      END DO

      REWIND( numnat )               ! read natrtd
      READ  ( numnat, natadd )

      IF(lwp) THEN                   ! control print
         WRITE(numout,*)
         WRITE(numout,*) ' Namelist : natadd'
         WRITE(numout,*) '    frequency of outputs for additional arrays nwriteadd = ', nwriteadd
         DO ji = 1, jpdia3d
            WRITE(numout,*) '    3d output field No :',ji,' names ',ctrc3d(ji), ctrc3l(ji), ' in ', ctrc3u(ji)
         END DO
         DO ji = 1, jpdia2d
            WRITE(numout,*) '    2d output field No :',ji,' names ',ctrc2d(ji), ctrc2l(ji), ' in ', ctrc2u(ji)
         END DO
      ENDIF
#endif

      !! Namelist natnum :
      !! -----------------
      rsc      = 1.                 ! default values
      rtrn     = 1.e-15
      ncortrc  = 1
      ndttrc   = 4
      crosster = .FALSE.

      REWIND( numnat )              ! read natnum
      READ  ( numnat, natnum )

      !!Chris  computes the first time step of tracer model
      nittrc000 = nit000 + ndttrc - 1

      IF(lwp) THEN                  ! control print
         WRITE(numout,*)
         WRITE(numout,*) ' Namelist : natnum'
         WRITE(numout,*)
         WRITE(numout,*) ' tuning coefficient              rsc     = ', rsc
         WRITE(numout,*) ' truncation value                rtrn    = ', rtrn
         WRITE(numout,*) ' number of corrective phase      ncortrc = ', ncortrc
         WRITE(numout,*) ' time step freq. for pass. trac. ndttrc  = ', ndttrc
         WRITE(numout,*) ' 1st time step for pass. trac. nittrc000 = ', nittrc000
         WRITE(numout,*) ' computes or not crossterms    crosster  = ', crosster
      ENDIF

      ! namelist of transport
      ! ---------------------
      CALL trc_trp_lec

      ! namelist of SMS
      ! ---------------      
      CALL trc_lsm
      !
   END SUBROUTINE trc_lec

#else
   !!----------------------------------------------------------------------
   !!  Dummy module :                                     No passive tracer
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE trc_lec                      ! Empty routine   
   END SUBROUTINE trc_lec
#endif

   !!======================================================================
END MODULE  trclec