New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 2688

Last change on this file since 2688 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions
25   USE lib_fortran
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   sbc_fwb    ! routine called by step
31
32   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
33   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
34   REAL(wp) ::   fwfold    ! fwfold to be suppressed
35   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
48      !!---------------------------------------------------------------------
49      !!                  ***  ROUTINE sbc_fwb  ***
50      !!
51      !! ** Purpose :   Control the mean sea surface drift
52      !!
53      !! ** Method  :   several ways  depending on kn_fwb
54      !!                =0 no control
55      !!                =1 global mean of emp set to zero at each nn_fsbc time step
56      !!                =2 annual global mean corrected from previous year
57      !!                =3 global mean of emp set to zero at each nn_fsbc time step
58      !!                   & spread out over erp area depending its sign
59      !!----------------------------------------------------------------------
60      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
61      USE wrk_nemo, ONLY:      ztmsk_neg => wrk_2d_1, ztmsk_pos=> wrk_2d_2
62      USE wrk_nemo, ONLY: ztmsk_tospread => wrk_2d_3
63      USE wrk_nemo, ONLY:          z_wgt => wrk_2d_4, zerp_cor => wrk_2d_5
64      !!
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      !!
69      INTEGER  ::   inum                  ! temporary logical unit
70      INTEGER  ::   ikty, iyear           !
71      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp       ! temporary scalars
72      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread
73      !!----------------------------------------------------------------------
74      !
75      IF( wrk_in_use(2, 1,2,3,4,5) ) THEN
76         CALL ctl_stop('sbc_fwb: requested workspace arrays are unavailable')   ;   RETURN
77      END IF
78      !
79      IF( kt == nit000 ) THEN
80         IF(lwp) THEN
81            WRITE(numout,*)
82            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
83            WRITE(numout,*) '~~~~~~~'
84            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
85            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
86            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
87         ENDIF
88         !
89         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
90         !
91         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
92      ENDIF
93     
94
95      SELECT CASE ( kn_fwb )
96      !
97      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
98         !
99         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
100            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
101            emp (:,:) = emp (:,:) - z_fwf 
102            emps(:,:) = emps(:,:) - z_fwf 
103         ENDIF
104         !
105      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
106         !
107         IF( kt == nit000 ) THEN                   ! initialisation
108            !                                         ! Read the corrective factor on precipitations (fwfold)
109            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
110            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
111            CLOSE( inum )
112            fwfold = a_fwb                            ! current year freshwater budget correction
113            !                                         ! estimate from the previous year budget
114            IF(lwp)WRITE(numout,*)
115            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
116            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
117            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
118         ENDIF   
119         !                                         ! Update fwfold if new year start
120         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
121         IF( MOD( kt, ikty ) == 0 ) THEN
122            a_fwb_b = a_fwb
123            a_fwb   = glob_sum( e1e2t(:,:) * sshn(:,:) )   ! sum over the global domain
124            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
125!!gm        !                                                      !!bug 365d year
126            fwfold =  a_fwb                           ! current year freshwater budget correction
127            !                                         ! estimate from the previous year budget
128         ENDIF
129         !
130         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
131            emp (:,:) = emp (:,:) + fwfold
132            emps(:,:) = emps(:,:) + fwfold
133         ENDIF
134         !
135         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
136            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
137            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
138            CLOSE( inum )
139         ENDIF
140         !
141      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
142         !
143         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
144            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
145            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
146            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
147            !
148            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
149            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
150            !                                                  ! fwf global mean
151            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
152            !           
153            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
154                zsurf_tospread      = zsurf_pos
155                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
156            ELSE                             ! spread out over <0 erp area to increase precipitation
157                zsurf_tospread      = zsurf_neg
158                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
159            ENDIF
160            !
161            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
162!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
163            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
164            !                                                  ! weight to respect erp field 2D structure
165            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
166            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
167            !                                                  ! final correction term to apply
168            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
169            !
170!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
171            CALL lbc_lnk( zerp_cor, 'T', 1. )
172            !
173            emp (:,:) = emp (:,:) + zerp_cor(:,:)
174            emps(:,:) = emps(:,:) + zerp_cor(:,:)
175            erp (:,:) = erp (:,:) + zerp_cor(:,:)
176            !
177            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
178               IF( z_fwf < 0._wp ) THEN
179                  WRITE(numout,*)'   z_fwf < 0'
180                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
181               ELSE
182                  WRITE(numout,*)'   z_fwf >= 0'
183                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
184               ENDIF
185               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
186               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
187               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
188               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
189               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
190            ENDIF
191         ENDIF
192         !
193      CASE DEFAULT                           !==  you should never be there  ==!
194         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
195         !
196      END SELECT
197      !
198      IF( wrk_not_released(2, 1,2,3,4,5) )   CALL ctl_stop('sbc_fwb: failed to release workspace arrays')
199      !
200   END SUBROUTINE sbc_fwb
201
202   !!======================================================================
203END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.