New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 2688

Last change on this file since 2688 was 2620, checked in by gm, 13 years ago

dynamic mem: #785 ; SBC: move dyn allocation from nemogcm to module when possible (continuation)
  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE restart         ! ocean restart
21   USE iom
22   USE in_out_manager  ! I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm    ! routine called by step.F90
28   
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE sbc_ssm( kt )
39      !!---------------------------------------------------------------------
40      !!                     ***  ROUTINE sbc_oce  ***
41      !!                     
42      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
43      !!                condition computation
44      !!               
45      !! ** Method  :   compute mean surface velocity (2 components at U and
46      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
47      !!      the periode (kt - nn_fsbc) to kt
48      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
49      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
50      !!---------------------------------------------------------------------
51      INTEGER, INTENT(in) ::   kt        ! ocean time step
52      !
53      REAL(wp) ::   zcoef       ! temporary scalar
54      REAL(wp) ::   zf_sbc      ! read sbc frequency
55      !!---------------------------------------------------------------------
56      !                                                   ! ---------------------------------------- !
57      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
58         !                                                ! ---------------------------------------- !
59         IF( kt == nit000 ) THEN
60            IF(lwp) WRITE(numout,*)
61            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
62            IF(lwp) WRITE(numout,*) '~~~~~~~ '
63         ENDIF
64         !
65         ssu_m(:,:) = ub(:,:,1)
66         ssv_m(:,:) = vb(:,:,1)
67         sst_m(:,:) = tn(:,:,1)
68         sss_m(:,:) = sn(:,:,1)
69         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
70         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
71         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
72         ENDIF
73
74         !
75      ELSE
76         !                                                ! ---------------------------------------- !
77         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
78            !                                             ! ---------------------------------------- !
79            IF(lwp) WRITE(numout,*)
80            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
81            !
82            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
83               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
84               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
85               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
86               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
87               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
88               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
89               !
90               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
91                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
92                     &                    'from ', zf_sbc, ' to ', nn_fsbc
93                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
94                  ssu_m(:,:) = zcoef * ssu_m(:,:)
95                  ssv_m(:,:) = zcoef * ssv_m(:,:)
96                  sst_m(:,:) = zcoef * sst_m(:,:)
97                  sss_m(:,:) = zcoef * sss_m(:,:)
98                  ssh_m(:,:) = zcoef * ssh_m(:,:)
99               ELSE
100                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
101               ENDIF
102            ELSE
103               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
104               zcoef = REAL( nn_fsbc - 1, wp )
105               ssu_m(:,:) = zcoef * ub(:,:,1)
106               ssv_m(:,:) = zcoef * vb(:,:,1)
107               sst_m(:,:) = zcoef * tn(:,:,1)
108               sss_m(:,:) = zcoef * sn(:,:,1)
109               !                          ! removed inverse barometer ssh when Patm forcing is used
110               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
111               ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
112               ENDIF
113
114            ENDIF
115            !                                             ! ---------------------------------------- !
116         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
117            !                                             ! ---------------------------------------- !
118            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
119            ssv_m(:,:) = 0.e0
120            sst_m(:,:) = 0.e0
121            sss_m(:,:) = 0.e0
122            ssh_m(:,:) = 0.e0
123         ENDIF
124         !                                                ! ---------------------------------------- !
125         !                                                !        Cumulate at each time step        !
126         !                                                ! ---------------------------------------- !
127         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
128         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
129         sst_m(:,:) = sst_m(:,:) + tn(:,:,1)
130         sss_m(:,:) = sss_m(:,:) + sn(:,:,1)
131         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
132         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
133         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
134         ENDIF
135
136         !                                                ! ---------------------------------------- !
137         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
138            !                                             ! ---------------------------------------- !
139            zcoef = 1. / REAL( nn_fsbc, wp )
140            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
141            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
142            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
143            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
144            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
145            !
146         ENDIF
147         !                                                ! ---------------------------------------- !
148         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
149            !                                             ! ---------------------------------------- !
150            IF(lwp) WRITE(numout,*)
151            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
152               &                    'at it= ', kt,' date= ', ndastp
153            IF(lwp) WRITE(numout,*) '~~~~~~~'
154            zf_sbc = REAL( nn_fsbc, wp )
155            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
156            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
157            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
158            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
161            !
162         ENDIF
163         !
164      ENDIF
165      !
166   END SUBROUTINE sbc_ssm
167
168   !!======================================================================
169END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.