New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 2187

Last change on this file since 2187 was 2187, checked in by smasson, 14 years ago

add diurna cycle in dev_r2174_DCY, see ticket:730
  • Property svn:keywords set to Id
File size: 47.4 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields   
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting   
13   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   sbc_blk_core  : bulk formulation as ocean surface boundary condition
18   !!                   (forced mode, CORE bulk formulea)
19   !!   blk_oce_core  : ocean: computes momentum, heat and freshwater fluxes
20   !!   blk_ice_core  : ice  : computes momentum, heat and freshwater fluxes
21   !!   turb_core     : computes the CORE turbulent transfer coefficients
22   !!----------------------------------------------------------------------
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE fldread         ! read input fields
27   USE sbc_oce         ! Surface boundary condition: ocean fields
28   USE sbcdcy          ! surface forcing: diurnal cycle
29   USE iom             ! I/O manager library
30   USE in_out_manager  ! I/O manager
31   USE lib_mpp         ! distribued memory computing library
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33   USE prtctl          ! Print control
34#if defined key_lim3
35   USE sbc_ice         ! Surface boundary condition: ice fields
36#endif
37
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   sbc_blk_core       ! routine called in sbcmod module
43   PUBLIC   blk_ice_core       ! routine called in sbc_ice_lim module
44     
45   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
47   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
48   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( - )
49   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
50   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
51   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
52   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
53   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
54   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
56         
57   !                                             !!! CORE bulk parameters
58   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
59   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
60   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
61   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
62   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
63   REAL(wp), PARAMETER ::   Cice =    1.63e-3     ! transfer coefficient over ice
64
65   !                                !!* Namelist namsbc_core : CORE bulk parameters
66   LOGICAL  ::   ln_2m     = .FALSE.     ! logical flag for height of air temp. and hum
67   LOGICAL  ::   ln_taudif = .FALSE.     ! logical flag to use the "mean of stress module - module of mean stress" data
68   REAL(wp) ::   rn_pfac   = 1.          ! multiplication factor for precipitation
69
70   !! * Substitutions
71#  include "domzgr_substitute.h90"
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
75   !! $Id$
76   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78
79CONTAINS
80
81   SUBROUTINE sbc_blk_core( kt )
82      !!---------------------------------------------------------------------
83      !!                    ***  ROUTINE sbc_blk_core  ***
84      !!                   
85      !! ** Purpose :   provide at each time step the surface ocean fluxes
86      !!      (momentum, heat, freshwater and runoff)
87      !!
88      !! ** Method  : (1) READ each fluxes in NetCDF files:
89      !!      the 10m wind velocity (i-component) (m/s)    at T-point
90      !!      the 10m wind velocity (j-component) (m/s)    at T-point
91      !!      the specific humidity               ( - )
92      !!      the solar heat                      (W/m2)
93      !!      the Long wave                       (W/m2)
94      !!      the 10m air temperature             (Kelvin)
95      !!      the total precipitation (rain+snow) (Kg/m2/s)
96      !!      the snow (solid prcipitation)       (kg/m2/s)
97      !!   OPTIONAL parameter (see ln_taudif namelist flag):
98      !!      the tau diff associated to HF tau   (N/m2)   at T-point
99      !!              (2) CALL blk_oce_core
100      !!
101      !!      C A U T I O N : never mask the surface stress fields
102      !!                      the stress is assumed to be in the mesh referential
103      !!                      i.e. the (i,j) referential
104      !!
105      !! ** Action  :   defined at each time-step at the air-sea interface
106      !!              - utau, vtau  i- and j-component of the wind stress
107      !!              - taum        wind stress module at T-point
108      !!              - wndm        10m wind module at T-point
109      !!              - qns, qsr    non-slor and solar heat flux
110      !!              - emp, emps   evaporation minus precipitation
111      !!----------------------------------------------------------------------
112      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
113      !!
114      INTEGER  ::   ierror   ! return error code
115      INTEGER  ::   ifpr     ! dummy loop indice
116      INTEGER  ::   jfld     ! dummy loop arguments
117      !!
118      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
119      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
120      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
121      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
122      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
123      NAMELIST/namsbc_core/ cn_dir , ln_2m  , ln_taudif, rn_pfac,           &
124         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
125         &                  sn_qlw , sn_tair, sn_prec  , sn_snow, sn_tdif
126      !!---------------------------------------------------------------------
127
128      !                                         ! ====================== !
129      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
130         !                                      ! ====================== !
131         ! set file information (default values)
132         cn_dir = './'       ! directory in which the model is executed
133         !
134         ! (NB: frequency positive => hours, negative => months)
135         !            !    file     ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
136         !            !    name     !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
137         sn_wndi = FLD_N( 'uwnd10m' ,    24     ,  'u_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
138         sn_wndj = FLD_N( 'vwnd10m' ,    24     ,  'v_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
139         sn_qsr  = FLD_N( 'qsw'     ,    24     ,  'qsw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
140         sn_qlw  = FLD_N( 'qlw'     ,    24     ,  'qlw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
141         sn_tair = FLD_N( 'tair10m' ,    24     ,  't_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
142         sn_humi = FLD_N( 'humi10m' ,    24     ,  'q_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
143         sn_prec = FLD_N( 'precip'  ,    -1     ,  'precip'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
144         sn_snow = FLD_N( 'snow'    ,    -1     ,  'snow'    ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
145         sn_tdif = FLD_N( 'taudif'  ,    24     ,  'taudif'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
146         !
147         REWIND( numnam )                    ! ... read in namlist namsbc_core
148         READ  ( numnam, namsbc_core )
149         !
150         ! do we plan to use ln_dm2dc with non-daily forcing?
151         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   &
152            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
153         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
154            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
155                 &         '              ==> We force time interpolation = .false. for qsr' )
156            sn_qsr%ln_tint = .false.
157         ENDIF
158         !
159         ! store namelist information in an array
160         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
161         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
162         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
163         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
164         slf_i(jp_tdif) = sn_tdif
165         !
166         ! do we use HF tau information?
167         lhftau = ln_taudif
168         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
169         !
170         ! set sf structure
171         ALLOCATE( sf(jfld), STAT=ierror )
172         IF( ierror > 0 ) THEN
173            CALL ctl_stop( 'sbc_blk_core: unable to allocate sf structure' )   ;   RETURN
174         ENDIF
175         DO ifpr= 1, jfld
176            ALLOCATE( sf(ifpr)%fnow(jpi,jpj) )
177            ALLOCATE( sf(ifpr)%fdta(jpi,jpj,2) )
178         END DO
179         !
180         ! fill sf with slf_i and control print
181         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
182         !
183      ENDIF
184
185      CALL fld_read( kt, nn_fsbc, sf )                   ! input fields provided at the current time-step
186
187      IF( ln_dm2dc )   CALL sbc_dcy( kt , sf(jp_qsr)%fnow )   ! modify sf(jp_qsr)%fnow for diurnal cycle
188
189#if defined key_lim3
190      tatm_ice(:,:) = sf(jp_tair)%fnow(:,:)
191#endif
192
193      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
194          CALL blk_oce_core( sf, sst_m, ssu_m, ssv_m )   ! compute the surface ocean fluxes using CLIO bulk formulea
195      ENDIF
196      !                                                  ! using CORE bulk formulea
197   END SUBROUTINE sbc_blk_core
198   
199   
200   SUBROUTINE blk_oce_core( sf, pst, pu, pv )
201      !!---------------------------------------------------------------------
202      !!                     ***  ROUTINE blk_core  ***
203      !!
204      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
205      !!      the ocean surface at each time step
206      !!
207      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
208      !!      fields read in sbc_read
209      !!
210      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
211      !!              - vtau    : j-component of the stress at V-point  (N/m2)
212      !!              - taum    : Wind stress module at T-point         (N/m2)
213      !!              - wndm    : Wind speed module at T-point          (m/s)
214      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
215      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
216      !!              - evap    : Evaporation over the ocean            (kg/m2/s)
217      !!              - emp(s)  : evaporation minus precipitation       (kg/m2/s)
218      !!
219      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
220      !!---------------------------------------------------------------------
221      TYPE(fld), INTENT(in), DIMENSION(:)       ::   sf    ! input data
222      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pst   ! surface temperature                      [Celcius]
223      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pu    ! surface current at U-point (i-component) [m/s]
224      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pv    ! surface current at V-point (j-component) [m/s]
225
226      INTEGER  ::   ji, jj     ! dummy loop indices
227      REAL(wp) ::   zcoef_qsatw
228      REAL(wp) ::   zztmp                                 ! temporary variable
229      REAL(wp), DIMENSION(jpi,jpj) ::   zwnd_i, zwnd_j    ! wind speed components at T-point
230      REAL(wp), DIMENSION(jpi,jpj) ::   zqsatw            ! specific humidity at pst
231      REAL(wp), DIMENSION(jpi,jpj) ::   zqlw, zqsb        ! long wave and sensible heat fluxes
232      REAL(wp), DIMENSION(jpi,jpj) ::   zqla, zevap       ! latent heat fluxes and evaporation
233      REAL(wp), DIMENSION(jpi,jpj) ::   Cd                ! transfer coefficient for momentum      (tau)
234      REAL(wp), DIMENSION(jpi,jpj) ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
235      REAL(wp), DIMENSION(jpi,jpj) ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
236      REAL(wp), DIMENSION(jpi,jpj) ::   zst               ! surface temperature in Kelvin
237      REAL(wp), DIMENSION(jpi,jpj) ::   zt_zu             ! air temperature at wind speed height
238      REAL(wp), DIMENSION(jpi,jpj) ::   zq_zu             ! air spec. hum.  at wind speed height
239      !!---------------------------------------------------------------------
240
241      ! local scalars ( place there for vector optimisation purposes)
242      zcoef_qsatw = 0.98 * 640380. / rhoa
243     
244      zst(:,:) = pst(:,:) + rt0      ! converte Celcius to Kelvin (and set minimum value far above 0 K)
245
246      ! ----------------------------------------------------------------------------- !
247      !      0   Wind components and module at T-point relative to the moving ocean   !
248      ! ----------------------------------------------------------------------------- !
249
250      ! ... components ( U10m - U_oce ) at T-point (unmasked)
251      zwnd_i(:,:) = 0.e0 
252      zwnd_j(:,:) = 0.e0
253#if defined key_vectopt_loop
254!CDIR COLLAPSE
255#endif
256      DO jj = 2, jpjm1
257         DO ji = fs_2, fs_jpim1   ! vect. opt.
258            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
259            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
260         END DO
261      END DO
262      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
263      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
264      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
265!CDIR NOVERRCHK
266!CDIR COLLAPSE
267      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
268         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
269
270      ! ----------------------------------------------------------------------------- !
271      !      I   Radiative FLUXES                                                     !
272      ! ----------------------------------------------------------------------------- !
273   
274      ! ocean albedo assumed to be 0.066
275!CDIR COLLAPSE
276      qsr (:,:) = ( 1. - 0.066 ) * sf(jp_qsr)%fnow(:,:) * tmask(:,:,1)                                 ! Short Wave
277!CDIR COLLAPSE
278      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
279                     
280      ! ----------------------------------------------------------------------------- !
281      !     II    Turbulent FLUXES                                                    !
282      ! ----------------------------------------------------------------------------- !
283
284      ! ... specific humidity at SST and IST
285!CDIR NOVERRCHK
286!CDIR COLLAPSE
287      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) 
288
289      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
290      IF( ln_2m ) THEN
291         !! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
292         CALL TURB_CORE_2Z(2.,10., zst   , sf(jp_tair)%fnow,         &
293            &                      zqsatw, sf(jp_humi)%fnow, wndm,   &
294            &                      Cd    , Ch              , Ce  ,   &
295            &                      zt_zu , zq_zu                   )
296      ELSE
297         !! If air temp. and spec. hum. are given at same height than wind (10m) :
298!gm bug?  at the compiling phase, add a copy in temporary arrays...  ==> check perf
299!         CALL TURB_CORE_1Z( 10., zst   (:,:), sf(jp_tair)%fnow(:,:),              &
300!            &                    zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:),   &
301!            &                    Cd    (:,:),             Ch  (:,:), Ce  (:,:)  )
302!gm bug
303         CALL TURB_CORE_1Z( 10., zst   , sf(jp_tair)%fnow,         &
304            &                    zqsatw, sf(jp_humi)%fnow, wndm,   &
305            &                    Cd    , Ch              , Ce    )
306      ENDIF
307
308      ! ... tau module, i and j component
309      DO jj = 1, jpj
310         DO ji = 1, jpi
311            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
312            taum  (ji,jj) = zztmp * wndm  (ji,jj)
313            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
314            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
315         END DO
316      END DO
317
318      ! ... add the HF tau contribution to the wind stress module?
319      IF( lhftau ) THEN 
320!CDIR COLLAPSE
321         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:)
322      ENDIF
323      CALL iom_put( "taum_oce", taum )   ! output wind stress module
324
325      ! ... utau, vtau at U- and V_points, resp.
326      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
327      DO jj = 1, jpjm1
328         DO ji = 1, fs_jpim1
329            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) )
330            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) )
331         END DO
332      END DO
333      CALL lbc_lnk( utau(:,:), 'U', -1. )
334      CALL lbc_lnk( vtau(:,:), 'V', -1. )
335
336      !  Turbulent fluxes over ocean
337      ! -----------------------------
338      IF( ln_2m ) THEN
339         ! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
340         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) )   ! Evaporation
341         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) ) * wndm(:,:)     ! Sensible Heat
342      ELSE
343!CDIR COLLAPSE
344         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:) ) * wndm(:,:) )   ! Evaporation
345!CDIR COLLAPSE
346         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:) ) * wndm(:,:)     ! Sensible Heat
347      ENDIF
348!CDIR COLLAPSE
349      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
350
351      IF(ln_ctl) THEN
352         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
353         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
354         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
355         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
356         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
357            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
358         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
359         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
360      ENDIF
361       
362      ! ----------------------------------------------------------------------------- !
363      !     III    Total FLUXES                                                       !
364      ! ----------------------------------------------------------------------------- !
365     
366!CDIR COLLAPSE
367      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
368!CDIR COLLAPSE
369      emp (:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:) * rn_pfac * tmask(:,:,1)
370!CDIR COLLAPSE
371      emps(:,:) = emp(:,:)
372      !
373      CALL iom_put( "qlw_oce",   zqlw )                 ! output downward longwave heat over the ocean
374      CALL iom_put( "qsb_oce", - zqsb )                 ! output downward sensible heat over the ocean
375      CALL iom_put( "qla_oce", - zqla )                 ! output downward latent   heat over the ocean
376      CALL iom_put( "qns_oce",   qns  )                 ! output downward non solar heat over the ocean
377      !
378      IF(ln_ctl) THEN
379         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
380         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
381         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
382         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
383            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
384      ENDIF
385      !
386   END SUBROUTINE blk_oce_core
387   
388   
389   SUBROUTINE blk_ice_core(  pst   , pui   , pvi   , palb ,   &
390      &                      p_taui, p_tauj, p_qns , p_qsr,   &
391      &                      p_qla , p_dqns, p_dqla,          &
392      &                      p_tpr , p_spr ,                  &
393      &                      p_fr1 , p_fr2 , cd_grid, pdim  ) 
394      !!---------------------------------------------------------------------
395      !!                     ***  ROUTINE blk_ice_core  ***
396      !!
397      !! ** Purpose :   provide the surface boundary condition over sea-ice
398      !!
399      !! ** Method  :   compute momentum, heat and freshwater exchanged
400      !!                between atmosphere and sea-ice using CORE bulk
401      !!                formulea, ice variables and read atmmospheric fields.
402      !!                NB: ice drag coefficient is assumed to be a constant
403      !!
404      !! caution : the net upward water flux has with mm/day unit
405      !!---------------------------------------------------------------------
406      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   pst      ! ice surface temperature (>0, =rt0 over land) [Kelvin]
407      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pui      ! ice surface velocity (i- and i- components      [m/s]
408      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pvi      !    at I-point (B-grid) or U & V-point (C-grid)
409      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   palb     ! ice albedo (clear sky) (alb_ice_cs)               [%]
410      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_taui   ! i- & j-components of surface ice stress        [N/m2]
411      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tauj   !   at I-point (B-grid) or U & V-point (C-grid)
412      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qns    ! non solar heat flux over ice (T-point)         [W/m2]
413      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qsr    !     solar heat flux over ice (T-point)         [W/m2]
414      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qla    ! latent    heat flux over ice (T-point)         [W/m2]
415      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqns   ! non solar heat sensistivity  (T-point)         [W/m2]
416      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqla   ! latent    heat sensistivity  (T-point)         [W/m2]
417      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tpr    ! total precipitation          (T-point)      [Kg/m2/s]
418      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_spr    ! solid precipitation          (T-point)      [Kg/m2/s]
419      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr1    ! 1sr fraction of qsr penetration in ice (T-point)  [%]
420      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr2    ! 2nd fraction of qsr penetration in ice (T-point)  [%]
421      CHARACTER(len=1), INTENT(in   )                ::   cd_grid  ! ice grid ( C or B-grid)
422      INTEGER, INTENT(in   )                         ::   pdim     ! number of ice categories
423      !!
424      INTEGER  ::   ji, jj, jl    ! dummy loop indices
425      INTEGER  ::   ijpl          ! number of ice categories (size of 3rd dim of input arrays)
426      REAL(wp) ::   zst2, zst3
427      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
428      REAL(wp) ::   zcoef_frca                                   ! fractional cloud amount
429      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f                  ! relative wind module and components at F-point
430      REAL(wp) ::             zwndi_t , zwndj_t                  ! relative wind components at T-point
431      REAL(wp), DIMENSION(jpi,jpj) ::   z_wnds_t                 ! wind speed ( = | U10m - U_ice | ) at T-point
432      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qlw               ! long wave heat flux over ice
433      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qsb               ! sensible  heat flux over ice
434      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqlw              ! long wave heat sensitivity over ice
435      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqsb              ! sensible  heat sensitivity over ice
436      !!---------------------------------------------------------------------
437
438      ijpl  = pdim                            ! number of ice categories
439
440      ! local scalars ( place there for vector optimisation purposes)
441      zcoef_wnorm = rhoa * Cice
442      zcoef_wnorm2 = rhoa * Cice * 0.5
443      zcoef_dqlw = 4.0 * 0.95 * Stef
444      zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8)
445      zcoef_dqsb = rhoa * cpa * Cice
446      zcoef_frca = 1.0  - 0.3
447
448!!gm brutal....
449      z_wnds_t(:,:) = 0.e0
450      p_taui  (:,:) = 0.e0
451      p_tauj  (:,:) = 0.e0
452!!gm end
453
454      ! ----------------------------------------------------------------------------- !
455      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
456      ! ----------------------------------------------------------------------------- !
457      SELECT CASE( cd_grid )
458      CASE( 'B' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
459         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
460#if defined key_vectopt_loop
461!CDIR COLLAPSE
462#endif
463!CDIR NOVERRCHK
464         DO jj = 2, jpjm1
465            DO ji = 2, jpim1   ! B grid : no vector opt
466               ! ... scalar wind at I-point (fld being at T-point)
467               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ) + sf(jp_wndi)%fnow(ji  ,jj  )   &
468                  &              + sf(jp_wndi)%fnow(ji-1,jj-1) + sf(jp_wndi)%fnow(ji  ,jj-1)  ) - pui(ji,jj)
469               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ) + sf(jp_wndj)%fnow(ji  ,jj  )   &
470                  &              + sf(jp_wndj)%fnow(ji-1,jj-1) + sf(jp_wndj)%fnow(ji  ,jj-1)  ) - pvi(ji,jj)
471               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
472               ! ... ice stress at I-point
473               p_taui(ji,jj) = zwnorm_f * zwndi_f
474               p_tauj(ji,jj) = zwnorm_f * zwndj_f
475               ! ... scalar wind at T-point (fld being at T-point)
476               zwndi_t = sf(jp_wndi)%fnow(ji,jj) - 0.25 * (  pui(ji,jj+1) + pui(ji+1,jj+1)   &
477                  &                                        + pui(ji,jj  ) + pui(ji+1,jj  )  )
478               zwndj_t = sf(jp_wndj)%fnow(ji,jj) - 0.25 * (  pvi(ji,jj+1) + pvi(ji+1,jj+1)   &
479                  &                                        + pvi(ji,jj  ) + pvi(ji+1,jj  )  )
480               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
481            END DO
482         END DO
483         CALL lbc_lnk( p_taui  , 'I', -1. )
484         CALL lbc_lnk( p_tauj  , 'I', -1. )
485         CALL lbc_lnk( z_wnds_t, 'T',  1. )
486         !
487      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
488#if defined key_vectopt_loop
489!CDIR COLLAPSE
490#endif
491         DO jj = 2, jpj
492            DO ji = fs_2, jpi   ! vect. opt.
493               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pui(ji-1,jj  ) + pui(ji,jj) )  )
494               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pvi(ji  ,jj-1) + pvi(ji,jj) )  )
495               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
496            END DO
497         END DO
498#if defined key_vectopt_loop
499!CDIR COLLAPSE
500#endif
501         DO jj = 2, jpjm1
502            DO ji = fs_2, fs_jpim1   ! vect. opt.
503               p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj) + z_wnds_t(ji,jj) )                          &
504                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj) + sf(jp_wndi)%fnow(ji,jj) ) - pui(ji,jj) )
505               p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1) + z_wnds_t(ji,jj) )                          &
506                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1) + sf(jp_wndj)%fnow(ji,jj) ) - pvi(ji,jj) )
507            END DO
508         END DO
509         CALL lbc_lnk( p_taui  , 'U', -1. )
510         CALL lbc_lnk( p_tauj  , 'V', -1. )
511         CALL lbc_lnk( z_wnds_t, 'T',  1. )
512         !
513      END SELECT
514
515      !                                     ! ========================== !
516      DO jl = 1, ijpl                       !  Loop over ice categories  !
517         !                                  ! ========================== !
518!CDIR NOVERRCHK
519!CDIR COLLAPSE
520         DO jj = 1 , jpj
521!CDIR NOVERRCHK
522            DO ji = 1, jpi
523               ! ----------------------------!
524               !      I   Radiative FLUXES   !
525               ! ----------------------------!
526               zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
527               zst3 = pst(ji,jj,jl) * zst2
528               ! Short Wave (sw)
529               p_qsr(ji,jj,jl) = ( 1. - palb(ji,jj,jl) ) * sf(jp_qsr)%fnow(ji,jj) * tmask(ji,jj,1)
530               ! Long  Wave (lw)
531               z_qlw(ji,jj,jl) = 0.95 * (  sf(jp_qlw)%fnow(ji,jj)       &                         
532                  &                   - Stef * pst(ji,jj,jl) * zst3  ) * tmask(ji,jj,1)
533               ! lw sensitivity
534               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
535
536               ! ----------------------------!
537               !     II    Turbulent FLUXES  !
538               ! ----------------------------!
539
540               ! ... turbulent heat fluxes
541               ! Sensible Heat
542               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj) )
543               ! Latent Heat
544               p_qla(ji,jj,jl) = MAX( 0.e0, rhoa * Ls  * Cice * z_wnds_t(ji,jj)   &                           
545                  &                    * (  11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj)  ) )
546               ! Latent heat sensitivity for ice (Dqla/Dt)
547               p_dqla(ji,jj,jl) = zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
548               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
549               z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
550
551               ! ----------------------------!
552               !     III    Total FLUXES     !
553               ! ----------------------------!
554               ! Downward Non Solar flux
555               p_qns (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)     
556               ! Total non solar heat flux sensitivity for ice
557               p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )   
558            END DO
559            !
560         END DO
561         !
562      END DO
563      !
564      !--------------------------------------------------------------------
565      ! FRACTIONs of net shortwave radiation which is not absorbed in the
566      ! thin surface layer and penetrates inside the ice cover
567      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
568   
569!CDIR COLLAPSE
570      p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
571!CDIR COLLAPSE
572      p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
573       
574!CDIR COLLAPSE
575      p_tpr(:,:) = sf(jp_prec)%fnow(:,:) * rn_pfac      ! total precipitation [kg/m2/s]
576!CDIR COLLAPSE
577      p_spr(:,:) = sf(jp_snow)%fnow(:,:) * rn_pfac      ! solid precipitation [kg/m2/s]
578      CALL iom_put( 'snowpre', p_spr )                  ! Snow precipitation
579      !
580      IF(ln_ctl) THEN
581         CALL prt_ctl(tab3d_1=p_qla   , clinfo1=' blk_ice_core: p_qla  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb  : ', kdim=ijpl)
582         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw  : ', tab3d_2=p_dqla  , clinfo2=' p_dqla : ', kdim=ijpl)
583         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw : ', kdim=ijpl)
584         CALL prt_ctl(tab3d_1=p_dqns  , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr   , clinfo2=' p_qsr  : ', kdim=ijpl)
585         CALL prt_ctl(tab3d_1=pst     , clinfo1=' blk_ice_core: pst    : ', tab3d_2=p_qns   , clinfo2=' p_qns  : ', kdim=ijpl)
586         CALL prt_ctl(tab2d_1=p_tpr   , clinfo1=' blk_ice_core: p_tpr  : ', tab2d_2=p_spr   , clinfo2=' p_spr  : ')
587         CALL prt_ctl(tab2d_1=p_taui  , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj  , clinfo2=' p_tauj : ')
588         CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
589      ENDIF
590
591   END SUBROUTINE blk_ice_core
592 
593
594   SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a,   &
595      &                        dU, Cd, Ch, Ce   )
596      !!----------------------------------------------------------------------
597      !!                      ***  ROUTINE  turb_core  ***
598      !!
599      !! ** Purpose :   Computes turbulent transfert coefficients of surface
600      !!                fluxes according to Large & Yeager (2004)
601      !!
602      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
603      !!      Momentum, Latent and sensible heat exchange coefficients
604      !!      Caution: this procedure should only be used in cases when air
605      !!      temperature (T_air), air specific humidity (q_air) and wind (dU)
606      !!      are provided at the same height 'zzu'!
607      !!
608      !! References :
609      !!      Large & Yeager, 2004 : ???
610      !! History :
611      !!        !  XX-XX  (???     )  Original code
612      !!   9.0  !  05-08  (L. Brodeau) Rewriting and optimization
613      !!----------------------------------------------------------------------
614      !! * Arguments
615
616      REAL(wp), INTENT(in) :: zu                 ! altitude of wind measurement       [m]
617      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
618         sst,       &       ! sea surface temperature         [Kelvin]
619         T_a,       &       ! potential air temperature       [Kelvin]
620         q_sat,     &       ! sea surface specific humidity   [kg/kg]
621         q_a,       &       ! specific air humidity           [kg/kg]
622         dU                 ! wind module |U(zu)-U(0)|        [m/s]
623      REAL(wp), intent(out), DIMENSION(jpi,jpj)  :: &
624         Cd,    &                ! transfert coefficient for momentum       (tau)
625         Ch,    &                ! transfert coefficient for temperature (Q_sens)
626         Ce                      ! transfert coefficient for evaporation  (Q_lat)
627
628      !! * Local declarations
629      REAL(wp), DIMENSION(jpi,jpj)  ::   &
630         dU10,        &       ! dU                                   [m/s]
631         dT,          &       ! air/sea temperature differeence      [K]
632         dq,          &       ! air/sea humidity difference          [K]
633         Cd_n10,      &       ! 10m neutral drag coefficient
634         Ce_n10,      &       ! 10m neutral latent coefficient
635         Ch_n10,      &       ! 10m neutral sensible coefficient
636         sqrt_Cd_n10, &       ! root square of Cd_n10
637         sqrt_Cd,     &       ! root square of Cd
638         T_vpot,      &       ! virtual potential temperature        [K]
639         T_star,      &       ! turbulent scale of tem. fluct.
640         q_star,      &       ! turbulent humidity of temp. fluct.
641         U_star,      &       ! turb. scale of velocity fluct.
642         L,           &       ! Monin-Obukov length                  [m]
643         zeta,        &       ! stability parameter at height zu
644         U_n10,       &       ! neutral wind velocity at 10m         [m]   
645         xlogt, xct, zpsi_h, zpsi_m
646      !!
647      INTEGER :: j_itt
648      INTEGER, PARAMETER :: nb_itt = 3
649      INTEGER, DIMENSION(jpi,jpj)  ::   &
650         stab         ! 1st guess stability test integer
651
652      REAL(wp), PARAMETER ::                        &
653         grav   = 9.8,          &  ! gravity                       
654         kappa  = 0.4              ! von Karman s constant
655
656      !! * Start
657      !! Air/sea differences
658      dU10 = max(0.5, dU)     ! we don't want to fall under 0.5 m/s
659      dT = T_a - sst          ! assuming that T_a is allready the potential temp. at zzu
660      dq = q_a - q_sat
661      !!   
662      !! Virtual potential temperature
663      T_vpot = T_a*(1. + 0.608*q_a)
664      !!
665      !! Neutral Drag Coefficient
666      stab    = 0.5 + sign(0.5,dT)    ! stable : stab = 1 ; unstable : stab = 0
667      Cd_n10  = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 )    !   L & Y eq. (6a)
668      sqrt_Cd_n10 = sqrt(Cd_n10)
669      Ce_n10  = 1E-3 * ( 34.6 * sqrt_Cd_n10 )               !   L & Y eq. (6b)
670      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1-stab)) !   L & Y eq. (6c), (6d)
671      !!
672      !! Initializing transfert coefficients with their first guess neutral equivalents :
673      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
674
675      !! * Now starting iteration loop
676      DO j_itt=1, nb_itt
677         !! Turbulent scales :
678         U_star  = sqrt_Cd*dU10                !   L & Y eq. (7a)
679         T_star  = Ch/sqrt_Cd*dT               !   L & Y eq. (7b)
680         q_star  = Ce/sqrt_Cd*dq               !   L & Y eq. (7c)
681
682         !! Estimate the Monin-Obukov length :
683         L  = (U_star**2)/( kappa*grav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
684
685         !! Stability parameters :
686         zeta = zu/L ;  zeta   = sign( min(abs(zeta),10.0), zeta )
687         zpsi_h = psi_h(zeta)
688         zpsi_m = psi_m(zeta)
689
690         !! Shifting the wind speed to 10m and neutral stability :
691         U_n10 = dU10*1./(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)) !  L & Y eq. (9a)
692
693         !! Updating the neutral 10m transfer coefficients :
694         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)              !  L & Y eq. (6a)
695         sqrt_Cd_n10 = sqrt(Cd_n10)
696         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                           !  L & Y eq. (6b)
697         stab    = 0.5 + sign(0.5,zeta)
698         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab))           !  L & Y eq. (6c), (6d)
699
700         !! Shifting the neutral  10m transfer coefficients to ( zu , zeta ) :
701         !!
702         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
703         Cd  = Cd_n10/(xct*xct) ;  sqrt_Cd = sqrt(Cd)
704         !!
705         xlogt = log(zu/10.) - zpsi_h
706         !!
707         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
708         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
709         !!
710         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
711         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
712         !!
713      END DO
714      !!
715    END SUBROUTINE TURB_CORE_1Z
716
717
718    SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
719      !!----------------------------------------------------------------------
720      !!                      ***  ROUTINE  turb_core  ***
721      !!
722      !! ** Purpose :   Computes turbulent transfert coefficients of surface
723      !!                fluxes according to Large & Yeager (2004).
724      !!
725      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
726      !!      Momentum, Latent and sensible heat exchange coefficients
727      !!      Caution: this procedure should only be used in cases when air
728      !!      temperature (T_air) and air specific humidity (q_air) are at 2m
729      !!      whereas wind (dU) is at 10m.
730      !!
731      !! References :
732      !!      Large & Yeager, 2004 : ???
733      !! History :
734      !!   9.0  !  06-12  (L. Brodeau) Original code for 2Z
735      !!----------------------------------------------------------------------
736      REAL(wp), INTENT(in)   :: &
737         zt,      &     ! height for T_zt and q_zt                   [m]
738         zu             ! height for dU                              [m]
739      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
740         sst,      &     ! sea surface temperature              [Kelvin]
741         T_zt,     &     ! potential air temperature            [Kelvin]
742         q_sat,    &     ! sea surface specific humidity         [kg/kg]
743         q_zt,     &     ! specific air humidity                 [kg/kg]
744         dU              ! relative wind module |U(zu)-U(0)|       [m/s]
745      REAL(wp), INTENT(out), DIMENSION(jpi,jpj)  ::  &
746         Cd,       &     ! transfer coefficient for momentum         (tau)
747         Ch,       &     ! transfer coefficient for sensible heat (Q_sens)
748         Ce,       &     ! transfert coefficient for evaporation   (Q_lat)
749         T_zu,     &     ! air temp. shifted at zu                     [K]
750         q_zu            ! spec. hum.  shifted at zu               [kg/kg]
751
752      !! * Local declarations
753      REAL(wp), DIMENSION(jpi,jpj) ::  &
754         dU10,        &     ! dU                                [m/s]
755         dT,          &     ! air/sea temperature differeence   [K]
756         dq,          &     ! air/sea humidity difference       [K]
757         Cd_n10,      &     ! 10m neutral drag coefficient
758         Ce_n10,      &     ! 10m neutral latent coefficient
759         Ch_n10,      &     ! 10m neutral sensible coefficient
760         sqrt_Cd_n10, &     ! root square of Cd_n10
761         sqrt_Cd,     &     ! root square of Cd
762         T_vpot_u,    &     ! virtual potential temperature        [K]
763         T_star,      &     ! turbulent scale of tem. fluct.
764         q_star,      &     ! turbulent humidity of temp. fluct.
765         U_star,      &     ! turb. scale of velocity fluct.
766         L,           &     ! Monin-Obukov length                  [m]
767         zeta_u,      &     ! stability parameter at height zu
768         zeta_t,      &     ! stability parameter at height zt
769         U_n10,       &     ! neutral wind velocity at 10m        [m]
770         xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
771
772      INTEGER :: j_itt
773      INTEGER, PARAMETER :: nb_itt = 3   ! number of itterations
774      INTEGER, DIMENSION(jpi,jpj) :: &
775           &     stab                ! 1st stability test integer
776      REAL(wp), PARAMETER ::                        &
777         grav   = 9.8,      &  ! gravity                       
778         kappa  = 0.4          ! von Karman's constant
779
780      !!  * Start
781
782      !! Initial air/sea differences
783      dU10 = max(0.5, dU)      !  we don't want to fall under 0.5 m/s
784      dT = T_zt - sst 
785      dq = q_zt - q_sat
786
787      !! Neutral Drag Coefficient :
788      stab = 0.5 + sign(0.5,dT)                 ! stab = 1  if dT > 0  -> STABLE
789      Cd_n10  = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 ) 
790      sqrt_Cd_n10 = sqrt(Cd_n10)
791      Ce_n10  = 1E-3*( 34.6 * sqrt_Cd_n10 )
792      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1 - stab))
793
794      !! Initializing transf. coeff. with their first guess neutral equivalents :
795      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
796
797      !! Initializing z_u values with z_t values :
798      T_zu = T_zt ;  q_zu = q_zt
799
800      !!  * Now starting iteration loop
801      DO j_itt=1, nb_itt
802         dT = T_zu - sst ;  dq = q_zu - q_sat ! Updating air/sea differences
803         T_vpot_u = T_zu*(1. + 0.608*q_zu)    ! Updating virtual potential temperature at zu
804         U_star = sqrt_Cd*dU10                ! Updating turbulent scales :   (L & Y eq. (7))
805         T_star  = Ch/sqrt_Cd*dT              !
806         q_star  = Ce/sqrt_Cd*dq              !
807         !!
808         L = (U_star*U_star) &                ! Estimate the Monin-Obukov length at height zu
809              & / (kappa*grav/T_vpot_u*(T_star*(1.+0.608*q_zu) + 0.608*T_zu*q_star))
810         !! Stability parameters :
811         zeta_u  = zu/L  ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
812         zeta_t  = zt/L  ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
813         zpsi_hu = psi_h(zeta_u)
814         zpsi_ht = psi_h(zeta_t)
815         zpsi_m  = psi_m(zeta_u)
816         !!
817         !! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
818!        U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
819         U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
820         !!
821         !! Shifting temperature and humidity at zu :          (L & Y eq. (9b-9c))
822!        T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
823         T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
824!        q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
825         q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
826         !!
827         !! q_zu cannot have a negative value : forcing 0
828         stab = 0.5 + sign(0.5,q_zu) ;  q_zu = stab*q_zu
829         !!
830         !! Updating the neutral 10m transfer coefficients :
831         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)    ! L & Y eq. (6a)
832         sqrt_Cd_n10 = sqrt(Cd_n10)
833         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                 ! L & Y eq. (6b)
834         stab    = 0.5 + sign(0.5,zeta_u)
835         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab)) ! L & Y eq. (6c-6d)
836         !!
837         !!
838         !! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
839!        xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u))
840         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
841         Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
842         !!
843!        xlogt = log(zu/10.) - psi_h(zeta_u)
844         xlogt = log(zu/10.) - zpsi_hu
845         !!
846         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
847         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
848         !!
849         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
850         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
851         !!
852         !!
853      END DO
854      !!
855    END SUBROUTINE TURB_CORE_2Z
856
857
858    FUNCTION psi_m(zta)   !! Psis, L & Y eq. (8c), (8d), (8e)
859      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
860
861      REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
862      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
863      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
864      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.0) ;  X  = sqrt(X2)
865      stabit    = 0.5 + sign(0.5,zta)
866      psi_m = -5.*zta*stabit  &                                                  ! Stable
867           & + (1. - stabit)*(2*log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2)  ! Unstable
868    END FUNCTION psi_m
869
870    FUNCTION psi_h(zta)    !! Psis, L & Y eq. (8c), (8d), (8e)
871      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
872
873      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
874      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
875      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.) ;  X  = sqrt(X2)
876      stabit    = 0.5 + sign(0.5,zta)
877      psi_h = -5.*zta*stabit  &                                       ! Stable
878           & + (1. - stabit)*(2.*log( (1. + X2)/2. ))                 ! Unstable
879    END FUNCTION psi_h
880 
881   !!======================================================================
882END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.