New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
eosbn2.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/eosbn2.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 39.3 KB
Line 
1MODULE eosbn2
2   !!==============================================================================
3   !!                       ***  MODULE  eosbn2  ***
4   !! Ocean diagnostic variable : equation of state - in situ and potential density
5   !!                                               - Brunt-Vaisala frequency
6   !!==============================================================================
7   !! History :  OPA  ! 1989-03  (O. Marti)  Original code
8   !!            6.0  ! 1994-07  (G. Madec, M. Imbard)  add bn2
9   !!            6.0  ! 1994-08  (G. Madec)  Add Jackett & McDougall eos
10   !!            7.0  ! 1996-01  (G. Madec)  statement function for e3
11   !!            8.1  ! 1997-07  (G. Madec)  density instead of volumic mass
12   !!             -   ! 1999-02  (G. Madec, N. Grima) semi-implicit pressure gradient
13   !!            8.2  ! 2001-09  (M. Ben Jelloul)  bugfix on linear eos
14   !!   NEMO     1.0  ! 2002-10  (G. Madec)  add eos_init
15   !!             -   ! 2002-11  (G. Madec, A. Bozec)  partial step, eos_insitu_2d
16   !!             -   ! 2003-08  (G. Madec)  F90, free form
17   !!            3.0  ! 2006-08  (G. Madec)  add tfreez function
18   !!            3.3  ! 2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!             -   ! 2010-10  (G. Nurser, G. Madec)  add eos_alpbet used in ldfslp
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   eos            : generic interface of the equation of state
24   !!   eos_insitu     : Compute the in situ density
25   !!   eos_insitu_pot : Compute the insitu and surface referenced potential
26   !!                    volumic mass
27   !!   eos_insitu_2d  : Compute the in situ density for 2d fields
28   !!   eos_bn2        : Compute the Brunt-Vaisala frequency
29   !!   eos_alpbet     : calculates the in situ thermal and haline expansion coeff.
30   !!   tfreez         : Compute the surface freezing temperature
31   !!   eos_init       : set eos parameters (namelist)
32   !!----------------------------------------------------------------------
33   USE dom_oce         ! ocean space and time domain
34   USE phycst          ! physical constants
35   USE in_out_manager  ! I/O manager
36   USE zdfddm          ! vertical physics: double diffusion
37   USE prtctl          ! Print control
38
39   IMPLICIT NONE
40   PRIVATE
41
42   !                   !! * Interface
43   INTERFACE eos
44      MODULE PROCEDURE eos_insitu, eos_insitu_pot, eos_insitu_2d
45   END INTERFACE
46   INTERFACE bn2
47      MODULE PROCEDURE eos_bn2
48   END INTERFACE
49
50   PUBLIC   eos        ! called by step, istate, tranpc and zpsgrd modules
51   PUBLIC   eos_init   ! called by istate module
52   PUBLIC   bn2        ! called by step module
53   PUBLIC   eos_alpbet ! called by ldfslp module
54   PUBLIC   tfreez     ! called by sbcice_... modules
55
56   !                                          !!* Namelist (nameos) *
57   INTEGER , PUBLIC ::   nn_eos   = 0         !: = 0/1/2 type of eq. of state and Brunt-Vaisala frequ.
58   REAL(wp), PUBLIC ::   rn_alpha = 2.0e-4_wp !: thermal expension coeff. (linear equation of state)
59   REAL(wp), PUBLIC ::   rn_beta  = 7.7e-4_wp !: saline  expension coeff. (linear equation of state)
60
61   REAL(wp), PUBLIC ::   ralpbet              !: alpha / beta ratio
62   
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65#  include "vectopt_loop_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   SUBROUTINE eos_insitu( pts, prd )
74      !!----------------------------------------------------------------------
75      !!                   ***  ROUTINE eos_insitu  ***
76      !!
77      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
78      !!       potential temperature and salinity using an equation of state
79      !!       defined through the namelist parameter nn_eos.
80      !!
81      !! ** Method  :   3 cases:
82      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
83      !!         the in situ density is computed directly as a function of
84      !!         potential temperature relative to the surface (the opa t
85      !!         variable), salt and pressure (assuming no pressure variation
86      !!         along geopotential surfaces, i.e. the pressure p in decibars
87      !!         is approximated by the depth in meters.
88      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
89      !!         with pressure                      p        decibars
90      !!              potential temperature         t        deg celsius
91      !!              salinity                      s        psu
92      !!              reference volumic mass        rau0     kg/m**3
93      !!              in situ volumic mass          rho      kg/m**3
94      !!              in situ density anomalie      prd      no units
95      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
96      !!          t = 40 deg celcius, s=40 psu
97      !!      nn_eos = 1 : linear equation of state function of temperature only
98      !!              prd(t) = 0.0285 - rn_alpha * t
99      !!      nn_eos = 2 : linear equation of state function of temperature and
100      !!               salinity
101      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
102      !!      Note that no boundary condition problem occurs in this routine
103      !!      as pts are defined over the whole domain.
104      !!
105      !! ** Action  :   compute prd , the in situ density (no units)
106      !!
107      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
108      !!----------------------------------------------------------------------
109      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
110      USE wrk_nemo, ONLY: zws => wrk_3d_1 ! temporary workspace
111      !!
112      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
113      !                                                               ! 2 : salinity               [psu]
114      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out) ::   prd   ! in situ density
115      !!
116      INTEGER  ::   ji, jj, jk           ! dummy loop indices
117      REAL(wp) ::   zt , zs , zh , zsr   ! temporary scalars
118      REAL(wp) ::   zr1, zr2, zr3, zr4   !    -         -
119      REAL(wp) ::   zrhop, ze, zbw, zb   !    -         -
120      REAL(wp) ::   zd , zc , zaw, za    !    -         -
121      REAL(wp) ::   zb1, za1, zkw, zk0   !    -         -
122      REAL(wp) ::   zrau0r               !    -         -
123      !!----------------------------------------------------------------------
124
125      IF(wrk_in_use(3, 1))THEN
126         CALL ctl_stop('eos_insitu : requested workspace array unavailable.')
127         RETURN
128      END IF
129
130      SELECT CASE( nn_eos )
131      !
132      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
133         zrau0r = 1.e0 / rau0
134!CDIR NOVERRCHK
135         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
136         ! 
137         DO jk = 1, jpkm1
138            DO jj = 1, jpj
139               DO ji = 1, jpi
140                  zt = pts   (ji,jj,jk,jp_tem)
141                  zs = pts   (ji,jj,jk,jp_sal)
142                  zh = fsdept(ji,jj,jk)        ! depth
143                  zsr= zws   (ji,jj,jk)        ! square root salinity
144                  !
145                  ! compute volumic mass pure water at atm pressure
146                  zr1= ( ( ( ( 6.536332e-9_wp  *zt - 1.120083e-6_wp )*zt + 1.001685e-4_wp )*zt   &
147                     &        -9.095290e-3_wp )*zt + 6.793952e-2_wp )*zt +  999.842594_wp
148                  ! seawater volumic mass atm pressure
149                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt        &
150                     &                      -4.0899e-3_wp ) *zt+0.824493_wp
151                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
152                  zr4= 4.8314e-4_wp
153                  !
154                  ! potential volumic mass (reference to the surface)
155                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
156                  !
157                  ! add the compression terms
158                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
159                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
160                  zb = zbw + ze * zs
161                  !
162                  zd = -2.042967e-2_wp
163                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
164                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
165                  za = ( zd*zsr + zc ) *zs + zaw
166                  !
167                  zb1=   (-0.1909078_wp*zt+7.390729_wp )        *zt-55.87545_wp
168                  za1= ( ( 2.326469e-3_wp*zt+1.553190_wp)       *zt-65.00517_wp ) *zt+1044.077_wp
169                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
170                  zk0= ( zb1*zsr + za1 )*zs + zkw
171                  !
172                  ! masked in situ density anomaly
173                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
174                     &             - rau0  ) * zrau0r * tmask(ji,jj,jk)
175               END DO
176            END DO
177         END DO
178         !
179      CASE( 1 )                !==  Linear formulation function of temperature only  ==!
180         DO jk = 1, jpkm1
181            prd(:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask(:,:,jk)
182         END DO
183         !
184      CASE( 2 )                !==  Linear formulation function of temperature and salinity  ==!
185         DO jk = 1, jpkm1
186            prd(:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask(:,:,jk)
187         END DO
188         !
189      END SELECT
190      !
191      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos  : ', ovlap=1, kdim=jpk )
192      !
193      IF(wrk_not_released(3, 1))THEN
194         CALL ctl_stop('eos_insitu : failed to release workspace array.')
195      END IF
196      !
197   END SUBROUTINE eos_insitu
198
199
200   SUBROUTINE eos_insitu_pot( pts, prd, prhop )
201      !!----------------------------------------------------------------------
202      !!                  ***  ROUTINE eos_insitu_pot  ***
203      !!           
204      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) and the
205      !!      potential volumic mass (Kg/m3) from potential temperature and
206      !!      salinity fields using an equation of state defined through the
207      !!     namelist parameter nn_eos.
208      !!
209      !! ** Method  :
210      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
211      !!         the in situ density is computed directly as a function of
212      !!         potential temperature relative to the surface (the opa t
213      !!         variable), salt and pressure (assuming no pressure variation
214      !!         along geopotential surfaces, i.e. the pressure p in decibars
215      !!         is approximated by the depth in meters.
216      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
217      !!              rhop(t,s)  = rho(t,s,0)
218      !!         with pressure                      p        decibars
219      !!              potential temperature         t        deg celsius
220      !!              salinity                      s        psu
221      !!              reference volumic mass        rau0     kg/m**3
222      !!              in situ volumic mass          rho      kg/m**3
223      !!              in situ density anomalie      prd      no units
224      !!
225      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
226      !!          t = 40 deg celcius, s=40 psu
227      !!
228      !!      nn_eos = 1 : linear equation of state function of temperature only
229      !!              prd(t) = ( rho(t) - rau0 ) / rau0 = 0.028 - rn_alpha * t
230      !!              rhop(t,s)  = rho(t,s)
231      !!
232      !!      nn_eos = 2 : linear equation of state function of temperature and
233      !!               salinity
234      !!              prd(t,s) = ( rho(t,s) - rau0 ) / rau0
235      !!                       = rn_beta * s - rn_alpha * tn - 1.
236      !!              rhop(t,s)  = rho(t,s)
237      !!      Note that no boundary condition problem occurs in this routine
238      !!      as (tn,sn) or (ta,sa) are defined over the whole domain.
239      !!
240      !! ** Action  : - prd  , the in situ density (no units)
241      !!              - prhop, the potential volumic mass (Kg/m3)
242      !!
243      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
244      !!                Brown and Campana, Mon. Weather Rev., 1978
245      !!----------------------------------------------------------------------
246      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
247      USE wrk_nemo, ONLY: zws => wrk_3d_1 ! 3D workspace
248      !!
249      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
250      !                                                               ! 2 : salinity               [psu]
251      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prd    ! in situ density
252      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
253
254      INTEGER  ::   ji, jj, jk   ! dummy loop indices
255      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! temporary scalars
256      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zrau0r       !    -         -
257      !!----------------------------------------------------------------------
258
259      IF(wrk_in_use(3, 1))THEN
260         CALL ctl_stop('eos_insitu_pot: requested workspace array unavailable.')
261         RETURN
262      END IF
263
264      SELECT CASE ( nn_eos )
265      !
266      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
267         zrau0r = 1.e0 / rau0
268!CDIR NOVERRCHK
269         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
270         ! 
271         DO jk = 1, jpkm1
272            DO jj = 1, jpj
273               DO ji = 1, jpi
274                  zt = pts   (ji,jj,jk,jp_tem)
275                  zs = pts   (ji,jj,jk,jp_sal)
276                  zh = fsdept(ji,jj,jk)        ! depth
277                  zsr= zws   (ji,jj,jk)        ! square root salinity
278                  !
279                  ! compute volumic mass pure water at atm pressure
280                  zr1= ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
281                     &                          -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
282                  ! seawater volumic mass atm pressure
283                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt   &
284                     &                                         -4.0899e-3_wp ) *zt+0.824493_wp
285                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
286                  zr4= 4.8314e-4_wp
287                  !
288                  ! potential volumic mass (reference to the surface)
289                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
290                  !
291                  ! save potential volumic mass
292                  prhop(ji,jj,jk) = zrhop * tmask(ji,jj,jk)
293                  !
294                  ! add the compression terms
295                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
296                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
297                  zb = zbw + ze * zs
298                  !
299                  zd = -2.042967e-2_wp
300                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
301                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
302                  za = ( zd*zsr + zc ) *zs + zaw
303                  !
304                  zb1=   (  -0.1909078_wp  *zt+7.390729_wp    ) *zt-55.87545_wp
305                  za1= ( (   2.326469e-3_wp*zt+1.553190_wp    ) *zt-65.00517_wp ) *zt + 1044.077_wp
306                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
307                  zk0= ( zb1*zsr + za1 )*zs + zkw
308                  !
309                  ! masked in situ density anomaly
310                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
311                     &             - rau0  ) * zrau0r * tmask(ji,jj,jk)
312               END DO
313            END DO
314         END DO
315         !
316      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
317         DO jk = 1, jpkm1
318            prd  (:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask(:,:,jk)
319            prhop(:,:,jk) = ( 1.e0_wp   +            prd (:,:,jk)       ) * rau0 * tmask(:,:,jk)
320         END DO
321         !
322      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
323         DO jk = 1, jpkm1
324            prd  (:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask(:,:,jk)
325            prhop(:,:,jk) = ( 1.e0_wp  + prd (:,:,jk) )                                       * rau0 * tmask(:,:,jk)
326         END DO
327         !
328      END SELECT
329      !
330      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-p: ', tab3d_2=prhop, clinfo2=' pot : ', ovlap=1, kdim=jpk )
331      !
332      IF(wrk_not_released(3, 1))THEN
333         CALL ctl_stop('eos_insitu_pot: failed to release workspace array.')
334      END IF
335      !
336   END SUBROUTINE eos_insitu_pot
337
338
339   SUBROUTINE eos_insitu_2d( pts, pdep, prd )
340      !!----------------------------------------------------------------------
341      !!                  ***  ROUTINE eos_insitu_2d  ***
342      !!
343      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
344      !!      potential temperature and salinity using an equation of state
345      !!      defined through the namelist parameter nn_eos. * 2D field case
346      !!
347      !! ** Method :
348      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
349      !!         the in situ density is computed directly as a function of
350      !!         potential temperature relative to the surface (the opa t
351      !!         variable), salt and pressure (assuming no pressure variation
352      !!         along geopotential surfaces, i.e. the pressure p in decibars
353      !!         is approximated by the depth in meters.
354      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
355      !!         with pressure                      p        decibars
356      !!              potential temperature         t        deg celsius
357      !!              salinity                      s        psu
358      !!              reference volumic mass        rau0     kg/m**3
359      !!              in situ volumic mass          rho      kg/m**3
360      !!              in situ density anomalie      prd      no units
361      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
362      !!          t = 40 deg celcius, s=40 psu
363      !!      nn_eos = 1 : linear equation of state function of temperature only
364      !!              prd(t) = 0.0285 - rn_alpha * t
365      !!      nn_eos = 2 : linear equation of state function of temperature and
366      !!               salinity
367      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
368      !!      Note that no boundary condition problem occurs in this routine
369      !!      as pts are defined over the whole domain.
370      !!
371      !! ** Action  : - prd , the in situ density (no units)
372      !!
373      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
374      !!----------------------------------------------------------------------
375      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
376      USE wrk_nemo, ONLY: zws => wrk_2d_5 ! 2D workspace
377      !!
378      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
379      !                                                           ! 2 : salinity               [psu]
380      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(in   ) ::   pdep  ! depth                  [m]
381      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(  out) ::   prd   ! in situ density
382      !!
383      INTEGER  ::   ji, jj                    ! dummy loop indices
384      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! temporary scalars
385      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zmask        !    -         -
386      !!----------------------------------------------------------------------
387
388      IF(wrk_in_use(2, 5))THEN
389         CALL ctl_stop('eos_insitu_2d: requested workspace array unavailable.')
390         RETURN
391      END IF
392
393      prd(:,:) = 0.e0
394
395      SELECT CASE( nn_eos )
396      !
397      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
398      !
399!CDIR NOVERRCHK
400         DO jj = 1, jpjm1
401!CDIR NOVERRCHK
402            DO ji = 1, fs_jpim1   ! vector opt.
403               zws(ji,jj) = SQRT( ABS( pts(ji,jj,jp_sal) ) )
404            END DO
405         END DO
406         DO jj = 1, jpjm1
407            DO ji = 1, fs_jpim1   ! vector opt.
408               zmask = tmask(ji,jj,1)          ! land/sea bottom mask = surf. mask
409               zt    = pts  (ji,jj,jp_tem)            ! interpolated T
410               zs    = pts  (ji,jj,jp_sal)            ! interpolated S
411               zsr   = zws  (ji,jj)            ! square root of interpolated S
412               zh    = pdep (ji,jj)            ! depth at the partial step level
413               !
414               ! compute volumic mass pure water at atm pressure
415               zr1 = ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
416                  &                        -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
417               ! seawater volumic mass atm pressure
418               zr2 = ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp )*zt+7.6438e-5_wp ) *zt   &
419                  &                                   -4.0899e-3_wp ) *zt+0.824493_wp
420               zr3 = ( -1.6546e-6_wp*zt+1.0227e-4_wp ) *zt-5.72466e-3_wp
421               zr4 = 4.8314e-4_wp
422               !
423               ! potential volumic mass (reference to the surface)
424               zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
425               !
426               ! add the compression terms
427               ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
428               zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
429               zb = zbw + ze * zs
430               !
431               zd =    -2.042967e-2_wp
432               zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
433               zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt -4.721788_wp
434               za = ( zd*zsr + zc ) *zs + zaw
435               !
436               zb1=     (-0.1909078_wp  *zt+7.390729_wp      ) *zt-55.87545_wp
437               za1=   ( ( 2.326469e-3_wp*zt+1.553190_wp      ) *zt-65.00517_wp ) *zt+1044.077_wp
438               zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp   ) *zt-30.41638_wp ) *zt   &
439                  &                             +2098.925_wp ) *zt+190925.6_wp
440               zk0= ( zb1*zsr + za1 )*zs + zkw
441               !
442               ! masked in situ density anomaly
443               prd(ji,jj) = ( zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  ) - rau0 ) / rau0 * zmask
444            END DO
445         END DO
446         !
447      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
448         DO jj = 1, jpjm1
449            DO ji = 1, fs_jpim1   ! vector opt.
450               prd(ji,jj) = ( 0.0285_wp - rn_alpha * pts(ji,jj,jp_tem) ) * tmask(ji,jj,1)
451            END DO
452         END DO
453         !
454      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
455         DO jj = 1, jpjm1
456            DO ji = 1, fs_jpim1   ! vector opt.
457               prd(ji,jj) = ( rn_beta * pts(ji,jj,jp_sal) - rn_alpha * pts(ji,jj,jp_tem) ) * tmask(ji,jj,1) 
458            END DO
459         END DO
460         !
461      END SELECT
462
463      IF(ln_ctl)   CALL prt_ctl( tab2d_1=prd, clinfo1=' eos2d: ' )
464      !
465      IF(wrk_not_released(2, 5))THEN
466         CALL ctl_stop('eos_insitu_2d: failed to release workspace array.')
467      END IF
468      !
469   END SUBROUTINE eos_insitu_2d
470
471
472   SUBROUTINE eos_bn2( pts, pn2 )
473      !!----------------------------------------------------------------------
474      !!                  ***  ROUTINE eos_bn2  ***
475      !!
476      !! ** Purpose :   Compute the local Brunt-Vaisala frequency at the time-
477      !!      step of the input arguments
478      !!     
479      !! ** Method :
480      !!       * nn_eos = 0  : UNESCO sea water properties
481      !!         The brunt-vaisala frequency is computed using the polynomial
482      !!      polynomial expression of McDougall (1987):
483      !!            N^2 = grav * beta * ( alpha/beta*dk[ t ] - dk[ s ] )/e3w
484      !!      If lk_zdfddm=T, the heat/salt buoyancy flux ratio Rrau is
485      !!      computed and used in zdfddm module :
486      !!              Rrau = alpha/beta * ( dk[ t ] / dk[ s ] )
487      !!       * nn_eos = 1  : linear equation of state (temperature only)
488      !!            N^2 = grav * rn_alpha * dk[ t ]/e3w
489      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
490      !!            N^2 = grav * (rn_alpha * dk[ t ] - rn_beta * dk[ s ] ) / e3w
491      !!      The use of potential density to compute N^2 introduces e r r o r
492      !!      in the sign of N^2 at great depths. We recommand the use of
493      !!      nn_eos = 0, except for academical studies.
494      !!        Macro-tasked on horizontal slab (jk-loop)
495      !!      N.B. N^2 is set to zero at the first level (JK=1) in inidtr
496      !!      and is never used at this level.
497      !!
498      !! ** Action  : - pn2 : the brunt-vaisala frequency
499      !!
500      !! References :   McDougall, J. Phys. Oceanogr., 17, 1950-1964, 1987.
501      !!----------------------------------------------------------------------
502      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
503      !                                                               ! 2 : salinity               [psu]
504      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pn2    ! Brunt-Vaisala frequency [s-1]
505      !!
506      INTEGER  ::   ji, jj, jk   ! dummy loop indices
507      REAL(wp) ::   zgde3w, zt, zs, zh, zalbet, zbeta   ! temporary scalars
508#if defined key_zdfddm
509      REAL(wp) ::   zds   ! temporary scalars
510#endif
511      !!----------------------------------------------------------------------
512
513      ! pn2 : interior points only (2=< jk =< jpkm1 )
514      ! --------------------------
515      !
516      SELECT CASE( nn_eos )
517      !
518      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
519         DO jk = 2, jpkm1
520            DO jj = 1, jpj
521               DO ji = 1, jpi
522                  zgde3w = grav / fse3w(ji,jj,jk)
523                  zt = 0.5 * ( pts(ji,jj,jk,jp_tem) + pts(ji,jj,jk-1,jp_tem) )          ! potential temperature at w-point
524                  zs = 0.5 * ( pts(ji,jj,jk,jp_sal) + pts(ji,jj,jk-1,jp_sal) ) - 35.0   ! salinity anomaly (s-35) at w-point
525                  zh = fsdepw(ji,jj,jk)                                     ! depth in meters  at w-point
526                  !
527                  zalbet = ( ( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &   ! ratio alpha/beta
528                     &                                  - 0.203814e-03_wp ) * zt   &
529                     &                                  + 0.170907e-01_wp ) * zt   &
530                     &   +         0.665157e-01_wp                                 &
531                     &   +     ( - 0.678662e-05_wp * zs                            &
532                     &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
533                     &   +   ( ( - 0.302285e-13_wp * zh                            &
534                     &           - 0.251520e-11_wp * zs                            &
535                     &           + 0.512857e-12_wp * zt * zt              ) * zh   &
536                     &           - 0.164759e-06_wp * zs                            &
537                     &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
538                     &                                  + 0.380374e-04_wp ) * zh
539                     !
540                  zbeta  = ( ( -0.415613e-09_wp * zt + 0.555579e-07_wp ) * zt      &   ! beta
541                     &                               - 0.301985e-05_wp ) * zt      &
542                     &   +       0.785567e-03_wp                                   &
543                     &   + (     0.515032e-08_wp * zs                              &
544                     &         + 0.788212e-08_wp * zt - 0.356603e-06_wp ) * zs     &
545                     &   + ( (   0.121551e-17_wp * zh                              &
546                     &         - 0.602281e-15_wp * zs                              &
547                     &         - 0.175379e-14_wp * zt + 0.176621e-12_wp ) * zh     &
548                     &                                + 0.408195e-10_wp   * zs     &
549                     &     + ( - 0.213127e-11_wp * zt + 0.192867e-09_wp ) * zt     &
550                     &                                - 0.121555e-07_wp ) * zh
551                     !
552                  pn2(ji,jj,jk) = zgde3w * zbeta * tmask(ji,jj,jk)           &   ! N^2
553                     &          * ( zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )   &
554                     &                     - ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) )
555#if defined key_zdfddm
556                  !                                                         !!bug **** caution a traiter zds=dk[S]= 0 !!!!
557                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )                    ! Rrau = (alpha / beta) (dk[t] / dk[s])
558                  IF ( ABS( zds) <= 1.e-20_wp ) zds = 1.e-20_wp
559                  rrau(ji,jj,jk) = zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
560#endif
561               END DO
562            END DO
563         END DO
564         !
565      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
566         DO jk = 2, jpkm1
567            pn2(:,:,jk) = grav * rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
568         END DO
569         !
570      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
571         DO jk = 2, jpkm1
572            pn2(:,:,jk) = grav * (  rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) )      &
573               &                  - rn_beta  * ( pts(:,:,jk-1,jp_sal) - pts(:,:,jk,jp_sal) )  )   &
574               &               / fse3w(:,:,jk) * tmask(:,:,jk)
575         END DO 
576#if defined key_zdfddm
577         DO jk = 2, jpkm1                                 ! Rrau = (alpha / beta) (dk[t] / dk[s])
578            DO jj = 1, jpj
579               DO ji = 1, jpi
580                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) 
581                  IF ( ABS( zds ) <= 1.e-20_wp ) zds = 1.e-20_wp
582                  rrau(ji,jj,jk) = ralpbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
583               END DO
584            END DO
585         END DO
586#endif
587      END SELECT
588
589      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pn2, clinfo1=' bn2  : ', ovlap=1, kdim=jpk )
590#if defined key_zdfddm
591      IF(ln_ctl)   CALL prt_ctl( tab3d_1=rrau, clinfo1=' rrau : ', ovlap=1, kdim=jpk )
592#endif
593      !
594   END SUBROUTINE eos_bn2
595
596
597   SUBROUTINE eos_alpbet( pts, palph, pbeta )
598      !!----------------------------------------------------------------------
599      !!                 ***  ROUTINE ldf_slp_grif  ***
600      !!
601      !! ** Purpose :   Calculates the thermal and haline expansion coefficients at T-points.
602      !!
603      !! ** Method  :   calculates alpha and beta at T-points
604      !!       * nn_eos = 0  : UNESCO sea water properties
605      !!         The brunt-vaisala frequency is computed using the polynomial
606      !!      polynomial expression of McDougall (1987):
607      !!            N^2 = grav * beta * ( alpha/beta*dk[ t ] - dk[ s ] )/e3w
608      !!      If lk_zdfddm=T, the heat/salt buoyancy flux ratio Rrau is
609      !!      computed and used in zdfddm module :
610      !!              Rrau = alpha/beta * ( dk[ t ] / dk[ s ] )
611      !!       * nn_eos = 1  : linear equation of state (temperature only)
612      !!            N^2 = grav * rn_alpha * dk[ t ]/e3w
613      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
614      !!            N^2 = grav * (rn_alpha * dk[ t ] - rn_beta * dk[ s ] ) / e3w
615      !!       * nn_eos = 3  : Jackett JAOT 2003 ???
616      !!
617      !! ** Action  : - palph, pbeta : thermal and haline expansion coeff. at T-point
618      !!----------------------------------------------------------------------
619      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts            ! pot. temperature & salinity
620      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   palph, pbeta   ! thermal & haline expansion coeff.
621      !!
622      INTEGER  ::   ji, jj, jk   ! dummy loop indices
623      REAL(wp) ::   zt, zs, zh   ! local scalars
624      !!----------------------------------------------------------------------
625      !
626      SELECT CASE ( nn_eos )
627      !
628      CASE ( 0 )               ! Jackett and McDougall (1994) formulation
629         DO jk = 1, jpk
630            DO jj = 1, jpj
631               DO ji = 1, jpi
632                  zt = pts(ji,jj,jk,jp_tem)           ! potential temperature
633                  zs = pts(ji,jj,jk,jp_sal) - 35._wp  ! salinity anomaly (s-35)
634                  zh = fsdept(ji,jj,jk)              ! depth in meters
635                  !
636                  pbeta(ji,jj,jk) = ( ( -0.415613e-09_wp * zt + 0.555579e-07_wp ) * zt   &
637                     &                                        - 0.301985e-05_wp ) * zt   &
638                     &           + 0.785567e-03_wp                                       &
639                     &           + (     0.515032e-08_wp * zs                            &
640                     &                 + 0.788212e-08_wp * zt - 0.356603e-06_wp ) * zs   &
641                     &           + ( (   0.121551e-17_wp * zh                            &
642                     &                 - 0.602281e-15_wp * zs                            &
643                     &                 - 0.175379e-14_wp * zt + 0.176621e-12_wp ) * zh   &
644                     &                                        + 0.408195e-10_wp   * zs   &
645                     &             + ( - 0.213127e-11_wp * zt + 0.192867e-09_wp ) * zt   &
646                     &                                        - 0.121555e-07_wp ) * zh
647                     !
648                  palph(ji,jj,jk) = - pbeta(ji,jj,jk) *                             &
649                      &     ((( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &
650                      &                                  - 0.203814e-03_wp ) * zt   &
651                      &                                  + 0.170907e-01_wp ) * zt   &
652                      &   + 0.665157e-01_wp                                         &
653                      &   +     ( - 0.678662e-05_wp * zs                            &
654                      &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
655                      &   +   ( ( - 0.302285e-13_wp * zh                            &
656                      &           - 0.251520e-11_wp * zs                            &
657                      &           + 0.512857e-12_wp * zt * zt              ) * zh   &
658                      &           - 0.164759e-06_wp * zs                            &
659                      &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
660                      &                                  + 0.380374e-04_wp ) * zh)
661               END DO
662            END DO
663         END DO
664         !
665      CASE ( 1 )
666         palph(:,:,:) = - rn_alpha
667         pbeta(:,:,:) =   0._wp
668         !
669      CASE ( 2 )
670         palph(:,:,:) = - rn_alpha
671         pbeta(:,:,:) =   rn_beta
672         !
673      CASE DEFAULT
674         IF(lwp) WRITE(numout,cform_err)
675         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
676         nstop = nstop + 1
677         !
678      END SELECT
679      !
680   END SUBROUTINE eos_alpbet
681
682
683   FUNCTION tfreez( psal ) RESULT( ptf )
684      !!----------------------------------------------------------------------
685      !!                 ***  ROUTINE eos_init  ***
686      !!
687      !! ** Purpose :   Compute the sea surface freezing temperature [Celcius]
688      !!
689      !! ** Method  :   UNESCO freezing point at the surface (pressure = 0???)
690      !!       freezing point [Celcius]=(-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s-7.53e-4*p
691      !!       checkvalue: tf= -2.588567 Celsius for s=40.0psu, p=500. decibars
692      !!
693      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
694      !!----------------------------------------------------------------------
695      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   psal   ! salinity             [psu]
696      ! Leave result array automatic rather than making explicitly allocated
697      REAL(wp), DIMENSION(jpi,jpj)                ::   ptf    ! freezing temperature [Celcius]
698      !!----------------------------------------------------------------------
699      !
700      ptf(:,:) = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal(:,:) )   &
701         &                     - 2.154996e-4_wp *       psal(:,:)   ) * psal(:,:)
702      !
703   END FUNCTION tfreez
704
705
706   SUBROUTINE eos_init
707      !!----------------------------------------------------------------------
708      !!                 ***  ROUTINE eos_init  ***
709      !!
710      !! ** Purpose :   initializations for the equation of state
711      !!
712      !! ** Method  :   Read the namelist nameos and control the parameters
713      !!----------------------------------------------------------------------
714      NAMELIST/nameos/ nn_eos, rn_alpha, rn_beta
715      !!----------------------------------------------------------------------
716      !
717      REWIND( numnam )            ! Read Namelist nameos : equation of state
718      READ  ( numnam, nameos )
719      !
720      IF(lwp) THEN                ! Control print
721         WRITE(numout,*)
722         WRITE(numout,*) 'eos_init : equation of state'
723         WRITE(numout,*) '~~~~~~~~'
724         WRITE(numout,*) '          Namelist nameos : set eos parameters'
725         WRITE(numout,*) '             flag for eq. of state and N^2  nn_eos   = ', nn_eos
726         WRITE(numout,*) '             thermal exp. coef. (linear)    rn_alpha = ', rn_alpha
727         WRITE(numout,*) '             saline  exp. coef. (linear)    rn_beta  = ', rn_beta
728      ENDIF
729      !
730      SELECT CASE( nn_eos )         ! check option
731      !
732      CASE( 0 )                        !==  Jackett and McDougall (1994) formulation  ==!
733         IF(lwp) WRITE(numout,*)
734         IF(lwp) WRITE(numout,*) '          use of Jackett & McDougall (1994) equation of state and'
735         IF(lwp) WRITE(numout,*) '                 McDougall (1987) Brunt-Vaisala frequency'
736         !
737      CASE( 1 )                        !==  Linear formulation = F( temperature )  ==!
738         IF(lwp) WRITE(numout,*)
739         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T) = rau0 * ( 1.0285 - rn_alpha * T )'
740         IF( lk_zdfddm ) CALL ctl_stop( '          double diffusive mixing parameterization requires',   &
741              &                         ' that T and S are used as state variables' )
742         !
743      CASE( 2 )                        !==  Linear formulation = F( temperature , salinity )  ==!
744         ralpbet = rn_alpha / rn_beta
745         IF(lwp) WRITE(numout,*)
746         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T,S) = rau0 * ( rn_beta * S - rn_alpha * T )'
747         !
748      CASE DEFAULT                     !==  ERROR in nn_eos  ==!
749         WRITE(ctmp1,*) '          bad flag value for nn_eos = ', nn_eos
750         CALL ctl_stop( ctmp1 )
751         !
752      END SELECT
753      !
754   END SUBROUTINE eos_init
755
756   !!======================================================================
757END MODULE eosbn2 
Note: See TracBrowser for help on using the repository browser.