New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_sal.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/LIM_SRC_3/limthd_sal.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE limthd_sal
2   !!======================================================================
3   !!                       ***  MODULE limthd_sal ***
4   !! LIM-3 sea-ice :  computation of salinity variations in the ice
5   !!======================================================================
6   !! History :   -   ! 2003-05 (M. Vancoppenolle) UCL-ASTR first coding for LIM3-1D
7   !!            3.0  ! 2005-12 (M. Vancoppenolle) adapted to the 3-D version
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!---------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM-3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_thd_sal : salinity variations in the ice
15   !!----------------------------------------------------------------------
16   USE par_oce          ! ocean parameters
17   USE phycst           ! physical constants (ocean directory)
18   USE sbc_oce          ! Surface boundary condition: ocean fields
19   USE ice              ! LIM variables
20   USE par_ice          ! LIM parameters
21   USE thd_ice          ! LIM thermodynamics
22   USE limvar           ! LIM variables
23   USE wrk_nemo         ! workspace manager
24   USE in_out_manager   ! I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   lim_thd_sal        ! called by limthd module
30   PUBLIC   lim_thd_sal_init   ! called by iceini module
31
32   !!----------------------------------------------------------------------
33   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE lim_thd_sal( kideb, kiut )
40      !!-------------------------------------------------------------------
41      !!                ***  ROUTINE lim_thd_sal  ***   
42      !!   
43      !! ** Purpose :   computes new salinities in the ice
44      !!
45      !! ** Method  :  4 possibilities
46      !!               -> num_sal = 1 -> constant salinity for z,t
47      !!               -> num_sal = 2 -> S = S(z,t) [simple Vancoppenolle et al 2005]
48      !!               -> num_sal = 3 -> S = S(z)   [multiyear ice]
49      !!               -> num_sal = 4 -> S = S(h)   [Cox and Weeks 74]
50      !!---------------------------------------------------------------------
51      INTEGER, INTENT(in) ::  kideb, kiut   ! thickness category index
52      !
53      INTEGER  ::   ji, jk     ! dummy loop indices
54      INTEGER  ::   zji, zjj   ! local integers
55      REAL(wp) ::   zsold, iflush, iaccrbo, igravdr, isnowic, i_ice_switch,  ztmelts   ! local scalars
56      REAL(wp) ::   zaaa, zbbb, zccc, zdiscrim   ! local scalars
57      !
58      REAL(wp), POINTER, DIMENSION(:) ::   ze_init, zhiold, zsiold
59      !!---------------------------------------------------------------------
60
61      IF(  wrk_in_use(1, 1,2,3)  ) THEN
62         CALL ctl_stop('lim_thd_dh : requestead workspace arrays unavailable.')   ;   RETURN
63      END IF
64      ! Set-up pointers to sub-arrays of workspace arrays
65      ze_init =>  wrk_1d_1 (1:jpij)
66      zhiold  =>  wrk_1d_2 (1:jpij)
67      zsiold  =>  wrk_1d_3 (1:jpij)
68
69      !------------------------------------------------------------------------------|
70      ! 1) Constant salinity, constant in time                                       |
71      !------------------------------------------------------------------------------|
72!!gm comment: if num_sal = 1 s_i_b and sm_i_b can be set to bulk_sal one for all in the initialisation phase !!
73      IF( num_sal == 1 ) THEN
74         !
75         DO jk = 1, nlay_i
76            DO ji = kideb, kiut
77               s_i_b(ji,jk) =  bulk_sal
78            END DO ! ji
79         END DO ! jk
80         !
81         DO ji = kideb, kiut
82            sm_i_b(ji)      =  bulk_sal 
83         END DO ! ji
84         !
85      ENDIF
86
87      !------------------------------------------------------------------------------|
88      !  Module 2 : Constant salinity varying in time                                |
89      !------------------------------------------------------------------------------|
90
91      IF(  num_sal == 2  .OR.  num_sal == 4  ) THEN
92
93         !---------------------------------
94         ! Thickness at previous time step
95         !---------------------------------
96         DO ji = kideb, kiut
97            zhiold(ji) = ht_i_b(ji) - dh_i_bott(ji) - dh_snowice(ji) - dh_i_surf(ji)
98         END DO
99
100         !---------------------
101         ! Global heat content
102         !---------------------
103         ze_init(:)  =  0._wp
104         DO jk = 1, nlay_i
105            DO ji = kideb, kiut
106               ze_init(ji) = ze_init(ji) + q_i_b(ji,jk) * ht_i_b(ji) / nlay_i
107            END DO
108         END DO
109
110         DO ji = kideb, kiut
111            !
112            ! Switches
113            !----------
114            iflush       =         MAX( 0._wp , SIGN( 1.0 , t_su_b(ji) - rtt )        )    ! =1 if summer
115            igravdr      =         MAX( 0._wp , SIGN( 1.0 , t_bo_b(ji) - t_su_b(ji) ) )    ! =1 if t_su < t_bo
116            iaccrbo      =         MAX( 0._wp , SIGN( 1.0 , dh_i_bott(ji) )           )    ! =1 if bottom accretion
117            i_ice_switch = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - ht_i_b(ji) + 1.e-2 ) )
118            isnowic      = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - dh_snowice(ji) ) ) * i_ice_switch   ! =1 if snow ice formation
119
120            !---------------------
121            ! Salinity tendencies
122            !---------------------
123            !                                   ! drainage by gravity drainage
124            dsm_i_gd_1d(ji) = - igravdr * MAX( sm_i_b(ji) - sal_G , 0._wp ) / time_G * rdt_ice 
125            !                                   ! drainage by flushing 
126            dsm_i_fl_1d(ji) = - iflush * MAX( sm_i_b(ji) - sal_F , 0._wp ) / time_F * rdt_ice
127
128            !-----------------
129            ! Update salinity   
130            !-----------------
131            ! only drainage terms ( gravity drainage and flushing )
132            ! snow ice / bottom sources are added in lim_thd_ent to conserve energy
133            zsiold(ji) = sm_i_b(ji)
134            sm_i_b(ji) = sm_i_b(ji) + dsm_i_fl_1d(ji) + dsm_i_gd_1d(ji)
135
136            ! if no ice, salinity = 0.1
137            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
138            sm_i_b(ji)   = i_ice_switch * sm_i_b(ji) + s_i_min * ( 1._wp - i_ice_switch )
139         END DO ! ji
140
141         ! Salinity profile
142         CALL lim_var_salprof1d( kideb, kiut )
143
144         !----------------------------
145         ! Heat flux - brine drainage
146         !----------------------------
147
148         DO ji = kideb, kiut
149!!gm useless
150            ! iflush  : 1 if summer
151            iflush  =  MAX( 0._wp , SIGN ( 1._wp , t_su_b(ji) - rtt ) ) 
152            ! igravdr : 1 if t_su lt t_bo
153            igravdr =  MAX( 0._wp , SIGN ( 1._wp , t_bo_b(ji) - t_su_b(ji) ) ) 
154            ! iaccrbo : 1 if bottom accretion
155            iaccrbo =  MAX( 0._wp , SIGN ( 1._wp , dh_i_bott(ji) ) )
156!!gm end useless
157            !
158            fhbri_1d(ji) = 0._wp
159         END DO ! ji
160
161         !----------------------------
162         ! Salt flux - brine drainage
163         !----------------------------
164         DO ji = kideb, kiut
165            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
166            fsbri_1d(ji) = fsbri_1d(ji) - i_ice_switch * rhoic * a_i_b(ji) * ht_i_b(ji)         &
167               &         * ( MAX(dsm_i_gd_1d(ji) + dsm_i_fl_1d(ji), sm_i_b(ji) - zsiold(ji) ) ) / rdt_ice
168            IF( num_sal == 4 ) fsbri_1d(ji) = 0._wp
169         END DO ! ji
170
171         ! Only necessary for conservation check since salinity is modified
172         !--------------------
173         ! Temperature update
174         !--------------------
175         DO jk = 1, nlay_i
176            DO ji = kideb, kiut
177               ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
178               !Conversion q(S,T) -> T (second order equation)
179               zaaa         =  cpic
180               zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
181               zccc         =  lfus * ( ztmelts - rtt )
182               zdiscrim     =  SQRT(  MAX( zbbb*zbbb - 4.0*zaaa*zccc, 0._wp )  )
183               t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
184            END DO
185         END DO
186         !
187      ENDIF ! num_sal .EQ. 2
188
189      !------------------------------------------------------------------------------|
190      !  Module 3 : Profile of salinity, constant in time                            |
191      !------------------------------------------------------------------------------|
192
193      IF( num_sal == 3 )   CALL lim_var_salprof1d( kideb, kiut )
194
195      !------------------------------------------------------------------------------|
196      !  Module 4 : Constant salinity varying in time                                |
197      !------------------------------------------------------------------------------|
198
199      IF( num_sal == 5 ) THEN      ! Cox and Weeks, 1974
200         !
201         DO ji = kideb, kiut
202            zsold = sm_i_b(ji)
203            IF( ht_i_b(ji) < 0.4 ) THEN
204               sm_i_b(ji) = 14.24 - 19.39 * ht_i_b(ji) 
205            ELSE
206               sm_i_b(ji) =  7.88 - 1.59 * ht_i_b(ji)
207               sm_i_b(ji) = MIN( sm_i_b(ji) , zsold ) 
208            ENDIF
209            IF( ht_i_b(ji) > 3.06918239 ) THEN
210               sm_i_b(ji) = 3._wp
211            ENDIF
212            DO jk = 1, nlay_i
213               s_i_b(ji,jk)   = sm_i_b(ji)
214            END DO
215         END DO
216         !
217      ENDIF ! num_sal
218
219      !------------------------------------------------------------------------------|
220      ! 5) Computation of salt flux due to Bottom growth
221      !------------------------------------------------------------------------------|
222
223      IF ( num_sal == 4 ) THEN
224         DO ji = kideb, kiut
225            zji = MOD( npb(ji) - 1 , jpi ) + 1
226            zjj =    ( npb(ji) - 1 ) / jpi + 1
227            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - bulk_sal    )               &
228               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
229         END DO
230      ELSE
231         DO ji = kideb, kiut
232            zji = MOD( npb(ji) - 1 , jpi ) + 1
233            zjj =    ( npb(ji) - 1 ) / jpi + 1
234            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - s_i_new(ji) )               &
235               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
236         END DO
237      ENDIF
238      !
239      IF( wrk_not_released(1, 1,2,3) )   CALL ctl_stop( 'lim_thd_lac : failed to release workspace arrays.' )
240      !
241   END SUBROUTINE lim_thd_sal
242
243
244   SUBROUTINE lim_thd_sal_init
245      !!-------------------------------------------------------------------
246      !!                  ***  ROUTINE lim_thd_sal_init  ***
247      !!
248      !! ** Purpose :   initialization of ice salinity parameters
249      !!
250      !! ** Method  :   Read the namicesal namelist and check the parameter
251      !!              values called at the first timestep (nit000)
252      !!
253      !! ** input   :   Namelist namicesal
254      !!-------------------------------------------------------------------
255      NAMELIST/namicesal/ num_sal, bulk_sal, sal_G, time_G, sal_F, time_F,   &
256         &                s_i_max, s_i_min, s_i_0, s_i_1
257      !!-------------------------------------------------------------------
258      !
259      REWIND( numnam_ice )                   ! Read Namelist namicesal
260      READ  ( numnam_ice  , namicesal )
261      !
262      IF(lwp) THEN                           ! control print
263         WRITE(numout,*)
264         WRITE(numout,*) 'lim_thd_sal_init : Ice parameters for salinity '
265         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
266         WRITE(numout,*) ' switch for salinity num_sal        : ', num_sal
267         WRITE(numout,*) ' bulk salinity value if num_sal = 1 : ', bulk_sal
268         WRITE(numout,*) ' restoring salinity for GD          : ', sal_G
269         WRITE(numout,*) ' restoring time for GD              : ', time_G
270         WRITE(numout,*) ' restoring salinity for flushing    : ', sal_F
271         WRITE(numout,*) ' restoring time for flushing        : ', time_F
272         WRITE(numout,*) ' Maximum tolerated ice salinity     : ', s_i_max
273         WRITE(numout,*) ' Minimum tolerated ice salinity     : ', s_i_min
274         WRITE(numout,*) ' 1st salinity for salinity profile  : ', s_i_0
275         WRITE(numout,*) ' 2nd salinity for salinity profile  : ', s_i_1
276      ENDIF
277      !
278   END SUBROUTINE lim_thd_sal_init
279
280#else
281   !!----------------------------------------------------------------------
282   !!   Default option         Dummy Module          No LIM-3 sea-ice model
283   !!----------------------------------------------------------------------
284#endif
285   !!======================================================================
286END MODULE limthd_sal
Note: See TracBrowser for help on using the repository browser.