New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limvar.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/LIM_SRC_3/limvar.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 22.2 KB
Line 
1MODULE limvar
2   !!======================================================================
3   !!                       ***  MODULE limvar ***
4   !!                 Different sets of ice model variables
5   !!                   how to switch from one to another
6   !!
7   !!                 There are three sets of variables
8   !!                 VGLO : global variables of the model
9   !!                        - v_i (jpi,jpj,jpl)
10   !!                        - v_s (jpi,jpj,jpl)
11   !!                        - a_i (jpi,jpj,jpl)
12   !!                        - t_s (jpi,jpj,jpl)
13   !!                        - e_i (jpi,jpj,nlay_i,jpl)
14   !!                        - smv_i(jpi,jpj,jpl)
15   !!                        - oa_i (jpi,jpj,jpl)
16   !!                 VEQV : equivalent variables sometimes used in the model
17   !!                        - ht_i(jpi,jpj,jpl)
18   !!                        - ht_s(jpi,jpj,jpl)
19   !!                        - t_i (jpi,jpj,nlay_i,jpl)
20   !!                        ...
21   !!                 VAGG : aggregate variables, averaged/summed over all
22   !!                        thickness categories
23   !!                        - vt_i(jpi,jpj)
24   !!                        - vt_s(jpi,jpj)
25   !!                        - at_i(jpi,jpj)
26   !!                        - et_s(jpi,jpj)  !total snow heat content
27   !!                        - et_i(jpi,jpj)  !total ice thermal content
28   !!                        - smt_i(jpi,jpj) !mean ice salinity
29   !!                        - ot_i(jpi,jpj)  !average ice age
30   !!======================================================================
31   !! History :   -   ! 2006-01 (M. Vancoppenolle) Original code
32   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
33   !!----------------------------------------------------------------------
34#if defined key_lim3
35   !!----------------------------------------------------------------------
36   !!   'key_lim3'                                      LIM3 sea-ice model
37   !!----------------------------------------------------------------------
38   !!   lim_var_agg       :
39   !!   lim_var_glo2eqv   :
40   !!   lim_var_eqv2glo   :
41   !!   lim_var_salprof   :
42   !!   lim_var_salprof1d :
43   !!   lim_var_bv        :
44   !!----------------------------------------------------------------------
45   USE par_oce          ! ocean parameters
46   USE phycst           ! physical constants (ocean directory)
47   USE sbc_oce          ! Surface boundary condition: ocean fields
48   USE ice              ! LIM variables
49   USE par_ice          ! LIM parameters
50   USE dom_ice          ! LIM domain
51   USE thd_ice          ! LIM thermodynamics
52   USE wrk_nemo         ! workspace manager
53   USE in_out_manager   ! I/O manager
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   lim_var_agg          !
59   PUBLIC   lim_var_glo2eqv      !
60   PUBLIC   lim_var_eqv2glo      !
61   PUBLIC   lim_var_salprof      !
62   PUBLIC   lim_var_bv           !
63   PUBLIC   lim_var_salprof1d    !
64
65   REAL(wp) ::   eps20 = 1.e-20_wp   ! module constants
66   REAL(wp) ::   eps16 = 1.e-16_wp   !    -       -
67   REAL(wp) ::   eps13 = 1.e-13_wp   !    -       -
68   REAL(wp) ::   eps10 = 1.e-10_wp   !    -       -
69   REAL(wp) ::   eps06 = 1.e-06_wp   !    -       -
70   REAL(wp) ::   zzero = 0.e0        !    -       -
71   REAL(wp) ::   zone  = 1.e0        !    -       -
72
73   !!----------------------------------------------------------------------
74   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
75   !! $Id$
76   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE lim_var_agg( kn )
81      !!------------------------------------------------------------------
82      !!                ***  ROUTINE lim_var_agg  ***
83      !!
84      !! ** Purpose :   aggregates ice-thickness-category variables to all-ice variables
85      !!              i.e. it turns VGLO into VAGG
86      !! ** Method  :
87      !!
88      !! ** Arguments : n = 1, at_i vt_i only
89      !!                n = 2 everything
90      !!
91      !! note : you could add an argument when you need only at_i, vt_i
92      !!        and when you need everything
93      !!------------------------------------------------------------------
94      INTEGER, INTENT( in ) ::   kn     ! =1 at_i & vt only ; = what is needed
95      !
96      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
97      REAL(wp) ::   zinda
98      !!------------------------------------------------------------------
99
100      !--------------------
101      ! Compute variables
102      !--------------------
103      vt_i (:,:) = 0._wp
104      vt_s (:,:) = 0._wp
105      at_i (:,:) = 0._wp
106      ato_i(:,:) = 1._wp
107      !
108      DO jl = 1, jpl
109         DO jj = 1, jpj
110            DO ji = 1, jpi
111               !
112               vt_i(ji,jj) = vt_i(ji,jj) + v_i(ji,jj,jl) ! ice volume
113               vt_s(ji,jj) = vt_s(ji,jj) + v_s(ji,jj,jl) ! snow volume
114               at_i(ji,jj) = at_i(ji,jj) + a_i(ji,jj,jl) ! ice concentration
115               !
116               zinda = MAX( zzero , SIGN( zone , at_i(ji,jj) - 0.10 ) ) 
117               icethi(ji,jj) = vt_i(ji,jj) / MAX( at_i(ji,jj) , eps16 ) * zinda  ! ice thickness
118            END DO
119         END DO
120      END DO
121
122      DO jj = 1, jpj
123         DO ji = 1, jpi
124            ato_i(ji,jj) = MAX( 1._wp - at_i(ji,jj), 0._wp )   ! open water fraction
125         END DO
126      END DO
127
128      IF( kn > 1 ) THEN
129         et_s (:,:) = 0._wp
130         ot_i (:,:) = 0._wp
131         smt_i(:,:) = 0._wp
132         et_i (:,:) = 0._wp
133         !
134         DO jl = 1, jpl
135            DO jj = 1, jpj
136               DO ji = 1, jpi
137                  et_s(ji,jj)  = et_s(ji,jj)  + e_s(ji,jj,1,jl)                                       ! snow heat content
138                  zinda = MAX( zzero , SIGN( zone , vt_i(ji,jj) - 0.10 ) ) 
139                  smt_i(ji,jj) = smt_i(ji,jj) + smv_i(ji,jj,jl) / MAX( vt_i(ji,jj) , eps13 ) * zinda   ! ice salinity
140                  zinda = MAX( zzero , SIGN( zone , at_i(ji,jj) - 0.10 ) ) 
141                  ot_i(ji,jj)  = ot_i(ji,jj)  + oa_i(ji,jj,jl)  / MAX( at_i(ji,jj) , eps13 ) * zinda   ! ice age
142               END DO
143            END DO
144         END DO
145         !
146         DO jl = 1, jpl
147            DO jk = 1, nlay_i
148               et_i(:,:) = et_i(:,:) + e_i(:,:,jk,jl)       ! ice heat content
149            END DO
150         END DO
151         !
152      ENDIF
153      !
154   END SUBROUTINE lim_var_agg
155
156
157   SUBROUTINE lim_var_glo2eqv
158      !!------------------------------------------------------------------
159      !!                ***  ROUTINE lim_var_glo2eqv ***
160      !!
161      !! ** Purpose :   computes equivalent variables as function of global variables
162      !!              i.e. it turns VGLO into VEQV
163      !!------------------------------------------------------------------
164      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
165      REAL(wp) ::   zq_i, zaaa, zbbb, zccc, zdiscrim     ! local scalars
166      REAL(wp) ::   ztmelts, zindb, zq_s, zfac1, zfac2   !   -      -
167      !!------------------------------------------------------------------
168
169      !-------------------------------------------------------
170      ! Ice thickness, snow thickness, ice salinity, ice age
171      !-------------------------------------------------------
172      DO jl = 1, jpl
173         DO jj = 1, jpj
174            DO ji = 1, jpi
175               zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) ) )   !0 if no ice and 1 if yes
176               ht_i(ji,jj,jl) = v_i (ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
177               ht_s(ji,jj,jl) = v_s (ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
178               o_i(ji,jj,jl)  = oa_i(ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
179            END DO
180         END DO
181      END DO
182
183      IF(  num_sal == 2  .OR.  num_sal == 4  )THEN
184         DO jl = 1, jpl
185            DO jj = 1, jpj
186               DO ji = 1, jpi
187                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) ) )   !0 if no ice and 1 if yes
188                  sm_i(ji,jj,jl) = smv_i(ji,jj,jl) / MAX( v_i(ji,jj,jl) , eps10 ) * zindb
189               END DO
190            END DO
191         END DO
192      ENDIF
193
194      CALL lim_var_salprof      ! salinity profile
195
196      !-------------------
197      ! Ice temperatures
198      !-------------------
199!CDIR NOVERRCHK
200      DO jl = 1, jpl
201!CDIR NOVERRCHK
202         DO jk = 1, nlay_i
203!CDIR NOVERRCHK
204            DO jj = 1, jpj
205!CDIR NOVERRCHK
206               DO ji = 1, jpi
207                  !                                                              ! Energy of melting q(S,T) [J.m-3]
208                  zq_i    = e_i(ji,jj,jk,jl) / area(ji,jj) / MAX( v_i(ji,jj,jl) , eps06 ) * REAL(nlay_i,wp) 
209                  zindb   = 1.0 - MAX( 0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
210                  zq_i    = zq_i * unit_fac * zindb                              !convert units
211                  ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt                       ! Ice layer melt temperature
212                  !
213                  zaaa       =  cpic                  ! Conversion q(S,T) -> T (second order equation)
214                  zbbb       =  ( rcp - cpic ) * ( ztmelts - rtt ) + zq_i / rhoic - lfus
215                  zccc       =  lfus * (ztmelts-rtt)
216                  zdiscrim   =  SQRT( MAX(zbbb*zbbb - 4._wp*zaaa*zccc , 0._wp) )
217                  t_i(ji,jj,jk,jl) = rtt + zindb *( - zbbb - zdiscrim ) / ( 2.0 *zaaa )
218                  t_i(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15_wp, t_i(ji,jj,jk,jl) ) )       ! 100-rtt < t_i < rtt
219               END DO
220            END DO
221         END DO
222      END DO
223
224      !--------------------
225      ! Snow temperatures
226      !--------------------
227      zfac1 = 1._wp / ( rhosn * cpic )
228      zfac2 = lfus / cpic 
229      DO jl = 1, jpl
230         DO jk = 1, nlay_s
231            DO jj = 1, jpj
232               DO ji = 1, jpi
233                  !Energy of melting q(S,T) [J.m-3]
234                  zq_s  = e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , eps06 ) ) * REAL(nlay_s,wp)
235                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp , - v_s(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
236                  zq_s  = zq_s * unit_fac * zindb                                    ! convert units
237                  !
238                  t_s(ji,jj,jk,jl) = rtt + zindb * ( - zfac1 * zq_s + zfac2 )
239                  t_s(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15, t_s(ji,jj,jk,jl) ) )     ! 100-rtt < t_i < rtt
240               END DO
241            END DO
242         END DO
243      END DO
244
245      !-------------------
246      ! Mean temperature
247      !-------------------
248      tm_i(:,:) = 0._wp
249      DO jl = 1, jpl
250         DO jk = 1, nlay_i
251            DO jj = 1, jpj
252               DO ji = 1, jpi
253                  zindb = (  1._wp - MAX( 0._wp , SIGN( 1._wp , -a_i(ji,jj,jl) ) )  )   &
254                     &  * (  1._wp - MAX( 0._wp , SIGN( 1._wp , -v_i(ji,jj,jl) ) )  )
255                  tm_i(ji,jj) = tm_i(ji,jj) + t_i(ji,jj,jk,jl) * v_i(ji,jj,jl)   &
256                     &                      / (  REAL(nlay_i,wp) * MAX( vt_i(ji,jj) , eps10 )  )
257               END DO
258            END DO
259         END DO
260      END DO
261      !
262   END SUBROUTINE lim_var_glo2eqv
263
264
265   SUBROUTINE lim_var_eqv2glo
266      !!------------------------------------------------------------------
267      !!                ***  ROUTINE lim_var_eqv2glo ***
268      !!
269      !! ** Purpose :   computes global variables as function of equivalent variables
270      !!                i.e. it turns VEQV into VGLO
271      !! ** Method  :
272      !!
273      !! ** History :  (01-2006) Martin Vancoppenolle, UCL-ASTR
274      !!------------------------------------------------------------------
275      !
276      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
277      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
278      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
279      oa_i (:,:,:) = o_i (:,:,:) * a_i(:,:,:)
280      !
281   END SUBROUTINE lim_var_eqv2glo
282
283
284   SUBROUTINE lim_var_salprof
285      !!------------------------------------------------------------------
286      !!                ***  ROUTINE lim_var_salprof ***
287      !!
288      !! ** Purpose :   computes salinity profile in function of bulk salinity     
289      !!
290      !! ** Method  : If bulk salinity greater than s_i_1,
291      !!              the profile is assumed to be constant (S_inf)
292      !!              If bulk salinity lower than s_i_0,
293      !!              the profile is linear with 0 at the surface (S_zero)
294      !!              If it is between s_i_0 and s_i_1, it is a
295      !!              alpha-weighted linear combination of s_inf and s_zero
296      !!
297      !! ** References : Vancoppenolle et al., 2007 (in preparation)
298      !!------------------------------------------------------------------
299      INTEGER  ::   ji, jj, jk, jl   ! dummy loop index
300      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac, zsal      ! local scalar
301      REAL(wp) ::   zind0, zind01, zindbal, zargtemp , zs_zero   !   -      -
302      !
303      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_slope_s, zalpha   ! 3D pointer
304      !!------------------------------------------------------------------
305
306      IF( wrk_in_use( 2, 1,2 ) ) THEN
307         CALL ctl_stop( 'lim_var_salprof : requested workspace arrays unavailable.' )   ;   RETURN
308      END IF
309
310      z_slope_s => wrk_3d_1(:,:,1:jpl)   ! slope of the salinity profile
311      zalpha    => wrk_3d_2(:,:,1:jpl)   ! weight factor for s between s_i_0 and s_i_1
312
313      !---------------------------------------
314      ! Vertically constant, constant in time
315      !---------------------------------------
316      IF( num_sal == 1 )   s_i(:,:,:,:) = bulk_sal
317
318      !-----------------------------------
319      ! Salinity profile, varying in time
320      !-----------------------------------
321
322      IF(   num_sal == 2  .OR.   num_sal == 4   ) THEN
323         !
324         DO jk = 1, nlay_i
325            s_i(:,:,jk,:)  = sm_i(:,:,:)
326         END DO
327         !
328         DO jl = 1, jpl                               ! Slope of the linear profile
329            DO jj = 1, jpj
330               DO ji = 1, jpi
331                  z_slope_s(ji,jj,jl) = 2._wp * sm_i(ji,jj,jl) / MAX( 0.01 , ht_i(ji,jj,jl) )
332               END DO
333            END DO
334         END DO
335         !
336         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )       ! Weighting factor between zs_zero and zs_inf
337         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
338
339         zalpha(:,:,:) = 0._wp
340         DO jl = 1, jpl
341            DO jj = 1, jpj
342               DO ji = 1, jpi
343                  ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
344                  zind0  = MAX( 0.0   , SIGN( 1.0  , s_i_0 - sm_i(ji,jj,jl) ) ) 
345                  ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
346                  zind01 = ( 1.0 - zind0 ) * MAX( 0.0   , SIGN( 1.0  , s_i_1 - sm_i(ji,jj,jl) ) ) 
347                  ! If 2.sm_i GE sss_m then zindbal = 1
348                  zindbal = MAX( 0.0 , SIGN( 1.0 , 2. * sm_i(ji,jj,jl) - sss_m(ji,jj) ) )
349                  zalpha(ji,jj,jl) = zind0  * 1.0 + zind01 * ( sm_i(ji,jj,jl) * dummy_fac0 + dummy_fac1 )
350                  zalpha(ji,jj,jl) = zalpha(ji,jj,jl) * ( 1.0 - zindbal )
351               END DO
352            END DO
353         END DO
354
355         dummy_fac = 1._wp / nlay_i                   ! Computation of the profile
356         DO jl = 1, jpl
357            DO jk = 1, nlay_i
358               DO jj = 1, jpj
359                  DO ji = 1, jpi
360                     !                                      ! linear profile with 0 at the surface
361                     zs_zero = z_slope_s(ji,jj,jl) * ( REAL(jk,wp) - 0.5_wp ) * ht_i(ji,jj,jl) * dummy_fac
362                     !                                      ! weighting the profile
363                     s_i(ji,jj,jk,jl) = zalpha(ji,jj,jl) * zs_zero + ( 1._wp - zalpha(ji,jj,jl) ) * sm_i(ji,jj,jl)
364                  END DO ! ji
365               END DO ! jj
366            END DO ! jk
367         END DO ! jl
368
369      ENDIF ! num_sal
370
371      !-------------------------------------------------------
372      ! Vertically varying salinity profile, constant in time
373      !-------------------------------------------------------
374
375      IF( num_sal == 3 ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
376         !
377         sm_i(:,:,:) = 2.30_wp
378         !
379         DO jl = 1, jpl
380!CDIR NOVERRCHK
381            DO jk = 1, nlay_i
382               zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
383               zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
384               s_i(:,:,jk,jl) =  zsal
385            END DO
386         END DO
387
388      ENDIF ! num_sal
389      !
390      IF( wrk_not_released( 2, 1,2 ) )   CALL ctl_stop('lim_var_salprof : failed to release workspace arrays.')
391      !
392   END SUBROUTINE lim_var_salprof
393
394
395   SUBROUTINE lim_var_bv
396      !!------------------------------------------------------------------
397      !!                ***  ROUTINE lim_var_bv ***
398      !!
399      !! ** Purpose :   computes mean brine volume (%) in sea ice
400      !!
401      !! ** Method  : e = - 0.054 * S (ppt) / T (C)
402      !!
403      !! References : Vancoppenolle et al., JGR, 2007
404      !!------------------------------------------------------------------
405      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
406      REAL(wp) ::   zbvi, zindb      ! local scalars
407      !!------------------------------------------------------------------
408      !
409      bv_i(:,:) = 0._wp
410      DO jl = 1, jpl
411         DO jk = 1, nlay_i
412            DO jj = 1, jpj
413               DO ji = 1, jpi
414                  zindb = 1.0-MAX(0.0,SIGN(1.0,-a_i(ji,jj,jl))) !0 if no ice and 1 if yes
415                  zbvi  = - zindb * tmut * s_i(ji,jj,jk,jl) / MIN( t_i(ji,jj,jk,jl) - 273.15 , eps13 )   &
416                     &                   * v_i(ji,jj,jl)    / REAL(nlay_i,wp)
417                  bv_i(ji,jj) = bv_i(ji,jj) + zbvi  / MAX( vt_i(ji,jj) , eps13 )
418               END DO
419            END DO
420         END DO
421      END DO
422      !
423   END SUBROUTINE lim_var_bv
424
425
426   SUBROUTINE lim_var_salprof1d( kideb, kiut )
427      !!-------------------------------------------------------------------
428      !!                  ***  ROUTINE lim_thd_salprof1d  ***
429      !!
430      !! ** Purpose :   1d computation of the sea ice salinity profile
431      !!                Works with 1d vectors and is used by thermodynamic modules
432      !!-------------------------------------------------------------------
433      INTEGER, INTENT(in) ::   kideb, kiut   ! thickness category index
434      !
435      INTEGER  ::   ji, jk    ! dummy loop indices
436      INTEGER  ::   zji, zjj  ! local integers
437      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac2, zargtemp, zsal   ! local scalars
438      REAL(wp) ::   zalpha, zind0, zind01, zindbal, zs_zero              !   -      -
439      !
440      REAL(wp), POINTER, DIMENSION(:) ::   z_slope_s
441      !!---------------------------------------------------------------------
442
443      IF(  wrk_in_use(1, 1)  ) THEN
444         CALL ctl_stop('lim_var_salprof1d : requestead workspace arrays unavailable.')   ;   RETURN
445      END IF
446      ! Set-up pointers to sub-arrays of workspace arrays
447      z_slope_s  =>  wrk_1d_1 (1:jpij)
448
449      !---------------------------------------
450      ! Vertically constant, constant in time
451      !---------------------------------------
452      IF( num_sal == 1 )   s_i_b(:,:) = bulk_sal
453
454      !------------------------------------------------------
455      ! Vertically varying salinity profile, varying in time
456      !------------------------------------------------------
457
458      IF(  num_sal == 2  .OR.  num_sal == 4  ) THEN
459         !
460         DO ji = kideb, kiut          ! Slope of the linear profile zs_zero
461            z_slope_s(ji) = 2._wp * sm_i_b(ji) / MAX( 0.01 , ht_i_b(ji) )
462         END DO
463
464         ! Weighting factor between zs_zero and zs_inf
465         !---------------------------------------------
466         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )
467         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
468         dummy_fac2 = 1._wp / REAL(nlay_i,wp)
469
470!CDIR NOVERRCHK
471         DO jk = 1, nlay_i
472!CDIR NOVERRCHK
473            DO ji = kideb, kiut
474               zji =  MOD( npb(ji) - 1 , jpi ) + 1
475               zjj =     ( npb(ji) - 1 ) / jpi + 1
476               ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
477               zind0  = MAX( 0._wp , SIGN( 1._wp  , s_i_0 - sm_i_b(ji) ) ) 
478               ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
479               zind01 = ( 1._wp - zind0 ) * MAX( 0._wp , SIGN( 1._wp , s_i_1 - sm_i_b(ji) ) ) 
480               ! if 2.sm_i GE sss_m then zindbal = 1
481               zindbal = MAX( 0._wp , SIGN( 1._wp , 2._wp * sm_i_b(ji) - sss_m(zji,zjj) ) )
482               !
483               zalpha = (  zind0 + zind01 * ( sm_i_b(ji) * dummy_fac0 + dummy_fac1 )  ) * ( 1.0 - zindbal )
484               !
485               zs_zero = z_slope_s(ji) * ( REAL(jk,wp) - 0.5_wp ) * ht_i_b(ji) * dummy_fac2
486               ! weighting the profile
487               s_i_b(ji,jk) = zalpha * zs_zero + ( 1._wp - zalpha ) * sm_i_b(ji)
488            END DO ! ji
489         END DO ! jk
490
491      ENDIF ! num_sal
492
493      !-------------------------------------------------------
494      ! Vertically varying salinity profile, constant in time
495      !-------------------------------------------------------
496
497      IF( num_sal == 3 ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
498         !
499         sm_i_b(:) = 2.30_wp
500         !
501!CDIR NOVERRCHK
502         DO jk = 1, nlay_i
503            zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
504            zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
505            DO ji = kideb, kiut
506               s_i_b(ji,jk) = zsal
507            END DO
508         END DO
509         !
510      ENDIF
511      !
512      IF( wrk_not_released(1, 1) )   CALL ctl_stop( 'lim_var_salprof1d : failed to release workspace arrays.' )
513      !
514   END SUBROUTINE lim_var_salprof1d
515
516#else
517   !!----------------------------------------------------------------------
518   !!   Default option         Dummy module          NO  LIM3 sea-ice model
519   !!----------------------------------------------------------------------
520CONTAINS
521   SUBROUTINE lim_var_agg          ! Empty routines
522   END SUBROUTINE lim_var_agg
523   SUBROUTINE lim_var_glo2eqv      ! Empty routines
524   END SUBROUTINE lim_var_glo2eqv
525   SUBROUTINE lim_var_eqv2glo      ! Empty routines
526   END SUBROUTINE lim_var_eqv2glo
527   SUBROUTINE lim_var_salprof      ! Empty routines
528   END SUBROUTINE lim_var_salprof
529   SUBROUTINE lim_var_bv           ! Emtpy routines
530   END SUBROUTINE lim_var_bv
531   SUBROUTINE lim_var_salprof1d    ! Emtpy routines
532   END SUBROUTINE lim_var_salprof1d
533#endif
534
535   !!======================================================================
536END MODULE limvar
Note: See TracBrowser for help on using the repository browser.