New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2662

Last change on this file since 2662 was 2625, checked in by gm, 13 years ago

dynamic mem: #785 ; OPA_SRC mpp compilation: suppression of the USE in_out_manager in lib_mpp + style in DYN
  • Property svn:keywords set to Id
File size: 7.8 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_ldf_lap   ! routine called by step.F90
32
33   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) ::   e1ur, e2vr   ! scale factor coefficients
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,      &
47      &                                ptb, pta, kjpt ) 
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_ldf_lap  ***
50      !!                   
51      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
52      !!      trend and add it to the general trend of tracer equation.
53      !!
54      !! ** Method  :   Second order diffusive operator evaluated using before
55      !!      fields (forward time scheme). The horizontal diffusive trends of
56      !!      the tracer is given by:
57      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
58      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
59      !!      Add this trend to the general tracer trend pta :
60      !!          pta = pta + difft
61      !!
62      !! ** Action  : - Update pta arrays with the before iso-level
63      !!                harmonic mixing trend.
64      !!----------------------------------------------------------------------
65      USE oce ,   ztu => ua   ! use ua as workspace
66      USE oce ,   ztv => va   ! use va as workspace
67      !!
68      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
71      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
74      !!
75      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
76      INTEGER  ::   iku, ikv, ierr       ! local integers
77      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
78      !!----------------------------------------------------------------------
79     
80      IF( kt == nit000 )  THEN
81         IF(lwp) WRITE(numout,*)
82         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
83         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
84         !
85         ALLOCATE( e1ur(jpi,jpj), e2vr(jpi,jpj), STAT=ierr )
86         IF( lk_mpp    )   CALL mpp_sum( ierr )
87         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'tra_ldf_lap : unable to allocate arrays' )
88         !
89         e1ur(:,:) = e2u(:,:) / e1u(:,:)
90         e2vr(:,:) = e1v(:,:) / e2v(:,:)
91      ENDIF
92
93      !                                                          ! =========== !
94      DO jn = 1, kjpt                                            ! tracer loop !
95         !                                                       ! =========== !   
96         DO jk = 1, jpkm1                                            ! slab loop
97            !                                           
98            ! 1. First derivative (gradient)
99            ! -------------------
100            DO jj = 1, jpjm1
101               DO ji = 1, fs_jpim1   ! vector opt.
102                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
103                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
104                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
105                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
106               END DO
107            END DO
108            IF( ln_zps ) THEN      ! set gradient at partial step level
109               DO jj = 1, jpjm1
110                  DO ji = 1, fs_jpim1   ! vector opt.
111                     ! last level
112                     iku = mbku(ji,jj)
113                     ikv = mbkv(ji,jj)
114                     IF( iku == jk ) THEN
115                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
116                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
117                     ENDIF
118                     IF( ikv == jk ) THEN
119                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
120                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
121                     ENDIF
122                  END DO
123               END DO
124            ENDIF
125         
126         
127            ! 2. Second derivative (divergence) added to the general tracer trends
128            ! ---------------------------------------------------------------------
129            DO jj = 2, jpjm1
130               DO ji = fs_2, fs_jpim1   ! vector opt.
131                  zbtr = 1._wp / ( e1t(ji,jj) *e2t(ji,jj) * fse3t(ji,jj,jk) )
132                  ! horizontal diffusive trends added to the general tracer trends
133                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
134                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
135               END DO
136            END DO
137            !
138         END DO                                             !  End of slab 
139         !
140         ! "Poleward" diffusive heat or salt transports
141         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
142            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
143            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
144         ENDIF
145         !                                                  ! ==================
146      END DO                                                ! end of tracer loop
147      !                                                     ! ==================
148   END SUBROUTINE tra_ldf_lap
149
150   !!==============================================================================
151END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.