New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2662

Last change on this file since 2662 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 15.9 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv,              &
52      &                                ptb, pta, kjpt, pahtb0 )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
67      !!      ========    with partial cell update if ln_zps=T.
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
71      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
72      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
74      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
84      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
88      !!         pta = pta + difft
89      !!
90      !! ** Action :   Update pta arrays with the before rotated diffusion
91      !!----------------------------------------------------------------------
92      USE oce         , zftu => ua   ! use ua as workspace
93      USE oce         , zftv => va   ! use va as workspace
94      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
95      USE wrk_nemo, ONLY: zdkt => wrk_2d_1, zdk1t => wrk_2d_2   ! 2D workspace
96      USE wrk_nemo, ONLY: zdit => wrk_3d_1, zdjt => wrk_3d_2, ztfw => wrk_3d_3   ! 3D workspace
97      USE wrk_nemo, ONLY: z2d => wrk_2d_3   ! 2D workspace - used if key_diaar5
98      !!
99      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
100      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
101      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
102      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
105      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
106      !!
107      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
111#if defined key_diaar5
112      REAL(wp)                         ::   zztmp               ! local scalar
113#endif
114      !!----------------------------------------------------------------------
115
116      IF( wrk_in_use(3, 1,2,3) .OR. wrk_in_use(2, 1,2,3) )THEN
117          CALL ctl_stop('tra_ldf_iso : requested workspace array unavailable.')
118          RETURN
119      END IF
120
121      IF( kt == nit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125      ENDIF
126      !
127      !                                                          ! ===========
128      DO jn = 1, kjpt                                            ! tracer loop
129         !                                                       ! ===========
130         !                                               
131         !!----------------------------------------------------------------------
132         !!   I - masked horizontal derivative
133         !!----------------------------------------------------------------------
134         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
135         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
136         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
137         !!end
138
139         ! Horizontal tracer gradient
140         DO jk = 1, jpkm1
141            DO jj = 1, jpjm1
142               DO ji = 1, fs_jpim1   ! vector opt.
143                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
144                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
145               END DO
146            END DO
147         END DO
148         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
149            DO jj = 1, jpjm1
150               DO ji = 1, fs_jpim1   ! vector opt.
151                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
152                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
153               END DO
154            END DO
155         ENDIF
156
157         !!----------------------------------------------------------------------
158         !!   II - horizontal trend  (full)
159         !!----------------------------------------------------------------------
160!CDIR PARALLEL DO PRIVATE( zdk1t )
161         !                                                ! ===============
162         DO jk = 1, jpkm1                                 ! Horizontal slab
163            !                                             ! ===============
164            ! 1. Vertical tracer gradient at level jk and jk+1
165            ! ------------------------------------------------
166            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
167            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
168            !
169            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
170            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
171            ENDIF
172
173            ! 2. Horizontal fluxes
174            ! --------------------   
175            DO jj = 1 , jpjm1
176               DO ji = 1, fs_jpim1   ! vector opt.
177                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
178                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
179                  !
180                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
181                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
182                  !
183                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
184                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
185                  !
186                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
187                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
188                  !
189                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
190                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
191                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
192                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
193                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
194                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
195               END DO
196            END DO
197
198            ! II.4 Second derivative (divergence) and add to the general trend
199            ! ----------------------------------------------------------------
200            DO jj = 2 , jpjm1
201               DO ji = fs_2, fs_jpim1   ! vector opt.
202                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
203                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
204                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
205               END DO
206            END DO
207            !                                          ! ===============
208         END DO                                        !   End of slab 
209         !                                             ! ===============
210         !
211         ! "Poleward" diffusive heat or salt transports (T-S case only)
212         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
213            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )
214            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
215         ENDIF
216 
217#if defined key_diaar5
218         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
219            z2d(:,:) = 0._wp 
220            zztmp = rau0 * rcp 
221            DO jk = 1, jpkm1
222               DO jj = 2, jpjm1
223                  DO ji = fs_2, fs_jpim1   ! vector opt.
224                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
225                  END DO
226               END DO
227            END DO
228            z2d(:,:) = zztmp * z2d(:,:)
229            CALL lbc_lnk( z2d, 'U', -1. )
230            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
231            z2d(:,:) = 0._wp 
232            DO jk = 1, jpkm1
233               DO jj = 2, jpjm1
234                  DO ji = fs_2, fs_jpim1   ! vector opt.
235                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
236                  END DO
237               END DO
238            END DO
239            z2d(:,:) = zztmp * z2d(:,:)
240            CALL lbc_lnk( z2d, 'V', -1. )
241            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
242         END IF
243#endif
244
245         !!----------------------------------------------------------------------
246         !!   III - vertical trend of T & S (extra diagonal terms only)
247         !!----------------------------------------------------------------------
248         
249         ! Local constant initialization
250         ! -----------------------------
251         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
252         
253         ! Vertical fluxes
254         ! ---------------
255         
256         ! Surface and bottom vertical fluxes set to zero
257         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
258         
259         ! interior (2=<jk=<jpk-1)
260         DO jk = 2, jpkm1
261            DO jj = 2, jpjm1
262               DO ji = fs_2, fs_jpim1   ! vector opt.
263                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
264                  !
265                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
266                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
267                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
268                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
269                  !
270                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
271                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
272                  !
273                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
274                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
275                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
276                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
277               END DO
278            END DO
279         END DO
280         
281         
282         ! I.5 Divergence of vertical fluxes added to the general tracer trend
283         ! -------------------------------------------------------------------
284         DO jk = 1, jpkm1
285            DO jj = 2, jpjm1
286               DO ji = fs_2, fs_jpim1   ! vector opt.
287                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
288                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
289                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
290               END DO
291            END DO
292         END DO
293         !
294      END DO
295      !
296      IF( wrk_not_released(3, 1,2,3) .OR.  &
297          wrk_not_released(2, 1,2,3) )THEN
298          CALL ctl_stop('tra_ldf_iso : failed to release workspace arrays.')
299      END IF
300      !
301   END SUBROUTINE tra_ldf_iso
302
303#else
304   !!----------------------------------------------------------------------
305   !!   default option :   Dummy code   NO rotation of the diffusive tensor
306   !!----------------------------------------------------------------------
307CONTAINS
308   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
309      CHARACTER(len=3) ::   cdtype
310      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
311      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
312      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, cdtype, pgu(1,1,1), pgv(1,1,1),   &
313         &                                                             ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
314   END SUBROUTINE tra_ldf_iso
315#endif
316
317   !!==============================================================================
318END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.