New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfevd.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfevd.F90 @ 2633

Last change on this file since 2633 was 2616, checked in by gm, 13 years ago

dynamic mem: #785 ; move the allocation vertical physics from nemogcm to ZDF modules (compilation check using key_esopa)
  • Property svn:keywords set to Id
File size: 6.1 KB
Line 
1MODULE zdfevd
2   !!======================================================================
3   !!                       ***  MODULE  zdfevd  ***
4   !! Ocean physics: parameterization of convection through an enhancement
5   !!                of vertical eddy mixing coefficient
6   !!======================================================================
7   !! History :  OPA  !  1997-06  (G. Madec, A. Lazar)  Original code
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!             -   !  2005-06  (C. Ethe) KPP parameterization
10   !!            3.2  !  2009-03  (M. Leclair, G. Madec, R. Benshila) test on both before & after
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_evd      : increase the momentum and tracer Kz at the location of
15   !!                  statically unstable portion of the water column (ln_zdfevd=T)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE zdfkpp          ! KPP vertical mixing
21   USE in_out_manager  ! I/O manager
22   USE iom             ! for iom_put
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_evd    ! called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE zdf_evd( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE zdf_evd  ***
42      !!                   
43      !! ** Purpose :   Local increased the vertical eddy viscosity and diffu-
44      !!      sivity coefficients when a static instability is encountered.
45      !!
46      !! ** Method  :   avt, avm, and the 4 neighbouring avmu, avmv coefficients
47      !!      are set to avevd (namelist parameter) if the water column is
48      !!      statically unstable (i.e. if rn2 < -1.e-12 )
49      !!
50      !! ** Action  :   avt, avm, avmu, avmv updted in static instability cases
51      !!
52      !! References :   Lazar, A., these de l'universite Paris VI, France, 1997
53      !!----------------------------------------------------------------------
54      USE oce,   zavt_evd  =>   ua   ! use ua as workspace
55      USE oce,   zavm_evd  =>   va   ! use va as workspace
56      !!
57      INTEGER, INTENT( in ) ::   kt   ! ocean time-step indexocean time step
58      !!
59      INTEGER ::   ji, jj, jk   ! dummy loop indices
60      !!----------------------------------------------------------------------
61
62      IF( kt == nit000 ) THEN
63         IF(lwp) WRITE(numout,*)
64         IF(lwp) WRITE(numout,*) 'zdf_evd : Enhanced Vertical Diffusion (evd)'
65         IF(lwp) WRITE(numout,*) '~~~~~~~ '
66         IF(lwp) WRITE(numout,*)
67      ENDIF
68
69      zavt_evd(:,:,:) = avt(:,:,:)           ! set avt prior to evd application
70
71      SELECT CASE ( nn_evdm )
72 
73      CASE ( 1 )           ! enhance vertical eddy viscosity and diffusivity (if rn2<-1.e-12)
74
75         zavm_evd(:,:,:) = avm(:,:,:)           ! set avm prior to evd application
76         !
77         DO jk = 1, jpkm1 
78#if defined key_vectopt_loop
79            DO jj = 1, 1                     ! big loop forced
80               DO ji = jpi+2, jpij   
81#else
82            DO jj = 2, jpj             ! no vector opt.
83               DO ji = 2, jpi
84#endif
85#if defined key_zdfkpp
86                  ! no evd mixing in the boundary layer with KPP
87                  IF( ( MIN( rn2(ji,jj,jk),  rn2b(ji,jj,jk) ) <= -1.e-12 ) .AND. ( fsdepw(ji,jj,jk) > hkpp(ji,jj) ) ) THEN
88#else
89                  IF(   MIN( rn2(ji,jj,jk),  rn2b(ji,jj,jk) ) <= -1.e-12 ) THEN
90#endif
91                     avt (ji  ,jj  ,jk) = rn_avevd * tmask(ji  ,jj  ,jk)
92                     avm (ji  ,jj  ,jk) = rn_avevd * tmask(ji  ,jj  ,jk)
93                     avmu(ji  ,jj  ,jk) = rn_avevd * umask(ji  ,jj  ,jk)
94                     avmu(ji-1,jj  ,jk) = rn_avevd * umask(ji-1,jj  ,jk)
95                     avmv(ji  ,jj  ,jk) = rn_avevd * vmask(ji  ,jj  ,jk)
96                     avmv(ji  ,jj-1,jk) = rn_avevd * vmask(ji  ,jj-1,jk)
97                  ENDIF
98               END DO
99            END DO
100         END DO
101         CALL lbc_lnk( avt , 'W', 1. )   ;   CALL lbc_lnk( avm , 'W', 1. )   ! Lateral boundary conditions   (unchanged sign)
102         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
103         !
104         zavm_evd(:,:,:) = avm(:,:,:) - zavm_evd(:,:,:)   ! change in avm due to evd
105         CALL iom_put( "avm_evd", zavm_evd )              ! output this change
106         !
107      CASE DEFAULT         ! enhance vertical eddy diffusivity only (if rn2<-1.e-12)
108         DO jk = 1, jpkm1
109!!!         WHERE( rn2(:,:,jk) <= -1.e-12 ) avt(:,:,jk) = tmask(:,:,jk) * avevd   ! agissant sur T SEUL!
110#if defined key_vectopt_loop
111            DO jj = 1, 1                     ! big loop forced
112               DO ji = 1, jpij   
113#else
114            DO jj = 1, jpj             ! loop over the whole domain (no lbc_lnk call)
115               DO ji = 1, jpi
116#endif
117#if defined key_zdfkpp
118                  ! no evd mixing in the boundary layer with KPP
119                  IF( ( MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) .AND. ( fsdepw(ji,jj,jk) > hkpp(ji,jj) ) ) &         
120#else
121                  IF(   MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) &
122#endif
123                     avt(ji,jj,jk) = rn_avevd * tmask(ji,jj,jk)
124               END DO
125            END DO
126         END DO
127         !
128      END SELECT
129
130      zavt_evd(:,:,:) = avt(:,:,:) - zavt_evd(:,:,:)   ! change in avt due to evd
131      CALL iom_put( "avt_evd", zavt_evd )              ! output this change
132      !
133   END SUBROUTINE zdf_evd
134
135   !!======================================================================
136END MODULE zdfevd
Note: See TracBrowser for help on using the repository browser.