New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

iom_ioipsl.F90 in branches/dev_001_SBC/NEMO/OPA_SRC/IOM – NEMO

Context Navigation

source: branches/dev_001_SBC/NEMO/OPA_SRC/IOM/iom_ioipsl.F90 @ 761

Last change on this file since 761 was 761, checked in by ctlod, 16 years ago
phasing IOM directory with the trunk, to get changeset 741, 742, 745, 752
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 23.3 KB

Line
1	MODULE iom_ioipsl
2	!!=====================================================================
3	!! * MODULE iom_ioipsl *
4	!! Input/Output manager : Library to read input files with IOIPSL (only fliocom module)
5	!!====================================================================
6	!! History : 9.0 ! 05 12 (J. Belier) Original code
7	!! 9.0 ! 06 02 (S. Masson) Adaptation to NEMO
8	!!--------------------------------------------------------------------
9	!!gm caution add !DIR nec: improved performance to be checked as well as no result changes
10
11	!!--------------------------------------------------------------------
12	!! iom_open : open a file read only
13	!! iom_close : close a file or all files opened by iom
14	!! iom_get : read a field (interfaced to several routines)
15	!! iom_gettime : read the time axis kvid in the file
16	!! iom_varid : get the id of a variable in a file
17	!! iom_rstput : write a field in a restart file (interfaced to several routines)
18	!!--------------------------------------------------------------------
19	USE in_out_manager ! I/O manager
20	USE dom_oce ! ocean space and time domain
21	USE iom_def ! iom variables definitions
22	USE ioipsl ! IOIPSL library
23
24	IMPLICIT NONE
25	PRIVATE
26
27	PUBLIC iom_ioipsl_open, iom_ioipsl_close, iom_ioipsl_varid, iom_ioipsl_get, iom_ioipsl_gettime, iom_ioipsl_rstput
28
29	INTERFACE iom_ioipsl_get
30	MODULE PROCEDURE iom_ioipsl_g0d, iom_ioipsl_g123d
31	END INTERFACE
32	INTERFACE iom_ioipsl_rstput
33	MODULE PROCEDURE iom_ioipsl_rp0123d
34	END INTERFACE
35	!!----------------------------------------------------------------------
36	!! OPA 9.0 , LOCEAN-IPSL (2006)
37	!! $Header: /home/opalod/NEMOCVSROOT/NEMO/OPA_SRC/IOM/iom_ioipsl.F90,v 1.8 2007/06/29 14:10:50 opalod Exp $
38	!! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39	!!----------------------------------------------------------------------
40
41	CONTAINS
42
43	SUBROUTINE iom_ioipsl_open( cdname, kiomid, ldwrt, ldok, kdompar )
44	!!---------------------------------------------------------------------
45	!! * SUBROUTINE iom_open *
46	!!
47	!! ** Purpose : open an input file with IOIPSL (only fliocom module)
48	!!---------------------------------------------------------------------
49	CHARACTER(len=*) , INTENT(inout) :: cdname ! File name
50	INTEGER , INTENT( out) :: kiomid ! ioipsl identifier of the opened file
51	LOGICAL , INTENT(in ) :: ldwrt ! read or write the file?
52	LOGICAL , INTENT(in ) :: ldok ! check the existence
53	INTEGER, DIMENSION(2,5), INTENT(in ), OPTIONAL :: kdompar ! domain parameters:
54
55	CHARACTER(LEN=100) :: clinfo ! info character
56	INTEGER :: iln ! lengths of character
57	INTEGER :: istop ! temporary storage of nstop
58	INTEGER :: ifliodom ! model domain identifier (see flio_dom_set)
59	INTEGER :: ioipslid ! ioipsl identifier of the opened file
60	INTEGER :: jl ! loop variable
61	!---------------------------------------------------------------------
62
63	clinfo = ' iom_ioipsl_open ~~~ '
64	istop = nstop
65	!
66	IF( ldok ) THEN ! Open existing file...
67	! ! =============
68	IF( ldwrt ) THEN ! ... in write mode
69	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
70	CALL flioopfd( TRIM(cdname), ioipslid, "WRITE" )
71	ELSE ! ... in read mode
72	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
73	CALL flioopfd( TRIM(cdname), ioipslid )
74	ENDIF
75	ELSE ! the file does not exist
76	! ! =============
77	iln = INDEX( cdname, '.nc' )
78	IF( ldwrt ) THEN ! the file should be open in write mode so we create it...
79	IF( jpnij > 1 ) THEN
80	! define the domain position regarding to the global domain (mainly useful in mpp)
81	CALL flio_dom_set( jpnij, narea-1, (/1, 2/), (/jpiglo, jpjglo/) &
82	& , kdompar(:,1), kdompar(:,2), kdompar(:,3), kdompar(:,4), kdompar(:,5) &
83	& , 'BOX', ifliodom )
84	! Note that fliocrfd may change the value of cdname (add the cpu number...)
85	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname(1:iln-1)//'... in WRITE mode'
86	CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) &
87	& , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, ifliodom )
88	ELSE ! the file should be open for read mode so it must exist...
89	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname//' in WRITE mode'
90	CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) &
91	& , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid )
92	ENDIF
93	ELSE ! the file should be open for read mode so it must exist...
94	CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
95	ENDIF
96	ENDIF
97	! start to fill file informations
98	! =============
99	IF( istop == nstop ) THEN ! no error within this routine
100	!does not work with some compilers kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
101	kiomid = 0
102	DO jl = jpmax_files, 1, -1
103	IF( iom_file(jl)%nfid == 0 ) kiomid = jl
104	ENDDO
105	iom_file(kiomid)%name = TRIM(cdname)
106	iom_file(kiomid)%nfid = ioipslid
107	iom_file(kiomid)%iolib = jpioipsl
108	iom_file(kiomid)%nvars = 0
109	iom_file(kiomid)%irec = -1 ! useless for NetCDF files
110	CALL flioinqf( ioipslid, id_uld = iom_file(kiomid)%iduld )
111	IF(lwp) WRITE(numout,*) ' ---> '//TRIM(cdname)//' OK'
112	ELSE
113	kiomid = 0 ! return error flag
114	ENDIF
115	!
116	END SUBROUTINE iom_ioipsl_open
117
118
119	SUBROUTINE iom_ioipsl_close( kiomid )
120	!!--------------------------------------------------------------------
121	!! * SUBROUTINE iom_ioipsl_close *
122	!!
123	!! ** Purpose : close an input file with IOIPSL (only fliocom module)
124	!!--------------------------------------------------------------------
125	INTEGER, INTENT(in) :: kiomid ! iom identifier of the file to be closed
126	!---------------------------------------------------------------------
127	!
128	CALL flioclo( iom_file(kiomid)%nfid )
129	!
130	END SUBROUTINE iom_ioipsl_close
131
132
133	FUNCTION iom_ioipsl_varid ( kiomid, cdvar, kiv, kdimsz )
134	!!-----------------------------------------------------------------------
135	!! * FUNCTION iom_varid *
136	!!
137	!! ** Purpose : get the id of a variable in a file with IOIPSL (only fliocom module)
138	!!-----------------------------------------------------------------------
139	INTEGER , INTENT(in ) :: kiomid ! file Identifier
140	CHARACTER(len=*) , INTENT(in ) :: cdvar ! name of the variable
141	INTEGER , INTENT(in ) :: kiv !
142	INTEGER, DIMENSION(:), INTENT( out), OPTIONAL :: kdimsz ! size of the dimensions
143	!
144	INTEGER :: iom_ioipsl_varid ! iom variable Id
145	INTEGER :: ioipslid ! ioipsl file identifier
146	INTEGER :: ji ! dummy loop index
147	INTEGER :: i_nvd ! number of dimension of the variable
148	INTEGER, DIMENSION(jpmax_dims) :: idimid ! dimension ids of the variable
149	LOGICAL :: ll_fnd ! found test
150	CHARACTER(LEN=100) :: clinfo ! info character
151	!!-----------------------------------------------------------------------
152	clinfo = 'iom_ioipsl_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
153	iom_ioipsl_varid = 0 ! default definition
154	IF( PRESENT(kdimsz) ) kdimsz(:) = 0 ! default definition
155	ioipslid = iom_file(kiomid)%nfid ! get back ioipsl file identifier
156	CALL flioinqv( ioipslid, cdvar, ll_fnd, nb_dims = i_nvd ) ! does the variable exist in the file
157	IF( ll_fnd ) THEN
158	IF( i_nvd <= jpmax_dims ) THEN
159	iom_ioipsl_varid = kiv
160	iom_file(kiomid)%nvars = kiv
161	iom_file(kiomid)%nvid(kiv) = -1 ! variable id is not available in ioipsl
162	iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
163	iom_file(kiomid)%ndims(kiv) = i_nvd
164	CALL flioinqv( ioipslid, cdvar, ll_fnd, &
165	& len_dims = iom_file(kiomid)%dimsz(1:i_nvd,kiv), & ! dimensions size
166	& id_dims = idimid(1:i_nvd) ) ! dimensions ids
167	iom_file(kiomid)%luld(kiv) = .FALSE. ! default value
168	DO ji = 1, i_nvd ! find the unlimited dimension
169	IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.
170	END DO
171	!---------- Deal with scale_factor and add_offset
172	CALL flioinqa( ioipslid, cdvar, 'scale_factor', ll_fnd )
173	IF( ll_fnd) THEN
174	CALL fliogeta( ioipslid, cdvar, 'scale_factor', iom_file(kiomid)%scf(kiv) )
175	ELSE
176	iom_file(kiomid)%scf(kiv) = 1.
177	END IF
178	CALL flioinqa( ioipslid, cdvar, 'add_offset', ll_fnd )
179	IF( ll_fnd ) THEN
180	CALL fliogeta( ioipslid, cdvar, 'add_offset', iom_file(kiomid)%ofs(kiv) )
181	ELSE
182	iom_file(kiomid)%ofs(kiv) = 0.
183	END IF
184	! return the simension size
185	IF( PRESENT(kdimsz) ) THEN
186	IF( i_nvd == SIZE(kdimsz) ) THEN
187	kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
188	ELSE
189	WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
190	CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
191	ENDIF
192	ENDIF
193	ELSE
194	CALL ctl_stop( TRIM(clinfo), 'Too many dimensions in the file '//iom_file(kiomid)%name, &
195	& 'increase the parameter jpmax_vars')
196	ENDIF
197	ELSE
198	iom_ioipsl_varid = -1 ! variable not found, return error code: -1
199	ENDIF
200	!
201	END FUNCTION iom_ioipsl_varid
202
203
204	SUBROUTINE iom_ioipsl_g0d( kiomid, kvid, pvar )
205	!!-----------------------------------------------------------------------
206	!! * ROUTINE iom_ioipsl_g0d *
207	!!
208	!! ** Purpose : read a scalar with IOIPSL (only fliocom module)
209	!!-----------------------------------------------------------------------
210	INTEGER , INTENT(in ) :: kiomid ! Identifier of the file
211	INTEGER , INTENT(in ) :: kvid ! variable id
212	REAL(wp), INTENT( out) :: pvar ! read field
213	!
214	CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), pvar )
215	!
216	END SUBROUTINE iom_ioipsl_g0d
217
218
219	SUBROUTINE iom_ioipsl_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2, &
220	& pv_r1d, pv_r2d, pv_r3d)
221	!!-----------------------------------------------------------------------
222	!! * ROUTINE iom_ioipsl_g123d *
223	!!
224	!! ** Purpose : read a 1D/2D/3D variable with IOIPSL (only fliocom module)
225	!!
226	!! ** Method : read ONE record at each CALL
227	!!-----------------------------------------------------------------------
228	INTEGER , INTENT(in ) :: kiomid ! iom identifier of the file
229	INTEGER , INTENT(in ) :: kvid ! Name of the variable
230	INTEGER , INTENT(in ) :: knbdim ! number of dimensions of the variable
231	INTEGER , DIMENSION(:) , INTENT(in ) :: kstart ! start position of the reading in each axis
232	INTEGER , DIMENSION(:) , INTENT(in ) :: kcount ! number of points to be read in each axis
233	INTEGER , INTENT(in ) :: kx1, kx2, ky1, ky2 ! subdomain indexes
234	REAL(wp), DIMENSION(:) , INTENT( out), OPTIONAL :: pv_r1d ! read field (1D case)
235	REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pv_r2d ! read field (2D case)
236	REAL(wp), DIMENSION(:,:,:) , INTENT( out), OPTIONAL :: pv_r3d ! read field (3D case)
237	!
238	INTEGER :: ioipslid ! ioipsl file identifier
239	CHARACTER(LEN=100) :: clvn ! variable name
240	!---------------------------------------------------------------------
241	clvn = TRIM(iom_file(kiomid)%cn_var(kvid)) ! get back variable name
242	ioipslid = iom_file(kiomid)%nfid ! get back IPIPSL file id
243	!
244	IF( PRESENT(pv_r1d) ) THEN
245	CALL fliogetv( ioipslid, clvn, pv_r1d(: ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
246	ELSEIF( PRESENT(pv_r2d) ) THEN
247	CALL fliogetv( ioipslid, clvn, pv_r2d(kx1:kx2,ky1:ky2 ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
248	ELSEIF( PRESENT(pv_r3d) ) THEN
249	CALL fliogetv( ioipslid, clvn, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), count = kcount(1:knbdim) )
250	ENDIF
251	!
252	!
253	END SUBROUTINE iom_ioipsl_g123d
254
255
256	SUBROUTINE iom_ioipsl_gettime( kiomid, kvid, ptime )
257	!!--------------------------------------------------------------------
258	!! * SUBROUTINE iom_gettime *
259	!!
260	!! ** Purpose : read the time axis kvid in the file with IOIPSL (only fliocom module)
261	!!--------------------------------------------------------------------
262	INTEGER , INTENT(in ) :: kiomid ! file Identifier
263	INTEGER , INTENT(in ) :: kvid ! variable id
264	REAL(wp), DIMENSION(:), INTENT( out) :: ptime ! the time axis
265	!---------------------------------------------------------------------
266	!
267	CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), ptime(:), &
268	& start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /) )
269	!
270	END SUBROUTINE iom_ioipsl_gettime
271
272
273	SUBROUTINE iom_ioipsl_rp0123d( kt, kwrite, kiomid, cdvar , kvid , ktype, &
274	& pv_r0d, pv_r1d, pv_r2d, pv_r3d )
275	!!--------------------------------------------------------------------
276	!! * SUBROUTINE iom_ioipsl_rstput *
277	!!
278	!! ** Purpose : read the time axis cdvar in the file
279	!!--------------------------------------------------------------------
280	INTEGER , INTENT(in) :: kt ! ocean time-step
281	INTEGER , INTENT(in) :: kwrite ! writing time-step
282	INTEGER , INTENT(in) :: kiomid ! Identifier of the file
283	CHARACTER(len=*) , INTENT(in) :: cdvar ! variable name
284	INTEGER , INTENT(in) :: kvid ! variable id
285	INTEGER , INTENT(in), OPTIONAL :: ktype ! variable type (default R8)
286	REAL(wp) , INTENT(in), OPTIONAL :: pv_r0d ! written Od field
287	REAL(wp), DIMENSION( jpk), INTENT(in), OPTIONAL :: pv_r1d ! written 1d field
288	REAL(wp), DIMENSION(jpi,jpj ), INTENT(in), OPTIONAL :: pv_r2d ! written 2d field
289	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL :: pv_r3d ! written 3d field
290	!
291	INTEGER :: idims ! number of dimension
292	INTEGER :: idvar ! variable id
293	INTEGER :: itype ! variable type
294	INTEGER :: ix1, ix2, iy1, iy2 ! subdomain indexes
295	INTEGER, DIMENSION(4) :: idimsz ! dimensions size
296	INTEGER, DIMENSION(4) :: idimid ! dimensions id
297	CHARACTER(LEN=100) :: clinfo ! info character
298	INTEGER :: ioipslid ! ioipsl file identifier
299	!---------------------------------------------------------------------
300	!
301	clinfo = ' iom_ioipsl_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
302	ioipslid = iom_file(kiomid)%nfid
303	!
304	! define dimension variables if it is not already done
305	! ==========================
306	IF( iom_file(kiomid)%nvars == 0 ) THEN
307	! define the dimension variables if it is not already done
308	CALL fliodefv( ioipslid,'nav_lon', (/1,2/), v_t=flio_r4 , axis='X', &
309	& long_name="Longitude", units="degrees_east" )
310	CALL fliodefv( ioipslid,'nav_lat', (/1,2/), v_t=flio_r4 , axis='Y', &
311	& long_name="Latitude", units="degrees_north" )
312	CALL fliodefv( ioipslid,'nav_lev', (/3/) , v_t=flio_i4 , axis='Z', &
313	& long_name="Model levels",units="model_levels")
314	CALL fliodefv( ioipslid,'time_counter', (/4/), v_t=flio_r4, axis='T', &
315	& long_name="Time axis", units='seconds since 0001-01-01 00:00:00' )
316	! update informations structure related the dimension variable we just added...
317	iom_file(kiomid)%nvars = 4
318	iom_file(kiomid)%luld(1:4) = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
319	iom_file(kiomid)%cn_var(1:3) = (/ 'nav_lon', 'nav_lat', 'nav_lev' /)
320	iom_file(kiomid)%cn_var(4) = 'time_counter'
321	iom_file(kiomid)%ndims(1:4) = (/ 2, 2, 1, 1 /)
322	! trick: defined to 0 to say that dimension variables are defined but not yet written
323	iom_file(kiomid)%dimsz(1, 1) = 0
324	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
325	ENDIF
326
327	! define the data if it is not already done
328	! ===============
329	IF( kvid <= 0 ) THEN
330	! variable definition
331	IF( PRESENT(pv_r0d) ) THEN ; idims = 0
332	ELSEIF( PRESENT(pv_r1d) ) THEN ; idims = 2 ; idimid(1:idims) = (/ 3,4/)
333	ELSEIF( PRESENT(pv_r2d) ) THEN ; idims = 3 ; idimid(1:idims) = (/1,2 ,4/)
334	ELSEIF( PRESENT(pv_r3d) ) THEN ; idims = 4 ; idimid(1:idims) = (/1,2,3,4/)
335	ENDIF
336	IF( PRESENT(ktype) ) THEN ! variable external type
337	SELECT CASE (ktype)
338	CASE (jp_r8) ; itype = flio_r8
339	CASE (jp_r4) ; itype = flio_r4
340	CASE (jp_i4) ; itype = flio_i4
341	CASE (jp_i2) ; itype = flio_i2
342	CASE (jp_i1) ; itype = flio_i1 ! fliocom does not handle i1 type of variable
343	CASE DEFAULT ; CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
344	END SELECT
345	ELSE
346	itype = flio_r8
347	ENDIF
348	IF( PRESENT(pv_r0d) ) THEN ; CALL fliodefv (ioipslid, TRIM(cdvar) , v_t = itype)
349	ELSE ; CALL fliodefv (ioipslid, TRIM(cdvar), idimid(1:idims), v_t = itype)
350	ENDIF
351	! update informations structure related the new variable we want to add...
352	idvar = iom_file(kiomid)%nvars + 1
353	iom_file(kiomid)%nvars = idvar
354	iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
355	iom_file(kiomid)%nvid(idvar) = -1 ! netcdf variable id is not available in ioipsl
356	iom_file(kiomid)%scf(idvar) = 1.
357	iom_file(kiomid)%ofs(idvar) = 0.
358	iom_file(kiomid)%ndims(idvar) = idims
359	IF( .NOT. PRESENT(pv_r0d) ) THEN
360	iom_file(kiomid)%luld(idvar) = .TRUE.
361	CALL flioinqf( ioipslid, ln_dim = idimsz )
362	iom_file(kiomid)%dimsz(1:idims-1,idvar) = idimsz(idimid(1:idims-1))
363	ELSE
364	iom_file(kiomid)%luld(idvar) = .FALSE.
365	ENDIF
366	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
367	ELSE
368	idvar = kvid
369	ENDIF
370
371	! time step kwrite : write the variable
372	IF( kt == kwrite ) THEN
373	! on what kind of domain must the data be written?
374	IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
375	idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
376	IF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
377	ix1 = nldi ; ix2 = nlei ; iy1 = nldj ; iy2 = nlej
378	ELSEIF( idimsz(1) == nlci .AND. idimsz(2) == nlcj ) THEN
379	ix1 = 1 ; ix2 = nlci ; iy1 = 1 ; iy2 = nlcj
380	ELSEIF( idimsz(1) == jpi .AND. idimsz(2) == jpj ) THEN
381	ix1 = 1 ; ix2 = jpi ; iy1 = 1 ; iy2 = jpj
382	ELSE
383	CALL ctl_stop( 'iom_ioipsl_rp0123d: should have been an impossible case...' )
384	ENDIF
385
386	! write dimension variables if it is not already done
387	! =============
388	! trick: is defined to 0 => dimension variable are defined but not yet written
389	IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
390	CALL flioputv( ioipslid, 'nav_lon' , glamt(ix1:ix2, iy1:iy2) )
391	CALL flioputv( ioipslid, 'nav_lat' , gphit(ix1:ix2, iy1:iy2) )
392	CALL flioputv( ioipslid, 'nav_lev' , gdept_0 )
393	! +++ WRONG VALUE: to be improved but not really useful...
394	CALL flioputv( ioipslid, 'time_counter', kt )
395	! update the values of the variables dimensions size
396	CALL flioinqf( ioipslid, ln_dim = idimsz )
397	iom_file(kiomid)%dimsz(1:2, 1) = idimsz(1:2)
398	iom_file(kiomid)%dimsz(1:2, 2) = idimsz(1:2)
399	iom_file(kiomid)%dimsz(1, 3:4) = (/idimsz(3), 1/)
400	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
401	ENDIF
402	ENDIF
403
404	! write the data
405	! =============
406	IF( PRESENT(pv_r0d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r0d )
407	ELSEIF( PRESENT(pv_r1d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r1d( :) )
408	ELSEIF( PRESENT(pv_r2d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r2d(ix1:ix2, iy1:iy2 ) )
409	ELSEIF( PRESENT(pv_r3d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r3d(ix1:ix2, iy1:iy2, :) )
410	ENDIF
411	! add 1 to the size of the temporal dimension (not really useful...)
412	IF( iom_file(kiomid)%luld(idvar) ) iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) &
413	& = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
414	IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
415	ENDIF
416	!
417	END SUBROUTINE iom_ioipsl_rp0123d
418
419
420	!!======================================================================
421	END MODULE iom_ioipsl

Note: See TracBrowser for help on using the repository browser.

Download in other formats: