New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2662

Last change on this file since 2662 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra      ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL  :: l_trd       ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_adv_tvd ( kt, cdtype, p2dt, pun, pvn, pwn,      &
54      &                                       ptb, ptn, pta, kjpt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_adv_tvd  ***
57      !!
58      !! **  Purpose :   Compute the now trend due to total advection of
59      !!       tracers and add it to the general trend of tracer equations
60      !!
61      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
62      !!       corrected flux (monotonic correction)
63      !!       note: - this advection scheme needs a leap-frog time scheme
64      !!
65      !! ** Action : - update (pta) with the now advective tracer trends
66      !!             - save the trends
67      !!----------------------------------------------------------------------
68      USE oce         , zwx => ua   ! use ua as workspace
69      USE oce         , zwy => va   ! use va as workspace
70      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
71      USE wrk_nemo, ONLY: zwi => wrk_3d_6, zwz => wrk_3d_7
72      !!
73      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !!
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
82      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
83      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
84      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
85
86      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
87      !!----------------------------------------------------------------------
88
89      IF(wrk_in_use(3, 6,7))THEN
90         CALL ctl_stop('tra_adv_tvd: ERROR: requested workspace arrays unavailable')
91         RETURN
92      END IF
93
94      IF( kt == nit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98         !
99         l_trd = .FALSE.
100         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
101      ENDIF
102      !
103      IF( l_trd )  THEN
104        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.e0
105        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.e0
106        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.e0
107      END IF
108      !
109      zwi(:,:,:) = 0.e0
110      !
111      !                                                          ! ===========
112      DO jn = 1, kjpt                                            ! tracer loop
113         !                                                       ! ===========
114         ! 1. Bottom value : flux set to zero
115         ! ----------------------------------
116         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
117         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
118
119         ! 2. upstream advection with initial mass fluxes & intermediate update
120         ! --------------------------------------------------------------------
121         ! upstream tracer flux in the i and j direction
122         DO jk = 1, jpkm1
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1   ! vector opt.
125                  ! upstream scheme
126                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
127                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
128                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
129                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
130                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
131                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
132               END DO
133            END DO
134         END DO
135
136         ! upstream tracer flux in the k direction
137         ! Surface value
138         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
139         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
140         ENDIF
141         ! Interior value
142         DO jk = 2, jpkm1
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
146                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
147                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
148               END DO
149            END DO
150         END DO
151
152         ! total advective trend
153         DO jk = 1, jpkm1
154            z2dtt = p2dt(jk)
155            DO jj = 2, jpjm1
156               DO ji = fs_2, fs_jpim1   ! vector opt.
157                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
158                  ! total intermediate advective trends
159                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
160                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
161                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
162                  ! update and guess with monotonic sheme
163                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
164                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
165               END DO
166            END DO
167         END DO
168         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
169         CALL lbc_lnk( zwi, 'T', 1. ) 
170
171         !                                 ! trend diagnostics (contribution of upstream fluxes)
172         IF( l_trd )  THEN 
173            ! store intermediate advective trends
174            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
175         END IF
176         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
177         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
178           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
179           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
180         ENDIF
181
182         ! 3. antidiffusive flux : high order minus low order
183         ! --------------------------------------------------
184         ! antidiffusive flux on i and j
185         DO jk = 1, jpkm1
186            DO jj = 1, jpjm1
187               DO ji = 1, fs_jpim1   ! vector opt.
188                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
189                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
190               END DO
191            END DO
192         END DO
193     
194         ! antidiffusive flux on k
195         zwz(:,:,1) = 0.e0         ! Surface value
196         !
197         DO jk = 2, jpkm1          ! Interior value
198            DO jj = 1, jpj
199               DO ji = 1, jpi
200                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
201               END DO
202            END DO
203         END DO
204         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
205         CALL lbc_lnk( zwz, 'W',  1. )
206
207         ! 4. monotonicity algorithm
208         ! -------------------------
209         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
210
211
212         ! 5. final trend with corrected fluxes
213         ! ------------------------------------
214         DO jk = 1, jpkm1
215            DO jj = 2, jpjm1
216               DO ji = fs_2, fs_jpim1   ! vector opt. 
217                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
218                  ! total advective trends
219                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
220                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
221                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
222                  ! add them to the general tracer trends
223                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
224               END DO
225            END DO
226         END DO
227
228         !                                 ! trend diagnostics (contribution of upstream fluxes)
229         IF( l_trd )  THEN
230            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
231            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
232            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
233           
234            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
235            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
236            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
237         END IF
238         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
239         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
240           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
241           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
242         ENDIF
243         !
244      ENDDO
245      !
246      IF( l_trd )  THEN
247        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
248      END IF
249      !
250      IF(wrk_not_released(3, 6,7))THEN
251         CALL ctl_stop('tra_adv_tvd: ERROR: failed to release workspace arrays')
252      END IF
253      !
254   END SUBROUTINE tra_adv_tvd
255
256
257   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
258      !!---------------------------------------------------------------------
259      !!                    ***  ROUTINE nonosc  ***
260      !!     
261      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
262      !!       scheme and the before field by a nonoscillatory algorithm
263      !!
264      !! **  Method  :   ... ???
265      !!       warning : pbef and paft must be masked, but the boundaries
266      !!       conditions on the fluxes are not necessary zalezak (1979)
267      !!       drange (1995) multi-dimensional forward-in-time and upstream-
268      !!       in-space based differencing for fluid
269      !!----------------------------------------------------------------------
270      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
271      USE wrk_nemo, ONLY: zbetup => wrk_3d_8, zbetdo => wrk_3d_9, &
272                          zbup => wrk_3d_10, zbdo => wrk_3d_11
273      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
274      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
275      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
276      !!
277      INTEGER ::   ji, jj, jk               ! dummy loop indices
278      INTEGER ::   ikm1
279      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
280      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv
281      REAL(wp) ::   zup, zdo
282      !!----------------------------------------------------------------------
283
284      IF(wrk_in_use(3, 8,9,10,11))THEN
285         CALL ctl_stop('nonosc: ERROR: requested workspace array unavailable')
286         RETURN
287      END IF
288
289      zbig = 1.e+40
290      zrtrn = 1.e-15
291      zbetup(:,:,jpk) = 0.e0   ;   zbetdo(:,:,jpk) = 0.e0
292
293
294      ! Search local extrema
295      ! --------------------
296      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
297      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
298         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
299      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
300         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
301
302      DO jk = 1, jpkm1
303         ikm1 = MAX(jk-1,1)
304         z2dtt = p2dt(jk)
305         DO jj = 2, jpjm1
306            DO ji = fs_2, fs_jpim1   ! vector opt.
307
308               ! search maximum in neighbourhood
309               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
310                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
311                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
312                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
313
314               ! search minimum in neighbourhood
315               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
316                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
317                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
318                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
319
320               ! positive part of the flux
321               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
322                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
323                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
324
325               ! negative part of the flux
326               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
327                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
328                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
329
330               ! up & down beta terms
331               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
332               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
333               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
334            END DO
335         END DO
336      END DO
337      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
338
339
340
341      ! 3. monotonic flux in the i & j direction (paa & pbb)
342      ! ----------------------------------------
343      DO jk = 1, jpkm1
344         DO jj = 2, jpjm1
345            DO ji = fs_2, fs_jpim1   ! vector opt.
346               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
347               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
348               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
349               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
350
351               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
352               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
353               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
354               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
355
356      ! monotonic flux in the k direction, i.e. pcc
357      ! -------------------------------------------
358               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
359               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
360               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
361               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
362            END DO
363         END DO
364      END DO
365      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
366      !
367      IF(wrk_not_released(3, 8,9,10,11))THEN
368         CALL ctl_stop('nonosc: ERROR: failed to release workspace arrays')
369      END IF
370      !
371   END SUBROUTINE nonosc
372
373   !!======================================================================
374END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.