New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component 
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE trc_oce         ! share passive tracers/Ocean variables
20   USE zdf_oce         ! ocean vertical physics
21   USE ldftra_oce      ! ocean active tracers: lateral physics
22   USE ldfslp          ! iso-neutral slopes
23   USE diaptr          ! poleward transport diagnostics
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_ldf_iso_grif   ! routine called by traldf.F90
32
33   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
34   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   ah_wslp2             !: aeiv*w-slope^2
35   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt                 !  atypic workspace
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41#  include "ldfeiv_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
50       &                                   ptb, pta, kjpt, pahtb0 )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
56      !!      add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The horizontal component of the lateral diffusive trends
59      !!      is provided by a 2nd order operator rotated along neural or geopo-
60      !!      tential surfaces to which an eddy induced advection can be added
61      !!      It is computed using before fields (forward in time) and isopyc-
62      !!      nal or geopotential slopes computed in routine ldfslp.
63      !!
64      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
65      !!      ========    with partial cell update if ln_zps=T.
66      !!
67      !!      2nd part :  horizontal fluxes of the lateral mixing operator
68      !!      ========   
69      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
70      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
71      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
72      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
73      !!      take the horizontal divergence of the fluxes:
74      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
75      !!      Add this trend to the general trend (ta,sa):
76      !!         ta = ta + difft
77      !!
78      !!      3rd part: vertical trends of the lateral mixing operator
79      !!      ========  (excluding the vertical flux proportional to dk[t] )
80      !!      vertical fluxes associated with the rotated lateral mixing:
81      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
82      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
83      !!      take the horizontal divergence of the fluxes:
84      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
85      !!      Add this trend to the general trend (ta,sa):
86      !!         pta = pta + difft
87      !!
88      !! ** Action :   Update pta arrays with the before rotated diffusion
89      !!----------------------------------------------------------------------
90      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
91      USE oce     , ONLY:   zftu => ua       , zftv => va            ! (ua,va) used as 3D workspace
92      USE wrk_nemo, ONLY:   zdit => wrk_3d_1 , zdjt => wrk_3d_2 , ztfw => wrk_3d_3   ! 3D workspace
93      USE wrk_nemo, ONLY:   z2d  => wrk_2d_1                                          ! 2D workspace
94      !!
95      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
96      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
97      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
98      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
101      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
102      !!
103      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
104      INTEGER  ::  ip,jp,kp        ! dummy loop indices
105      INTEGER  ::  ierr            ! temporary integer
106      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
107      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
108      REAL(wp) ::  zcoef0, zbtr                  !   -      -
109      !REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdkt           ! 2D+1 workspace
110      !
111      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
112      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
113      REAL(wp) ::   zah, zah_slp, zaei_slp
114#if defined key_diaar5
115      REAL(wp)                         ::   zztmp              ! local scalar
116#endif
117      !!----------------------------------------------------------------------
118
119      IF( wrk_in_use(3, 1,2,3) .OR. wrk_in_use(2, 1) ) THEN
120         CALL ctl_stop('tra_ldf_iso_grif : requested workspace arrays unavailable.')   ;   RETURN
121      ENDIF
122      ! ARP - line below uses 'bounds re-mapping' which is only defined in
123      ! Fortran 2003 and up. We would be OK if code was written to use
124      ! zdkt(:,:,1:2) instead as then wouldn't need to re-map bounds.
125      ! As it is, we make zdkt a module array and allocate it in _alloc().
126      !zdkt(1:jpi,1:jpj,0:1) => wrk_3d_4(:,:,1:2)
127
128      IF( kt == nit000 )  THEN
129         IF(lwp) WRITE(numout,*)
130         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
131         IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
132         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
133         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt(jpi,jpj,0:1), STAT=ierr )
134         IF( lk_mpp   )   CALL mpp_sum ( ierr )
135         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays')
136         IF( ln_traldf_gdia ) THEN
137            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
138            IF( lk_mpp   )   CALL mpp_sum ( ierr )
139            IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics')
140         ENDIF
141      ENDIF
142
143      !!----------------------------------------------------------------------
144      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
145      !!----------------------------------------------------------------------
146
147!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
148
149      ah_wslp2(:,:,:) = 0._wp
150      IF( ln_traldf_gdia ) THEN
151         psix_eiv(:,:,:) = 0._wp
152         psiy_eiv(:,:,:) = 0._wp
153      ENDIF
154
155      DO ip = 0, 1
156         DO kp = 0, 1
157            DO jk = 1, jpkm1
158               DO jj = 1, jpjm1
159                  DO ji = 1, fs_jpim1
160                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
161                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
162                     zah   = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
163                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
164                     zslope2 = zslope_skew - ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
165                     zslope2 = zslope2 *zslope2
166                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
167                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
168                     IF( ln_traldf_gdia ) THEN
169                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        !fsaeit(ji+ip,jj,jk)*zslope_skew
170                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
171                     ENDIF
172                  END DO
173               END DO
174            END DO
175         END DO
176      END DO
177      !
178      DO jp = 0, 1
179         DO kp = 0, 1
180            DO jk = 1, jpkm1
181               DO jj = 1, jpjm1
182                  DO ji=1,fs_jpim1
183                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
184                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
185                     zah   = fsahtu(ji,jj,jk)                                       !fsaht(ji,jj+jp,jk)
186                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
187                     zslope2 = zslope_skew - ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
188                     zslope2 = zslope2 * zslope2
189                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
190                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
191                     IF( ln_traldf_gdia ) THEN
192                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
193                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
194                     ENDIF
195                  END DO
196               END DO
197            END DO
198         END DO
199      END DO
200      !
201      !                                                          ! ===========
202      DO jn = 1, kjpt                                            ! tracer loop
203         !                                                       ! ===========
204         ! Zero fluxes for each tracer
205         ztfw(:,:,:) = 0._wp
206         zftu(:,:,:) = 0._wp
207         zftv(:,:,:) = 0._wp
208         !                                               
209         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
210            DO jj = 1, jpjm1
211               DO ji = 1, fs_jpim1   ! vector opt.
212                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
213                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
214               END DO
215            END DO
216         END DO
217         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
218# if defined key_vectopt_loop
219            DO jj = 1, 1
220               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
221# else
222            DO jj = 1, jpjm1
223               DO ji = 1, jpim1
224# endif
225                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
226                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
227               END DO
228            END DO
229         ENDIF
230
231         !!----------------------------------------------------------------------
232         !!   II - horizontal trend  (full)
233         !!----------------------------------------------------------------------
234         !
235         DO jk = 1, jpkm1
236            !
237            !                    !==  Vertical tracer gradient at level jk and jk+1
238            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
239            !
240            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
241            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
242            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
243            ENDIF
244
245            IF( .NOT. l_triad_iso ) THEN
246               triadi = triadi_g
247               triadj = triadj_g
248            ENDIF
249
250            DO ip = 0, 1              !==  Horizontal & vertical fluxes
251               DO kp = 0, 1
252                  DO jj = 1, jpjm1
253                     DO ji = 1, fs_jpim1
254                        ze1ur = 1._wp / e1u(ji,jj)
255                        zdxt = zdit(ji,jj,jk) * ze1ur
256                        ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
257                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
258                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
259                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
260
261                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
262                        zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
263                        zah_slp  = zah * zslope_iso
264                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
265                        zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
266                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
267                     END DO
268                  END DO
269               END DO
270            END DO
271
272            DO jp = 0, 1
273               DO kp = 0, 1
274                  DO jj = 1, jpjm1
275                     DO ji = 1, fs_jpim1
276                        ze2vr = 1._wp / e2v(ji,jj)
277                        zdyt = zdjt(ji,jj,jk) * ze2vr
278                        ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
279                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
280                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
281                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
282                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
283                        zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
284                        zah_slp = zah * zslope_iso
285                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew    !fsaeit(ji,jj+jp,jk)*zslope_skew
286                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
287                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
288                     END DO
289                  END DO
290               END DO
291            END DO
292
293            !                        !==  divergence and add to the general trend  ==!
294            DO jj = 2 , jpjm1
295               DO ji = fs_2, fs_jpim1   ! vector opt.
296                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
297                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
298                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
299               END DO
300            END DO
301            !
302         END DO
303         !
304         DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
305            DO jj = 2, jpjm1
306               DO ji = fs_2, fs_jpim1   ! vector opt.
307                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
308                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
309               END DO
310            END DO
311         END DO
312         !
313         !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
314         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
315            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
316            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
317         ENDIF
318
319#if defined key_diaar5
320         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
321            z2d(:,:) = 0._wp 
322            zztmp = rau0 * rcp 
323            DO jk = 1, jpkm1
324               DO jj = 2, jpjm1
325                  DO ji = fs_2, fs_jpim1   ! vector opt.
326                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
327                  END DO
328               END DO
329            END DO
330            z2d(:,:) = zztmp * z2d(:,:)
331            CALL lbc_lnk( z2d, 'U', -1. )
332            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
333            z2d(:,:) = 0._wp 
334            DO jk = 1, jpkm1
335               DO jj = 2, jpjm1
336                  DO ji = fs_2, fs_jpim1   ! vector opt.
337                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
338                  END DO
339               END DO
340            END DO
341            z2d(:,:) = zztmp * z2d(:,:)
342            CALL lbc_lnk( z2d, 'V', -1. )
343            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
344         END IF
345#endif
346         !
347      END DO
348      !
349      IF( wrk_not_released(3, 1,2,3,4) .OR. wrk_not_released(2, 1) )THEN
350         CALL ctl_stop('tra_ldf_iso_grif : failed to release workspace arrays.')
351      END IF
352      !
353  END SUBROUTINE tra_ldf_iso_grif
354
355#else
356   !!----------------------------------------------------------------------
357   !!   default option :   Dummy code   NO rotation of the diffusive tensor
358   !!----------------------------------------------------------------------
359CONTAINS
360   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
361      CHARACTER(len=3) ::   cdtype
362      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
363      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
364      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
365         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
366   END SUBROUTINE tra_ldf_iso_grif
367#endif
368
369   !!==============================================================================
370END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.