New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaptr.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DIA/diaptr.F90 @ 2620

Last change on this file since 2620 was 2618, checked in by gm, 13 years ago

dynamic mem: #785 ; move dyn allocation from nemogcm to module when possible (continuation)
  • Property svn:keywords set to Id
File size: 42.7 KB
Line 
1MODULE diaptr
2   !!======================================================================
3   !!                       ***  MODULE  diaptr  ***
4   !! Ocean physics:  Computes meridonal transports and zonal means
5   !!=====================================================================
6   !! History :  1.0  ! 2003-09  (C. Talandier, G. Madec)  Original code
7   !!            2.0  ! 2006-01  (A. Biastoch)  Allow sub-basins computation
8   !!            3.2  ! 2010-03  (O. Marti, S. Flavoni) Add fields
9   !!            3.3  ! 2010-10  (G. Madec)  dynamical allocation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dia_ptr      : Poleward Transport Diagnostics module
14   !!   dia_ptr_init : Initialization, namelist read
15   !!   dia_ptr_wri  : Output of poleward fluxes
16   !!   ptr_vjk      : "zonal" sum computation of a "meridional" flux array
17   !!   ptr_tjk      : "zonal" mean computation of a tracer field
18   !!   ptr_vj       : "zonal" and vertical sum computation of a "meridional" flux array
19   !!                   (Generic interface to ptr_vj_3d, ptr_vj_2d)
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and active tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE ldftra_oce       ! ocean active tracers: lateral physics
25   USE dianam           !
26   USE iom              ! IOM library
27   USE ioipsl           ! IO-IPSL library
28   USE in_out_manager   ! I/O manager
29   USE lib_mpp          ! MPP library
30   USE lbclnk           ! lateral boundary condition - processor exchanges
31
32   IMPLICIT NONE
33   PRIVATE
34
35   INTERFACE ptr_vj
36      MODULE PROCEDURE ptr_vj_3d, ptr_vj_2d
37   END INTERFACE
38
39   PUBLIC   dia_ptr_init   ! call in opa module
40   PUBLIC   dia_ptr        ! call in step module
41   PUBLIC   ptr_vj         ! call by tra_ldf & tra_adv routines
42   PUBLIC   ptr_vjk        ! call by tra_ldf & tra_adv routines
43
44   !                                           !!** namelist  namptr  **
45   LOGICAL , PUBLIC ::   ln_diaptr  = .FALSE.   !: Poleward transport flag (T) or not (F)
46   LOGICAL , PUBLIC ::   ln_subbas  = .FALSE.   !: Atlantic/Pacific/Indian basins calculation
47   LOGICAL , PUBLIC ::   ln_diaznl  = .FALSE.   !: Add zonal means and meridional stream functions
48   LOGICAL , PUBLIC ::   ln_ptrcomp = .FALSE.   !: Add decomposition : overturning (and gyre, soon ...)
49   INTEGER , PUBLIC ::   nn_fptr    = 15        !: frequency of ptr computation  [time step]
50   INTEGER , PUBLIC ::   nn_fwri    = 15        !: frequency of ptr outputs      [time step]
51
52   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   htr_adv, htr_ldf, htr_ove   !: Heat TRansports (adv, diff, overturn.)
53   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   str_adv, str_ldf, str_ove   !: Salt TRansports (adv, diff, overturn.)
54   
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   btmsk                  ! T-point basin interior masks
56   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   btm30                  ! mask out Southern Ocean (=0 south of 30°S)
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr  , str             ! adv heat and salt transports (approx)
58   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tn_jk, sn_jk , v_msf   ! i-mean T and S, j-Stream-Function
59   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sjk  , r1_sjk          ! i-mean i-k-surface and its inverse       
60   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr_eiv, str_eiv       ! bolus adv heat ans salt transports ('key_diaeiv')
61   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   v_msf_eiv              ! bolus j-streamfuction              ('key_diaeiv')
62
63
64   INTEGER ::   niter       !
65   INTEGER ::   nidom_ptr   !
66   INTEGER ::   numptr      ! logical unit for Poleward TRansports
67   INTEGER ::   nptr        ! = 1 (ln_subbas=F) or = 5 (glo, atl, pac, ind, ipc) (ln_subbas=T)
68
69   REAL(wp) ::   rc_sv    = 1.e-6_wp   ! conversion from m3/s to Sverdrup
70   REAL(wp) ::   rc_pwatt = 1.e-15_wp  ! conversion from W    to PW (further x rau0 x Cp)
71   REAL(wp) ::   rc_ggram = 1.e-6_wp   ! conversion from g    to Pg
72
73   REAL(wp), TARGET, DIMENSION(:),   ALLOCATABLE, SAVE :: p_fval1d
74   REAL(wp), TARGET, DIMENSION(:,:), ALLOCATABLE, SAVE :: p_fval2d
75
76   !! Integer, 1D workspace arrays. Not common enough to be implemented in
77   !! wrk_nemo module.
78   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex  , ndex_atl     , ndex_pac     , ndex_ind     , ndex_ipc
79   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) ::         ndex_atl_30  , ndex_pac_30  , ndex_ind_30  , ndex_ipc_30
80   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex_h, ndex_h_atl_30, ndex_h_pac_30, ndex_h_ind_30, ndex_h_ipc_30
81
82   !! * Substitutions
83#  include "domzgr_substitute.h90"
84#  include "vectopt_loop_substitute.h90"
85   !!----------------------------------------------------------------------
86   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
87   !! $Id$
88   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
89   !!----------------------------------------------------------------------
90CONTAINS
91
92   FUNCTION dia_ptr_alloc()
93      !!----------------------------------------------------------------------
94      !!                    ***  ROUTINE dia_ptr_alloc  ***
95      !!----------------------------------------------------------------------
96      INTEGER               ::   dia_ptr_alloc   ! return value
97      INTEGER, DIMENSION(5) ::   ierr
98      !!----------------------------------------------------------------------
99
100      ierr(:) = 0
101
102      ALLOCATE( btmsk(jpi,jpj,nptr) ,           &
103         &       htr_adv(jpj) , str_adv(jpj) ,   &
104         &       htr_ldf(jpj) , str_ldf(jpj) ,   &
105         &       htr_ove(jpj) , str_ove(jpj),    &
106         &       htr(jpj,nptr) , str(jpj,nptr) , &
107         &       tn_jk(jpj,jpk,nptr) , sn_jk (jpj,jpk,nptr) , v_msf(jpj,jpk,nptr) , &
108         &       sjk  (jpj,jpk,nptr) , r1_sjk(jpj,jpk,nptr) , STAT=ierr(1)  )
109         !
110#if defined key_diaeiv
111      ALLOCATE( htr_eiv(jpj,nptr) , str_eiv(jpj,nptr) , &
112         &      v_msf_eiv(jpj,jpk,nptr) , STAT=ierr(2) )
113#endif
114
115      ALLOCATE( p_fval1d(jpj), p_fval2d(jpj,jpk), Stat=ierr(3))
116
117      ALLOCATE(ndex(jpj*jpk),        ndex_atl(jpj*jpk), ndex_pac(jpj*jpk), &
118         &     ndex_ind(jpj*jpk),    ndex_ipc(jpj*jpk),                    &
119         &     ndex_atl_30(jpj*jpk), ndex_pac_30(jpj*jpk), Stat=ierr(4))
120
121      ALLOCATE(ndex_ind_30(jpj*jpk), ndex_ipc_30(jpj*jpk),                   &
122         &     ndex_h(jpj),          ndex_h_atl_30(jpj), ndex_h_pac_30(jpj), &
123         &     ndex_h_ind_30(jpj),   ndex_h_ipc_30(jpj), Stat=ierr(5) )
124         !
125      dia_ptr_alloc = MAXVAL( ierr )
126      IF(lk_mpp)   CALL mpp_sum( dia_ptr_alloc )
127      !
128   END FUNCTION dia_ptr_alloc
129
130
131   FUNCTION ptr_vj_3d( pva )   RESULT ( p_fval )
132      !!----------------------------------------------------------------------
133      !!                    ***  ROUTINE ptr_vj_3d  ***
134      !!
135      !! ** Purpose :   i-k sum computation of a j-flux array
136      !!
137      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
138      !!              pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
139      !!
140      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
141      !!----------------------------------------------------------------------
142      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pva   ! mask flux array at V-point
143      !!
144      INTEGER                  ::   ji, jj, jk   ! dummy loop arguments
145      INTEGER                  ::   ijpj         ! ???
146      REAL(wp), POINTER, DIMENSION(:) :: p_fval  ! function value
147      !!--------------------------------------------------------------------
148      !
149      p_fval => p_fval1d
150
151      ijpj = jpj
152      p_fval(:) = 0._wp
153      DO jk = 1, jpkm1
154         DO jj = 2, jpjm1
155            DO ji = fs_2, fs_jpim1   ! Vector opt.
156               p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj) 
157            END DO
158         END DO
159      END DO
160#if defined key_mpp_mpi
161      IF(lk_mpp)   CALL mpp_sum( p_fval, ijpj, ncomm_znl)
162#endif
163      !
164   END FUNCTION ptr_vj_3d
165
166
167   FUNCTION ptr_vj_2d( pva )   RESULT ( p_fval )
168      !!----------------------------------------------------------------------
169      !!                    ***  ROUTINE ptr_vj_2d  ***
170      !!
171      !! ** Purpose :   "zonal" and vertical sum computation of a i-flux array
172      !!
173      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
174      !!      pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
175      !!
176      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
177      !!----------------------------------------------------------------------
178      IMPLICIT none
179      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) ::   pva   ! mask flux array at V-point
180      !!
181      INTEGER                  ::   ji,jj       ! dummy loop arguments
182      INTEGER                  ::   ijpj        ! ???
183      REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
184      !!--------------------------------------------------------------------
185      !
186      p_fval => p_fval1d
187
188      ijpj = jpj
189      p_fval(:) = 0._wp
190      DO jj = 2, jpjm1
191         DO ji = nldi, nlei   ! No vector optimisation here. Better use a mask ?
192            p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj)
193         END DO
194      END DO
195#if defined key_mpp_mpi
196      CALL mpp_sum( p_fval, ijpj, ncomm_znl )
197#endif
198      !
199   END FUNCTION ptr_vj_2d
200
201
202   FUNCTION ptr_vjk( pva, pmsk )   RESULT ( p_fval )
203      !!----------------------------------------------------------------------
204      !!                    ***  ROUTINE ptr_vjk  ***
205      !!
206      !! ** Purpose :   i-sum computation of a j-velocity array
207      !!
208      !! ** Method  : - i-sum of pva using the interior 2D vmask (vmask_i).
209      !!              pva is supposed to be a masked flux (i.e. * vmask)
210      !!
211      !! ** Action  : - p_fval: i-mean poleward flux of pva
212      !!----------------------------------------------------------------------
213#if defined key_mpp_mpi
214      USE wrk_nemo, ONLY: wrk_use, wrk_release
215      USE wrk_nemo, ONLY: zwork => wrk_1d_1
216#endif
217      !!
218      IMPLICIT none
219      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk)           ::   pva    ! mask flux array at V-point
220      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)    , OPTIONAL ::   pmsk   ! Optional 2D basin mask
221      !!
222      INTEGER                           :: ji, jj, jk ! dummy loop arguments
223      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval     ! return function value
224#if defined key_mpp_mpi
225      INTEGER, DIMENSION(1) ::   ish
226      INTEGER, DIMENSION(2) ::   ish2
227      INTEGER               ::   ijpjjpk
228#endif
229      !!--------------------------------------------------------------------
230      !
231#if defined key_mpp_mpi
232      IF( .not. wrk_use(1, 1) ) THEN
233         CALL ctl_stop('ptr_vjk: ERROR - requested workspace array is unavailable')   ;   RETURN
234      END IF
235#endif
236
237      p_fval => p_fval2d
238
239      p_fval(:,:) = 0._wp
240      !
241      IF( PRESENT( pmsk ) ) THEN
242         DO jk = 1, jpkm1
243            DO jj = 2, jpjm1
244!!gm here, use of tmask_i  ==> no need of loop over nldi, nlei....
245               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
246                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * pmsk(ji,jj)
247               END DO
248            END DO
249         END DO
250      ELSE
251         DO jk = 1, jpkm1
252            DO jj = 2, jpjm1
253               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
254                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * tmask_i(ji,jj)
255               END DO
256            END DO
257         END DO
258      END IF
259      !
260#if defined key_mpp_mpi
261      ijpjjpk = jpj*jpk
262      ish(1) = ijpjjpk  ;   ish2(1) = jpj   ;   ish2(2) = jpk
263      zwork(1:ijpjjpk) = RESHAPE( p_fval, ish )
264      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
265      p_fval(:,:) = RESHAPE( zwork, ish2 )
266#endif
267      !
268#if defined key_mpp_mpi
269      IF(.NOT. wrk_release(1, 1) )   CALL ctl_stop('ptr_vjk: ERROR - failed to release workspace array')
270#endif
271      !
272   END FUNCTION ptr_vjk
273
274
275   FUNCTION ptr_tjk( pta, pmsk )   RESULT ( p_fval )
276      !!----------------------------------------------------------------------
277      !!                    ***  ROUTINE ptr_tjk  ***
278      !!
279      !! ** Purpose :   i-sum computation of e1t*e3t * a tracer field
280      !!
281      !! ** Method  : - i-sum of mj(pta) using tmask
282      !!
283      !! ** Action  : - p_fval: i-sum of e1t*e3t*pta
284      !!----------------------------------------------------------------------
285#if defined key_mpp_mpi
286      USE wrk_nemo, ONLY: wrk_use, wrk_release
287      USE wrk_nemo, ONLY: zwork => wrk_1d_1
288#endif
289      !!
290      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pta    ! tracer flux array at T-point
291      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)     ::   pmsk   ! Optional 2D basin mask
292      !!
293      INTEGER                           :: ji, jj, jk   ! dummy loop arguments
294      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval       ! return function value
295#if defined key_mpp_mpi
296      INTEGER, DIMENSION(1) ::   ish
297      INTEGER, DIMENSION(2) ::   ish2
298      INTEGER               ::   ijpjjpk
299#endif
300      !!--------------------------------------------------------------------
301      !
302#if defined key_mpp_mpi
303      IF(.NOT. wrk_use(1, 1))THEN
304         CALL ctl_stop('ptr_tjk: requested workspace array unavailable.')
305         RETURN
306      END IF
307#endif
308
309      p_fval => p_fval2d
310
311      p_fval(:,:) = 0._wp
312      DO jk = 1, jpkm1
313         DO jj = 2, jpjm1
314            DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
315               p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * e1t(ji,jj) * fse3t(ji,jj,jk) * pmsk(ji,jj)
316            END DO
317         END DO
318      END DO
319#if defined key_mpp_mpi
320      ijpjjpk = jpj*jpk
321      ish(1) = jpj*jpk   ;   ish2(1) = jpj   ;   ish2(2) = jpk
322      zwork(1:ijpjjpk)= RESHAPE( p_fval, ish )
323      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
324      p_fval(:,:)= RESHAPE( zwork, ish2 )
325#endif
326      !
327#if defined key_mpp_mpi
328      IF( .NOT. wrk_release(1, 1) )   CALL ctl_stop('ptr_tjk: failed to release workspace array.')
329#endif
330      !   
331   END FUNCTION ptr_tjk
332
333
334   SUBROUTINE dia_ptr( kt )
335      !!----------------------------------------------------------------------
336      !!                  ***  ROUTINE dia_ptr  ***
337      !!----------------------------------------------------------------------
338      USE oce,     vt  =>   ua   ! use ua as workspace
339      USE oce,     vs  =>   ua   ! use ua as workspace
340      IMPLICIT none
341      !!
342      INTEGER, INTENT(in) ::   kt   ! ocean time step index
343      !
344      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
345      REAL(wp) ::   zv               ! local scalar
346      !!----------------------------------------------------------------------
347      !
348      IF( kt == nit000 .OR. MOD( kt, nn_fptr ) == 0 )   THEN
349         !
350         IF( MOD( kt, nn_fptr ) == 0 ) THEN 
351            !
352            IF( ln_diaznl ) THEN               ! i-mean temperature and salinity
353               DO jn = 1, nptr
354                  tn_jk(:,:,jn) = ptr_tjk( tn(:,:,:), btmsk(:,:,jn) ) * r1_sjk(:,:,jn)
355               END DO
356            ENDIF
357            !
358            !                          ! horizontal integral and vertical dz
359            !                                ! eulerian velocity
360            v_msf(:,:,1) = ptr_vjk( vn(:,:,:) ) 
361            DO jn = 2, nptr
362               v_msf(:,:,jn) = ptr_vjk( vn(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) 
363            END DO
364#if defined key_diaeiv
365            DO jn = 1, nptr                  ! bolus velocity
366               v_msf_eiv(:,:,jn) = ptr_vjk( v_eiv(:,:,:), btmsk(:,:,jn) )   ! here no btm30 for MSFeiv
367            END DO
368            !                                ! add bolus stream-function to the eulerian one
369            v_msf(:,:,:) = v_msf(:,:,:) + v_msf_eiv(:,:,:)
370#endif
371            !
372            !                          ! Transports
373            !                                ! local heat & salt transports at T-points  ( tn*mj[vn+v_eiv] )
374            vt(:,:,jpk) = 0._wp   ;   vs(:,:,jpk) = 0._wp
375            DO jk= 1, jpkm1
376               DO jj = 2, jpj
377                  DO ji = 1, jpi
378#if defined key_diaeiv 
379                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) + v_eiv(ji,jj,jk) + v_eiv(ji,jj-1,jk) ) * 0.5_wp
380#else
381                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) ) * 0.5_wp
382#endif
383                     vt(:,jj,jk) = zv * tn(:,jj,jk)
384                     vs(:,jj,jk) = zv * sn(:,jj,jk)
385                  END DO
386               END DO
387            END DO
388!!gm useless as overlap areas are not used in ptr_vjk
389            CALL lbc_lnk( vs, 'V', -1. )   ;   CALL lbc_lnk( vt, 'V', -1. )
390!!gm
391            !                                ! heat & salt advective transports (approximation)
392            htr(:,1) = SUM( ptr_vjk( vt(:,:,:) ) , 2 ) * rc_pwatt   ! SUM over jk + conversion
393            str(:,1) = SUM( ptr_vjk( vs(:,:,:) ) , 2 ) * rc_ggram
394            DO jn = 2, nptr 
395               htr(:,jn) = SUM( ptr_vjk( vt(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_pwatt   ! mask Southern Ocean
396               str(:,jn) = SUM( ptr_vjk( vs(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_ggram   ! mask Southern Ocean
397            END DO
398
399            IF( ln_ptrcomp ) THEN            ! overturning transport
400               htr_ove(:) = SUM( v_msf(:,:,1) * tn_jk(:,:,1), 2 ) * rc_pwatt   ! SUM over jk + conversion
401               str_ove(:) = SUM( v_msf(:,:,1) * sn_jk(:,:,1), 2 ) * rc_ggram
402            END IF
403            !                                ! Advective and diffusive transport
404            htr_adv(:) = htr_adv(:) * rc_pwatt        ! these are computed in tra_adv... and tra_ldf... routines
405            htr_ldf(:) = htr_ldf(:) * rc_pwatt        ! here just the conversion in PW and Gg
406            str_adv(:) = str_adv(:) * rc_ggram
407            str_ldf(:) = str_ldf(:) * rc_ggram
408
409#if defined key_diaeiv
410            DO jn = 1, nptr                  ! Bolus component
411               htr_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * tn_jk(:,:,jn), 2 ) * rc_pwatt   ! SUM over jk
412               str_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * sn_jk(:,:,jn), 2 ) * rc_ggram   ! SUM over jk
413            END DO
414#endif
415            !                                ! "Meridional" Stream-Function
416            DO jn = 1, nptr
417               DO jk = 2, jpk 
418                  v_msf    (:,jk,jn) = v_msf    (:,jk-1,jn) + v_msf    (:,jk,jn)       ! Eulerian j-Stream-Function
419#if defined key_diaeiv
420                  v_msf_eiv(:,jk,jn) = v_msf_eiv(:,jk-1,jn) + v_msf_eiv(:,jk,jn)       ! Bolus    j-Stream-Function
421
422#endif
423               END DO
424            END DO
425            v_msf    (:,:,:) = v_msf    (:,:,:) * rc_sv       ! converte in Sverdrups
426#if defined key_diaeiv
427            v_msf_eiv(:,:,:) = v_msf_eiv(:,:,:) * rc_sv
428#endif
429         ENDIF
430         !
431         CALL dia_ptr_wri( kt )                        ! outputs
432         !
433      ENDIF
434      !
435      IF( kt == nitend )   CALL histclo( numptr )      ! Close the file
436      !
437   END SUBROUTINE dia_ptr
438
439
440   SUBROUTINE dia_ptr_init
441      !!----------------------------------------------------------------------
442      !!                  ***  ROUTINE dia_ptr_init  ***
443      !!                   
444      !! ** Purpose :   Initialization, namelist read
445      !!----------------------------------------------------------------------
446      INTEGER ::   jn           ! dummy loop indices
447      INTEGER ::   inum, ierr   ! local integers
448#if defined key_mpp_mpi
449      INTEGER, DIMENSION(1) :: iglo, iloc, iabsf, iabsl, ihals, ihale, idid
450#endif
451      !!
452      NAMELIST/namptr/ ln_diaptr, ln_diaznl, ln_subbas, ln_ptrcomp, nn_fptr, nn_fwri
453      !!----------------------------------------------------------------------
454
455      !                                      ! allocate dia_ptr arrays
456      IF( dia_ptr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate arrays' )
457
458      REWIND( numnam )                 ! Read Namelist namptr : poleward transport parameters
459      READ  ( numnam, namptr )
460
461      IF(lwp) THEN                     ! Control print
462         WRITE(numout,*)
463         WRITE(numout,*) 'dia_ptr_init : poleward transport and msf initialization'
464         WRITE(numout,*) '~~~~~~~~~~~~'
465         WRITE(numout,*) '   Namelist namptr : set ptr parameters'
466         WRITE(numout,*) '      Poleward heat & salt transport (T) or not (F)      ln_diaptr  = ', ln_diaptr
467         WRITE(numout,*) '      Overturning heat & salt transport                  ln_ptrcomp = ', ln_ptrcomp
468         WRITE(numout,*) '      T & S zonal mean and meridional stream function    ln_diaznl  = ', ln_diaznl 
469         WRITE(numout,*) '      Global (F) or glo/Atl/Pac/Ind/Indo-Pac basins      ln_subbas  = ', ln_subbas
470         WRITE(numout,*) '      Frequency of computation                           nn_fptr    = ', nn_fptr
471         WRITE(numout,*) '      Frequency of outputs                               nn_fwri    = ', nn_fwri
472      ENDIF
473
474      IF( ln_subbas ) THEN   ;   nptr = 5       ! Global, Atlantic, Pacific, Indian, Indo-Pacific
475      ELSE                   ;   nptr = 1       ! Global only
476      ENDIF
477
478      rc_pwatt = rc_pwatt * rau0 * rcp          ! conversion from K.s-1 to PetaWatt
479
480      IF( .NOT. ln_diaptr ) THEN       ! diaptr not used
481        RETURN
482      ENDIF
483     
484      IF( lk_mpp )   CALL mpp_ini_znl     ! Define MPI communicator for zonal sum
485
486      IF( ln_subbas ) THEN                ! load sub-basin mask
487         CALL iom_open( 'subbasins', inum )
488         CALL iom_get( inum, jpdom_data, 'atlmsk', btmsk(:,:,2) )   ! Atlantic basin
489         CALL iom_get( inum, jpdom_data, 'pacmsk', btmsk(:,:,3) )   ! Pacific  basin
490         CALL iom_get( inum, jpdom_data, 'indmsk', btmsk(:,:,4) )   ! Indian   basin
491         CALL iom_close( inum )
492         btmsk(:,:,5) = MAX ( btmsk(:,:,3), btmsk(:,:,4) )          ! Indo-Pacific basin
493         WHERE( gphit(:,:) < -30._wp)   ;   btm30(:,:) = 0._wp      ! mask out Southern Ocean
494         ELSE WHERE                     ;   btm30(:,:) = tmask(:,:,1)
495         END WHERE
496      ENDIF
497      btmsk(:,:,1) = tmask_i(:,:)                                   ! global ocean
498     
499      DO jn = 1, nptr
500         btmsk(:,:,jn) = btmsk(:,:,jn) * tmask_i(:,:)               ! interior domain only
501      END DO
502     
503      IF( lk_vvl )   CALL ctl_stop( 'diaptr: error in vvl case as constant i-mean surface is used' )
504
505      !                                   ! i-sum of e1v*e3v surface and its inverse
506      DO jn = 1, nptr
507         sjk(:,:,jn) = ptr_tjk( tmask(:,:,:), btmsk(:,:,jn) )
508         r1_sjk(:,:,jn) = 0._wp
509         WHERE( sjk(:,:,jn) /= 0._wp )   r1_sjk(:,:,jn) = 1._wp / sjk(:,:,jn)
510      END DO
511
512#if defined key_mpp_mpi 
513      iglo (1) = jpjglo                   ! MPP case using MPI  ('key_mpp_mpi')
514      iloc (1) = nlcj
515      iabsf(1) = njmppt(narea)
516      iabsl(:) = iabsf(:) + iloc(:) - 1
517      ihals(1) = nldj - 1
518      ihale(1) = nlcj - nlej
519      idid (1) = 2
520      CALL flio_dom_set( jpnj, nproc/jpni, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom_ptr )
521#else
522      nidom_ptr = FLIO_DOM_NONE
523#endif
524      !
525   END SUBROUTINE dia_ptr_init
526
527
528   SUBROUTINE dia_ptr_wri( kt )
529      !!---------------------------------------------------------------------
530      !!                ***  ROUTINE dia_ptr_wri  ***
531      !!
532      !! ** Purpose :   output of poleward fluxes
533      !!
534      !! ** Method  :   NetCDF file
535      !!----------------------------------------------------------------------
536      USE wrk_nemo, ONLY: wrk_use, wrk_release
537      USE wrk_nemo, ONLY: zphi => wrk_1d_1, zfoo => wrk_1d_2
538      USE wrk_nemo, ONLY: z_1  => wrk_2d_1
539      !!
540      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
541      !!
542      INTEGER, SAVE ::   nhoridz, ndepidzt, ndepidzw
543      INTEGER, SAVE ::   ndim  , ndim_atl     , ndim_pac     , ndim_ind     , ndim_ipc
544      INTEGER, SAVE ::           ndim_atl_30  , ndim_pac_30  , ndim_ind_30  , ndim_ipc_30
545      INTEGER, SAVE ::   ndim_h, ndim_h_atl_30, ndim_h_pac_30, ndim_h_ind_30, ndim_h_ipc_30
546      !!
547      CHARACTER (len=40) ::   clhstnam, clop, clop_once, cl_comment   ! temporary names
548      INTEGER            ::   iline, it, itmod, ji, jj, jk            !
549#if defined key_iomput
550      INTEGER            ::   inum                                    ! temporary logical unit
551#endif
552      REAL(wp)           ::   zsto, zout, zdt, zjulian                ! temporary scalars
553      !!----------------------------------------------------------------------
554
555      IF( (.not. wrk_use(1, 1,2)) .OR. (.not. wrk_use(2, 1)) )THEN
556         CALL ctl_stop('dia_ptr_wri: ERROR: requested workspace arrays unavailable')   ;   RETURN
557      END IF
558
559      ! define time axis
560      it    = kt / nn_fptr
561      itmod = kt - nit000 + 1
562     
563      ! Initialization
564      ! --------------
565      IF( kt == nit000 ) THEN
566         niter = ( nit000 - 1 ) / nn_fptr
567         zdt = rdt
568         IF( nacc == 1 )   zdt = rdtmin
569         !
570         IF(lwp) THEN
571            WRITE(numout,*)
572            WRITE(numout,*) 'dia_ptr_wri : poleward transport and msf writing: initialization , niter = ', niter
573            WRITE(numout,*) '~~~~~~~~~~~~'
574         ENDIF
575
576         ! Reference latitude (used in plots)
577         ! ------------------
578         !                                           ! =======================
579         IF( cp_cfg == "orca" ) THEN                 !   ORCA configurations
580            !                                        ! =======================
581            IF( jp_cfg == 05  )   iline = 192   ! i-line that passes near the North Pole
582            IF( jp_cfg == 025 )   iline = 384   ! i-line that passes near the North Pole
583            IF( jp_cfg == 1   )   iline =  96   ! i-line that passes near the North Pole
584            IF( jp_cfg == 2   )   iline =  48   ! i-line that passes near the North Pole
585            IF( jp_cfg == 4   )   iline =  24   ! i-line that passes near the North Pole
586            zphi(1:jpj) = 0._wp
587            DO ji = mi0(iline), mi1(iline) 
588               zphi(1:jpj) = gphiv(ji,:)         ! if iline is in the local domain
589               ! Correct highest latitude for some configurations - will work if domain is parallelized in J ?
590               IF( jp_cfg == 05 ) THEN
591                  DO jj = mj0(jpjdta), mj1(jpjdta) 
592                     zphi( jj ) = zphi(mj0(jpjdta-1)) + ( zphi(mj0(jpjdta-1))-zphi(mj0(jpjdta-2)) ) * 0.5_wp
593                     zphi( jj ) = MIN( zphi(jj), 90._wp )
594                  END DO
595               END IF
596               IF( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) THEN
597                  DO jj = mj0(jpjdta-1), mj1(jpjdta-1) 
598                     zphi( jj ) = 88.5_wp
599                  END DO
600                  DO jj = mj0(jpjdta  ), mj1(jpjdta  ) 
601                     zphi( jj ) = 89.5_wp
602                  END DO
603               END IF
604            END DO
605            ! provide the correct zphi to all local domains
606#if defined key_mpp_mpi
607            CALL mpp_sum( zphi, jpj, ncomm_znl )       
608#endif
609            !                                        ! =======================
610         ELSE                                        !   OTHER configurations
611            !                                        ! =======================
612            zphi(1:jpj) = gphiv(1,:)             ! assume lat/lon coordinate, select the first i-line
613            !
614         ENDIF
615         !
616         ! Work only on westmost processor (will not work if mppini2 is used)
617#if defined key_mpp_mpi
618         IF( l_znl_root ) THEN 
619#endif
620            !
621            ! OPEN netcdf file
622            ! ----------------
623            ! Define frequency of output and means
624            zsto = nn_fptr * zdt
625            IF( ln_mskland )   THEN    ! put 1.e+20 on land (very expensive!!)
626               clop      = "ave(only(x))"
627               clop_once = "once(only(x))"
628            ELSE                       ! no use of the mask value (require less cpu time)
629               clop      = "ave(x)"       
630               clop_once = "once"
631            ENDIF
632
633            zout = nn_fwri * zdt
634            zfoo(1:jpj) = 0._wp
635
636            CALL ymds2ju( nyear, nmonth, nday, rdt, zjulian )  ! Compute julian date from starting date of the run
637            zjulian = zjulian - adatrj                         ! set calendar origin to the beginning of the experiment
638
639#if defined key_iomput
640            ! Requested by IPSL people, use by their postpro...
641            IF(lwp) THEN
642               CALL dia_nam( clhstnam, nn_fwri,' ' )
643               CALL ctl_opn( inum, 'date.file', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
644               WRITE(inum,*) clhstnam
645               CLOSE(inum)
646            ENDIF
647#endif
648
649            CALL dia_nam( clhstnam, nn_fwri, 'diaptr' )
650            IF(lwp)WRITE( numout,*)" Name of diaptr NETCDF file : ", clhstnam
651
652            ! Horizontal grid : zphi()
653            CALL histbeg(clhstnam, 1, zfoo, jpj, zphi,   &
654               1, 1, 1, jpj, niter, zjulian, zdt*nn_fptr, nhoridz, numptr, domain_id=nidom_ptr)
655            ! Vertical grids : gdept_0, gdepw_0
656            CALL histvert( numptr, "deptht", "Vertical T levels",   &
657               &                   "m", jpk, gdept_0, ndepidzt, "down" )
658            CALL histvert( numptr, "depthw", "Vertical W levels",   &
659               &                   "m", jpk, gdepw_0, ndepidzw, "down" )
660            !
661            CALL wheneq ( jpj*jpk, MIN(sjk(:,:,1), 1._wp), 1, 1., ndex  , ndim  )      ! Lat-Depth
662            CALL wheneq ( jpj    , MIN(sjk(:,1,1), 1._wp), 1, 1., ndex_h, ndim_h )     ! Lat
663
664            IF( ln_subbas ) THEN
665               z_1(:,1) = 1._wp
666               WHERE ( gphit(jpi/2,:) < -30._wp )   z_1(:,1) = 0._wp
667               DO jk = 2, jpk
668                  z_1(:,jk) = z_1(:,1)
669               END DO
670               !                       ! Atlantic (jn=2)
671               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)         , 1._wp), 1, 1., ndex_atl     , ndim_atl      ) ! Lat-Depth
672               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)*z_1(:,:), 1._wp), 1, 1., ndex_atl_30  , ndim_atl_30   ) ! Lat-Depth
673               CALL wheneq ( jpj    , MIN(sjk(:,1,2)*z_1(:,1), 1._wp), 1, 1., ndex_h_atl_30, ndim_h_atl_30 ) ! Lat
674               !                       ! Pacific (jn=3)
675               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)         , 1._wp), 1, 1., ndex_pac     , ndim_pac      ) ! Lat-Depth
676               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)*z_1(:,:), 1._wp), 1, 1., ndex_pac_30  , ndim_pac_30   ) ! Lat-Depth
677               CALL wheneq ( jpj    , MIN(sjk(:,1,3)*z_1(:,1), 1._wp), 1, 1., ndex_h_pac_30, ndim_h_pac_30 ) ! Lat
678               !                       ! Indian (jn=4)
679               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)         , 1._wp), 1, 1., ndex_ind     , ndim_ind      ) ! Lat-Depth
680               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)*z_1(:,:), 1._wp), 1, 1., ndex_ind_30  , ndim_ind_30   ) ! Lat-Depth
681               CALL wheneq ( jpj    , MIN(sjk(:,1,4)*z_1(:,1), 1._wp), 1, 1., ndex_h_ind_30, ndim_h_ind_30 ) ! Lat
682               !                       ! Indo-Pacific (jn=5)
683               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)         , 1._wp), 1, 1., ndex_ipc     , ndim_ipc      ) ! Lat-Depth
684               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)*z_1(:,:), 1._wp), 1, 1., ndex_ipc_30  , ndim_ipc_30   ) ! Lat-Depth
685               CALL wheneq ( jpj    , MIN(sjk(:,1,5)*z_1(:,1), 1._wp), 1, 1., ndex_h_ipc_30, ndim_h_ipc_30 ) ! Lat
686            ENDIF
687            !
688#if defined key_diaeiv
689            cl_comment = ' (Bolus part included)'
690#else
691            cl_comment = '                      '
692#endif
693            IF( ln_diaznl ) THEN             !  Zonal mean T and S
694               CALL histdef( numptr, "zotemglo", "Zonal Mean Temperature","C" ,   &
695                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
696               CALL histdef( numptr, "zosalglo", "Zonal Mean Salinity","PSU"  ,   &
697                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
698
699               CALL histdef( numptr, "zosrfglo", "Zonal Mean Surface","m^2"   ,   &
700                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
701               !
702               IF (ln_subbas) THEN
703                  CALL histdef( numptr, "zotematl", "Zonal Mean Temperature: Atlantic","C" ,   &
704                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
705                  CALL histdef( numptr, "zosalatl", "Zonal Mean Salinity: Atlantic","PSU"  ,   &
706                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
707                  CALL histdef( numptr, "zosrfatl", "Zonal Mean Surface: Atlantic","m^2"   ,   &
708                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
709
710                  CALL histdef( numptr, "zotempac", "Zonal Mean Temperature: Pacific","C"  ,   &
711                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
712                  CALL histdef( numptr, "zosalpac", "Zonal Mean Salinity: Pacific","PSU"   ,   &
713                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
714                  CALL histdef( numptr, "zosrfpac", "Zonal Mean Surface: Pacific","m^2"    ,   &
715                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
716
717                  CALL histdef( numptr, "zotemind", "Zonal Mean Temperature: Indian","C"   ,   &
718                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
719                  CALL histdef( numptr, "zosalind", "Zonal Mean Salinity: Indian","PSU"    ,   &
720                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
721                  CALL histdef( numptr, "zosrfind", "Zonal Mean Surface: Indian","m^2"     ,   &
722                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
723
724                  CALL histdef( numptr, "zotemipc", "Zonal Mean Temperature: Pacific+Indian","C" ,   &
725                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
726                  CALL histdef( numptr, "zosalipc", "Zonal Mean Salinity: Pacific+Indian","PSU"  ,   &
727                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
728                  CALL histdef( numptr, "zosrfipc", "Zonal Mean Surface: Pacific+Indian","m^2"   ,   &
729                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
730               ENDIF
731            ENDIF
732            !
733            !  Meridional Stream-Function (Eulerian and Bolus)
734            CALL histdef( numptr, "zomsfglo", "Meridional Stream-Function: Global"//TRIM(cl_comment),"Sv" ,   &
735               1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
736            IF( ln_subbas .AND. ln_diaznl ) THEN
737               CALL histdef( numptr, "zomsfatl", "Meridional Stream-Function: Atlantic"//TRIM(cl_comment),"Sv" ,   &
738                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
739               CALL histdef( numptr, "zomsfpac", "Meridional Stream-Function: Pacific"//TRIM(cl_comment),"Sv"  ,   &
740                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
741               CALL histdef( numptr, "zomsfind", "Meridional Stream-Function: Indian"//TRIM(cl_comment),"Sv"   ,   &
742                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
743               CALL histdef( numptr, "zomsfipc", "Meridional Stream-Function: Indo-Pacific"//TRIM(cl_comment),"Sv" ,&
744                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
745            ENDIF
746            !
747            !  Heat transport
748            CALL histdef( numptr, "sophtadv", "Advective Heat Transport"      ,   &
749               "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
750            CALL histdef( numptr, "sophtldf", "Diffusive Heat Transport"      ,   &
751               "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
752            IF ( ln_ptrcomp ) THEN
753               CALL histdef( numptr, "sophtove", "Overturning Heat Transport"    ,   &
754                  "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
755            END IF
756            IF( ln_subbas ) THEN
757               CALL histdef( numptr, "sohtatl", "Heat Transport Atlantic"//TRIM(cl_comment),  &
758                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
759               CALL histdef( numptr, "sohtpac", "Heat Transport Pacific"//TRIM(cl_comment) ,  &
760                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
761               CALL histdef( numptr, "sohtind", "Heat Transport Indian"//TRIM(cl_comment)  ,  &
762                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
763               CALL histdef( numptr, "sohtipc", "Heat Transport Pacific+Indian"//TRIM(cl_comment), &
764                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
765            ENDIF
766            !
767            !  Salt transport
768            CALL histdef( numptr, "sopstadv", "Advective Salt Transport"      ,   &
769               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
770            CALL histdef( numptr, "sopstldf", "Diffusive Salt Transport"      ,   &
771               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
772            IF ( ln_ptrcomp ) THEN
773               CALL histdef( numptr, "sopstove", "Overturning Salt Transport"    ,   &
774                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
775            END IF
776#if defined key_diaeiv
777            ! Eddy induced velocity
778            CALL histdef( numptr, "zomsfeiv", "Bolus Meridional Stream-Function: global",   &
779               "Sv"      , 1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
780            CALL histdef( numptr, "sophteiv", "Bolus Advective Heat Transport",   &
781               "PW"      , 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
782            CALL histdef( numptr, "sopsteiv", "Bolus Advective Salt Transport",   &
783               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
784#endif
785            IF( ln_subbas ) THEN
786               CALL histdef( numptr, "sostatl", "Salt Transport Atlantic"//TRIM(cl_comment)      ,  &
787                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
788               CALL histdef( numptr, "sostpac", "Salt Transport Pacific"//TRIM(cl_comment)      ,   &
789                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
790               CALL histdef( numptr, "sostind", "Salt Transport Indian"//TRIM(cl_comment)      ,    &
791                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
792               CALL histdef( numptr, "sostipc", "Salt Transport Pacific+Indian"//TRIM(cl_comment),  &
793                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
794            ENDIF
795            !
796            CALL histend( numptr )
797            !
798         END IF
799#if defined key_mpp_mpi
800      END IF
801#endif
802
803#if defined key_mpp_mpi
804      IF( MOD( itmod, nn_fptr ) == 0 .AND. l_znl_root ) THEN
805#else
806      IF( MOD( itmod, nn_fptr ) == 0  ) THEN
807#endif
808         niter = niter + 1
809
810         IF( ln_diaznl ) THEN
811            CALL histwrite( numptr, "zosrfglo", niter, sjk  (:,:,1) , ndim, ndex )
812            CALL histwrite( numptr, "zotemglo", niter, tn_jk(:,:,1)  , ndim, ndex )
813            CALL histwrite( numptr, "zosalglo", niter, sn_jk(:,:,1)  , ndim, ndex )
814
815            IF (ln_subbas) THEN
816               CALL histwrite( numptr, "zosrfatl", niter, sjk(:,:,2), ndim_atl, ndex_atl )
817               CALL histwrite( numptr, "zosrfpac", niter, sjk(:,:,3), ndim_pac, ndex_pac )
818               CALL histwrite( numptr, "zosrfind", niter, sjk(:,:,4), ndim_ind, ndex_ind )
819               CALL histwrite( numptr, "zosrfipc", niter, sjk(:,:,5), ndim_ipc, ndex_ipc )
820
821               CALL histwrite( numptr, "zotematl", niter, tn_jk(:,:,2)  , ndim_atl, ndex_atl )
822               CALL histwrite( numptr, "zosalatl", niter, sn_jk(:,:,2)  , ndim_atl, ndex_atl )
823               CALL histwrite( numptr, "zotempac", niter, tn_jk(:,:,3)  , ndim_pac, ndex_pac )
824               CALL histwrite( numptr, "zosalpac", niter, sn_jk(:,:,3)  , ndim_pac, ndex_pac )
825               CALL histwrite( numptr, "zotemind", niter, tn_jk(:,:,4)  , ndim_ind, ndex_ind )
826               CALL histwrite( numptr, "zosalind", niter, sn_jk(:,:,4)  , ndim_ind, ndex_ind )
827               CALL histwrite( numptr, "zotemipc", niter, tn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
828               CALL histwrite( numptr, "zosalipc", niter, sn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
829            END IF
830         ENDIF
831
832         ! overturning outputs:
833         CALL histwrite( numptr, "zomsfglo", niter, v_msf(:,:,1), ndim, ndex )
834         IF( ln_subbas .AND. ln_diaznl ) THEN
835            CALL histwrite( numptr, "zomsfatl", niter, v_msf(:,:,2) , ndim_atl_30, ndex_atl_30 )
836            CALL histwrite( numptr, "zomsfpac", niter, v_msf(:,:,3) , ndim_pac_30, ndex_pac_30 )
837            CALL histwrite( numptr, "zomsfind", niter, v_msf(:,:,4) , ndim_ind_30, ndex_ind_30 )
838            CALL histwrite( numptr, "zomsfipc", niter, v_msf(:,:,5) , ndim_ipc_30, ndex_ipc_30 )
839         ENDIF
840#if defined key_diaeiv
841         CALL histwrite( numptr, "zomsfeiv", niter, v_msf_eiv(:,:,1), ndim  , ndex   )
842#endif
843
844         ! heat transport outputs:
845         IF( ln_subbas ) THEN
846            CALL histwrite( numptr, "sohtatl", niter, htr(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
847            CALL histwrite( numptr, "sohtpac", niter, htr(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
848            CALL histwrite( numptr, "sohtind", niter, htr(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
849            CALL histwrite( numptr, "sohtipc", niter, htr(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
850            CALL histwrite( numptr, "sostatl", niter, str(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
851            CALL histwrite( numptr, "sostpac", niter, str(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
852            CALL histwrite( numptr, "sostind", niter, str(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
853            CALL histwrite( numptr, "sostipc", niter, str(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
854         ENDIF
855
856         CALL histwrite( numptr, "sophtadv", niter, htr_adv     , ndim_h, ndex_h )
857         CALL histwrite( numptr, "sophtldf", niter, htr_ldf     , ndim_h, ndex_h )
858         CALL histwrite( numptr, "sopstadv", niter, str_adv     , ndim_h, ndex_h )
859         CALL histwrite( numptr, "sopstldf", niter, str_ldf     , ndim_h, ndex_h )
860         IF( ln_ptrcomp ) THEN
861            CALL histwrite( numptr, "sopstove", niter, str_ove(:) , ndim_h, ndex_h )
862            CALL histwrite( numptr, "sophtove", niter, htr_ove(:) , ndim_h, ndex_h )
863         ENDIF
864#if defined key_diaeiv
865         CALL histwrite( numptr, "sophteiv", niter, htr_eiv(:,1)  , ndim_h, ndex_h )
866         CALL histwrite( numptr, "sopsteiv", niter, str_eiv(:,1)  , ndim_h, ndex_h )
867#endif
868         !
869      ENDIF
870      !
871      IF( .not. wrk_release(1, 1,2) .OR. (.not. wrk_release(2, 1)) )   &
872         CALL ctl_stop('dia_ptr_wri: failed to release workspace arrays')
873      !
874  END SUBROUTINE dia_ptr_wri
875
876   !!======================================================================
877END MODULE diaptr
Note: See TracBrowser for help on using the repository browser.