New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2598

Last change on this file since 2598 was 2590, checked in by trackstand2, 13 years ago

Merge branch 'dynamic_memory' into master-svn-dyn
  • Property svn:keywords set to Id
File size: 8.2 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_ldf_lap       ! routine called by step.F90
31   PUBLIC   tra_ldf_lap_alloc ! routine called by nemogcm.F90
32
33   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) ::   e1ur, e2vr   ! scale factor coefficients
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   FUNCTION tra_ldf_lap_alloc()
47      !!----------------------------------------------------------------------
48      !!                ***  ROUTINE tra_ldf_lap_alloc  ***
49      !!----------------------------------------------------------------------
50      IMPLICIT none
51      INTEGER :: tra_ldf_lap_alloc
52      !!----------------------------------------------------------------------
53
54      ALLOCATE(e1ur(jpi,jpj), e2vr(jpi,jpj), Stat=tra_ldf_lap_alloc)
55
56      IF( tra_ldf_lap_alloc /= 0)THEN
57         CALL ctl_warn('tra_ldf_lap_alloc: failed to allocate e1ur and e2vr arrays.')
58      END IF
59
60   END FUNCTION tra_ldf_lap_alloc
61
62   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,      &
63      &                                ptb, pta, kjpt ) 
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE tra_ldf_lap  ***
66      !!                   
67      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
68      !!      trend and add it to the general trend of tracer equation.
69      !!
70      !! ** Method  :   Second order diffusive operator evaluated using before
71      !!      fields (forward time scheme). The horizontal diffusive trends of
72      !!      the tracer is given by:
73      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
74      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
75      !!      Add this trend to the general tracer trend pta :
76      !!          pta = pta + difft
77      !!
78      !! ** Action  : - Update pta arrays with the before iso-level
79      !!                harmonic mixing trend.
80      !!----------------------------------------------------------------------
81      USE oce         , ztu => ua   ! use ua as workspace
82      USE oce         , ztv => va   ! use va as workspace
83      !!
84      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
85      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
86      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
87      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
89      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
90      !!
91      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
92      INTEGER  ::   iku, ikv             ! local integers
93      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
94      !!----------------------------------------------------------------------
95     
96      IF( kt == nit000 )  THEN
97         IF(lwp) WRITE(numout,*)
98         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
99         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
100         e1ur(:,:) = e2u(:,:) / e1u(:,:)
101         e2vr(:,:) = e1v(:,:) / e2v(:,:)
102      ENDIF
103
104      !                                                          ! =========== !
105      DO jn = 1, kjpt                                            ! tracer loop !
106         !                                                       ! =========== !   
107         DO jk = 1, jpkm1                                            ! slab loop
108            !                                           
109            ! 1. First derivative (gradient)
110            ! -------------------
111            DO jj = 1, jpjm1
112               DO ji = 1, fs_jpim1   ! vector opt.
113                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
114                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
115                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
116                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
117               END DO
118            END DO
119            IF( ln_zps ) THEN      ! set gradient at partial step level
120               DO jj = 1, jpjm1
121                  DO ji = 1, fs_jpim1   ! vector opt.
122                     ! last level
123                     iku = mbku(ji,jj)
124                     ikv = mbkv(ji,jj)
125                     IF( iku == jk ) THEN
126                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
127                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
128                     ENDIF
129                     IF( ikv == jk ) THEN
130                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
131                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
132                     ENDIF
133                  END DO
134               END DO
135            ENDIF
136         
137         
138            ! 2. Second derivative (divergence) added to the general tracer trends
139            ! ---------------------------------------------------------------------
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
143                  ! horizontal diffusive trends added to the general tracer trends
144                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
145                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
146               END DO
147            END DO
148            !
149         END DO                                             !  End of slab 
150         !
151         ! "Poleward" diffusive heat or salt transports
152         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
153            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
154            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
155         ENDIF
156         !                                                  ! ==================
157      END DO                                                ! end of tracer loop
158      !                                                     ! ==================
159   END SUBROUTINE tra_ldf_lap
160
161   !!==============================================================================
162END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.