1 | MODULE dynzdf_exp |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE dynzdf_exp *** |
---|
4 | !! Ocean dynamics: vertical component(s) of the momentum mixing trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
---|
7 | !! 8.0 ! 1997-05 (G. Madec) vertical component of isopycnal |
---|
8 | !! NEMO 1.0 ! 1002-08 (G. Madec) F90: Free form and module |
---|
9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! dyn_zdf_exp : update the momentum trend with the vertical diffu- |
---|
14 | !! sion using an explicit time-stepping scheme. |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE phycst ! physical constants |
---|
19 | USE zdf_oce ! ocean vertical physics |
---|
20 | USE sbc_oce ! surface boundary condition: ocean |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | PUBLIC dyn_zdf_exp ! called by step.F90 |
---|
27 | |
---|
28 | !! * Substitutions |
---|
29 | # include "domzgr_substitute.h90" |
---|
30 | # include "vectopt_loop_substitute.h90" |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
33 | !! $Id$ |
---|
34 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | |
---|
37 | CONTAINS |
---|
38 | |
---|
39 | SUBROUTINE dyn_zdf_exp( kt, p2dt ) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! *** ROUTINE dyn_zdf_exp *** |
---|
42 | !! |
---|
43 | !! ** Purpose : Compute the trend due to the vert. momentum diffusion |
---|
44 | !! |
---|
45 | !! ** Method : Explicit forward time stepping with a time splitting |
---|
46 | !! technique. The vertical diffusion of momentum is given by: |
---|
47 | !! diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) ) |
---|
48 | !! Surface boundary conditions: wind stress input (averaged over kt-1/2 & kt+1/2) |
---|
49 | !! Bottom boundary conditions : bottom stress (cf zdfbfr.F90) |
---|
50 | !! Add this trend to the general trend ua : |
---|
51 | !! ua = ua + dz( avmu dz(u) ) |
---|
52 | !! |
---|
53 | !! ** Action : - Update (ua,va) with the vertical diffusive trend |
---|
54 | !!--------------------------------------------------------------------- |
---|
55 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
---|
56 | REAL(wp), INTENT(in) :: p2dt ! time-step |
---|
57 | !! |
---|
58 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
---|
59 | REAL(wp) :: zrau0r, zlavmr, zua, zva ! temporary scalars |
---|
60 | REAL(wp), DIMENSION(jpi,jpk) :: zwx, zwy, zwz, zww ! 2D workspace |
---|
61 | !!---------------------------------------------------------------------- |
---|
62 | |
---|
63 | IF( kt == nit000 ) THEN |
---|
64 | IF(lwp) WRITE(numout,*) |
---|
65 | IF(lwp) WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion - explicit operator' |
---|
66 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
---|
67 | ENDIF |
---|
68 | |
---|
69 | zrau0r = 1. / rau0 ! Local constant initialization |
---|
70 | zlavmr = 1. / REAL( nn_zdfexp ) |
---|
71 | |
---|
72 | ! ! =============== |
---|
73 | DO jj = 2, jpjm1 ! Vertical slab |
---|
74 | ! ! =============== |
---|
75 | DO ji = 2, jpim1 ! Surface boundary condition |
---|
76 | zwy(ji,1) = ( utau_b(ji,jj) + utau(ji,jj) ) * zrau0r |
---|
77 | zww(ji,1) = ( vtau_b(ji,jj) + vtau(ji,jj) ) * zrau0r |
---|
78 | END DO |
---|
79 | DO jk = 1, jpk ! Initialization of x, z and contingently trends array |
---|
80 | DO ji = 2, jpim1 |
---|
81 | zwx(ji,jk) = ub(ji,jj,jk) |
---|
82 | zwz(ji,jk) = vb(ji,jj,jk) |
---|
83 | END DO |
---|
84 | END DO |
---|
85 | ! |
---|
86 | DO jl = 1, nn_zdfexp ! Time splitting loop |
---|
87 | ! |
---|
88 | DO jk = 2, jpk ! First vertical derivative |
---|
89 | DO ji = 2, jpim1 |
---|
90 | zwy(ji,jk) = avmu(ji,jj,jk) * ( zwx(ji,jk-1) - zwx(ji,jk) ) / fse3uw(ji,jj,jk) |
---|
91 | zww(ji,jk) = avmv(ji,jj,jk) * ( zwz(ji,jk-1) - zwz(ji,jk) ) / fse3vw(ji,jj,jk) |
---|
92 | END DO |
---|
93 | END DO |
---|
94 | DO jk = 1, jpkm1 ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp |
---|
95 | DO ji = 2, jpim1 |
---|
96 | zua = zlavmr * ( zwy(ji,jk) - zwy(ji,jk+1) ) / fse3u(ji,jj,jk) |
---|
97 | zva = zlavmr * ( zww(ji,jk) - zww(ji,jk+1) ) / fse3v(ji,jj,jk) |
---|
98 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
99 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
100 | ! |
---|
101 | zwx(ji,jk) = zwx(ji,jk) + p2dt * zua * umask(ji,jj,jk) |
---|
102 | zwz(ji,jk) = zwz(ji,jk) + p2dt * zva * vmask(ji,jj,jk) |
---|
103 | END DO |
---|
104 | END DO |
---|
105 | ! |
---|
106 | END DO |
---|
107 | ! ! =============== |
---|
108 | END DO ! End of slab |
---|
109 | ! ! =============== |
---|
110 | END SUBROUTINE dyn_zdf_exp |
---|
111 | |
---|
112 | !!============================================================================== |
---|
113 | END MODULE dynzdf_exp |
---|