New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfdyn.F90 in branches/dev_r1821_mixed_ldfdyn/NEMO/OPA_SRC/LDF – NEMO

source: branches/dev_r1821_mixed_ldfdyn/NEMO/OPA_SRC/LDF/ldfdyn.F90 @ 2182

Last change on this file since 2182 was 2182, checked in by edblockley, 14 years ago

3rd commit for mixed_ldfdyn to include the remainder of the namelist changes and some other modifications
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE ldfdyn
2   !!======================================================================
3   !!                       ***  MODULE  ldfdyn  ***
4   !! Ocean physics:  lateral viscosity coefficient
5   !!=====================================================================
6   !! History :  OPA  ! 1997-07  (G. Madec)  multi dimensional coefficients
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   ldf_dyn_init : initialization, namelist read, and parameters control
12   !!   ldf_dyn_c3d   : 3D eddy viscosity coefficient initialization
13   !!   ldf_dyn_c2d   : 2D eddy viscosity coefficient initialization
14   !!   ldf_dyn_c1d   : 1D eddy viscosity coefficient initialization
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers   
17   USE dom_oce         ! ocean space and time domain
18   USE ldfdyn_oce      ! ocean dynamics lateral physics
19   USE phycst          ! physical constants
20   USE ldfslp          ! ???
21   USE ioipsl
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   ldf_dyn_init   ! called by opa.F90
30
31  INTERFACE ldf_zpf
32     MODULE PROCEDURE ldf_zpf_1d, ldf_zpf_1d_3d, ldf_zpf_3d
33  END INTERFACE
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE ldf_dyn_init
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE ldf_dyn_init  ***
48      !!                   
49      !! ** Purpose :   set the horizontal ocean dynamics physics
50      !!
51      !! ** Method  : 
52      !!      -  default option : ahm = constant coef. = rn_ahm_0 (namelist)
53      !!      - 'key_dynldf_c1d': ahm = F(depth)                     see ldf_dyn_c1d.h90
54      !!      - 'key_dynldf_c2d': ahm = F(latitude,longitude)        see ldf_dyn_c2d.h90
55      !!      - 'key_dynldf_c3d': ahm = F(latitude,longitude,depth)  see ldf_dyn_c3d.h90
56      !!
57      !!      N.B. User defined include files.  By default, 3d and 2d coef.
58      !!      are set to a constant value given in the namelist and the 1d
59      !!      coefficients are initialized to a hyperbolic tangent vertical
60      !!      profile.
61      !!
62      !! Reference :   Madec, G. and M. Imbard, 1996: Climate Dynamics, 12, 381-388.
63      !!----------------------------------------------------------------------
64      INTEGER ::   ioptio         ! ???
65      LOGICAL :: ll_print = .FALSE.    ! Logical flag for printing viscosity coef.
66      !!
67      NAMELIST/namdyn_ldf/ ln_dynldf_lap  , ln_dynldf_bilap,                  &
68         &                 ln_dynldf_level, ln_dynldf_hor  , ln_dynldf_iso,   &
69         &                 rn_ahm_0_lap   , rn_ahmb_0      , rn_ahm_0_blp
70      !!----------------------------------------------------------------------
71
72      REWIND( numnam )                  ! Read Namelist namdyn_ldf : Lateral physics
73      READ  ( numnam, namdyn_ldf )
74
75      IF(lwp) THEN                      ! Parameter print
76         WRITE(numout,*)
77         WRITE(numout,*) 'ldf_dyn : lateral momentum physics'
78         WRITE(numout,*) '~~~~~~~'
79         WRITE(numout,*) '   Namelist nam_dynldf : set lateral mixing parameters'
80         WRITE(numout,*) '      laplacian operator                      ln_dynldf_lap   = ', ln_dynldf_lap
81         WRITE(numout,*) '      bilaplacian operator                    ln_dynldf_bilap = ', ln_dynldf_bilap
82         WRITE(numout,*) '      iso-level                               ln_dynldf_level = ', ln_dynldf_level
83         WRITE(numout,*) '      horizontal (geopotential)               ln_dynldf_hor   = ', ln_dynldf_hor
84         WRITE(numout,*) '      iso-neutral                             ln_dynldf_iso   = ', ln_dynldf_iso
85         WRITE(numout,*) '      horizontal laplacian eddy viscosity     rn_ahm_0_lap    = ', rn_ahm_0_lap
86         WRITE(numout,*) '      background viscosity                    rn_ahmb_0       = ', rn_ahmb_0
87         WRITE(numout,*) '      horizontal bilaplacian eddy viscosity   rn_ahm_0_blp    = ', rn_ahm_0_blp
88
89      ENDIF
90
91      ahm0     = rn_ahm_0_lap              ! OLD namelist variables defined from DOCTOR namelist variables
92      ahmb0    = rn_ahmb_0
93      ahm0_blp = rn_ahm_0_blp
94
95      ! ... check of lateral diffusive operator on tracers
96      !           ==> will be done in trazdf module
97
98      ! ... Space variation of eddy coefficients
99      ioptio = 0
100#if defined key_dynldf_c3d
101      IF(lwp) WRITE(numout,*) '   momentum mixing coef. = F( latitude, longitude, depth)'
102      ioptio = ioptio+1
103#endif
104#if defined key_dynldf_c2d
105      IF(lwp) WRITE(numout,*) '   momentum mixing coef. = F( latitude, longitude)'
106      ioptio = ioptio+1
107#endif
108#if defined key_dynldf_c1d
109      IF(lwp) WRITE(numout,*) '   momentum mixing coef. = F( depth )'
110      ioptio = ioptio+1
111      IF( ln_sco ) CALL ctl_stop( 'key_dynldf_c1d cannot be used in s-coordinate (ln_sco)' )
112#endif
113      IF( ioptio == 0 ) THEN
114          IF(lwp) WRITE(numout,*) '   momentum mixing coef. = constant  (default option)'
115        ELSEIF( ioptio > 1 ) THEN
116           CALL ctl_stop( 'use only one of the following keys: key_dynldf_c3d, key_dynldf_c2d, key_dynldf_c1d' )
117      ENDIF
118
119
120      IF( ln_dynldf_bilap ) THEN
121         IF(lwp) WRITE(numout,*) '   biharmonic momentum diffusion'
122         IF( .NOT. ln_dynldf_lap ) ahm0 = ahm0_blp   ! Allow spatially varying coefs, which use ahm0 as input
123         IF( ahm0_blp > 0 .AND. .NOT. lk_esopa )   CALL ctl_stop( 'The horizontal viscosity coef. ahm0 must be negative' )
124      ELSE
125         IF(lwp) WRITE(numout,*) '   harmonic momentum diff. (default)'
126         IF( ahm0 < 0 .AND. .NOT. lk_esopa )   CALL ctl_stop( 'The horizontal viscosity coef. ahm0 must be positive' )
127      ENDIF
128
129
130      ! Lateral eddy viscosity
131      ! ======================
132#if defined key_dynldf_c3d
133      CALL ldf_dyn_c3d( ll_print )   ! ahm = 3D coef. = F( longitude, latitude, depth )
134#elif defined key_dynldf_c2d
135      CALL ldf_dyn_c2d( ll_print )   ! ahm = 1D coef. = F( longitude, latitude )
136#elif defined key_dynldf_c1d
137      CALL ldf_dyn_c1d( ll_print )   ! ahm = 1D coef. = F( depth )
138#else
139                                     ! Constant coefficients
140      IF(lwp) WRITE(numout,*)
141      IF(lwp) WRITE(numout,*) 'inildf: constant eddy viscosity coef. '
142      IF(lwp) WRITE(numout,*) '~~~~~~'
143      IF(lwp) WRITE(numout,*) '        ahm1 = ahm2 = ahm0 =  ',ahm0
144#endif
145      !
146   END SUBROUTINE ldf_dyn_init
147
148#if defined key_dynldf_c3d
149#   include "ldfdyn_c3d.h90"
150#elif defined key_dynldf_c2d
151#   include "ldfdyn_c2d.h90"
152#elif defined key_dynldf_c1d
153#   include "ldfdyn_c1d.h90"
154#endif
155
156
157   SUBROUTINE ldf_zpf_1d( ld_print, pdam, pwam, pbot, pdep, pah )
158      !!----------------------------------------------------------------------
159      !!                  ***  ROUTINE ldf_zpf  ***
160      !!                   
161      !! ** Purpose :   vertical adimensional profile for eddy coefficient
162      !!
163      !! ** Method  :   1D eddy viscosity coefficients ( depth )
164      !!----------------------------------------------------------------------
165      LOGICAL , INTENT(in   )                 ::   ld_print   ! If true, output arrays on numout
166      REAL(wp), INTENT(in   )                 ::   pdam       ! depth of the inflection point
167      REAL(wp), INTENT(in   )                 ::   pwam       ! width of inflection
168      REAL(wp), INTENT(in   )                 ::   pbot       ! bottom value (0<pbot<= 1)
169      REAL(wp), INTENT(in   ), DIMENSION(jpk) ::   pdep       ! depth of the gridpoint (T, U, V, F)
170      REAL(wp), INTENT(inout), DIMENSION(jpk) ::   pah        ! adimensional vertical profile
171      !!
172      INTEGER  ::   jk           ! dummy loop indices
173      REAL(wp) ::   zm00, zm01, zmhb, zmhs       ! temporary scalars
174      !!----------------------------------------------------------------------
175
176      zm00 = TANH( ( pdam - gdept_0(1    ) ) / pwam )
177      zm01 = TANH( ( pdam - gdept_0(jpkm1) ) / pwam )
178      zmhs = zm00 / zm01
179      zmhb = ( 1.e0 - pbot ) / ( 1.e0 - zmhs ) / zm01
180
181      DO jk = 1, jpk
182         pah(jk) = 1.e0 + zmhb * ( zm00 - TANH( ( pdam - pdep(jk) ) / pwam )  )
183      END DO
184
185      IF(lwp .AND. ld_print ) THEN      ! Control print
186         WRITE(numout,*)
187         WRITE(numout,*) '         ahm profile : '
188         WRITE(numout,*)
189         WRITE(numout,'("  jk      ahm       ","  depth t-level " )')
190         DO jk = 1, jpk
191            WRITE(numout,'(i6,2f12.4,3x,2f12.4)') jk, pah(jk), pdep(jk)
192         END DO
193      ENDIF
194      !
195   END SUBROUTINE ldf_zpf_1d
196
197
198   SUBROUTINE ldf_zpf_1d_3d( ld_print, pdam, pwam, pbot, pdep, pah )
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE ldf_zpf  ***
201      !!
202      !! ** Purpose :   vertical adimensional profile for eddy coefficient
203      !!
204      !! ** Method  :   1D eddy viscosity coefficients ( depth )
205      !!----------------------------------------------------------------------
206      LOGICAL , INTENT(in   )                         ::   ld_print   ! If true, output arrays on numout
207      REAL(wp), INTENT(in   )                         ::   pdam       ! depth of the inflection point
208      REAL(wp), INTENT(in   )                         ::   pwam       ! width of inflection
209      REAL(wp), INTENT(in   )                         ::   pbot       ! bottom value (0<pbot<= 1)
210      REAL(wp), INTENT(in   ), DIMENSION        (jpk) ::   pdep       ! depth of the gridpoint (T, U, V, F)
211      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pah        ! adimensional vertical profile
212      !!
213      INTEGER  ::   jk           ! dummy loop indices
214      REAL(wp) ::   zm00, zm01, zmhb, zmhs, zcf  ! temporary scalars
215      !!----------------------------------------------------------------------
216
217      zm00 = TANH( ( pdam - gdept_0(1    ) ) / pwam )
218      zm01 = TANH( ( pdam - gdept_0(jpkm1) ) / pwam )
219      zmhs = zm00 / zm01
220      zmhb = ( 1.e0 - pbot ) / ( 1.e0 - zmhs ) / zm01
221
222      DO jk = 1, jpk
223         zcf = 1.e0 + zmhb * ( zm00 - TANH( ( pdam - pdep(jk) ) / pwam )  )
224         pah(:,:,jk) = zcf
225      END DO
226
227      IF(lwp .AND. ld_print ) THEN      ! Control print
228         WRITE(numout,*)
229         WRITE(numout,*) '         ahm profile : '
230         WRITE(numout,*)
231         WRITE(numout,'("  jk      ahm       ","  depth t-level " )')
232         DO jk = 1, jpk
233            WRITE(numout,'(i6,2f12.4,3x,2f12.4)') jk, pah(1,1,jk), pdep(jk)
234         END DO
235      ENDIF
236      !
237   END SUBROUTINE ldf_zpf_1d_3d
238
239
240   SUBROUTINE ldf_zpf_3d( ld_print, pdam, pwam, pbot, pdep, pah )
241      !!----------------------------------------------------------------------
242      !!                  ***  ROUTINE ldf_zpf  ***
243      !!
244      !! ** Purpose :   vertical adimensional profile for eddy coefficient
245      !!
246      !! ** Method  :   3D for partial step or s-coordinate
247      !!----------------------------------------------------------------------
248      LOGICAL , INTENT(in   )                         ::   ld_print   ! If true, output arrays on numout
249      REAL(wp), INTENT(in   )                         ::   pdam       ! depth of the inflection point
250      REAL(wp), INTENT(in   )                         ::   pwam       ! width of inflection
251      REAL(wp), INTENT(in   )                         ::   pbot       ! bottom value (0<pbot<= 1)
252      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pdep       ! dep of the gridpoint (T, U, V, F)
253      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pah        ! adimensional vertical profile
254      !!
255      INTEGER  ::   jk           ! dummy loop indices
256      REAL(wp) ::   zm00, zm01, zmhb, zmhs       ! temporary scalars
257      !!----------------------------------------------------------------------
258
259      zm00 = TANH( ( pdam - gdept_0(1    ) ) / pwam )   
260      zm01 = TANH( ( pdam - gdept_0(jpkm1) ) / pwam )
261      zmhs = zm00 / zm01
262      zmhb = ( 1.e0 - pbot ) / ( 1.e0 - zmhs ) / zm01
263
264      DO jk = 1, jpk
265         pah(:,:,jk) = 1.e0 + zmhb * ( zm00 - TANH( ( pdam - pdep(:,:,jk) ) / pwam )  )
266      END DO
267
268      IF(lwp .AND. ld_print ) THEN      ! Control print
269         WRITE(numout,*)
270         WRITE(numout,*) '         ahm profile : '
271         WRITE(numout,*)
272         WRITE(numout,'("  jk      ahm       ","  depth t-level " )')
273         DO jk = 1, jpk
274            WRITE(numout,'(i6,2f12.4,3x,2f12.4)') jk, pah(1,1,jk), pdep(1,1,jk)
275         END DO
276      ENDIF
277      !
278   END SUBROUTINE ldf_zpf_3d
279
280   !!======================================================================
281END MODULE ldfdyn
Note: See TracBrowser for help on using the repository browser.