New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfric.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfric.F90 @ 2620

Last change on this file since 2620 was 2616, checked in by gm, 13 years ago

dynamic mem: #785 ; move the allocation vertical physics from nemogcm to ZDF modules (compilation check using key_esopa)
  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE zdfric
2   !!======================================================================
3   !!                       ***  MODULE  zdfric  ***
4   !! Ocean physics:  vertical mixing coefficient compute from the local
5   !!                 Richardson number dependent formulation
6   !!======================================================================
7   !! History :  OPA  ! 1987-09  (P. Andrich)  Original code
8   !!            4.0  ! 1991-11  (G. Madec)
9   !!            7.0  ! 1996-01  (G. Madec)  complet rewriting of multitasking suppression of common work arrays
10   !!            8.0  ! 1997-06 (G. Madec)  complete rewriting of zdfmix
11   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
12   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
13   !!----------------------------------------------------------------------
14#if defined key_zdfric   ||   defined key_esopa
15   !!----------------------------------------------------------------------
16   !!   'key_zdfric'                                             Kz = f(Ri)
17   !!----------------------------------------------------------------------
18   !!   zdf_ric      : update momentum and tracer Kz from the Richardson
19   !!                  number computation
20   !!   zdf_ric_init : initialization, namelist read, & parameters control
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers variables
23   USE dom_oce         ! ocean space and time domain variables
24   USE zdf_oce         ! ocean vertical physics
25   USE in_out_manager  ! I/O manager
26   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   zdf_ric         ! called by step.F90
32   PUBLIC   zdf_ric_init    ! called by opa.F90
33
34   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfric = .TRUE.   !: Richardson vertical mixing flag
35
36   !                                    !!* Namelist namzdf_ric : Richardson number dependent Kz *
37   INTEGER  ::   nn_ric   = 2            ! coefficient of the parameterization
38   REAL(wp) ::   rn_avmri = 100.e-4_wp   ! maximum value of the vertical eddy viscosity
39   REAL(wp) ::   rn_alp   =   5._wp      ! coefficient of the parameterization
40
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tmric       ! coef. for the horizontal mean at t-point
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   INTEGER FUNCTION zdf_ric_alloc()
53      !!----------------------------------------------------------------------
54      !!                 ***  FUNCTION zdf_ric_alloc  ***
55      !!----------------------------------------------------------------------
56      ALLOCATE( tmric(jpi,jpj,jpk)     , STAT=zdf_ric_alloc )
57      !
58      IF( lk_mpp             )   CALL mpp_sum ( zdf_ric_alloc )
59      IF( zdf_ric_alloc /= 0 )   CALL ctl_warn('zdf_ric_alloc: failed to allocate arrays.')
60   END FUNCTION zdf_ric_alloc
61
62
63   SUBROUTINE zdf_ric( kt )
64      !!----------------------------------------------------------------------
65      !!                 ***  ROUTINE zdfric  ***
66      !!                   
67      !! ** Purpose :   Compute the before eddy viscosity and diffusivity as
68      !!              a function of the local richardson number.
69      !!
70      !! ** Method  :   Local richardson number dependent formulation of the
71      !!              vertical eddy viscosity and diffusivity coefficients.
72      !!                The eddy coefficients are given by:
73      !!                    avm = avm0 + avmb
74      !!                    avt = avm0 / (1 + rn_alp*ri)
75      !!              with ri  = N^2 / dz(u)**2
76      !!                       = e3w**2 * rn2/[ mi( dk(ub) )+mj( dk(vb) ) ]
77      !!                   avm0= rn_avmri / (1 + rn_alp*ri)**nn_ric
78      !!      Where ri is the before local Richardson number,
79      !!            rn_avmri is the maximum value reaches by avm and avt
80      !!            avmb and avtb are the background (or minimum) values
81      !!            and rn_alp, nn_ric are adjustable parameters.
82      !!      Typical values used are : avm0=1.e-2 m2/s, avmb=1.e-6 m2/s
83      !!      avtb=1.e-7 m2/s, rn_alp=5. and nn_ric=2.
84      !!      a numerical threshold is impose on the vertical shear (1.e-20)
85      !!        N.B. the mask are required for implicit scheme, and surface
86      !!      and bottom value already set in zdfini.F90
87      !!
88      !! References : Pacanowski & Philander 1981, JPO, 1441-1451.
89      !!----------------------------------------------------------------------
90      USE wrk_nemo, ONLY: wrk_use, wrk_release
91      USE wrk_nemo, ONLY: zwx => wrk_2d_1
92      !!
93      INTEGER, INTENT( in ) ::   kt         ! ocean time-step indexocean time step
94      !!
95      INTEGER  ::   ji, jj, jk               ! dummy loop indices
96      REAL(wp) ::   zcoef, zdku, zdkv, zri, z05alp     ! temporary scalars
97      !!----------------------------------------------------------------------
98
99      IF(.NOT. wrk_use(2, 1))THEN
100         CALL ctl_stop('zdf_ric : requested workspace array unavailable.')
101         RETURN
102      END IF
103      !                                                ! ===============
104      DO jk = 2, jpkm1                                 ! Horizontal slab
105         !                                             ! ===============
106         ! Richardson number (put in zwx(ji,jj))
107         ! -----------------
108         DO jj = 2, jpjm1
109            DO ji = 2, jpim1
110               zcoef = 0.5 / fse3w(ji,jj,jk)
111               !                                            ! shear of horizontal velocity
112               zdku = zcoef * (  ub(ji-1,jj,jk-1) + ub(ji,jj,jk-1)   &
113                  &             -ub(ji-1,jj,jk  ) - ub(ji,jj,jk  )  )
114               zdkv = zcoef * (  vb(ji,jj-1,jk-1) + vb(ji,jj,jk-1)   &
115                  &             -vb(ji,jj-1,jk  ) - vb(ji,jj,jk  )  )
116               !                                            ! richardson number (minimum value set to zero)
117               zri = rn2(ji,jj,jk) / ( zdku*zdku + zdkv*zdkv + 1.e-20 )
118               zwx(ji,jj) = MAX( zri, 0.e0 )
119            END DO
120         END DO
121         CALL lbc_lnk( zwx, 'W', 1. )                       ! Boundary condition   (sign unchanged)
122
123
124         ! Vertical eddy viscosity and diffusivity coefficients
125         ! -------------------------------------------------------
126         z05alp = 0.5 * rn_alp
127         DO jj = 1, jpjm1                                   ! Eddy viscosity coefficients (avm)
128            DO ji = 1, jpim1
129               avmu(ji,jj,jk) = umask(ji,jj,jk)   &
130                  &           * rn_avmri / ( 1. + z05alp*( zwx(ji+1,jj)+zwx(ji,jj) ) )**nn_ric
131               avmv(ji,jj,jk) = vmask(ji,jj,jk)   &
132                  &           * rn_avmri / ( 1. + z05alp*( zwx(ji,jj+1)+zwx(ji,jj) ) )**nn_ric
133            END DO
134         END DO
135         DO jj = 2, jpjm1                                   ! Eddy diffusivity coefficients (avt)
136            DO ji = 2, jpim1
137               avt(ji,jj,jk) = tmric(ji,jj,jk) / ( 1. + rn_alp * zwx(ji,jj) )   &
138                  &          * (  avmu(ji,jj,jk) + avmu(ji-1, jj ,jk)        &
139                  &             + avmv(ji,jj,jk) + avmv( ji ,jj-1,jk)  )     &
140                  &          + avtb(jk) * tmask(ji,jj,jk)
141               !                                            ! Add the background coefficient on eddy viscosity
142               avmu(ji,jj,jk) = avmu(ji,jj,jk) + avmb(jk) * umask(ji,jj,jk)
143               avmv(ji,jj,jk) = avmv(ji,jj,jk) + avmb(jk) * vmask(ji,jj,jk)
144            END DO
145         END DO
146         !                                             ! ===============
147      END DO                                           !   End of slab
148      !                                                ! ===============
149      !
150      CALL lbc_lnk( avt , 'W', 1. )                         ! Boundary conditions   (unchanged sign)
151      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
152      !
153      IF(.NOT. wrk_release(2, 1))THEN
154         CALL ctl_stop('zdf_ric : failed to release workspace array.')
155      END IF
156      !
157   END SUBROUTINE zdf_ric
158
159
160   SUBROUTINE zdf_ric_init
161      !!----------------------------------------------------------------------
162      !!                 ***  ROUTINE zdfbfr_init  ***
163      !!                   
164      !! ** Purpose :   Initialization of the vertical eddy diffusivity and
165      !!      viscosity coef. for the Richardson number dependent formulation.
166      !!
167      !! ** Method  :   Read the namzdf_ric namelist and check the parameter values
168      !!
169      !! ** input   :   Namelist namzdf_ric
170      !!
171      !! ** Action  :   increase by 1 the nstop flag is setting problem encounter
172      !!----------------------------------------------------------------------
173      INTEGER :: ji, jj, jk        ! dummy loop indices
174      !!
175      NAMELIST/namzdf_ric/ rn_avmri, rn_alp, nn_ric
176      !!----------------------------------------------------------------------
177      !
178      REWIND( numnam )               ! Read Namelist namzdf_ric : richardson number dependent Kz
179      READ  ( numnam, namzdf_ric )
180      !
181      IF(lwp) THEN                   ! Control print
182         WRITE(numout,*)
183         WRITE(numout,*) 'zdf_ric : Ri depend vertical mixing scheme'
184         WRITE(numout,*) '~~~~~~~'
185         WRITE(numout,*) '   Namelist namzdf_ric : set Kz(Ri) parameters'
186         WRITE(numout,*) '      maximum vertical viscosity     rn_avmri = ', rn_avmri
187         WRITE(numout,*) '      coefficient                    rn_alp   = ', rn_alp
188         WRITE(numout,*) '      coefficient                    nn_ric   = ', nn_ric
189      ENDIF
190      !
191      !                              ! allocate zdfric arrays
192      IF( zdf_ric_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_ric_init : unable to allocate arrays' )
193      !
194      DO jk = 1, jpk                 ! weighting mean array tmric for 4 T-points
195         DO jj = 2, jpj              ! which accounts for coastal boundary conditions           
196            DO ji = 2, jpi
197               tmric(ji,jj,jk) =  tmask(ji,jj,jk)                                  &
198                  &            / MAX( 1.,  umask(ji-1,jj  ,jk) + umask(ji,jj,jk)   &
199                  &                      + vmask(ji  ,jj-1,jk) + vmask(ji,jj,jk)  )
200            END DO
201         END DO
202      END DO
203      tmric(:,1,:) = 0._wp
204      !
205      DO jk = 1, jpk                 ! Initialization of vertical eddy coef. to the background value
206         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
207         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
208         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
209      END DO
210      !
211   END SUBROUTINE zdf_ric_init
212
213#else
214   !!----------------------------------------------------------------------
215   !!   Dummy module :              NO Richardson dependent vertical mixing
216   !!----------------------------------------------------------------------
217   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfric = .FALSE.   !: Richardson mixing flag
218CONTAINS
219   SUBROUTINE zdf_ric_init         ! Dummy routine
220   END SUBROUTINE zdf_ric_init
221   SUBROUTINE zdf_ric( kt )        ! Dummy routine
222      WRITE(*,*) 'zdf_ric: You should not have seen this print! error?', kt
223   END SUBROUTINE zdf_ric
224#endif
225
226   !!======================================================================
227END MODULE zdfric
Note: See TracBrowser for help on using the repository browser.