1 | MODULE p4zprod |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zprod *** |
---|
4 | !! TOP : PISCES |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_pisces |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_pisces' PISCES bio-model |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! p4z_prod : |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE trc |
---|
16 | USE oce_trc ! |
---|
17 | USE sms_pisces ! |
---|
18 | USE prtctl_trc |
---|
19 | USE p4zopt |
---|
20 | USE p4zint |
---|
21 | USE p4zlim |
---|
22 | USE iom |
---|
23 | |
---|
24 | IMPLICIT NONE |
---|
25 | PRIVATE |
---|
26 | |
---|
27 | PUBLIC p4z_prod ! called in p4zbio.F90 |
---|
28 | PUBLIC p4z_prod_init ! called in trcsms_pisces.F90 |
---|
29 | PUBLIC p4z_prod_alloc |
---|
30 | |
---|
31 | REAL(wp), PUBLIC :: & |
---|
32 | pislope = 3.0_wp , & !: |
---|
33 | pislope2 = 3.0_wp , & !: |
---|
34 | excret = 10.e-5_wp , & !: |
---|
35 | excret2 = 0.05_wp , & !: |
---|
36 | chlcnm = 0.033_wp , & !: |
---|
37 | chlcdm = 0.05_wp , & !: |
---|
38 | fecnm = 10.E-6_wp , & !: |
---|
39 | fecdm = 15.E-6_wp , & !: |
---|
40 | grosip = 0.151_wp |
---|
41 | |
---|
42 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: prmax !: |
---|
43 | |
---|
44 | REAL(wp) :: & |
---|
45 | rday1 , & !: 0.6 / rday |
---|
46 | texcret , & !: 1 - excret |
---|
47 | texcret2 , & !: 1 - excret2 |
---|
48 | tpp !: Total primary production |
---|
49 | |
---|
50 | !!* Substitution |
---|
51 | # include "top_substitute.h90" |
---|
52 | !!---------------------------------------------------------------------- |
---|
53 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
54 | !! $Id$ |
---|
55 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
56 | !!---------------------------------------------------------------------- |
---|
57 | CONTAINS |
---|
58 | |
---|
59 | SUBROUTINE p4z_prod( kt , jnt ) |
---|
60 | !!--------------------------------------------------------------------- |
---|
61 | !! *** ROUTINE p4z_prod *** |
---|
62 | !! |
---|
63 | !! ** Purpose : Compute the phytoplankton production depending on |
---|
64 | !! light, temperature and nutrient availability |
---|
65 | !! |
---|
66 | !! ** Method : - ??? |
---|
67 | !!--------------------------------------------------------------------- |
---|
68 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
69 | USE wrk_nemo, ONLY: zmixnano => wrk_2d_1 , zmixdiat => wrk_2d_2 , zstrn => wrk_2d_3 |
---|
70 | USE wrk_nemo, ONLY: zpislopead => wrk_3d_2 , zpislopead2 => wrk_3d_3 |
---|
71 | USE wrk_nemo, ONLY: zprdia => wrk_3d_4 , zprbio => wrk_3d_5 , zysopt => wrk_3d_6 |
---|
72 | USE wrk_nemo, ONLY: zprorca => wrk_3d_7 , zprorcad => wrk_3d_8 |
---|
73 | USE wrk_nemo, ONLY: zprofed => wrk_3d_9 , zprofen => wrk_3d_10 |
---|
74 | USE wrk_nemo, ONLY: zprochln => wrk_3d_11 , zprochld => wrk_3d_12 |
---|
75 | USE wrk_nemo, ONLY: zpronew => wrk_3d_13 , zpronewd => wrk_3d_14 |
---|
76 | ! |
---|
77 | INTEGER, INTENT(in) :: kt, jnt |
---|
78 | ! |
---|
79 | INTEGER :: ji, jj, jk |
---|
80 | REAL(wp) :: zsilfac, zfact |
---|
81 | REAL(wp) :: zprdiachl, zprbiochl, zsilim, ztn, zadap, zadap2 |
---|
82 | REAL(wp) :: zlim, zsilfac2, zsiborn, zprod, zetot2, zmax, zproreg, zproreg2 |
---|
83 | REAL(wp) :: zmxltst, zmxlday, zlim1 |
---|
84 | REAL(wp) :: zpislopen , zpislope2n |
---|
85 | REAL(wp) :: zrum, zcodel, zargu, zval, zvol |
---|
86 | #if defined key_diatrc |
---|
87 | REAL(wp) :: zrfact2 |
---|
88 | #endif |
---|
89 | CHARACTER (len=25) :: charout |
---|
90 | !!--------------------------------------------------------------------- |
---|
91 | |
---|
92 | IF( wrk_in_use(2, 1,2,3) .OR. & |
---|
93 | wrk_in_use(3, 2,3,4,5,6,7,8,9,10,11,12,13,14) ) THEN |
---|
94 | CALL ctl_stop('p4z_prod: requested workspace arrays unavailable') ; RETURN |
---|
95 | ENDIF |
---|
96 | |
---|
97 | zprorca (:,:,:) = 0._wp |
---|
98 | zprorcad(:,:,:) = 0._wp |
---|
99 | zprofed (:,:,:) = 0._wp |
---|
100 | zprofen (:,:,:) = 0._wp |
---|
101 | zprochln(:,:,:) = 0._wp |
---|
102 | zprochld(:,:,:) = 0._wp |
---|
103 | zpronew (:,:,:) = 0._wp |
---|
104 | zpronewd(:,:,:) = 0._wp |
---|
105 | zprdia (:,:,:) = 0._wp |
---|
106 | zprbio (:,:,:) = 0._wp |
---|
107 | zysopt (:,:,:) = 0._wp |
---|
108 | |
---|
109 | ! Computation of the optimal production |
---|
110 | # if defined key_degrad |
---|
111 | prmax(:,:,:) = rday1 * tgfunc(:,:,:) * facvol(:,:,:) |
---|
112 | # else |
---|
113 | prmax(:,:,:) = rday1 * tgfunc(:,:,:) |
---|
114 | # endif |
---|
115 | |
---|
116 | ! compute the day length depending on latitude and the day |
---|
117 | zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp ) |
---|
118 | zcodel = ASIN( SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp ) ) |
---|
119 | |
---|
120 | ! day length in hours |
---|
121 | zstrn(:,:) = 0._wp |
---|
122 | DO jj = 1, jpj |
---|
123 | DO ji = 1, jpi |
---|
124 | zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad ) |
---|
125 | zargu = MAX( -1., MIN( 1., zargu ) ) |
---|
126 | zval = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. ) |
---|
127 | IF( zval < 1.e0 ) zval = 24. |
---|
128 | zstrn(ji,jj) = 24. / zval |
---|
129 | END DO |
---|
130 | END DO |
---|
131 | |
---|
132 | |
---|
133 | !CDIR NOVERRCHK |
---|
134 | DO jk = 1, jpkm1 |
---|
135 | !CDIR NOVERRCHK |
---|
136 | DO jj = 1, jpj |
---|
137 | !CDIR NOVERRCHK |
---|
138 | DO ji = 1, jpi |
---|
139 | |
---|
140 | ! Computation of the P-I slope for nanos and diatoms |
---|
141 | IF( etot(ji,jj,jk) > 1.E-3 ) THEN |
---|
142 | ztn = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. ) |
---|
143 | zadap = 0.+ 1.* ztn / ( 2.+ ztn ) |
---|
144 | zadap2 = 0.e0 |
---|
145 | |
---|
146 | zfact = EXP( -0.21 * emoy(ji,jj,jk) ) |
---|
147 | |
---|
148 | zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap * zfact ) |
---|
149 | zpislopead2(ji,jj,jk) = pislope2 * ( 1.+ zadap2 * zfact ) |
---|
150 | |
---|
151 | zpislopen = zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch) & |
---|
152 | & / ( trn(ji,jj,jk,jpphy) * 12. + rtrn ) & |
---|
153 | & / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn ) |
---|
154 | |
---|
155 | zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch) & |
---|
156 | & / ( trn(ji,jj,jk,jpdia) * 12. + rtrn ) & |
---|
157 | & / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn ) |
---|
158 | |
---|
159 | ! Computation of production function |
---|
160 | zprbio(ji,jj,jk) = prmax(ji,jj,jk) * & |
---|
161 | & ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) ) |
---|
162 | zprdia(ji,jj,jk) = prmax(ji,jj,jk) * & |
---|
163 | & ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) ) |
---|
164 | ENDIF |
---|
165 | END DO |
---|
166 | END DO |
---|
167 | END DO |
---|
168 | |
---|
169 | |
---|
170 | DO jk = 1, jpkm1 |
---|
171 | DO jj = 1, jpj |
---|
172 | DO ji = 1, jpi |
---|
173 | |
---|
174 | IF( etot(ji,jj,jk) > 1.E-3 ) THEN |
---|
175 | ! Si/C of diatoms |
---|
176 | ! ------------------------ |
---|
177 | ! Si/C increases with iron stress and silicate availability |
---|
178 | ! Si/C is arbitrariliy increased for very high Si concentrations |
---|
179 | ! to mimic the very high ratios observed in the Southern Ocean (silpot2) |
---|
180 | |
---|
181 | zlim1 = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 ) |
---|
182 | zlim = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) |
---|
183 | |
---|
184 | zsilim = MIN( zprdia(ji,jj,jk) / ( rtrn + prmax(ji,jj,jk) ), & |
---|
185 | & trn(ji,jj,jk,jpfer) / ( concdfe(ji,jj,jk) + trn(ji,jj,jk,jpfer) ), & |
---|
186 | & trn(ji,jj,jk,jppo4) / ( concdnh4 + trn(ji,jj,jk,jppo4) ), & |
---|
187 | & zlim ) |
---|
188 | zsilfac = 5.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim1 - 0.5 ) ) ) + 1.e0 |
---|
189 | zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) ) |
---|
190 | zsilfac2 = 1.+ 3.* zsiborn / ( zsiborn + xksi2 ) |
---|
191 | zsilfac = MIN( 6.4,zsilfac * zsilfac2) |
---|
192 | zysopt(ji,jj,jk) = grosip * zlim1 * zsilfac |
---|
193 | ENDIF |
---|
194 | END DO |
---|
195 | END DO |
---|
196 | END DO |
---|
197 | |
---|
198 | ! Computation of the limitation term due to |
---|
199 | ! A mixed layer deeper than the euphotic depth |
---|
200 | DO jj = 1, jpj |
---|
201 | DO ji = 1, jpi |
---|
202 | zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) ) |
---|
203 | zmxlday = zmxltst**2 / rday |
---|
204 | zmixnano(ji,jj) = 1.- zmxlday / ( 1.+ zmxlday ) |
---|
205 | zmixdiat(ji,jj) = 1.- zmxlday / ( 3.+ zmxlday ) |
---|
206 | END DO |
---|
207 | END DO |
---|
208 | |
---|
209 | ! Mixed-layer effect on production |
---|
210 | DO jk = 1, jpkm1 |
---|
211 | DO jj = 1, jpj |
---|
212 | DO ji = 1, jpi |
---|
213 | IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN |
---|
214 | zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj) |
---|
215 | zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj) |
---|
216 | ENDIF |
---|
217 | END DO |
---|
218 | END DO |
---|
219 | END DO |
---|
220 | |
---|
221 | |
---|
222 | !CDIR NOVERRCHK |
---|
223 | DO jk = 1, jpkm1 |
---|
224 | !CDIR NOVERRCHK |
---|
225 | DO jj = 1, jpj |
---|
226 | !CDIR NOVERRCHK |
---|
227 | DO ji = 1, jpi |
---|
228 | |
---|
229 | IF( etot(ji,jj,jk) > 1.E-3 ) THEN |
---|
230 | ! Computation of the various production terms for nanophyto. |
---|
231 | zetot2 = enano(ji,jj,jk) * zstrn(ji,jj) |
---|
232 | zmax = MAX( 0.1, xlimphy(ji,jj,jk) ) |
---|
233 | zpislopen = zpislopead(ji,jj,jk) & |
---|
234 | & * trn(ji,jj,jk,jpnch) / ( rtrn + trn(ji,jj,jk,jpphy) * 12.) & |
---|
235 | & / ( prmax(ji,jj,jk) * rday * zmax + rtrn ) |
---|
236 | |
---|
237 | zprbiochl = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * zetot2 ) ) |
---|
238 | |
---|
239 | zprorca(ji,jj,jk) = zprbio(ji,jj,jk) * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2 |
---|
240 | |
---|
241 | zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) & |
---|
242 | & / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn ) |
---|
243 | zprod = rday * zprorca(ji,jj,jk) * zprbiochl * trn(ji,jj,jk,jpphy) *zmax |
---|
244 | |
---|
245 | zprofen(ji,jj,jk) = (fecnm)**2 * zprod / chlcnm & |
---|
246 | & / ( zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnfe) + rtrn ) |
---|
247 | |
---|
248 | zprochln(ji,jj,jk) = chlcnm * 144. * zprod & |
---|
249 | & / ( zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnch) + rtrn ) |
---|
250 | ENDIF |
---|
251 | END DO |
---|
252 | END DO |
---|
253 | END DO |
---|
254 | |
---|
255 | !CDIR NOVERRCHK |
---|
256 | DO jk = 1, jpkm1 |
---|
257 | !CDIR NOVERRCHK |
---|
258 | DO jj = 1, jpj |
---|
259 | !CDIR NOVERRCHK |
---|
260 | DO ji = 1, jpi |
---|
261 | IF( etot(ji,jj,jk) > 1.E-3 ) THEN |
---|
262 | ! Computation of the various production terms for diatoms |
---|
263 | zetot2 = ediat(ji,jj,jk) * zstrn(ji,jj) |
---|
264 | zmax = MAX( 0.1, xlimdia(ji,jj,jk) ) |
---|
265 | zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch) & |
---|
266 | & / ( rtrn + trn(ji,jj,jk,jpdia) * 12.) & |
---|
267 | & / ( prmax(ji,jj,jk) * rday * zmax + rtrn ) |
---|
268 | |
---|
269 | zprdiachl = prmax(ji,jj,jk) * ( 1.- EXP( -zetot2 * zpislope2n ) ) |
---|
270 | |
---|
271 | zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2 |
---|
272 | |
---|
273 | zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) & |
---|
274 | & / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn ) |
---|
275 | |
---|
276 | zprod = rday * zprorcad(ji,jj,jk) * zprdiachl * trn(ji,jj,jk,jpdia) * zmax |
---|
277 | |
---|
278 | zprofed(ji,jj,jk) = (fecdm)**2 * zprod / chlcdm & |
---|
279 | & / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdfe) + rtrn ) |
---|
280 | |
---|
281 | zprochld(ji,jj,jk) = chlcdm * 144. * zprod & |
---|
282 | & / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdch) + rtrn ) |
---|
283 | |
---|
284 | ENDIF |
---|
285 | END DO |
---|
286 | END DO |
---|
287 | END DO |
---|
288 | ! |
---|
289 | |
---|
290 | ! Update the arrays TRA which contain the biological sources and sinks |
---|
291 | DO jk = 1, jpkm1 |
---|
292 | DO jj = 1, jpj |
---|
293 | DO ji =1 ,jpi |
---|
294 | zproreg = zprorca(ji,jj,jk) - zpronew(ji,jj,jk) |
---|
295 | zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk) |
---|
296 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk) |
---|
297 | tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk) |
---|
298 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2 |
---|
299 | tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret |
---|
300 | tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret |
---|
301 | tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret |
---|
302 | tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2 |
---|
303 | tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2 |
---|
304 | tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2 |
---|
305 | tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2 |
---|
306 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + & |
---|
307 | & excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk) |
---|
308 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) & |
---|
309 | & + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) |
---|
310 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) & |
---|
311 | & - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk) |
---|
312 | tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) & |
---|
313 | & - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) |
---|
314 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk) |
---|
315 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) & |
---|
316 | & + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) |
---|
317 | END DO |
---|
318 | END DO |
---|
319 | END DO |
---|
320 | |
---|
321 | ! Total primary production per year |
---|
322 | |
---|
323 | #if defined key_degrad |
---|
324 | tpp = tpp + glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) * facvol(:,:,:) ) |
---|
325 | #else |
---|
326 | tpp = tpp + glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) ) |
---|
327 | #endif |
---|
328 | |
---|
329 | IF( kt == nitend .AND. jnt == nrdttrc .AND. lwp ) THEN |
---|
330 | WRITE(numout,*) 'Total PP (Gtc) :' |
---|
331 | WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12 |
---|
332 | WRITE(numout,*) |
---|
333 | ENDIF |
---|
334 | |
---|
335 | #if defined key_diatrc && ! defined key_iomput |
---|
336 | ! Supplementary diagnostics |
---|
337 | zrfact2 = 1.e3 * rfact2r |
---|
338 | trc3d(:,:,:,jp_pcs0_3d + 4) = zprorca (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
339 | trc3d(:,:,:,jp_pcs0_3d + 5) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) |
---|
340 | trc3d(:,:,:,jp_pcs0_3d + 6) = zpronew (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
341 | trc3d(:,:,:,jp_pcs0_3d + 7) = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) |
---|
342 | trc3d(:,:,:,jp_pcs0_3d + 8) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) |
---|
343 | trc3d(:,:,:,jp_pcs0_3d + 9) = zprofed (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
344 | # if ! defined key_kriest |
---|
345 | trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
346 | # endif |
---|
347 | #endif |
---|
348 | |
---|
349 | #if defined key_diatrc && defined key_iomput |
---|
350 | zrfact2 = 1.e3 * rfact2r |
---|
351 | IF ( jnt == nrdttrc ) then |
---|
352 | CALL iom_put( "PPPHY" , zprorca (:,:,:) * zrfact2 * tmask(:,:,:) ) ! primary production by nanophyto |
---|
353 | CALL iom_put( "PPPHY2", zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) ) ! primary production by diatom |
---|
354 | CALL iom_put( "PPNEWN", zpronew (:,:,:) * zrfact2 * tmask(:,:,:) ) ! new primary production by nanophyto |
---|
355 | CALL iom_put( "PPNEWD", zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) ) ! new primary production by diatom |
---|
356 | CALL iom_put( "PBSi" , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production |
---|
357 | CALL iom_put( "PFeD" , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) ) ! biogenic iron production by diatom |
---|
358 | CALL iom_put( "PFeN" , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) ) ! biogenic iron production by nanophyto |
---|
359 | ENDIF |
---|
360 | #endif |
---|
361 | |
---|
362 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
363 | WRITE(charout, FMT="('prod')") |
---|
364 | CALL prt_ctl_trc_info(charout) |
---|
365 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
366 | ENDIF |
---|
367 | |
---|
368 | IF( wrk_not_released(2, 1,2,3) .OR. & |
---|
369 | wrk_not_released(3, 2,3,4,5,6,7,8,9,10,11,12,13,14) ) & |
---|
370 | CALL ctl_stop('p4z_prod: failed to release workspace arrays') |
---|
371 | ! |
---|
372 | END SUBROUTINE p4z_prod |
---|
373 | |
---|
374 | |
---|
375 | SUBROUTINE p4z_prod_init |
---|
376 | !!---------------------------------------------------------------------- |
---|
377 | !! *** ROUTINE p4z_prod_init *** |
---|
378 | !! |
---|
379 | !! ** Purpose : Initialization of phytoplankton production parameters |
---|
380 | !! |
---|
381 | !! ** Method : Read the nampisprod namelist and check the parameters |
---|
382 | !! called at the first timestep (nit000) |
---|
383 | !! |
---|
384 | !! ** input : Namelist nampisprod |
---|
385 | !!---------------------------------------------------------------------- |
---|
386 | NAMELIST/nampisprod/ pislope, pislope2, excret, excret2, chlcnm, chlcdm, & |
---|
387 | & fecnm, fecdm, grosip |
---|
388 | !!---------------------------------------------------------------------- |
---|
389 | |
---|
390 | REWIND( numnat ) ! read numnat |
---|
391 | READ ( numnat, nampisprod ) |
---|
392 | |
---|
393 | IF(lwp) THEN ! control print |
---|
394 | WRITE(numout,*) ' ' |
---|
395 | WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod' |
---|
396 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
397 | WRITE(numout,*) ' mean Si/C ratio grosip =', grosip |
---|
398 | WRITE(numout,*) ' P-I slope pislope =', pislope |
---|
399 | WRITE(numout,*) ' excretion ratio of nanophytoplankton excret =', excret |
---|
400 | WRITE(numout,*) ' excretion ratio of diatoms excret2 =', excret2 |
---|
401 | WRITE(numout,*) ' P-I slope for diatoms pislope2 =', pislope2 |
---|
402 | WRITE(numout,*) ' Minimum Chl/C in nanophytoplankton chlcnm =', chlcnm |
---|
403 | WRITE(numout,*) ' Minimum Chl/C in diatoms chlcdm =', chlcdm |
---|
404 | WRITE(numout,*) ' Maximum Fe/C in nanophytoplankton fecnm =', fecnm |
---|
405 | WRITE(numout,*) ' Minimum Fe/C in diatoms fecdm =', fecdm |
---|
406 | ENDIF |
---|
407 | ! |
---|
408 | rday1 = 0.6 / rday |
---|
409 | texcret = 1.0 - excret |
---|
410 | texcret2 = 1.0 - excret2 |
---|
411 | tpp = 0. |
---|
412 | ! |
---|
413 | END SUBROUTINE p4z_prod_init |
---|
414 | |
---|
415 | |
---|
416 | INTEGER FUNCTION p4z_prod_alloc() |
---|
417 | !!---------------------------------------------------------------------- |
---|
418 | !! *** ROUTINE p4z_prod_alloc *** |
---|
419 | !!---------------------------------------------------------------------- |
---|
420 | ALLOCATE( prmax(jpi,jpj,jpk), STAT=p4z_prod_alloc ) |
---|
421 | ! |
---|
422 | IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.') |
---|
423 | ! |
---|
424 | END FUNCTION p4z_prod_alloc |
---|
425 | |
---|
426 | #else |
---|
427 | !!====================================================================== |
---|
428 | !! Dummy module : No PISCES bio-model |
---|
429 | !!====================================================================== |
---|
430 | CONTAINS |
---|
431 | SUBROUTINE p4z_prod ! Empty routine |
---|
432 | END SUBROUTINE p4z_prod |
---|
433 | #endif |
---|
434 | |
---|
435 | !!====================================================================== |
---|
436 | END MODULE p4zprod |
---|