New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 2210

Last change on this file since 2210 was 2188, checked in by smasson, 14 years ago

code review but GM for dev_r2174_DCY
  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  !  2006-07  (G. Madec)  Original code
7   !!             -   !  2008-08  (S. Masson, E. .... ) coupled interface
8   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_init       : read namsbc namelist
13   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
14   !!----------------------------------------------------------------------
15   USE oce              ! ocean dynamics and tracers
16   USE dom_oce          ! ocean space and time domain
17   USE phycst           ! physical constants
18   USE sbc_oce          ! Surface boundary condition: ocean fields
19   USE sbc_ice          ! Surface boundary condition: ice fields
20   USE sbcssm           ! surface boundary condition: sea-surface mean variables
21   USE sbcana           ! surface boundary condition: analytical formulation
22   USE sbcflx           ! surface boundary condition: flux formulation
23   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
24   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
25   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
26   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
27   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
28   USE sbccpl           ! surface boundary condition: coupled florulation
29   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
30   USE sbcssr           ! surface boundary condition: sea surface restoring
31   USE sbcrnf           ! surface boundary condition: runoffs
32   USE sbcfwb           ! surface boundary condition: freshwater budget
33   USE closea           ! closed sea
34
35   USE prtctl           ! Print control                    (prt_ctl routine)
36   USE restart          ! ocean restart
37   USE iom              ! IOM library
38   USE in_out_manager   ! I/O manager
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   sbc        ! routine called by step.F90
44   PUBLIC   sbc_init   ! routine called by opa.F90
45   
46   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
47     
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
52   !! $Id$
53   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE sbc_init
58      !!---------------------------------------------------------------------
59      !!                    ***  ROUTINE sbc_init ***
60      !!
61      !! ** Purpose :   Initialisation of the ocean surface boundary computation
62      !!
63      !! ** Method  :   Read the namsbc namelist and set derived parameters
64      !!
65      !! ** Action  : - read namsbc parameters
66      !!              - nsbc: type of sbc
67      !!----------------------------------------------------------------------
68      INTEGER ::   icpt      ! temporary integer
69      !!
70      NAMELIST/namsbc/ nn_fsbc, ln_ana  , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl    ,   &
71         &             nn_ice , ln_dm2dc, ln_rnf, ln_ssr     , nn_fwb     , nn_ico_cpl
72      !!----------------------------------------------------------------------
73
74      IF(lwp) THEN
75         WRITE(numout,*)
76         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
77         WRITE(numout,*) '~~~~~~~~ '
78      ENDIF
79
80      REWIND( numnam )           ! Read Namelist namsbc
81      READ  ( numnam, namsbc )
82
83      !                          ! overwrite namelist parameter using CPP key information
84      IF( Agrif_Root() ) THEN                ! AGRIF zoom
85        IF( lk_lim2 )   nn_ice      = 2
86        IF( lk_lim3 )   nn_ice      = 3
87      ENDIF
88      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
89          ln_ana      = .TRUE.   
90          nn_ice      =   0
91      ENDIF
92     
93      IF(lwp) THEN               ! Control print
94         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
95         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
96         WRITE(numout,*) '           Type of sbc : '
97         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
98         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
99         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
100         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_core = ', ln_blk_core
101         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
102         WRITE(numout,*) '           Misc. options of sbc : '
103         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
104         WRITE(numout,*) '              ice-ocean stress computation (=0/1/2)      nn_ico_cpl  = ', nn_ico_cpl
105         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
106         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
107         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
108         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
109         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
110      ENDIF
111
112      !                          ! Checks:
113      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
114         ln_rnf_mouth  = .false.                     
115         nkrnf         = 0
116         rnfmsk  (:,:) = 0.e0
117         rnfmsk_z(:)   = 0.e0
118      ENDIF
119      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
120
121      !                                            ! restartability   
122      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
123          MOD( nstock             , nn_fsbc) /= 0 ) THEN
124         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
125            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
126         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
127      ENDIF
128      !
129      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
130         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
131      !
132      IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
133         &   CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
134     
135      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
136         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
137     
138      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
139         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
140     
141      !                          ! Choice of the Surface Boudary Condition (set nsbc)
142      icpt = 0
143      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
144      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
145      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
146      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
147      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
148      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
149      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
150      !
151      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
152         WRITE(numout,*)
153         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
154         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
155         WRITE(numout,*) '                     We stop'
156         nstop = nstop + 1
157      ENDIF
158      IF(lwp) THEN
159         WRITE(numout,*)
160         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
161         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
162         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
163         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
164         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
165         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
166         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
167      ENDIF
168      !
169   END SUBROUTINE sbc_init
170
171
172   SUBROUTINE sbc( kt )
173      !!---------------------------------------------------------------------
174      !!                    ***  ROUTINE sbc  ***
175      !!             
176      !! ** Purpose :   provide at each time-step the ocean surface boundary
177      !!                condition (momentum, heat and freshwater fluxes)
178      !!
179      !! ** Method  :   blah blah  to be written ?????????
180      !!                CAUTION : never mask the surface stress field (tke sbc)
181      !!
182      !! ** Action  : - set the ocean surface boundary condition, i.e. 
183      !!                utau, vtau, qns, qsr, emp, emps, qrp, erp
184      !!              - updte the ice fraction : fr_i
185      !!----------------------------------------------------------------------
186      INTEGER, INTENT(in) ::   kt       ! ocean time step
187      !!---------------------------------------------------------------------
188
189      CALL iom_setkt( kt + nn_fsbc - 1 )         !  in sbc, iom_put is called every nn_fsbc time step
190      !
191      ! ocean to sbc mean sea surface variables (ss._m)
192      ! ---------------------------------------
193      CALL sbc_ssm( kt )                         ! sea surface mean currents (at U- and V-points),
194      !                                          ! temperature and salinity (at T-point) over nf_sbc time-step
195      !                                          ! (i.e. sst_m, sss_m, ssu_m, ssv_m)
196
197      ! sbc formulation
198      ! ---------------
199         
200      SELECT CASE( nsbc )                        ! Compute ocean surface boundary condition
201      !                                          ! (i.e. utau,vtau, qns, qsr, emp, emps)
202      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
203      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
204      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
205      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
206      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
207      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
208      CASE( -1 )                               
209                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
210                       CALL sbc_gyre    ( kt )                    !
211                       CALL sbc_flx     ( kt )                    !
212                       CALL sbc_blk_clio( kt )                    !
213                       CALL sbc_blk_core( kt )                    !
214                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
215      END SELECT
216
217      ! Misc. Options
218      ! -------------
219     
220      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
221      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                   ! Ice-cover climatology ("Ice-if" model)
222         !                                                     
223      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )             ! LIM 2.0 ice model
224         !                                                     
225      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc, nn_ico_cpl)  ! LIM 3.0 ice model
226      END SELECT                                             
227
228      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
229 
230      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
231
232      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
233
234      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
235      !                                                         ! (update freshwater fluxes)
236      !
237      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
238         CALL iom_put( "emp"    , emp       )                   ! upward water flux
239         CALL iom_put( "emps"   , emps      )                   ! c/d water flux
240         CALL iom_put( "qns+qsr", qns + qsr )                   ! total heat flux
241         CALL iom_put( "qns"    , qns       )                   ! solar heat flux
242         CALL iom_put( "qsr"    ,       qsr )                   ! solar heat flux
243         IF(  nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )  ! ice fraction
244      ENDIF
245      !
246      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
247      !
248      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
249      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
250      CALL iom_put( "taum", taum )   ! wind stress module
251      CALL iom_put( "wspd", wndm )   ! wind speed  module
252      !
253      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
254         CALL prt_ctl(tab2d_1=fr_i   , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
255         CALL prt_ctl(tab2d_1=emp    , clinfo1=' emp  - : ', mask1=tmask, ovlap=1 )
256         CALL prt_ctl(tab2d_1=emps   , clinfo1=' emps - : ', mask1=tmask, ovlap=1 )
257         CALL prt_ctl(tab2d_1=qns    , clinfo1=' qns  - : ', mask1=tmask, ovlap=1 )
258         CALL prt_ctl(tab2d_1=qsr    , clinfo1=' qsr  - : ', mask1=tmask, ovlap=1 )
259         CALL prt_ctl(tab3d_1=tmask  , clinfo1=' tmask  : ', mask1=tmask, ovlap=1, kdim=jpk )
260         CALL prt_ctl(tab3d_1=tn     , clinfo1=' sst  - : ', mask1=tmask, ovlap=1, kdim=1   )
261         CALL prt_ctl(tab3d_1=sn     , clinfo1=' sss  - : ', mask1=tmask, ovlap=1, kdim=1   )
262         CALL prt_ctl(tab2d_1=utau   , clinfo1=' utau - : ', mask1=umask,                      &
263            &         tab2d_2=vtau   , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
264      ENDIF
265      !
266   END SUBROUTINE sbc
267
268   !!======================================================================
269END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.