New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 2590

Last change on this file since 2590 was 2590, checked in by trackstand2, 13 years ago

Merge branch 'dynamic_memory' into master-svn-dyn
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE diaar5, ONLY :   lk_diaar5
28# endif 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_eiv   ! routine called by step.F90
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "ldfeiv_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_adv_eiv  ***
51      !!
52      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
53      !!      trend and add it to the general trend of tracer equation.
54      !!
55      !! ** Method  :   The eddy induced advection is computed from the slope
56      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
57      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
58      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
59      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
60      !!                               + dj[ aeiv e1v mj(wslpj) ] }
61      !!      add the eiv component to the model velocity:
62      !!         p.n = p.n + z._eiv
63      !!
64      !! ** Action  : - add to p.n the eiv component
65      !!----------------------------------------------------------------------
66      USE wrk_nemo, ONLY: wrk_use, wrk_release
67      USE wrk_nemo, ONLY: zu_eiv => wrk_2d_1, zv_eiv => wrk_2d_2, &
68                          zw_eiv => wrk_2d_3
69# if defined key_diaeiv 
70      USE wrk_nemo, ONLY: z2d => wrk_2d_4
71#endif
72      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
73      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
74      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
75      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
76      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
77      !!
78      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
79      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
80      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
81# if defined key_diaeiv 
82      REAL(wp) ::   zztmp                      ! local scalar
83# endif 
84      !!----------------------------------------------------------------------
85
86# if defined key_diaeiv 
87      IF(.not. wrk_use(2, 1,2,3,4))THEN
88#else
89      IF(.not. wrk_use(2, 1,2,3))THEN
90#endif
91         CALL ctl_stop('tra_adv_eiv: ERROR: requested workspace arrays are unavailable.')
92         RETURN
93      END IF
94
95      IF( kt == nit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
99# if defined key_diaeiv 
100         IF( cdtype == 'TRA') THEN
101            u_eiv(:,:,:) = 0.e0
102            v_eiv(:,:,:) = 0.e0
103            w_eiv(:,:,:) = 0.e0
104         END IF
105# endif
106      ENDIF
107
108      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
109     
110                                                    ! =================
111      DO jk = 1, jpkm1                              !  Horizontal slab
112         !                                          ! =================
113         DO jj = 1, jpjm1
114            DO ji = 1, fs_jpim1   ! vector opt.
115               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
116               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
117               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
118               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
119
120               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
121               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
122   
123               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
124               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
125            END DO
126         END DO
127# if defined key_diaeiv 
128         IF( cdtype == 'TRA') THEN
129            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
130            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
131         END IF
132# endif
133         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
134            DO jj = 2, jpjm1
135               DO ji = fs_2, fs_jpim1   ! vector opt.
136# if defined key_traldf_c2d || defined key_traldf_c3d
137                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
138                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
139                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
140                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
141 
142                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
143# else
144                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
145                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
146                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
147                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
148
149                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
150# endif
151                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
152               END DO
153            END DO
154# if defined key_diaeiv 
155            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
156# endif
157         ENDIF
158         !                                          ! =================
159      END DO                                        !    End of slab 
160      !                                             ! =================
161
162# if defined key_diaeiv 
163      IF( cdtype == 'TRA') THEN
164         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
165         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
166         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
167         IF( lk_diaar5 ) THEN
168            zztmp = 0.5 * rau0 * rcp 
169            z2d(:,:) = 0.e0 
170            DO jk = 1, jpkm1
171               DO jj = 2, jpjm1
172                  DO ji = fs_2, fs_jpim1   ! vector opt.
173                     z2d(ji,jj) = z2d(ji,jj) + zztmp * u_eiv(ji,jj,jk) &
174                       &         * (tsn(ji,jj,jk,jp_tem)+tsn(ji+1,jj,jk,jp_tem)) * e1u(ji,jj) * fse3u(ji,jj,jk) 
175                  END DO
176               END DO
177            END DO
178            CALL lbc_lnk( z2d, 'U', -1. )
179            CALL iom_put( "ueiv_heattr", z2d )                  ! heat transport in i-direction
180            z2d(:,:) = 0.e0 
181            DO jk = 1, jpkm1
182               DO jj = 2, jpjm1
183                  DO ji = fs_2, fs_jpim1   ! vector opt.
184                     z2d(ji,jj) = z2d(ji,jj) + zztmp * v_eiv(ji,jj,jk) &
185                     &           * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) * e2v(ji,jj) * fse3v(ji,jj,jk) 
186                  END DO
187               END DO
188            END DO
189            CALL lbc_lnk( z2d, 'V', -1. )
190            CALL iom_put( "veiv_heattr", z2d )                  !  heat transport in i-direction
191         ENDIF
192    END IF
193# endif 
194      !
195# if defined key_diaeiv 
196      IF(.not. wrk_release(2, 1,2,3,4))THEN
197#else
198      IF(.not. wrk_release(2, 1,2,3))THEN
199#endif
200         CALL ctl_stop('tra_adv_eiv: ERROR: failed to release workspace arrays.')
201      END IF
202      !
203    END SUBROUTINE tra_adv_eiv
204
205#else
206   !!----------------------------------------------------------------------
207   !!   Dummy module :             No rotation of the lateral mixing tensor
208   !!----------------------------------------------------------------------
209CONTAINS
210   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )              ! Empty routine
211      INTEGER  ::   kt   
212      CHARACTER(len=3) ::   cdtype
213      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
214      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, cdtype
215      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
216   END SUBROUTINE tra_adv_eiv
217#endif
218
219   !!==============================================================================
220END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.