1 | MODULE iom_rstdimg |
---|
2 | !!===================================================================== |
---|
3 | !! *** MODULE iom_rstdimg *** |
---|
4 | !! Input/Output manager : Library to read input rstdimg files |
---|
5 | !!==================================================================== |
---|
6 | !! History : 9.0 ! 06 09 (S. Masson) Original code |
---|
7 | !!-------------------------------------------------------------------- |
---|
8 | |
---|
9 | !!-------------------------------------------------------------------- |
---|
10 | !! iom_open : open a file read only |
---|
11 | !! iom_close : close a file or all files opened by iom |
---|
12 | !! iom_get : read a field (interfaced to several routines) |
---|
13 | !! iom_gettime : read the time axis kvid in the file |
---|
14 | !! iom_varid : get the id of a variable in a file |
---|
15 | !! iom_rstput : write a field in a restart file (interfaced to several routines) |
---|
16 | !!-------------------------------------------------------------------- |
---|
17 | USE in_out_manager ! I/O manager |
---|
18 | USE dom_oce ! ocean space and time domain |
---|
19 | USE lbclnk ! lateal boundary condition / mpp exchanges |
---|
20 | USE iom_def ! iom variables definitions |
---|
21 | |
---|
22 | IMPLICIT NONE |
---|
23 | PRIVATE |
---|
24 | |
---|
25 | PUBLIC iom_rstdimg_open, iom_rstdimg_close, iom_rstdimg_get, iom_rstdimg_rstput |
---|
26 | |
---|
27 | INTERFACE iom_rstdimg_get |
---|
28 | MODULE PROCEDURE iom_rstdimg_g0d, iom_rstdimg_g123d |
---|
29 | END INTERFACE |
---|
30 | INTERFACE iom_rstdimg_rstput |
---|
31 | MODULE PROCEDURE iom_rstdimg_rp0d, iom_rstdimg_rp123d |
---|
32 | END INTERFACE |
---|
33 | |
---|
34 | INTEGER, PARAMETER :: jpvnl = 32 ! variable name length |
---|
35 | |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! OPA 9.0 , LOCEAN-IPSL (2006) |
---|
38 | !! $Id$ |
---|
39 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | |
---|
42 | CONTAINS |
---|
43 | |
---|
44 | SUBROUTINE iom_rstdimg_open( cdname, kiomid, ldwrt, ldok, kdompar ) |
---|
45 | !!--------------------------------------------------------------------- |
---|
46 | !! *** SUBROUTINE iom_open *** |
---|
47 | !! |
---|
48 | !! ** Purpose : open an input file read only (return 0 if not found) |
---|
49 | !!--------------------------------------------------------------------- |
---|
50 | CHARACTER(len=*) , INTENT(inout) :: cdname ! File name |
---|
51 | INTEGER , INTENT( out) :: kiomid ! iom identifier of the opened file |
---|
52 | LOGICAL , INTENT(in ) :: ldwrt ! read or write the file? |
---|
53 | LOGICAL , INTENT(in ) :: ldok ! check the existence |
---|
54 | INTEGER, DIMENSION(2,5), INTENT(in ), OPTIONAL :: kdompar ! domain parameters: |
---|
55 | |
---|
56 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
57 | CHARACTER(LEN=100) :: cltmp ! temporary character |
---|
58 | CHARACTER(LEN=10 ) :: clstatus ! status of opened file (REPLACE or NEW) |
---|
59 | INTEGER :: jv ! loop counter |
---|
60 | INTEGER :: istop ! temporary storage of nstop |
---|
61 | INTEGER :: idrst ! logical unit of the restart file |
---|
62 | INTEGER :: iln ! lengths of character |
---|
63 | INTEGER :: irecl8 ! record length |
---|
64 | INTEGER :: ios ! IO status |
---|
65 | INTEGER :: irhd ! record of the header infos |
---|
66 | INTEGER :: ivnum ! number of variables |
---|
67 | INTEGER :: ishft ! counter shift |
---|
68 | INTEGER :: inx, iny, inz ! x,y,z dimension of the variable |
---|
69 | INTEGER :: in0d, in1d, in2d, in3d ! number of 0/1/2/3D variables |
---|
70 | INTEGER :: ipni, ipnj, ipnij, iarea ! domain decomposition |
---|
71 | INTEGER :: iiglo, ijglo ! domain global size |
---|
72 | INTEGER :: jl ! loop variable |
---|
73 | LOGICAL :: llclobber ! local definition of ln_clobber |
---|
74 | CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) :: clna0d, clna1d, clna2d, clna3d ! name of 0/1/2/3D variables |
---|
75 | REAL(wp), DIMENSION(jpmax_vars) :: zval0d, zval1d, zval2d, zval3d ! value of 0d variables or record |
---|
76 | ! ! position for 1/2/3D variables |
---|
77 | !--------------------------------------------------------------------- |
---|
78 | clinfo = ' iom_rstdimg_open ~~~ ' |
---|
79 | istop = nstop ! store the actual value of nstop |
---|
80 | ios = 0 ! default definition |
---|
81 | kiomid = 0 ! default definition |
---|
82 | llclobber = ldwrt .AND. ln_clobber |
---|
83 | ! get a free unit |
---|
84 | idrst = getunit() ! get a free logical unit for the restart file |
---|
85 | !!$#if defined key_agrif |
---|
86 | !!$ idrst = Agrif_Get_Unit() |
---|
87 | !!$#endif |
---|
88 | ! Open the file... |
---|
89 | ! ============= |
---|
90 | IF( ldok .AND. .NOT. llclobber ) THEN ! Open existing file... |
---|
91 | ! find the record length |
---|
92 | OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct' & |
---|
93 | & , RECL = 8, STATUS = 'old', ACTION = 'read', IOSTAT = ios, ERR = 987 ) |
---|
94 | READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8 |
---|
95 | CLOSE( idrst ) |
---|
96 | ! Open the file with the appropriate record length and parameters |
---|
97 | IF( ldwrt ) THEN ! ... in readwrite mode |
---|
98 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READWRITE mode' |
---|
99 | OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct' & |
---|
100 | & , RECL = irecl8, STATUS = 'old', ACTION = 'readwrite', IOSTAT = ios, ERR = 987 ) |
---|
101 | ELSE ! ... in read mode |
---|
102 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode' |
---|
103 | OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct' & |
---|
104 | & , RECL = irecl8, STATUS = 'old', ACTION = 'read' , IOSTAT = ios, ERR = 987 ) |
---|
105 | ENDIF |
---|
106 | ELSE ! the file does not exist (or we overwrite it) |
---|
107 | iln = INDEX( cdname, '.dimg' ) |
---|
108 | IF( ldwrt ) THEN ! the file should be open in readwrite mode so we create it... |
---|
109 | irecl8= MAX( kdompar(1,1) * kdompar(2,1) * wp, ( 8*jpnij + 15 ) * 4 ) |
---|
110 | IF( jpnij > 1 ) THEN |
---|
111 | WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea, '.dimg' |
---|
112 | cdname = TRIM(cltmp) |
---|
113 | ENDIF |
---|
114 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in READWRITE mode' |
---|
115 | |
---|
116 | IF( llclobber ) THEN ; clstatus = 'REPLACE' |
---|
117 | ELSE ; clstatus = 'NEW' |
---|
118 | ENDIF |
---|
119 | OPEN( idrst, FILE = TRIM(cdname), FORM = 'UNFORMATTED', ACCESS = 'DIRECT' & |
---|
120 | & , RECL = irecl8, STATUS = TRIM(clstatus), ACTION = 'readwrite', IOSTAT = ios, ERR = 987 ) |
---|
121 | ELSE ! the file should be open for read mode so it must exist... |
---|
122 | CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' ) |
---|
123 | ENDIF |
---|
124 | ENDIF |
---|
125 | ! Performs checks on the file |
---|
126 | ! ============= |
---|
127 | IF( ldok .AND. .NOT. llclobber ) THEN ! old file |
---|
128 | READ( idrst, REC = 1 , IOSTAT = ios, ERR = 987 ) & |
---|
129 | & irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd, & |
---|
130 | & ipni, ipnj, ipnij, iarea, iiglo, ijglo |
---|
131 | READ( idrst, REC = irhd, IOSTAT = ios, ERR = 987 ) & |
---|
132 | & clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d), & |
---|
133 | & clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d) |
---|
134 | clinfo = TRIM(clinfo)//' file '//TRIM(cdname) |
---|
135 | IF( iiglo /= jpiglo ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in global domain size in i direction' ) |
---|
136 | IF( ijglo /= jpjglo ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in global domain size in j direction' ) |
---|
137 | IF( ldwrt ) THEN |
---|
138 | IF( inx /= kdompar(1,1) ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in local domain size in i direction' ) |
---|
139 | IF( iny /= kdompar(2,1) ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in local domain size in j direction' ) |
---|
140 | ENDIF |
---|
141 | IF( inz /= jpk ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in domain size in k direction' ) |
---|
142 | IF( ipni /= jpni ) CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along I' ) |
---|
143 | IF( ipnj /= jpnj ) CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along J' ) |
---|
144 | IF( ipnij /= jpnij ) CALL ctl_stop( TRIM(clinfo), 'Total number of processors changed' ) |
---|
145 | IF( iarea /= narea ) CALL ctl_stop( TRIM(clinfo), 'Mismatch in area numbering ...' ) |
---|
146 | ENDIF |
---|
147 | ! fill file informations |
---|
148 | ! ============= |
---|
149 | IF( istop == nstop ) THEN ! no error within this routine |
---|
150 | !does not work with some compilers kiomid = MINLOC(iom_file(:)%nfid, dim = 1) |
---|
151 | kiomid = 0 |
---|
152 | DO jl = jpmax_files, 1, -1 |
---|
153 | IF( iom_file(jl)%nfid == 0 ) kiomid = jl |
---|
154 | ENDDO |
---|
155 | iom_file(kiomid)%name = TRIM(cdname) |
---|
156 | iom_file(kiomid)%nfid = idrst |
---|
157 | iom_file(kiomid)%iolib = jprstdimg |
---|
158 | iom_file(kiomid)%iduld = -1 |
---|
159 | IF( ldok ) THEN ! old file |
---|
160 | ! read variables informations from the file header |
---|
161 | IF( TRIM(clna0d(1)) == 'no0d' ) in0d = 0 |
---|
162 | IF( TRIM(clna1d(1)) == 'no1d' ) in1d = 0 |
---|
163 | IF( TRIM(clna2d(1)) == 'no2d' ) in2d = 0 |
---|
164 | IF( TRIM(clna3d(1)) == 'no3d' ) in3d = 0 |
---|
165 | ivnum = in0d + in1d + in2d + in3d |
---|
166 | iom_file(kiomid)%nvars = ivnum |
---|
167 | iom_file(kiomid)%irec = 2 + in1d + in2d + inz * in3d |
---|
168 | iom_file(kiomid)%luld( 1:ivnum) = .FALSE. |
---|
169 | iom_file(kiomid)%scf( 1:ivnum) = 1. |
---|
170 | ! scalar variable |
---|
171 | DO jv = 1, in0d |
---|
172 | iom_file(kiomid)%cn_var(jv) = TRIM(clna0d(jv)) |
---|
173 | iom_file(kiomid)%nvid( jv) = 1 |
---|
174 | iom_file(kiomid)%ndims( jv) = 0 |
---|
175 | iom_file(kiomid)%ofs( jv) = zval0d(jv) ! warning: trick... we use ofs to store the value |
---|
176 | END DO |
---|
177 | ! 1d variable |
---|
178 | ishft = in0d |
---|
179 | DO jv = 1, in1d |
---|
180 | iom_file(kiomid)%cn_var( ishft + jv) = TRIM(clna1d(jv)) |
---|
181 | iom_file(kiomid)%nvid( ishft + jv) = zval1d(jv) |
---|
182 | iom_file(kiomid)%ndims( ishft + jv) = 1 |
---|
183 | iom_file(kiomid)%dimsz(1 , ishft + jv) = jpk |
---|
184 | iom_file(kiomid)%ofs( ishft + jv) = 0. |
---|
185 | END DO |
---|
186 | ! 2d variable |
---|
187 | ishft = in0d + in1d |
---|
188 | DO jv = 1, in2d |
---|
189 | iom_file(kiomid)%cn_var( ishft + jv) = TRIM(clna2d(jv)) |
---|
190 | iom_file(kiomid)%nvid( ishft + jv) = zval2d(jv) |
---|
191 | iom_file(kiomid)%ndims( ishft + jv) = 2 |
---|
192 | iom_file(kiomid)%dimsz(1:2, ishft + jv) = (/ inx, iny /) |
---|
193 | iom_file(kiomid)%ofs( ishft + jv) = 0. |
---|
194 | END DO |
---|
195 | ! 3d variable |
---|
196 | ishft = in0d + in1d + in2d |
---|
197 | DO jv = 1, in3d |
---|
198 | iom_file(kiomid)%cn_var( ishft + jv) = TRIM(clna3d(jv)) |
---|
199 | iom_file(kiomid)%nvid( ishft + jv) = zval3d(jv) |
---|
200 | iom_file(kiomid)%ndims( ishft + jv) = 3 |
---|
201 | iom_file(kiomid)%dimsz(1:3, ishft + jv) = (/ inx, iny, jpk /) |
---|
202 | iom_file(kiomid)%ofs( ishft + jv) = 0. |
---|
203 | END DO |
---|
204 | ELSE ! new file |
---|
205 | iom_file(kiomid)%nvars = 0 |
---|
206 | iom_file(kiomid)%irec = 2 |
---|
207 | ! store file informations |
---|
208 | WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, kdompar(:,1), jpk ! store domain size |
---|
209 | ENDIF |
---|
210 | ENDIF |
---|
211 | 987 CONTINUE |
---|
212 | IF( ios /= 0 ) THEN |
---|
213 | WRITE(ctmp1,*) ' iostat = ', ios |
---|
214 | CALL ctl_stop( TRIM(clinfo), ' error in opening file '//TRIM(cdname), ctmp1 ) |
---|
215 | ENDIF |
---|
216 | ! |
---|
217 | END SUBROUTINE iom_rstdimg_open |
---|
218 | |
---|
219 | |
---|
220 | SUBROUTINE iom_rstdimg_close( kiomid ) |
---|
221 | !!-------------------------------------------------------------------- |
---|
222 | !! *** SUBROUTINE iom_rstdimg_close *** |
---|
223 | !! |
---|
224 | !! ** Purpose : close an input file |
---|
225 | !!-------------------------------------------------------------------- |
---|
226 | INTEGER, INTENT(in) :: kiomid ! iom identifier of the file to be closed |
---|
227 | ! |
---|
228 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
229 | INTEGER :: jv ! loop counter |
---|
230 | INTEGER :: irecl8 ! record length |
---|
231 | INTEGER :: ios ! IO status |
---|
232 | INTEGER :: irhd ! record of the header infos |
---|
233 | INTEGER :: ivnum ! number of variables |
---|
234 | INTEGER :: idrst ! file logical unit |
---|
235 | INTEGER :: inx, iny, inz ! x,y,z dimension of the variable |
---|
236 | INTEGER :: in0d, in1d, in2d, in3d ! number of 0/1/2/3D variables |
---|
237 | CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) :: clna0d, clna1d, clna2d, clna3d ! name of 0/1/2/3D variables |
---|
238 | REAL(wp), DIMENSION(jpmax_vars) :: zval0d, zval1d, zval2d, zval3d ! value of 0d variables or record |
---|
239 | ! ! position for 1/2/3D variables |
---|
240 | !--------------------------------------------------------------------- |
---|
241 | ! |
---|
242 | clinfo = ' iom_rstdimg_close ~~~ ' |
---|
243 | idrst = iom_file(kiomid)%nfid ! get back the logical unit of the restart file |
---|
244 | ! test if we can write in the file (test with INQUIRE gives alsways YES even with read only files...) |
---|
245 | READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz |
---|
246 | WRITE( idrst, REC = 1, IOSTAT = ios ) irecl8, inx, iny, inz |
---|
247 | ! We can write in the file => we update its header before closing |
---|
248 | IF( ios == 0 ) THEN |
---|
249 | READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz ! get back domain size |
---|
250 | irhd = iom_file(kiomid)%irec |
---|
251 | ivnum = iom_file(kiomid)%nvars |
---|
252 | in0d = 0 ; in1d = 0 ; in2d = 0 ; in3d = 0 |
---|
253 | DO jv = 1, ivnum ! loop on each variable to get its name and value/record position |
---|
254 | SELECT CASE (iom_file(kiomid)%ndims(jv)) |
---|
255 | CASE (0) ! scalar variable |
---|
256 | in0d = in0d + 1 |
---|
257 | clna0d(in0d) = TRIM(iom_file(kiomid)%cn_var(jv)) |
---|
258 | zval0d(in0d) = iom_file(kiomid)%ofs(jv) ! warning: trick... we use ofs to store the value |
---|
259 | CASE (1) ! 1d variable |
---|
260 | in1d = in1d + 1 |
---|
261 | clna1d(in1d) = TRIM(iom_file(kiomid)%cn_var(jv)) |
---|
262 | zval1d(in1d) = iom_file(kiomid)%nvid(jv) |
---|
263 | CASE (2) ! 2d variable |
---|
264 | in2d = in2d + 1 |
---|
265 | clna2d(in2d) = TRIM(iom_file(kiomid)%cn_var(jv)) |
---|
266 | zval2d(in2d) = iom_file(kiomid)%nvid(jv) |
---|
267 | CASE (3) ! 3d variable |
---|
268 | in3d = in3d + 1 |
---|
269 | clna3d(in3d) = TRIM(iom_file(kiomid)%cn_var(jv)) |
---|
270 | zval3d(in3d) = iom_file(kiomid)%nvid(jv) |
---|
271 | CASE DEFAULT ; CALL ctl_stop( TRIM(clinfo), 'Should not ne there...' ) |
---|
272 | END SELECT |
---|
273 | END DO |
---|
274 | ! force to have at least 1 variable in each list (not necessary (?), but safer...) |
---|
275 | IF( in0d == 0 ) THEN ; in0d = 1 ; clna0d(1) = 'no0d' ; zval0d(1) = -1. ; ENDIF |
---|
276 | IF( in1d == 0 ) THEN ; in1d = 1 ; clna1d(1) = 'no1d' ; zval1d(1) = -1. ; ENDIF |
---|
277 | IF( in2d == 0 ) THEN ; in2d = 1 ; clna2d(1) = 'no2d' ; zval2d(1) = -1. ; ENDIF |
---|
278 | IF( in3d == 0 ) THEN ; in3d = 1 ; clna3d(1) = 'no3d' ; zval3d(1) = -1. ; ENDIF |
---|
279 | ! update the file header before closing it |
---|
280 | WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) & |
---|
281 | & irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd, & |
---|
282 | & jpni, jpnj, jpnij, narea, jpiglo, jpjglo, & |
---|
283 | & nlcit, nlcjt, nldit, nldjt, nleit, nlejt, nimppt, njmppt |
---|
284 | IF( (ivnum * (jpvnl + wp)) > irecl8 ) THEN |
---|
285 | CALL ctl_stop( TRIM(clinfo), & |
---|
286 | & 'Last record size is too big... You could reduce the value of jpvnl' ) |
---|
287 | ELSE |
---|
288 | WRITE( idrst, REC = irhd, IOSTAT = ios, ERR = 987 ) & |
---|
289 | & clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d), & |
---|
290 | & clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d) |
---|
291 | ENDIF |
---|
292 | ELSE |
---|
293 | ios = 0 ! we cannot write in the file |
---|
294 | ENDIF |
---|
295 | ! |
---|
296 | CLOSE( idrst, IOSTAT = ios, ERR = 987 ) |
---|
297 | 987 CONTINUE |
---|
298 | IF( ios /= 0 ) THEN |
---|
299 | WRITE(ctmp1,*) ' iostat = ', ios |
---|
300 | CALL ctl_stop( TRIM(clinfo), & |
---|
301 | & ' error when updating the header of '//TRIM(iom_file(kiomid)%name), ctmp1 ) |
---|
302 | ENDIF |
---|
303 | ! |
---|
304 | END SUBROUTINE iom_rstdimg_close |
---|
305 | |
---|
306 | |
---|
307 | SUBROUTINE iom_rstdimg_g0d( kiomid, kvid, pvar ) |
---|
308 | !!----------------------------------------------------------------------- |
---|
309 | !! *** ROUTINE iom_rstdimg_g0d *** |
---|
310 | !! |
---|
311 | !! ** Purpose : read a scalar with RSTDIMG |
---|
312 | !!----------------------------------------------------------------------- |
---|
313 | INTEGER, INTENT(in ) :: kiomid ! Identifier of the file |
---|
314 | INTEGER, INTENT(in ) :: kvid ! variable id |
---|
315 | REAL(wp), INTENT( out) :: pvar ! read field |
---|
316 | !--------------------------------------------------------------------- |
---|
317 | ! |
---|
318 | pvar = iom_file(kiomid)%ofs(kvid) ! warning: trick... we use ofs to store the value |
---|
319 | ! |
---|
320 | END SUBROUTINE iom_rstdimg_g0d |
---|
321 | |
---|
322 | |
---|
323 | SUBROUTINE iom_rstdimg_rp0d( kiomid, cdvar, kvid, pv_r0d ) |
---|
324 | !!-------------------------------------------------------------------- |
---|
325 | !! *** SUBROUTINE iom_rstdimg_rstput *** |
---|
326 | !! |
---|
327 | !! ** Purpose : write a scalar with RSTDIMG |
---|
328 | !!-------------------------------------------------------------------- |
---|
329 | INTEGER , INTENT(in) :: kiomid ! Identifier of the file |
---|
330 | CHARACTER(len=*) , INTENT(in) :: cdvar ! time axis name |
---|
331 | INTEGER , INTENT(in) :: kvid ! variable id |
---|
332 | REAL(wp) , INTENT(in) :: pv_r0d ! written 0d field |
---|
333 | ! |
---|
334 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
335 | INTEGER :: idvar ! variable id |
---|
336 | !--------------------------------------------------------------------- |
---|
337 | ! |
---|
338 | clinfo = ' iom_rstdimg_rp0d ~~~ ' |
---|
339 | IF( kvid <= 0 ) THEN ! new variable |
---|
340 | idvar = iom_file(kiomid)%nvars + 1 |
---|
341 | ELSE ! the variable already exists in the file |
---|
342 | idvar = kvid |
---|
343 | ENDIF |
---|
344 | IF( idvar <= jpmax_vars ) THEN |
---|
345 | iom_file(kiomid)%nvars = idvar |
---|
346 | iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar) |
---|
347 | iom_file(kiomid)%nvid( idvar) = 1 ! useless, Od variables a strored in record 1 |
---|
348 | iom_file(kiomid)%ndims( idvar) = 0 |
---|
349 | iom_file(kiomid)%luld( idvar) = .FALSE. |
---|
350 | iom_file(kiomid)%scf( idvar) = 1. |
---|
351 | iom_file(kiomid)%ofs( idvar) = pv_r0d ! warning: trick... we use ofs to store the value |
---|
352 | ELSE |
---|
353 | CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' ) |
---|
354 | ENDIF |
---|
355 | END SUBROUTINE iom_rstdimg_rp0d |
---|
356 | |
---|
357 | |
---|
358 | SUBROUTINE iom_rstdimg_g123d( kiomid, kdom , kvid, kx1, kx2, ky1, ky2, & |
---|
359 | & pv_r1d, pv_r2d, pv_r3d ) |
---|
360 | !!----------------------------------------------------------------------- |
---|
361 | !! *** ROUTINE iom_rstdimg_g123d *** |
---|
362 | !! |
---|
363 | !! ** Purpose : read a 1D/2D/3D variable with RSTDIMG |
---|
364 | !! |
---|
365 | !! ** Method : read ONE record at each CALL |
---|
366 | !!----------------------------------------------------------------------- |
---|
367 | INTEGER , INTENT(in ) :: kiomid ! iom identifier of the file |
---|
368 | INTEGER , INTENT(in ) :: kdom ! Type of domain to be read |
---|
369 | INTEGER , INTENT(in ) :: kvid ! variable id |
---|
370 | INTEGER , INTENT(inout) :: kx1, kx2, ky1, ky2 ! subdomain indexes |
---|
371 | REAL(wp), DIMENSION(:) , INTENT( out), OPTIONAL :: pv_r1d ! read field (1D case) |
---|
372 | REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pv_r2d ! read field (2D case) |
---|
373 | REAL(wp), DIMENSION(:,:,:) , INTENT( out), OPTIONAL :: pv_r3d ! read field (3D case) |
---|
374 | |
---|
375 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
376 | INTEGER :: ios ! IO status |
---|
377 | INTEGER :: jk ! loop counter |
---|
378 | INTEGER :: idrst ! logical unit of the restart file |
---|
379 | !--------------------------------------------------------------------- |
---|
380 | clinfo = ' iom_rstdimg_g123d ~~~ ' |
---|
381 | ! |
---|
382 | IF( kdom == jpdom_data .OR. kdom == jpdom_global ) THEN |
---|
383 | CALL ctl_stop( TRIM(clinfo), TRIM(iom_file(kiomid)%cn_var(kvid))//': case not coded for rstdimg files' ) |
---|
384 | ELSE |
---|
385 | ! |
---|
386 | idrst = iom_file(kiomid)%nfid ! get back the logical unit of the restart file |
---|
387 | ! modify the subdomain indexes because we cannot directly extract the appropriate subdomaine |
---|
388 | IF( kdom == jpdom_local_full ) THEN ; kx1 = 1 ; kx2 = jpi ; ky1 = 1 |
---|
389 | ELSEIF( kdom == jpdom_local_noextra ) THEN ; kx1 = 1 ; kx2 = nlci ; ky1 = 1 |
---|
390 | ENDIF |
---|
391 | ! |
---|
392 | IF( PRESENT(pv_r1d) ) THEN ! read 1D variables |
---|
393 | READ( idrst, REC = iom_file(kiomid)%nvid(kvid) , IOSTAT = ios, ERR = 987 ) pv_r1d(:) |
---|
394 | ELSEIF( PRESENT(pv_r2d) ) THEN ! read 2D variables |
---|
395 | READ( idrst, REC = iom_file(kiomid)%nvid(kvid) , IOSTAT = ios, ERR = 987 ) pv_r2d(kx1:kx2, ky1:ky2 ) |
---|
396 | ELSEIF( PRESENT(pv_r3d) ) THEN ! read 3D variables |
---|
397 | DO jk = 1, iom_file(kiomid)%dimsz(3,kvid) ! do loop on each level |
---|
398 | READ( idrst, REC = iom_file(kiomid)%nvid(kvid) + jk - 1, IOSTAT = ios, ERR = 987 ) pv_r3d(kx1:kx2, ky1:ky2, jk) |
---|
399 | END DO |
---|
400 | ENDIF |
---|
401 | 987 CONTINUE |
---|
402 | IF( ios /= 0 ) THEN |
---|
403 | WRITE(ctmp1,*) ' iostat = ', ios |
---|
404 | CALL ctl_stop( TRIM(clinfo), ' IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 ) |
---|
405 | ENDIF |
---|
406 | ENDIF |
---|
407 | ! |
---|
408 | END SUBROUTINE iom_rstdimg_g123d |
---|
409 | |
---|
410 | |
---|
411 | SUBROUTINE iom_rstdimg_rp123d( kiomid, cdvar, kvid, pv_r1d, pv_r2d, pv_r3d ) |
---|
412 | !!-------------------------------------------------------------------- |
---|
413 | !! *** SUBROUTINE iom_rstdimg_rstput *** |
---|
414 | !! |
---|
415 | !! ** Purpose : write a 2D/3D variable with RSTDIMG |
---|
416 | !!-------------------------------------------------------------------- |
---|
417 | INTEGER , INTENT(in) :: kiomid ! Identifier of the file |
---|
418 | CHARACTER(len=*) , INTENT(in) :: cdvar ! time axis name |
---|
419 | INTEGER , INTENT(in) :: kvid ! variable id |
---|
420 | REAL(wp), DIMENSION( jpk), INTENT(in), OPTIONAL :: pv_r1d ! written 1d field |
---|
421 | REAL(wp), DIMENSION(jpi,jpj ), INTENT(in), OPTIONAL :: pv_r2d ! written 2d field |
---|
422 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL :: pv_r3d ! written 3d field |
---|
423 | ! |
---|
424 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
425 | INTEGER :: irecl8 ! reacord length |
---|
426 | INTEGER :: ios ! IO status |
---|
427 | INTEGER :: idrst ! reacord length |
---|
428 | INTEGER :: inx, iny, inz ! x,y,z dimension of the variable |
---|
429 | INTEGER :: idvar ! variable id |
---|
430 | INTEGER :: istop ! temporary storage of nstop |
---|
431 | INTEGER :: irec ! record number |
---|
432 | INTEGER :: ix1, ix2, iy1, iy2 ! subdomain indexes |
---|
433 | INTEGER :: jk ! loop counter |
---|
434 | !--------------------------------------------------------------------- |
---|
435 | ! |
---|
436 | clinfo = ' iom_rstdimg_rp123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar) |
---|
437 | istop = nstop ! store the actual value of nstop |
---|
438 | irec = iom_file(kiomid)%irec ! get back the record number of the variable |
---|
439 | idrst = iom_file(kiomid)%nfid ! get back the logical unit of the restart file |
---|
440 | IF( kvid <= 0 ) THEN ! new variable |
---|
441 | idvar = iom_file(kiomid)%nvars + 1 |
---|
442 | ELSE ! the variable already exists in the file |
---|
443 | idvar = kvid |
---|
444 | ENDIF |
---|
445 | IF( idvar > jpmax_vars ) CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' ) |
---|
446 | IF( .NOT. PRESENT(pv_r1d) ) THEN |
---|
447 | ! find which part of data must be written |
---|
448 | READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz |
---|
449 | IF( inx == (nlei - nldi + 1) .AND. iny == (nlej - nldj + 1) ) THEN |
---|
450 | ix1 = nldi ; ix2 = nlei ; iy1 = nldj ; iy2 = nlej |
---|
451 | ELSEIF( inx == nlci .AND. iny == nlcj ) THEN |
---|
452 | ix1 = 1 ; ix2 = nlci ; iy1 = 1 ; iy2 = nlcj |
---|
453 | ELSEIF( inx == jpi .AND. iny == jpj ) THEN |
---|
454 | ix1 = 1 ; ix2 = jpi ; iy1 = 1 ; iy2 = jpj |
---|
455 | ELSE |
---|
456 | CALL ctl_stop( clinfo, 'should have been an impossible case...' ) |
---|
457 | ENDIF |
---|
458 | ENDIF |
---|
459 | IF( istop == nstop ) THEN |
---|
460 | ! write the data |
---|
461 | IF( PRESENT(pv_r1d) ) THEN ! 1D variable |
---|
462 | WRITE( idrst, REC = irec , IOSTAT = ios, ERR = 987 ) pv_r1d(:) |
---|
463 | ELSEIF( PRESENT(pv_r2d) ) THEN ! 2D variable |
---|
464 | WRITE( idrst, REC = irec , IOSTAT = ios, ERR = 987 ) pv_r2d(ix1:ix2, iy1:iy2 ) |
---|
465 | ELSEIF( PRESENT(pv_r3d) ) THEN ! 3D variable |
---|
466 | DO jk = 1, jpk ! do loop on each level |
---|
467 | WRITE( idrst, REC = irec + jk - 1, IOSTAT = ios, ERR = 987 ) pv_r3d(ix1:ix2, iy1:iy2, jk) |
---|
468 | END DO |
---|
469 | ENDIF |
---|
470 | ! fill the file informations |
---|
471 | iom_file(kiomid)%nvars = idvar |
---|
472 | IF( PRESENT(pv_r1d) ) THEN |
---|
473 | iom_file(kiomid)%irec = irec + 1 |
---|
474 | iom_file(kiomid)%ndims( idvar) = 1 |
---|
475 | iom_file(kiomid)%dimsz(1 , idvar) = inz |
---|
476 | ELSEIF( PRESENT(pv_r2d) ) THEN |
---|
477 | iom_file(kiomid)%irec = irec + 1 |
---|
478 | iom_file(kiomid)%ndims( idvar) = 2 |
---|
479 | iom_file(kiomid)%dimsz(1:2, idvar) = (/ inx, iny /) |
---|
480 | ELSEIF( PRESENT(pv_r3d) ) THEN |
---|
481 | iom_file(kiomid)%irec = irec + inz |
---|
482 | iom_file(kiomid)%ndims( idvar) = 3 |
---|
483 | iom_file(kiomid)%dimsz(1:3, idvar) = (/ inx, iny, inz /) |
---|
484 | ENDIF |
---|
485 | iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar) |
---|
486 | iom_file(kiomid)%nvid( idvar) = irec |
---|
487 | iom_file(kiomid)%luld( idvar) = .FALSE. |
---|
488 | iom_file(kiomid)%scf( idvar) = 1. |
---|
489 | iom_file(kiomid)%ofs( idvar) = 0. |
---|
490 | ENDIF |
---|
491 | 987 CONTINUE |
---|
492 | IF( ios /= 0 ) THEN |
---|
493 | WRITE(ctmp1,*) ' iostat = ', ios |
---|
494 | CALL ctl_stop( TRIM(clinfo), ' IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 ) |
---|
495 | ELSE |
---|
496 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok' |
---|
497 | ENDIF |
---|
498 | ! |
---|
499 | END SUBROUTINE iom_rstdimg_rp123d |
---|
500 | |
---|
501 | |
---|
502 | !!====================================================================== |
---|
503 | END MODULE iom_rstdimg |
---|